How to fill number (string) with previous 0 (zeros)

[MarcoPajotter]

Hello,

And yes I have a new question,

I'm numbering a list, from 0 ... 100, and I like this line numbers as "0001" ... "0100" and not "1" ... "100"

Q) How can I fill the string with previous zero's in front of the "1" to show it as "0001"

I already did this:

Code: QB64: [Select]

1. COMMON SHARED MyNumberValue AS LONG
2. COMMON SHARED MyNumberString AS STRING * 8
3.  
4. LET MyNumberValue = 1
5.  
6. LET MyNumberString = "00000000"
7. RSET MyNumberString = LTRIM$ ( RTRIM$ ( STR$ (MyNumberValue)))
8.  
9. PRINT MyNumberString
10. PRINT "00000001"
11.  

But this is not showing the good result ...

Thanks,
Marco

[FellippeHeitor]

Code: QB64: [Select]

1. Print zeropad$(1, 8)
2.  
3. Function zeropad$ (number&, length&)
4.     zeropad$ = Right$(String$(length&, "0") + LTrim$(Str$(number&)), length&)
5. End Function

[zaadstra]

Something like this?

Code: QB64: [Select]

1. FOR i = 1 TO 100
2.    numberstring$ = MID$(STR$(10000 + i), 3)
3.    PRINT "'"; numberstring$; "'"
4. NEXT
5.  

Printed with quoutes to show there are no spaces in the strings.

[NOVARSEG]

Slight mod

DIM Digits AS INTEGER
DIM i AS _UNSIGNED LONG

Digits = 4


FOR i = 0 TO 10 ^ Digits - 1

    numberstring$ = RIGHT$(STR$(10 ^ Digits + i), Digits)

    PRINT "'"; numberstring$; "'"
NEXT i

Max digits = 6.  If more than 6 digits, the output goes exponent notation ?

[NOVARSEG]

This one works better.


DIM Digits AS INTEGER
DIM i AS _UNSIGNED LONG
DIM Base10 AS _UNSIGNED LONG
Digits = 7
Base10 = 10

FOR i = 0 TO 10 ^ Digits - 1

    numberstring$ = RIGHT$(STR$(Base10 ^ Digits + i), Digits)

    PRINT "'"; numberstring$; "'"
NEXT i

[SMcNeill]

Digits = 7
FOR i = 1 TO 100
    numberstring$ = RIGHT$(“0000000000000000000000000” + _TRIM$(STR$(i)), Digits)
    PRINT numberstring$
    IF i MOD 20 = 0 THEN SLEEP
NEXT i

Good for as many digits as an _INTEGER64 can contain.  Just change the value of Digits.

[NOVARSEG]

With _INTEGER64  the max digits is 18?

DIM i AS _INTEGER64
DIM Digits AS INTEGER

Digits = 18

FOR i = 0 TO 10 ^ Digits - 1
    numberstring$ = RIGHT$(STRING$(Digits, "0") + _TRIM$(STR$(i)), Digits)
    PRINT numberstring$
    IF i MOD 20 = 0 THEN SLEEP
NEXT i

Hey that's a neat trick i MOD 20 = 0 !

[MarcoPajotter]

Thanks everyone,

It works well, and I need some time now to make the good choice ...

And thanks for the quick responses.
 
Marco