array in type

[Ivan]

Is arrays of types also missing?

[SpriggsySpriggs]

You can have arrays of types. You just can't have arrays IN types.

[Ivan]

You can have arrays of types. You just can't have arrays IN types.

The basic i'm currently using don't have types but can have structs of arrays and can have arrays in structs, and I think I mostly can use structs like types.

Exepct that types in QB64 are more precise and more nicely listed and much easier to read.

I' in midst of programming a relational database with one to many relations using arrays with four different files.

[SpriggsySpriggs]

To me, this seems absolutely simple enough for an array in type:

Code: QB64: [Select]

1. Option _Explicit
2.  
3. Type arrTest
4.     As _MEM array
5. End Type
6.  
7. Dim As arrTest arrTest
8.  
9. Dim As Long array(1 To 3)
10.  
11. array(1) = 100
12. array(2) = 5
13. array(3) = 34
14.  
15. arrTest.array = _Mem(array())
16.  
17. Dim As Long array2(1 To Val(Str$(arrTest.array.SIZE)) / Val(Str$(arrTest.array.ELEMENTSIZE)))
18. _MemGet arrTest.array, arrTest.array.OFFSET, array2()
19. '_MemFree arrTest.array
20.  
21. Dim x
22. For x = LBound(array2) To UBound(array2)
23.     Print array2(x)
24. Next

[Ivan]

Most code I have just done seems maybe not simple, but clear. Not many days later, when i have look at the same code I think, what is going on...

I think if I dig into your code I would understand how to use it.

But I wish someting like this pseudo code in QB64:

type vector(array)
  x(array)
  y(array)
  z(array)
end type

or the basic I use (not pseudo):

dim vector_{ a(9,9,9), x(9), y(9), z(9) }

[bplus]

Here is how to do it (use variable length String Arrays instead of number arrays) in a Type.

Demo of building a Double Spiral without resort to arrays, storing all the points into a Type Variable:

Code: QB64: [Select]

1. Option _Explicit
2. _Title "Array strings in Type Demo" ' b+ 2021-06-15
3. Const xmx = 640
4. Const ymx = 640
5.  
6. Screen _NewImage(xmx, ymx, 32)
7. _Delay .25
8. _ScreenMove _Middle
9.  
10. Type points
11.     xA As String
12.     yA As String
13. End Type
14. Dim sq, s2, points, ga, scale, n
15. sq = ymx: s2 = sq / 2: points = 100: ga = 137.5
16. scale = sq * 30 / 640
17. Dim dblSpiral As points
18.  
19. ' build it into string arrays
20. For n = 1 To points
21.     'compare to xA(n) = s2 + scale * Sqr(n) * Cos(_D2R(n * ga))
22.     'compare to yA(n) = s2 + scale * Sqr(n) * Sin(_D2R(n * ga))
23.     SetLong dblSpiral.xA, n, s2 + scale * Sqr(n) * Cos(_D2R(n * ga))
24.     SetLong dblSpiral.yA, n, s2 + scale * Sqr(n) * Sin(_D2R(n * ga))
25. Next
26.  
27. ''display it
28. For n = 3 To points
29.     Line (GetLong&(dblSpiral.xA, n - 2), GetLong&(dblSpiral.yA, n - 2))-(GetLong&(dblSpiral.xA, n), GetLong&(dblSpiral.yA, n))
30. Next
31.  
32. Sub SetLong (array$, index As Long, value&) ' Luke's Method except option explicit requires mod, no variables needed for one type
33.     If Len(array$) < 4 * (index + 1) Then array$ = array$ + String$(4 * (index + 1) - Len(array$), Chr$(0))
34.     Mid$(array$, index * 4 + 1) = _MK$(Long, value&)
35. End Sub
36.  
37. Function GetLong& (array$, index As Long)
38.     GetLong& = _CV(Long, Mid$(array$, index * 4 + 1, 4))
39. End Function
40.  
41.  

Of course you could display the Double Spiral immediately but you wouldn't have the points saved for further processing.

[madscijr]

It must be time for my YEARLY or MULTI-YEARLY petition for ARRAYs in UDT!

ARRAYs IN UDTs PLEASE!

I second this motion! :-D

[madscijr]

To me, this seems absolutely simple enough for an array in type:

Two questions for you Spriggs

• Is this cross-platform? Will it work in Windows, Mac, and Linux?
• Someone mentioned it doesn't do garbage collection. If that is true, would you update your example to show how to release the array from memory when done with it?

Thanks

[SpriggsySpriggs]

@madscijr The example does show how to release it from memory. I just have it commented out. And of course it is cross-platform. It's just a regular QB64 function.

[SpriggsySpriggs]

The way that arrays are passed in Windows API from QB64 in TYPEs are always through an _Offset variable because we are passing it as a pointer in memory. What I'm showing is similar, although I'm instead passing the whole _MEM block rather than just the reference _MEM.OFFSET.

In my Task Dialog library, one passes an array of buttons in a variable called pButtons; an element of the TASKDIALOGCONFIG struct/type. The "p" in pButtons means "pointer" or, in our case, an _Offset. I pass the entire array using _Offset(btnArray()) and the Windows API handles it. I assume they are doing something similar on their end by copying the referenced memory to a newly defined array on the API side. That is why I suggested something similar for us since it works so well in all the APIs that have required an array in a struct.

[madscijr]

@madscijr The example does show how to release it from memory. I just have it commented out. And of course it is cross-platform. It's just a regular QB64 function.

Aha, thanks. I see the _MEMFREE now, not sure how that escaped my attention, maybe I need to adjust the colors on my monitor (I see it just fine on the iPhone screen!) Or maybe I just need coffee.
Either way thanks!

[xra7en]

yes, but mem requires a lot of house keeping, not user friendly
I thinking of faking an array using a string*size

Use a function similar to PHP "serialize"

https://www.php.net/manual/en/function.serialize.php

when I get time, i'll dig around in one of my libs and post it. I made a "kludgy" version as I too was disappointed at the arrays in TYPED vars. :-(

However - ALWAYS follow Spriggs tips!