Swizzle

[bplus]

A quickie:

Code: QB64: [Select]

1. _Title "Swizzle" ' b+ 2021-05-29
2. Const Xmax = 600, Ymax = 600, cxy = 300, Pi = _Pi
3. Screen _NewImage(Xmax, Ymax, 32)
4. _Delay .25
5. _ScreenMove _Middle
6. Dim vScreenR(Xmax, Ymax), vScreenG(Xmax, Ymax), vScreenB(Xmax, Ymax)
7. restart:
8. r = Rnd * Rnd: g = Rnd * Rnd: b = Rnd * Rnd
9. For x = 0 To Xmax
10.     Line (x, 0)-(x, Ymax), _RGB32(128 + 128 * Sin(r * x), 128 + 128 * Sin(g * x), 128 + 128 * Sin(b * x))
11.     For y = 0 To Ymax
12.         vScreenR(x, y) = 128 + 128 * Sin(r * x)
13.         vScreenG(x, y) = 128 + 128 * Sin(g * x)
14.         vScreenB(x, y) = 128 + 128 * Sin(b * x)
15.     Next
16. Next
17. swizzle = Rnd * .5 + .8
18. _Title "Swizzle @" + _Trim$(Str$(swizzle))
19. For radius = 1 To 200
20.     For a = 0 To 2 * Pi Step 1 / (2 * Pi * radius)
21.         x = Int(cxy + radius * Cos(a))
22.         y = Int(cxy + radius * Sin(a))
23.         r = vScreenR(x, y)
24.         g = vScreenG(x, y)
25.         b = vScreenB(x, y)
26.         PSet (cxy + radius * Cos(a + radius ^ swizzle * Pi / 180), cxy + radius * Sin(a + radius ^ swizzle * Pi / 180)), _RGB32(r, g, b)
27.     Next
28. Next
29. _Delay 3
30. GoTo restart
31.  

 

[bplus]

Here's a variation:

Code: QB64: [Select]

1. _Title "Swizzle YY" ' b+ 2021-05-29
2. Const Xmax = 600, Ymax = 600, cxy = 300, Pi = _Pi
3. Screen _NewImage(Xmax, Ymax, 32)
4. _Delay .25
5. _ScreenMove _Middle
6. Dim vScreenR(Xmax, Ymax), vScreenG(Xmax, Ymax), vScreenB(Xmax, Ymax)
7.  
8. For x = 0 To Xmax
9.     If x < (.5 * Xmax) Then
10.         r = 0: g = 0: b = 0
11.     Else
12.         r = 255: g = 255: b = 255
13.     End If
14.     Line (x, 0)-(x, Ymax), _RGB32(r, g, b)
15.     For y = 0 To Ymax
16.         vScreenR(x, y) = r
17.         vScreenG(x, y) = g
18.         vScreenB(x, y) = b
19.     Next
20. Next
21. swizzle = 1.
22. _Title "Swizzle @" + _Trim$(Str$(swizzle))
23. For radius = 1 To 180
24.     For a = 0 To 2 * Pi Step 1 / (2 * Pi * radius)
25.         x = Int(cxy + radius * Cos(a))
26.         y = Int(cxy + radius * Sin(a))
27.         r = vScreenR(x, y)
28.         g = vScreenG(x, y)
29.         b = vScreenB(x, y)
30.         PSet (cxy + radius * Cos(a + radius ^ swizzle * Pi / 180), cxy + radius * Sin(a + radius ^ swizzle * Pi / 180)), _RGB32(r, g, b)
31.     Next
32. Next
33.  
34.  
35.  

Remind anybody of anything?

EDIT: adjust radius

[SMcNeill]

The picture remind me of my little screen eater demo I did a few years back, which basically simulated a black hole in the center of the screen which rotated and flushed the image on the screen down the drain.  ;)

[Dav]

Nice effect!  I just had to give it spin...

- Dav

Edit: Changed _LIMIT to 15, went too fast before.
 

Code: QB64: [Select]

1. _TITLE "Swizzle" ' b+ 2021-05-29
2. CONST Xmax = 600, Ymax = 600, cxy = 300, Pi = _PI
3. SCREEN _NEWIMAGE(Xmax, Ymax, 32)
4. _DELAY .25
5. _SCREENMOVE _MIDDLE
6. DIM vScreenR(Xmax, Ymax), vScreenG(Xmax, Ymax), vScreenB(Xmax, Ymax)
7.  
8. r = RND * RND: g = RND * RND: b = RND * RND
9. FOR x = 0 TO Xmax
10.     LINE (x, 0)-(x, Ymax), _RGB32(128 + 128 * SIN(r * x), 128 + 128 * SIN(g * x), 128 + 128 * SIN(b * x))
11.     FOR y = 0 TO Ymax
12.         vScreenR(x, y) = 128 + 128 * SIN(r * x)
13.         vScreenG(x, y) = 128 + 128 * SIN(g * x)
14.         vScreenB(x, y) = 128 + 128 * SIN(b * x)
15.     NEXT
16. NEXT
17. swizzle = RND * .5 + .8
18.  
19. FOR radius = 1 TO 200
20.     FOR a = 0 TO 2 * Pi STEP 1 / (2 * Pi * radius)
21.         x = INT(cxy + radius * COS(a))
22.         y = INT(cxy + radius * SIN(a))
23.         r = vScreenR(x, y)
24.         g = vScreenG(x, y)
25.         b = vScreenB(x, y)
26.         PSET (cxy + radius * COS(a + radius ^ swizzle * Pi / 180), cxy + radius * SIN(a + radius ^ swizzle * Pi / 180)), _RGB32(r, g, b)
27.     NEXT
28. NEXT
29.  
30. DO
31.     s& = _COPYIMAGE(_DISPLAY)
32.     RotoZoom _WIDTH / 2, _HEIGHT / 2, s&, 1, a
33.     a = a + 1: IF a >= 360 THEN a = a - 360
34.     _FREEIMAGE s&
35.     _DISPLAY: _LIMIT 15
36. LOOP UNTIL INKEY$ <> ""
37.  
38.  
39. SUB RotoZoom (X AS LONG, Y AS LONG, Image AS LONG, Scale AS SINGLE, Rotation AS SINGLE)
40.     DIM px(3) AS SINGLE: DIM py(3) AS SINGLE
41.     W& = _WIDTH(Image&): H& = _HEIGHT(Image&)
42.     px(0) = -W& / 2: py(0) = -H& / 2: px(1) = -W& / 2: py(1) = H& / 2
43.     px(2) = W& / 2: py(2) = H& / 2: px(3) = W& / 2: py(3) = -H& / 2
44.     sinr! = SIN(-Rotation / 57.2957795131): cosr! = COS(-Rotation / 57.2957795131)
45.     FOR i& = 0 TO 3
46.         x2& = (px(i&) * cosr! + sinr! * py(i&)) * Scale + X: y2& = (py(i&) * cosr! - px(i&) * sinr!) * Scale + Y
47.         px(i&) = x2&: py(i&) = y2&
48.     NEXT
49.     _MAPTRIANGLE _SEAMLESS(0, 0)-(0, H& - 1)-(W& - 1, H& - 1), Image& TO(px(0), py(0))-(px(1), py(1))-(px(2), py(2))
50.     _MAPTRIANGLE _SEAMLESS(0, 0)-(W& - 1, 0)-(W& - 1, H& - 1), Image& TO(px(0), py(0))-(px(3), py(3))-(px(2), py(2))
51. END SUB
52.  
53.  

[bplus]

Man doing copies of copies really gets raggedy with Rotozoom, I modified Dav's maybe what he was intending?

Code: QB64: [Select]

1. _Title "Swizzle Spin" ' b+ 2021-05-29 mod Dav mod b+
2. Const Xmax = 600, Ymax = 600, cxy = 300, Pi = _Pi
3. Screen _NewImage(Xmax, Ymax, 32)
4. _Delay .25
5. _ScreenMove _Middle
6. Randomize Timer
7. Dim vScreenR(Xmax, Ymax), vScreenG(Xmax, Ymax), vScreenB(Xmax, Ymax)
8. restart:
9. r = Rnd * Rnd: g = Rnd * Rnd: b = Rnd * Rnd
10. For x = 0 To Xmax
11.     Line (x, 0)-(x, Ymax), _RGB32(128 + 128 * Sin(r * x), 128 + 128 * Sin(g * x), 128 + 128 * Sin(b * x))
12.     For y = 0 To Ymax
13.         vScreenR(x, y) = 128 + 128 * Sin(r * x)
14.         vScreenG(x, y) = 128 + 128 * Sin(g * x)
15.         vScreenB(x, y) = 128 + 128 * Sin(b * x)
16.     Next
17. Next
18. swizzle = Rnd * .5 + .8
19.  
20. For radius = 1 To 200
21.     For a = 0 To 2 * Pi Step 1 / (2 * Pi * radius)
22.         x = Int(cxy + radius * Cos(a))
23.         y = Int(cxy + radius * Sin(a))
24.         r = vScreenR(x, y)
25.         g = vScreenG(x, y)
26.         b = vScreenB(x, y)
27.         PSet (cxy + radius * Cos(a + radius ^ swizzle * Pi / 180), cxy + radius * Sin(a + radius ^ swizzle * Pi / 180)), _RGB32(r, g, b)
28.     Next
29. Next
30. s& = _NewImage(Xmax * 2.2, Ymax * 2.2, 32)
31. _PutImage , 0, s&
32. Do
33.     RotoZoom cxy, cxy, s&, 1, a
34.     a = a - 3: If a < -360 Then a = 0: _FreeImage s&: GoTo restart
35.     _Display: _Limit 30
36. Loop Until InKey$ <> ""
37.  
38.  
39. Sub RotoZoom (X As Long, Y As Long, Image As Long, Scale As Single, Rotation As Single)
40.     Dim px(3) As Single: Dim py(3) As Single
41.     W& = _Width(Image&): H& = _Height(Image&)
42.     px(0) = -W& / 2: py(0) = -H& / 2: px(1) = -W& / 2: py(1) = H& / 2
43.     px(2) = W& / 2: py(2) = H& / 2: px(3) = W& / 2: py(3) = -H& / 2
44.     sinr! = Sin(-Rotation / 57.2957795131): cosr! = Cos(-Rotation / 57.2957795131)
45.     For i& = 0 To 3
46.         x2& = (px(i&) * cosr! + sinr! * py(i&)) * Scale + X: y2& = (py(i&) * cosr! - px(i&) * sinr!) * Scale + Y
47.         px(i&) = x2&: py(i&) = y2&
48.     Next
49.     _MapTriangle _Seamless(0, 0)-(0, H& - 1)-(W& - 1, H& - 1), Image& To(px(0), py(0))-(px(1), py(1))-(px(2), py(2))
50.     _MapTriangle _Seamless(0, 0)-(W& - 1, 0)-(W& - 1, H& - 1), Image& To(px(0), py(0))-(px(3), py(3))-(px(2), py(2))
51. End Sub
52.  
53.  
54.  
55.  

[johnno56]

Way cool.... Just the thing I need to see at 7:30am on a Sunday morning! Good thing I have my coffee at hand to refocus my optic nerves... LOL

Nay. Cool effect... Does it come in blue? lol

[Dav]

That's it, bplus!  Very Cool.  Yeah I wanted to get it there, but didn't know exactly how to do it.  Thanks for showing.  I'm definitely saving that one...

- Dav

[Richard Frost]

Distorting spacetime creates marbles!

[OldMoses]

This sort of thing amazes me. I am just about able to solve a right triangle with trig commands...

[Ashish]

@bplus very nice effect! I find it more beautiful when swizzle get values slightly less than 1.
One Question.. Why you have used 2D array... since the color only depends on x,  you can just make it a 1D array.

[bplus]

Very good points @Ashish here are some changes towards those points:

Code: QB64: [Select]

1. _Title "Swizzle 2" ' b+ 2021-05-30  Make use of 2D Arrays
2. Const Xmax = 600, Ymax = 600, cxy = 300, Pi = _Pi
3. Screen _NewImage(Xmax, Ymax, 32)
4. _Delay .25
5. _ScreenMove _Middle
6. Dim vScreenR(Xmax, Ymax), vScreenG(Xmax, Ymax), vScreenB(Xmax, Ymax)
7. restart:
8. r = Rnd * Rnd * .25: g = Rnd * Rnd * .25: b = Rnd * Rnd * .25
9. For x = 0 To .5 * Xmax
10.     Line (x, x)-(Xmax - x, Ymax - x), _RGB32(128 + 128 * Sin(r * x), 128 + 128 * Sin(g * x), 128 + 128 * Sin(b * x)), B
11.     For y = x To Ymax - x
12.         vScreenR(x, y) = 128 + 128 * Sin(r * x)
13.         vScreenG(x, y) = 128 + 128 * Sin(g * x)
14.         vScreenB(x, y) = 128 + 128 * Sin(b * x)
15.         vScreenR(Xmax - x, y) = 128 + 128 * Sin(r * x)
16.         vScreenG(Xmax - x, y) = 128 + 128 * Sin(g * x)
17.         vScreenB(Xmax - x, y) = 128 + 128 * Sin(b * x)
18.     Next
19.     For y = x To Xmax - x
20.         vScreenR(y, x) = 128 + 128 * Sin(r * x)
21.         vScreenG(y, x) = 128 + 128 * Sin(g * x)
22.         vScreenB(y, x) = 128 + 128 * Sin(b * x)
23.         vScreenR(Xmax - y, Ymax - x) = 128 + 128 * Sin(r * x)
24.         vScreenG(Xmax - y, Ymax - x) = 128 + 128 * Sin(g * x)
25.         vScreenB(Xmax - y, Ymax - x) = 128 + 128 * Sin(b * x)
26.     Next
27. Next
28. _Delay 1
29. swizzle = Rnd * .2 + .9
30. _Title "Swizzle @" + _Trim$(Str$(swizzle))
31. For radius = 1 To 300
32.     For a = 0 To 2 * Pi Step 1 / (2 * Pi * radius)
33.         x = Int(cxy + radius * Cos(a))
34.         y = Int(cxy + radius * Sin(a))
35.         r = vScreenR(x, y)
36.         g = vScreenG(x, y)
37.         b = vScreenB(x, y)
38.         PSet (cxy + radius * Cos(a + radius ^ swizzle * Pi / 180), cxy + radius * Sin(a + radius ^ swizzle * Pi / 180)), _RGB32(r, g, b)
39.     Next
40. Next
41. _Delay 3
42. GoTo restart
43.  
44.  
45.  

[bplus]

I tried an image of Picasso:

Code: QB64: [Select]

1. _Title "Swizzle Image" ' b+ 2021-05-30  Make use of 2D Arrays
2. Const Xmax = 600, Ymax = 600, cxy = 300, Pi = _Pi
3. Screen _NewImage(Xmax, Ymax, 32)
4. _Delay .25
5. _ScreenMove _Middle
6. Randomize Timer
7. Dim As _Unsigned Long vScreen(Xmax, Ymax)
8. p& = _LoadImage("Picasso.PNG")
9. restart:
10. r = .0041: g = .001: b = .0072 ' <<<<<<<<<<<<<<< adjust as needed
11. For x = 0 To .5 * Xmax
12.     Line (x, x)-(Xmax - x, Ymax - x), _RGB32(128 - 64 * Sin(r * x), 64 - 64 * Sin(g * x), 128 - 64 * Sin(b * x)), B
13. Next
14. _PutImage ((_Width - _Width(p&)) / 2, (_Height - _Height(p&)) / 2)-Step(_Width(p&), _Height(p&)), p&, 0
15. For y = 0 To Ymax
16.     For x = 0 To Xmax
17.         vScreen(x, y) = Point(x, y)
18.     Next
19. Next
20. _Delay 2
21. swizzle = .85
22. _Title "Swizzle @" + _Trim$(Str$(swizzle))
23. For radius = 1 To 300
24.     For a = 0 To 2 * Pi Step 1 / (2 * Pi * radius)
25.         x = Int(cxy + radius * Cos(a))
26.         y = Int(cxy + radius * Sin(a))
27.         PSet (cxy + radius * Cos(a + radius ^ swizzle * Pi / 180), cxy + radius * Sin(a + radius ^ swizzle * Pi / 180)), vScreen(x, y)
28.     Next
29. Next
30. Sleep
31.  
32.  
33.  

[Ashish]

@bplus woah! amazing work! :D