array in type

[jack]

apparently arrays are not allowed in a type, that's a pity
is there a work-around for this limitation?

[SpriggsySpriggs]

Use MEM and then store the array in the MEM

[jack]

yes, but mem requires a lot of house keeping, not user friendly
I thinking of faking an array using a string*size

[SpriggsySpriggs]

Do it however you wish

[jack]

here's my attempt at a fake array

Code: QB64: [Select]

1. Type dec
2.     m As String * 50
3. End Type
4.  
5. Dim As _Unsigned Long i, j, n
6. Dim As String v
7. Dim As dec d
8.  
9. j = 1
10. For i = 1 To 12
11.     v = MKL$(i)
12.     Mid$(d.m, j, 4) = v
13.     j = j + 4
14. Next
15.  
16. j = 1
17. For i = 1 To 12
18.     n = CVL(Mid$(d.m, j, 4))
19.     j = j + 4
20.     Print i, n
21. Next
22.  

[bplus]

I've been talking about String arrays like forever!
So has Luke: https://www.qb64.org/forum/index.php?topic=1511.msg129084#msg129084

Right after that reply there is one for variable length strings.

[SpriggsySpriggs]

I fail to see how that is more elegant than MEM.

[luke]

It doesn't require initialising the men block, and (more importantly) is automatically collected by the garbage collector when it goes out of scope.

[FellippeHeitor]

I've used string arrays quite often too.

[NOVARSEG]

from https://stackoverflow.com/questions/53410020/use-an-array-in-a-user-defined-type-in-qbasic

Although you CANNOT do this in QB1.1, QB4.5, or QB64, you CAN do this in supersets of the BASIC dialect known as QB7.1(BC7/PDS), and VBDOS(v1.00):

[Cobalt]

It must be time for my YEARLY or MULTI-YEARLY petition for ARRAYs in UDT!

ARRAYs IN UDTs PLEASE!

[bplus]

It must be time for my YEARLY or MULTI-YEARLY petition for ARRAYs in UDT!

ARRAYs IN UDTs PLEASE!

What! and waste all these great work-arounds? ;-))

[jack]

thanks bplus, my example above can be simplified a bit if our simulated array index starts at 0

Code: QB64: [Select]

1. For i = 0 To 12-1
2.     v = MKL$(i)
3.     Mid$(d.m, 4 * i + 1, 4) = v
4. Next
5.  

no need for a dedicated variable for the index

[jack]

here's the start of my project, a decimal floating-point package and hence the need for array in type
I chose unsigned long for the elements because the result of multiplying two longs fits in a 64-bit integer
the code here is only the foundation, as a test it converts strings to decfloat and back, I also did a proof of concept addition

3.14159265 358979323 846264338 327950288 419716939 937510582E+00000
 3.14159265 358979323 846264338 327950288 419716939 937510582E+00000
 6.28318530 717958647 692528676 655900576 839433879 875021164E+00000

Code: QB64: [Select]

1. $Console:Only
2. _Dest _Console
3.  
4. Const NUM_DIGITS = 9 * 10
5. Const NUM_DWORDS = NUM_DIGITS \ 9
6. Const NUM_BYTES = 2 + 4 * NUM_DWORDS
7. Const BIAS = 1073741824 '2 ^ 30
8.  
9. ' Error definitions
10.  
11. Const DIVZ_ERR = 1 'Divide by zero
12. Const EXPO_ERR = 2 'Exponent overflow error
13. Const EXPU_ERR = 3 'Exponent underflow error
14.  
15. Type decfloat
16.     sign As _Unsigned Integer
17.     exponent As _Unsigned Long
18.     mantissa As String * Num_bytes
19. End Type
20.  
21. Dim As decfloat x, y
22. Dim As _Unsigned Long v, c
23. Dim As Long i
24.  
25. Dim As String pi
26. pi = "3.14159265358979323846264338327950288419716939937510582097494459"
27. pi = pi + "230781640628620899862803482534211706798214808651328230664709384"
28.  
29. Call str2dec(pi, x)
30. Call str2dec(pi, y)
31.  
32. Print dec2str(x)
33. Print dec2str(y)
34.  
35. ' =====================================================
36. ' add x + y = 2 * Pi
37.  
38. c = 0
39. For i = NUM_DWORDS - 1 To 0 Step -1
40.     v = CVL(Mid$(x.mantissa, 4 * i + 1, 4)) + CVL(Mid$(y.mantissa, 4 * i + 1, 4)) + c
41.     If v > 999999999 Then
42.         v = v - 1000000000
43.         c = 1
44.     Else
45.         c = 0
46.     End If
47.     Mid$(y.mantissa, 4 * i + 1, 4) = MKL$(v)
48. Next
49.  
50. Print dec2str(y)
51. Call RSHIFT_1(y)
52. Call LSHIFT_1(y)
53. Print "the last digit before E should be 0 due to right-shift"
54. Print dec2str(y)
55.  
56. Sub str2dec (value As String, n As decfloat)
57.     Dim As Integer j, s, d, e, ep, ex, es, i, f, fp, fln
58.     Dim As String c, f1, f2, f3, ts
59.     Dim As _Unsigned Long ulng
60.  
61.     j = 1
62.     s = 1
63.     d = 0
64.     e = 0
65.     ep = 0
66.     ex = 0
67.     es = 1
68.     i = 0
69.     f = 0
70.     fp = 0
71.     f1 = ""
72.     f2 = ""
73.     f3 = ""
74.     value = UCase$(value)
75.     fln = Len(value)
76.  
77.     While j <= fln
78.         c = Mid$(value, j, 1)
79.         If ep = 1 Then
80.             If c = " " Then
81.                 j = j + 1
82.                 GoTo skip_while
83.             End If
84.             If c = "-" Then
85.                 es = -es
86.                 c = ""
87.             End If
88.             If c = "+" Then
89.                 j = j + 1
90.                 GoTo skip_while
91.             End If
92.             If (c = "0") And (f3 = "") Then
93.                 j = j + 1
94.                 GoTo skip_while
95.             End If
96.             If (c > "/") And (c < ":") Then 'c is digit between 0 and 9
97.                 f3 = f3 + c
98.                 ex = 10 * ex + (Asc(c) - 48)
99.                 j = j + 1
100.                 GoTo skip_while
101.             End If
102.         End If
103.  
104.         If c = " " Then
105.             j = j + 1
106.             GoTo skip_while
107.         End If
108.         If c = "-" Then
109.             s = -s
110.             j = j + 1
111.             GoTo skip_while
112.         End If
113.         If c = "+" Then
114.             j = j + 1
115.             GoTo skip_while
116.         End If
117.         If c = "." Then
118.             If d = 1 Then
119.                 j = j + 1
120.                 GoTo skip_while
121.             End If
122.             d = 1
123.         End If
124.         If (c > "/") And (c < ":") Then 'c is digit between 0 and 9
125.             If ((c = "0") And (i = 0)) Then
126.                 If d = 0 Then
127.                     j = j + 1
128.                     GoTo skip_while
129.                 End If
130.                 If (d = 1) And (f = 0) Then
131.                     e = e - 1
132.                     j = j + 1
133.                     GoTo skip_while
134.                 End If
135.             End If
136.             If d = 0 Then
137.                 f1 = f1 + c
138.                 i = i + 1
139.             Else
140.                 If (c > "0") Then
141.                     fp = 1
142.                 End If
143.                 f2 = f2 + c
144.                 f = f + 1
145.             End If
146.         End If
147.         If c = "E" Then
148.             ep = 1
149.         End If
150.         j = j + 1
151.         skip_while:
152.     Wend
153.     If fp = 0 Then
154.         f = 0
155.         f2 = ""
156.     End If
157.  
158.     If s = -1 Then s = &H8000 Else s = 0
159.     n.sign = s
160.     ex = es * ex - 1 + i + e
161.     f1 = f1 + f2
162.     f1 = Mid$(f1, 1, 1) + Right$(f1, Len(f1) - 1)
163.     fln = Len(f1)
164.     If Len(f1) > ((NUM_DWORDS * 9) + 1) Then
165.         f1 = Mid$(f1, 1, ((NUM_DWORDS * 9) + 1))
166.     End If
167.     While Len(f1) < ((NUM_DWORDS * 9) + 1)
168.         f1 = f1 + "0"
169.     Wend
170.     j = 1
171.     For i = 0 To NUM_DWORDS - 1
172.         ts = Mid$(f1, j, 9)
173.         ulng = Val(ts)
174.         Mid$(n.mantissa, 4 * i + 1, 4) = MKL$(ulng)
175.         If ulng <> 0 Then fp = 1
176.         j = j + 9
177.     Next
178.     If fp Then n.exponent = (ex + BIAS + 1) Else n.exponent = 0
179. End Sub
180.  
181. Function dec2str$ (n As decfloat)
182.     Dim As Integer i, ex
183.     Dim As String v, f, ts
184.     If n.exponent > 0 Then
185.         ex = (n.exponent And &H7FFFFFFF) - BIAS - 1
186.     Else
187.         ex = 0
188.     End If
189.     If n.sign Then v = "-" Else v = " "
190.     ts = _Trim$(Str$(CVL(Mid$(n.mantissa, 4 * 0 + 1, 4))))
191.     If Len(ts) < 9 Then
192.         ts = ts + String$(9 - Len(ts), "0")
193.     End If
194.     v = v + Left$(ts, 1) + "." + Mid$(ts, 2)
195.     For i = 1 To NUM_DWORDS - 1
196.         ts = _Trim$(Str$(CVL(Mid$(n.mantissa, 4 * i + 1, 4))))
197.         If Len(ts) < 9 Then
198.             ts = String$(9 - Len(ts), "0") + ts
199.         End If
200.         v = v + ts
201.     Next
202.     f = _Trim$(Str$(Abs(ex)))
203.     f = String$(5 - Len(f), "0") + f
204.     If ex < 0 Then v = v + "E-" Else v = v + "E+"
205.     v = v + f
206.     dec2str = v
207. End Function
208.  
209. Sub RSHIFT_1 (mantissa As decfloat)
210.     Dim As _Unsigned Long v1, v2
211.     Dim As Long i
212.     For i = NUM_DWORDS - 1 To 1 Step -1
213.         v1 = CVL(Mid$(mantissa.mantissa, 4 * i + 1, 4)) \ 10
214.         v2 = CVL(Mid$(mantissa.mantissa, 4 * (i - 1) + 1, 4)) Mod 10
215.         v2 = v2 * 100000000 + v1
216.         Mid$(mantissa.mantissa, 4 * i + 1, 4) = MKL$(v2)
217.     Next
218.     Mid$(mantissa.mantissa, 4 * 0 + 1, 4) = MKL$(CVL(Mid$(mantissa.mantissa, 4 * 0 + 1, 4)) \ 10)
219. End Sub
220.  
221. Sub LSHIFT_1 (mantissa As decfloat)
222.     Dim As _Unsigned Long v1, v2
223.     Dim As Long i
224.     For i = 0 To NUM_DWORDS - 2
225.         v1 = CVL(Mid$(mantissa.mantissa, 4 * i + 1, 4)) Mod 100000000
226.         v2 = CVL(Mid$(mantissa.mantissa, 4 * (i + 1) + 1, 4)) \ 100000000
227.         Mid$(mantissa.mantissa, 4 * i + 1, 4) = MKL$(v1 * 10 + v2)
228.         Mid$(mantissa.mantissa, 4 * (i + 1) + 1, 4) = MKL$(CVL(Mid$(mantissa.mantissa, 4 * (i + 1) + 1, 4)) Mod 100000000)
229.     Next
230.     Mid$(mantissa.mantissa, 4 * (NUM_DWORDS - 1) + 1, 4) = MKL$(10 * CVL(Mid$(mantissa.mantissa, 4 * (NUM_DWORDS - 1) + 1, 4)) Mod 100000000)
231. End Sub
232.  

[jack]

instead of using the convoluted CVL, Mkl$ and Mid$ to access the memory I think using a temporary array would be far better
proof of concept
<edit> not reliable

Code: QB64: [Select]

1. Declare CustomType Library
2.     Sub memcpy (ByVal dest As _Offset, Byval source As _Offset, Byval bytes As Long)
3. End Declare
4.  
5. Type dec
6.     m As String * 46
7. End Type
8.  
9. Dim As Long i, m
10. Dim As Long a(0 To 10), b(0 To 10)
11. Dim x As dec
12.  
13. For i = 0 To 10
14.     a(i) = i * i
15. Next
16.  
17. memcpy _Offset(x.m), _Offset(a()), Len(a())
18.  
19. For i = 0 To 10
20.     m = CVL(Mid$(x.m, 4 * i + 1, 4))
21.     Print i, m
22. Next
23.  
24. memcpy _Offset(b()), _Offset(x.m), Len(b())
25.  
26. For i = 0 To 10
27.     Print i, b(i)
28. Next
29.