Author Topic: Problem to print values on the axis inside and outside WINDOW. (Read 6406 times)

bartok · « **on:** February 20, 2021, 05:56:41 am »

Hi,
I have a problem and I don't find a solution.
Launching the code, press 1 or 2, and then any key at time.
In the ordinate is drawn a notch every X mc/s.

Given this notch, the target is to print the corresponding value on the axis. The problem is just to print it in the right position.
In the code below, we have to see the subroutine "grafici": lines 302 to 385, but the core of the problem is in lines 365 (inside the command WINDOW) and 374 (outside).

I have thought to print the value with che command _PRINTSTRING. At the moment there is no value, but the string "-". _PRINTSTRING, unfortunately, doesn't use the local coordinates of WINDOW (line 333), but always the general coordinates in pixels of the screen in use (line 331). So, in order to use _PRINTSTRING, the idea was to transform (line 365 and 374) the general coordinates of _PRINTSTRING, into the local coordinates of WINDOW by using fx! and fy!: lines 323-328.

But, as we can see launching the code, there is no way in order to have the strings "-" to fit and match the notches, also introducing a parameter k! (line 362) to do so. In any way, the strings "-" are ot of phase with the notches. The solution is not to use double precision variables for the transformation between coordinates.

So how we can print the values on the axis? I never thought that the problem was this!

Code: QB64: [Select]

OPTION BASE 1
 
mockus: 'dati dell'idrogramma unitario di Mockus
DATA 0.1,0.2,0.3,0.4,0.5,0.6,0.7,0.8,0.9,1,1.1,1.2,1.3,1.4,1.5,1.6,1.7,1.8,1.9,2,2.1,2.2,2.3,2.4,2.5,2.6,2.7,2.8,2.9,3,3.1,3.2,3.3,3.4,3.5,3.6,3.7,3.8,3.9,4,4.1,4.2,4.3,4.4,4.5,4.6,4.7,4.8,4.9,5: 't/ta
DATA 0.030,0.100,0.190,0.310,0.470,0.660,0.820,0.930,0.990,1.000,0.990,0.930,0.860,0.780,0.680,0.560,0.460,0.390,0.330,0.280,0.244,0.207,0.177,0.147,0.127,0.107,0.092,0.077,0.066,0.055,0.048,0.040,0.035,0.029,0.025,0.021,0.018,0.015,0.013,0.011,0.009,0.008,0.007,0.006,0.006,0.005,0.004,0.003,0.001,0.000: ' t/tp
 
coefficienti:
DATA 1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16,18,20,22,24,26,28,30,32: 'N volte tc!.
DATA 0.1,0.1,0.1,0.2,0.3,0.2,0.3,0.3,0.5,0.5,0.5,0.5,0.5,0.5,0.5,0.5,1,1,1,1,1,1,1,1: 'discretizzazione dei coeff. di Mockus.
 
TYPE mockus
    MOCKUStSUta AS SINGLE
    MOCKUSqSUqp AS SINGLE
END TYPE
 
TYPE matrice1
    m AS INTEGER '[numero naturale] conta il numero di interazioni fino al raggiungimento di "d".
    mdt AS SINGLE '[ore] conta la progessione delle ore fino al raggiungimento di "d".
    tminuti AS SINGLE '[minuti] trasforma mdt in minuti.
    h1 AS SINGLE '[mm] valore h della curva di possibilità climatica.
    i1 AS SINGLE '[mm/ora] intensità di pioggia.
    i2 AS SINGLE '[mm/ora] intensità di pioggia secondo lo ietogramma Chicago o costante.
    DH AS SINGLE '[mm] pioggia in ogni istante temporale dt.
    H2 AS SINGLE '[mm] pioggia cumulata ad ogni istante temporale.
    he AS SINGLE '[mm] piggia efficace cumulata ad ogni istante temporale.
    Dhe AS SINGLE '[mm] pioggia efficace ad ogni istante temporale.
    MOCKUStSUta AS SINGLE
    MOCKUSqSUqp AS SINGLE
    tmSUta AS SINGLE '[-].
    qmSUqp AS SINGLE '[-] il valore di qm/qp corrispondente a tm/ta e' = al valore di q/qp che corrisponde a t/ta=tm/ta.
    qm AS SINGLE '[mc/s].
END TYPE
 
TYPE coefficienti
    d AS SINGLE
    tSUta AS SINGLE
END TYPE
 
TYPE idrogramma
    ore AS SINGLE
    minuti AS SINGLE
    portata AS SINGLE
END TYPE
 
CONST limit = 200 '50
 
DIM schermo&
 
DIM SHARED mockus(50) AS mockus
DIM SHARED dt!(2, 24)
DIM SHARED matrice1(2, 24, 50, 1) AS matrice1
DIM SHARED coefficienti(24) AS coefficienti
DIM SHARED matrice2!(2, 24, 50, 50)
DIM SHARED idrogramma(2, 24, 50, 1) AS idrogramma
DIM SHARED massimi1(2, 24, 1) AS idrogramma
DIM SHARED massimi2(2) AS idrogramma
DIM SHARED i%, n%, z%, ieto%
DIM SHARED m%(2, 24)
DIM SHARED S2! '[mm] contenuto idrico massimo del terreno.
DIM SHARED Ia! '[mm] perdite iniziali.
DIM SHARED tc! '[ore] tempo di corrivazione
DIM SHARED ta! '[ore] tempo di picco.
DIM SHARED qp! '[mc/s] portata al colmo dell'idrogramma unitario.
DIM SHARED k! '[-] coeff. della curva di possibilità climatica tado dal sito della Regione.
DIM SHARED a2! '[mm/d^n] coeff. della curva di possibilità climatica.
DIM SHARED n1! '[-] coeff. della curva di possibilità climatica.
DIM SHARED visualizzaieto%
DIM A1! '[mq] superficie bacino idrografico.
DIM L! '[m] lunghezza asta principale.
DIM HmaxL! '[m] punto più alto dell'astra principale.
DIM HminL! '[m] punto più basso dell'asta principale.
DIM s1! '[-] pendenza media del bacino non espressa in percentuale ma come 0,x.
DIM CNII! '[-] tabellato.
DIM CNIII '[-] discende da CNII.
DIM tl! '[ore] tempo di ritardo.
DIM keypress$
 
schermo& = _NEWIMAGE(_DESKTOPWIDTH, _DESKTOPHEIGHT, 32)
SCREEN schermo&
_SCREENMOVE 0, 0
 
A1! = 2641902
k! = 2.34
a2! = 14.6653
n1! = 0.45596
L! = 3300
HmaxL! = 1981
HminL! = 1062
s1! = 0.415
CNII! = 70
 
'INPUT A1!
'INPUT k!
'INPUT a2!
'INPUT n1!
'INPUT L!
'INPUT HmaxL!
'INPUT HminL!
'INPUT s1!
'INPUT CNII!
'INPUT d1!
 
CNIII! = (23 * CNII!) / (10 + 0.13 * CNII!)
tl! = 0.342 * ((L! / 1000) ^ 0.8 / (100 * s1!) ^ 0.5) * (1000 / CNIII! - 9) ^ 0.7 'formula di Mockus.
S2! = 25.4 * (1000 / CNIII! - 10)
Ia! = 0.1 * S2! 'coeff.=0.03-0.2.
tc! = tl! / 0.6
ta! = tl! / 0.9
qp! = 0.208 * ((A1! / 1000000) / ta!)
 
RESTORE mockus
FOR i% = 1 TO 100
    IF i% <= 50 THEN READ mockus(i%).MOCKUStSUta
    IF i% > 50 THEN READ mockus(i% - 50).MOCKUSqSUqp
NEXT i%
 
RESTORE coefficienti
FOR i% = 1 TO 48
    IF i% <= 24 THEN READ coefficienti(i%).d: coefficienti(i%).d = coefficienti(i%).d * tc!
    IF i% > 24 THEN READ coefficienti(i% - 24).tSUta
NEXT i%
 
CLS
PRINT "Ietogramma Chicago/costante: 1/2> "
DO
    _LIMIT 60 'limit
    keypress$ = INKEY$
LOOP UNTIL keypress$ = "1" OR keypress$ = "2"
visualizzaieto% = VAL(keypress$)
 
FOR ieto% = 1 TO 2
    CALL creamatrici
NEXT ieto%
 
CLS
CALL grafici(massimi1(visualizzaieto%, 24, 1).ore, massimi2(visualizzaieto%).ore, massimi2(visualizzaieto%).portata) 'valori passati per disegnare il grafico.
SLEEP
 
'CALL risultati
 
'-----------------------------------------matrice1---------------------------------------------------------------------------------------------------------------------------------
SUB creamatrici ()
    z% = 0
    DO
        z% = z% + 1
        dt!(ieto%, z%) = coefficienti(z%).tSUta * ta!
        m%(ieto%, z%) = coefficienti(z%).d / (coefficienti(z%).tSUta * ta!) 'determina il numero di passi temporali necessari ad arrivare allla durata d considerata con il paso temporale dt!.
        FOR i% = 1 TO 50
            matrice1(ieto%, z%, i%, 1).MOCKUStSUta = mockus(i%).MOCKUStSUta
            matrice1(ieto%, z%, i%, 1).MOCKUSqSUqp = mockus(i%).MOCKUSqSUqp
            matrice1(ieto%, z%, i%, 1).m = i%
            matrice1(ieto%, z%, i%, 1).mdt = matrice1(ieto%, z%, i%, 1).m * dt!(ieto%, z%)
            matrice1(ieto%, z%, i%, 1).tminuti = matrice1(ieto%, z%, i%, 1).mdt * 60
            SELECT CASE (_ROUND(10 * (i% * coefficienti(z%).tSUta))) / 10 'crea il vettore dell'idrogramma unitario di Mockus con i multipli del coeff. z% considerato (0.1,0.2,0.3,0.5,1).
                CASE IS <= 5 'valore massimo di t/ta di Mockus
                    matrice1(ieto%, z%, i%, 1).tmSUta = (_ROUND(10 * (i% * coefficienti(z%).tSUta))) / 10 '=matrice1(i%).m *  matrice1(i%).mdt / ta!
                CASE ELSE
                    matrice1(ieto%, z%, i%, 1).tmSUta = 0
            END SELECT
        NEXT i%
        FOR i% = 1 TO 50
            n% = 1
            DO 'crea il vettore dell'idrogramma unitario Mockus prendendo i valori corrispondenti di ai coefficienti.
                IF matrice1(ieto%, z%, i%, 1).tmSUta = matrice1(ieto%, z%, n%, 1).MOCKUStSUta THEN
                    matrice1(ieto%, z%, i%, 1).qmSUqp = matrice1(ieto%, z%, n%, 1).MOCKUSqSUqp
                    EXIT DO
                ELSE
                    n% = n% + 1
                END IF
            LOOP UNTIL n% = 50
            matrice1(ieto%, z%, i%, 1).qm = matrice1(ieto%, z%, i%, 1).qmSUqp * qp!
        NEXT i%
        FOR i% = 1 TO m%(ieto%, z%)
            matrice1(ieto%, z%, i%, 1).h1 = k! * a2! * matrice1(ieto%, z%, i%, 1).mdt ^ n1!
            IF i% = 1 THEN
                matrice1(ieto%, z%, i%, 1).i1 = matrice1(ieto%, z%, i%, 1).h1 / dt!(ieto%, z%)
            ELSE
                matrice1(ieto%, z%, i%, 1).i1 = (matrice1(ieto%, z%, i%, 1).h1 - matrice1(ieto%, z%, i% - 1, 1).h1) / dt!(ieto%, z%)
            END IF
        NEXT i%
        SELECT CASE ieto%
            CASE 1 'Chicago.
                CALL chicago
            CASE 2 'costante
                FOR i% = 1 TO m%(ieto%, z%)
                    matrice1(ieto%, z%, i%, 1).i2 = matrice1(ieto%, z%, m%(ieto%, z%), 1).h1 / matrice1(ieto%, z%, m%(ieto%, z%), 1).mdt
                NEXT i%
        END SELECT
        FOR i% = 1 TO m%(ieto%, z%)
            matrice1(ieto%, z%, i%, 1).DH = matrice1(ieto%, z%, i%, 1).i2 * dt!(ieto%, z%)
            IF i% = 1 THEN
                matrice1(ieto%, z%, i%, 1).H2 = matrice1(ieto%, z%, i%, 1).DH
            ELSE
                matrice1(ieto%, z%, i%, 1).H2 = matrice1(ieto%, z%, i%, 1).DH + matrice1(ieto%, z%, i% - 1, 1).H2
            END IF
            SELECT CASE matrice1(ieto%, z%, i%, 1).H2 - Ia!
                CASE IS < 0
                    matrice1(ieto%, z%, i%, 1).he = 0
                CASE IS >= 0
                    matrice1(ieto%, z%, i%, 1).he = (matrice1(ieto%, z%, i%, 1).H2 - Ia!) ^ 2 / (matrice1(ieto%, z%, i%, 1).H2 - Ia! + S2!)
            END SELECT
            IF i% = 1 THEN
                matrice1(ieto%, z%, i%, 1).Dhe = matrice1(ieto%, z%, i%, 1).he
            ELSE
                matrice1(ieto%, z%, i%, 1).Dhe = matrice1(ieto%, z%, i%, 1).he - matrice1(ieto%, z%, i% - 1, 1).he
            END IF
        NEXT i%
 
        '-------------------------------matrice2-------------------------------------------------------------------------------------------------------------------------
 
        FOR n% = 1 TO 50 'colonna
            FOR i% = n% TO 50 ' riga
                matrice2!(ieto%, z%, i%, n%) = matrice1(ieto%, z%, i% - n% + 1, 1).Dhe * matrice1(ieto%, z%, n%, 1).qm
            NEXT i%
        NEXT n%
        '-------------------------------idrogramma------------------------------------------------------------------------------------------------------------------
        FOR i% = 1 TO 50 'riga
            FOR n% = 1 TO 50 'colonna
                idrogramma(ieto%, z%, i%, 1).portata = idrogramma(ieto%, z%, i%, 1).portata + matrice2!(ieto%, z%, i%, n%)
 
            NEXT n%
            idrogramma(ieto%, z%, i%, 1).ore = matrice1(ieto%, z%, i%, 1).mdt
            idrogramma(ieto%, z%, i%, 1).minuti = matrice1(ieto%, z%, i%, 1).tminuti
        NEXT i%
        '-------------------------------Massimi-----------------------------------------------------
        i% = 1
        'massimi1(ieto%, z%, 1).portata = idrogramma(ieto%, z%, 1, 1).portata
        DO
            IF massimi1(ieto%, z%, 1).portata < idrogramma(ieto%, z%, i%, 1).portata THEN
                massimi1(ieto%, z%, 1).portata = idrogramma(ieto%, z%, i%, 1).portata
                massimi1(ieto%, z%, 1).ore = idrogramma(ieto%, z%, i%, 1).ore
                massimi1(ieto%, z%, 1).minuti = idrogramma(ieto%, z%, i%, 1).minuti
            END IF
            i% = i% + 1
        LOOP UNTIL i% = 50
        ' IF massimi2(ieto%).ore < massimi1(visualizzaieto%, z%, 1).ore THEN massimi2(ieto%).ore = massimi1(visualizzaieto%, z%, 1).ore
        IF massimi2(ieto%).portata < massimi1(visualizzaieto%, z%, 1).portata THEN
            massimi2(ieto%).portata = massimi1(visualizzaieto%, z%, 1).portata
            massimi2(ieto%).ore = massimi1(visualizzaieto%, z%, 1).ore
        END IF
    LOOP UNTIL z% = UBOUND(coefficienti)
END SUB
'---------------------------------------------------------------------------------------------------------------------------------------------------
'Questa subroutine crea gli ietogrammi chicago per ogni iterazione z%.
'Ad ogni nuovo dt! pone l'ultimo valore di pioggia come ultimo, il penultimo come primo, il terzultimo come penultimo, il quartultimo come secondo e così via.
'Quando vi è un valore di z% che ha un dt! non nuovo, cerca la precedente iterazione z% con lo stesso dt! e copia i suoi valori dello ietogramma chicago in quello dell'iterazione z% in corso. I valori rimanenti sono riempiti
'procedendo come prima.
'Quindi per esempio l'iterazione z%=1 corrisponde a d=1tc con passo temporale dt!. L'iterazione z%=2 corrisponde a d=2tc con il medesimo passo temporale. Per cui lo ietogramma chicago per d=2tc e' dato dallo stesso ietogramma
'chicago che si ha per d=1tc, con l'aggiunta, ai suoi estremi, dei nuovi valori. Il meccanismo si ripete per z%=3, che corrisponde a d=3tc, con il medesimo dt!. Per z%=4, corrispondente a d=4tc, invece, il passo temporale dt!
'cambia.
'Quanto detto e' necessario per evitare piccole discrepanze che potrebbero comportare il fatto che alcuni massimi risultino localmente poco piu' bassi del precedente, anche quando il trend generale e' chiaramente di aumento dei
'massimi all'aumentare della durata della pioggia. In questo modo si fa l'ipotesi che all'aumentare della durata della pioggia, discretizzata con uno stesso passo temporale dt!, ogni ietogramma contenga a sua volta il precedente.
'In tal modo, se si condiera per esempio d=2tc, si assume che l'altezza di pioggia corrispondente a 1tc, segua lo ietogramma relativo a d=1tc, cosi' che l'altezza di pioggia rimamente sia eclusivamente dovuta ai nuovi valori.
SUB chicago ()
    DIM test%
    DIM k%
    n% = 1
    DO
        IF z% = 1 THEN test% = 0: EXIT DO 'permette il calcolo dello ietogramma chicago della prima iterazione. test%=0
        IF dt!(ieto%, z%) = dt!(ieto%, z% - n%) THEN ' se trova un'iterazione z% precedente con lo stesso dt! di quella in corso, esegue i comandi successivi
            test% = 1
            k% = m%(ieto%, z%)
            i% = 0
            DO 'inserisce i nuovi valori dello ietogramma chicago dell'iterazione z% in corso.
                matrice1(ieto%, z%, m%(ieto%, z%) - i%, 1).i2 = matrice1(ieto%, z%, k%, 1).i1
                k% = k% - 1
                IF k% = m%(ieto%, z% - n%) THEN EXIT DO 'se ha completato l'inserimento dei nuovi valori, passa oltre.
                matrice1(ieto%, z%, i% + 1, 1).i2 = matrice1(ieto%, z%, k%, 1).i1
                k% = k% - 1
                i% = i% + 1
            LOOP UNTIL k% = m%(ieto%, z% - n%)
            IF matrice1(ieto%, z%, i%, 1).i2 = 0 THEN i% = i% - 1
            k% = 1
            DO 'inserisce lo ietogramma chicago dell'iterazione z% precedente con lo stesso dt!, nello ietogramma dell'iterazione z% in corso.
                i% = i% + 1
                matrice1(ieto%, z%, i%, 1).i2 = matrice1(ieto%, z% - n%, k%, 1).i2
                k% = k% + 1
            LOOP UNTIL k% > m%(ieto%, z% - n%)
            EXIT DO 'siccome ha completato lo ietogramma dell'iterazione z% in corso, non serve incrementare n%, quindi passa oltre. test%=1.
        ELSE ' se non trova l'iterazione z% precedente con lo stesso dt! di quella in corso, incrementa n% e ripete la ricerca.
            test% = 0
            n% = n% + 1
        END IF
    LOOP UNTIL n% = z% - 1 'se non ha trovato iterazioni z% precedenti con lo stesso dt!, allora passa oltre e test%=0.
    SELECT CASE test%
        CASE IS = 1 'esce dalla subroutine, in quanto lo ietogramma e' definito.
            EXIT SUB
        CASE IS = 0 'calcola ex-novo lo ietogramma relativo all'iterazione z% in corso in quanto non vi e' un'iterazioni z% precedente con lo stesso dt! dell'iterazione z% in corso.
            k% = m%(ieto%, z%)
            i% = 0
            DO
                matrice1(ieto%, z%, m%(ieto%, z%) - i%, 1).i2 = matrice1(ieto%, z%, k%, 1).i1
                k% = k% - 1
                IF k% = 0 THEN EXIT DO
                matrice1(ieto%, z%, i% + 1, 1).i2 = matrice1(ieto%, z%, k%, 1).i1
                k% = k% - 1
                i% = i% + 1
            LOOP UNTIL k% = 0
    END SELECT
END SUB
'-----------------------------------------------------------------------------------------------------------------------------------------------------------------
SUB grafici (ore!, oreM!, QM!)
    'ore!: ore massime di analisi.
    'oreM!: ore corrispondenti alla portata massima.
    'QM!: portata massima.
 
    CONST dxy% = 30
    CONST L% = 800
    CONST H% = 600
 
    ' CONST LH! = L% / H% 'costante che, all'interno del comando WINDOW, di portare la scala delle ordinate uguale a quella delle ascisse.
    CONST rosso = _RGB32(255, 0, 0)
    CONST bianco = _RGB32(255, 255, 255)
    CONST giallo = _RGB32(255, 255, 0)
 
    DIM grafico&
    DIM fx! 'all'interno del comando WINDOW e VIEW permette di disegnare in pixel sull'asse x e nelle circonferenze.
    DIM fy! 'all'interno del comando WINDOW e VIEW permette di disegnare in pixel sull'asse y.
    DIM dx!, dy!
    DIM tacca%
    DIM k%
 
    grafico& = _NEWIMAGE(L%, H%, 32)
    fx! = L% / (ore! * 1.1) '=168.3349 'pixel/ora
    fy! = H% / (QM! * 1.1) '=23.3657 'pixel/mc
    dx! = dxy% / fx! '=0.1782162:dx! e' la lunghezza dentro WINDOWS per avere un numero di pixel=dxy%.
    dy! = dxy% / fy! '=1.283933
    tacca% = QM! \ 5
 
    _DEST grafico&
    SCREEN grafico&
    LINE (0, 0)-(L% - 1, H% - 1), rosso, B
    WINDOW (0, 0)-(ore! * 1.1 + dx!, QM! * 1.1 + dy!) 'scala ascisse e ordinate in base alle ore e alla portata, estendendole del 10%.
    LINE (dx!, QM! * 1.1)-(dx!, dy!): LINE -(ore! * 1.1, dy!), bianco
    PSET (dx!, QM! * 1.1!), bianco: DRAW "F20": PSET (dx!, QM! * 1.1), bianco: DRAW "G20" ': LOCATE 7, 65: PRINT "y"
    PSET (ore! * 1.1, dy!), bianco: DRAW "G20": PSET (ore! * 1.1, dy!), bianco: DRAW "H20" ': LOCATE 25, 112: PRINT "x"
    FOR z% = 1 TO 24
        CIRCLE (dx! + massimi1(visualizzaieto%, z%, 1).ore, dy! + massimi1(visualizzaieto%, z%, 1).portata), 3 / fx!, rosso
        PAINT (dx! + massimi1(visualizzaieto%, z%, 1).ore + 0.5 / fx!, dy! + massimi1(visualizzaieto%, z%, 1).portata + 0.5 / fx!), rosso
        IF z% = 1 THEN
            LINE (dx!, dy!)-(dx! + massimi1(visualizzaieto%, z%, 1).ore, dy! + massimi1(visualizzaieto%, z%, 1).portata), rosso
        ELSE
            LINE (dx! + massimi1(visualizzaieto%, z% - 1, 1).ore, dy! + massimi1(visualizzaieto%, z% - 1, 1).portata)-(dx! + massimi1(visualizzaieto%, z%, 1).ore, dy! + massimi1(visualizzaieto%, z%, 1).portata), rosso
        END IF
        IF z% = 24 THEN
            SELECT CASE visualizzaieto%
                CASE IS = 1
                    LINE -(dx!, dy! + massimi1(visualizzaieto%, z%, 1).portata), bianco, , 61440
                    LINE (dx! + massimi1(visualizzaieto%, z%, 1).ore, dy! + massimi1(visualizzaieto%, z%, 1).portata)-(dx! + massimi1(visualizzaieto%, z%, 1).ore, dy!), bianco, , 61440
                CASE IS = 2
                    LINE (dx! + massimi1(visualizzaieto%, z%, 1).ore, dy! + massimi1(visualizzaieto%, z%, 1).portata)-(dx! + massimi1(visualizzaieto%, z%, 1).ore, dy!), bianco, , 61440
            END SELECT
        END IF
    NEXT z%
    IF visualizzaieto% = 2 THEN
        LINE (dx!, dy! + QM!)-(dx! + oreM!, dy! + QM!), bianco, , 61440
        LINE -(dx! + oreM!, dy!), bianco, , 61440
    END IF
    ' _PRINTSTRING (L% \ 2, H% \ 2), "O" '_PRINTSTRING non usa le coordinate locali di VIEW, ma sempre quello dello SCREEN in uso. Per tal ragione e' stato necessario creare grafico&.
    SLEEP
    i% = 1
    k! = 0.98
    WHILE i% * tacca% <= QM!
        LINE (dx! - 5 / fx!, dy! + i% * tacca%)-(dx! + 5 / fx!, dy! + i% * tacca%): SLEEP
        _PRINTSTRING (dx! * fx! - 20, H% - 1 - (dy! + i% * tacca%) * fy! * k!), "-": SLEEP
        i% = i% + 1
    WEND
    WINDOW
    i% = 1
    '  k! = 1
    WHILE i% * tacca% <= QM!
        '   LINE (dxy% - 1 - 5, H% - 1 - (dy! + i% * tacca%) * fy! * k!)-(dxy% - 1 + 1000, H% - 1 - (dy! + i% * tacca%) * fy! * k!), giallo: SLEEP
        '   PRINT (dy! + i% * tacca%) * fy!: SLEEP
        _PRINTSTRING (dx! * fx! - 20, H% - 1 - (dy! + i% * tacca%) * fy! * k!), "--": SLEEP
        i% = i% + 1
    WEND
    ' k% = i% * tacca%
    'i% = 1
    'WHILE i% <= ore!
    '    _PRINTSTRING (dxy%, H% - 1 - (dxy% + i% * k%)), "-"
    'i% = i% + 1
    'WEND
    '  _PUTIMAGE ((_DESKTOPWIDTH - L%) \ 2, (_DESKTOPHEIGHT - H%) \ 2), grafico&, schermo&
    '   _FREEIMAGE grafico&
END SUB
'------------------------------------------------------------------------------------------------------------------------------------------------------------------------------
SUB risultati ()
    FOR z% = 1 TO 24
        CLS
        PRINT "z%="; z%
        PRINT "dt="; dt!(visualizzaieto%, z%); ";"; dt!(visualizzaieto%, z%) * 60
        PRINT "visualizzaieto%="; visualizzaieto%
        PRINT "m%="; m%(visualizzaieto%, z%)
        PRINT "N="; coefficienti(z%).d / tc!
        PRINT "n="; coefficienti(z%).tSUta
        FOR i% = 1 TO 50
            '  _LIMIT limit
    PRINT _TRIM$(STR$(matrice1(visualizzaieto%,z%,i%, 1).m)), _TRIM$(STR$(matrice1(visualizzaieto%,z%,i%, 1).mdt)), _TRIM$(STR$(matrice1(visualizzaieto%,z%,i%, 1).tminuti)), _TRIM$(STR$(matrice1(visualizzaieto%,z%,i%, 1).h1)),_
     _TRIM$(STR$(matrice1(visualizzaieto%,z%,i%, 1).i1)),_TRIM$(STR$(matrice1(visualizzaieto%,z%,i%, 1).i2)),_TRIM$(STR$(matrice1(visualizzaieto%,z%,i%, 1).DH)), _TRIM$(STR$(matrice1(visualizzaieto%,z%,i%, 1).H2)),_
      _TRIM$(STR$(matrice1(visualizzaieto%,z%,i%, 1).he)),_TRIM$(STR$(matrice1(visualizzaieto%,z%,i%, 1).Dhe)),_TRIM$(STR$(matrice1(visualizzaieto%,z%,i%, 1).MOCKUStSUta)),_
       _TRIM$(STR$(matrice1(visualizzaieto%,z%,i%, 1).MOCKUSqSUqp)),_TRIM$(STR$(matrice1(visualizzaieto%,z%,i%, 1).tmSUta)), _TRIM$(STR$(matrice1(visualizzaieto%,z%,i%, 1).qmSUqp)),_TRIM$(STR$(matrice1(visualizzaieto%,z%,i%, 1).qm))
        NEXT i%
        SLEEP
        CLS
        FOR n% = 1 TO 50
            '  _LIMIT limit
            LOCATE 1,
            FOR i% = 1 TO 50
                LOCATE , n% * 4 - 3
                PRINT matrice2!(visualizzaieto%, z%, i%, n%)
            NEXT i%
        NEXT n%
        SLEEP
    NEXT z%
    CLS
    FOR n% = 1 TO 24
        ' _LIMIT limit
        SELECT CASE n%
            CASE IS <= 16
                FOR i% = 1 TO 50
                    LOCATE i%, n% * 15 - 14
                    PRINT _TRIM$(STR$(idrogramma(visualizzaieto%, n%, i%, 1).portata))
                    'PRINT _TRIM$(STR$(idrogramma(visualizzaieto%, n%, i%, 1).ore))
                    'PRINT _TRIM$(STR$(idrogramma(visualizzaieto%, n%, i%, 1).minuti))
 
                NEXT i%
                IF n% = 16 THEN SLEEP: CLS
            CASE IS > 16
                FOR i% = 1 TO 50
                    LOCATE i%, (n% - 16) * 15 - 14
                    PRINT _TRIM$(STR$(idrogramma(visualizzaieto%, n%, i%, 1).portata))
                    'PRINT _TRIM$(STR$(idrogramma(visualizzaieto%, n%, i%, 1).ore))
                    'PRINT _TRIM$(STR$(idrogramma(visualizzaieto%, n%, i%, 1).minuti))
                NEXT i%
        END SELECT
    NEXT n%
    SLEEP
    CLS
    FOR z% = 1 TO 24
        ' _LIMIT limit
        PRINT massimi1(visualizzaieto%, z%, 1).ore, massimi1(visualizzaieto%, z%, 1).minuti, massimi1(visualizzaieto%, z%, 1).portata
    NEXT z%
    SLEEP
    PRINT
    PRINT massimi2(visualizzaieto%).ore; massimi2(visualizzaieto%).portata
END SUB
 

OldMoses · « **Reply #1 on:** February 20, 2021, 08:07:07 am »

I don't know if I understand this correctly, but if you have a positioning problem between screen absolute coordinates and WINDOW defined coordinates, I've used the map! function to good effect. If you have a value that needs translation from an old range {minRange!/maxRange!}, it will translate that value to the new range {newMinRange!/newMaxRange!}. The order depends upon which way one is going, from WINDOW to screen or from screen to WINDOW. Hope this helps

Code: QB64: [Select]

Function map! (value!, minRange!, maxRange!, newMinRange!, newMaxRange!)
 
    map! = ((value! - minRange!) / (maxRange! - minRange!)) * (newMaxRange! - newMinRange!) + newMinRange!
 
End Function 'map!

bplus · « **Reply #2 on:** February 20, 2021, 10:52:47 am »

Aren't _PrintString coordinates automatically translated to Window coordinates like the graphics pset, line, circle..., if not, try same trick for translating Mouse Coordinates in a Window use PMap see Wiki.

~~Use Moses idea if printing outside the Window or returning screen back to normal.~~

~~BTW is your graph reversed? Both look flipped: up/down and left/right?~~ Your screen bigger than my laptop, didn't see the axis arrows they were over in the storage shelf left of my laptop on my desk. :)

Ah TempodiBasic and or Kiara are recruiting ;-))

bartok · « **Reply #3 on:** February 20, 2021, 11:36:36 am »

Quote from: OldMoses on February 20, 2021, 08:07:07 am

I don't know if I understand this correctly, but if you have a positioning problem between screen absolute coordinates and WINDOW defined coordinates, I've used the map! function to good effect. If you have a value that needs translation from an old range {minRange!/maxRange!}, it will translate that value to the new range {newMinRange!/newMaxRange!}. The order depends upon which way one is going, from WINDOW to screen or from screen to WINDOW. Hope this helps

Code: QB64: [Select]
Function map! (value!, minRange!, maxRange!, newMinRange!, newMaxRange!)

map! = ((value! - minRange!) / (maxRange! - minRange!)) * (newMaxRange! - newMinRange!) + newMinRange!

End Function 'map!

Hi and thanks for the tip, but it doesn't work with the damned _PRINTSTRING!

As you can see in the semplified code above (press any key to go ahead), outside WINDOW, your function works, because lines drawn in the WHILE cicle of lines 55 to 59, perfetly mach the notches drawn inside WINDOW in the WHILE circle of lines 40 to 44.

But, in the WHILE cicle of lines 62 to 66, no matches! I have also tried to add something like this:

_PRINTSTRING (55, H% - 1 - test!+K)

where K is an empirical and inexplicable value brutally added in order to have the match: no way.

Code: QB64: [Select]

CONST ore! = 6.723612
CONST oreM! = 6.723612
CONST QM! = 29.88063
 
CONST dxy% = 30
CONST L% = 800
CONST H% = 600
 
CONST rosso = _RGB32(255, 0, 0)
CONST bianco = _RGB32(255, 255, 255)
CONST giallo = _RGB32(255, 255, 0)
 
DIM grafico&
DIM fx! 'all'interno del comando WINDOW e VIEW permette di disegnare in pixel sull'asse x e nelle circonferenze.
DIM fy! 'all'interno del comando WINDOW e VIEW permette di disegnare in pixel sull'asse y.
DIM dx!, dy!
DIM test%
DIM tacca%
DIM i%
 
grafico& = _NEWIMAGE(L%, H%, 32)
fx! = L% / (ore! * 1.1) '=168.3349 'pixel/ora
fy! = H% / (QM! * 1.1) '=23.3657 'pixel/mc
dx! = dxy% / fx! '=0.1782162:dx! e' la lunghezza dentro WINDOWS per avere un numero di pixel=dxy%.
dy! = dxy% / fy! '=1.283933
tacca% = QM! \ 5
 
 
 
_DEST grafico&
SCREEN grafico&
LINE (0, 0)-(L% - 1, H% - 1), rosso, B
WINDOW (0, 0)-(ore! * 1.1 + dx!, QM! * 1.1 + dy!) 'scala ascisse e ordinate in base alle ore e alla portata, estendendole del 10%.
'test! = map!(QM! \ 5 + dy!, 0, dy! + QM! * 1.1, 0, H% - 1)
LINE (dx!, QM! * 1.1)-(dx!, dy!): LINE -(ore! * 1.1, dy!), bianco
PSET (dx!, QM! * 1.1!), bianco: DRAW "F20": PSET (dx!, QM! * 1.1), bianco: DRAW "G20" ': LOCATE 7, 65: PRINT "y"
PSET (ore! * 1.1, dy!), bianco: DRAW "G20": PSET (ore! * 1.1, dy!), bianco: DRAW "H20" ': LOCATE 25, 112: PRINT "x"
SLEEP
i% = 1
WHILE i% * tacca% <= QM!
    LINE (dx! - 5 / fx!, dy! + i% * tacca%)-(dx! + 5 / fx!, dy! + i% * tacca%): SLEEP
    '  _PRINTSTRING (dx! * fx! - 20, H% - 1 - (dy! + i% * tacca%) * fy! * k!), "-": SLEEP
    i% = i% + 1
WEND
 
WINDOW
 
'i% = 1
'WHILE i% * tacca% <= QM!
'_PRINTSTRING (dx! * fx! - 20, H% - 1 - (dy! + i% * tacca%) * fy!), "--": SLEEP
'i% = i% + 1
'WEND
 
i% = 1
WHILE i% * tacca% <= QM!
    test! = map!(i% * QM! \ 5 + dy!, 0, dy! + QM! * 1.1, 0, H% - 1)
    LINE (35, H% - 1 - test!)-(50, H% - 1 - test!): PRINT test!: SLEEP '------|
    i% = i% + 1 '                                                             |
WEND '                                                                        |
'                                                                             |
i% = 1 '                                                                      |---Same (H%-1-test!), different output!
WHILE i% * tacca% <= QM! '                                                    |
    test! = map!(i% * QM! \ 5 + dy!, 0, dy! + QM! * 1.1, 0, H% - 1) '         |
    _PRINTSTRING (55, H% - 1 - test!), "--": PRINT test!: SLEEP '-------------|
    i% = i% + 1
WEND
'---------------------------------------------------------------------------------------
FUNCTION map! (value!, minWINDOW!, maxWINDOW!, minPIXEL%, maxPIXEL%)
    map! = ((value! - minWINDOW!) / (maxWINDOW! - minWINDOW!)) * (maxPIXEL% - minPIXEL%) + minPIXEL%
END FUNCTION
 

bartok · « **Reply #4 on:** February 20, 2021, 11:42:07 am »

Quote from: bplus on February 20, 2021, 10:52:47 am

Your screen bigger than my laptop, didn't see the axis arrows they were over in the storage shelf left of my laptop on my desk. :)

Ah TempodiBasic and or Kiara are recruiting ;-))

I have changed both of the 2 codes with 800x600.

In the second post, I have semplified the code, because the core of my problem is in the "graphs" subroutine of the first code I have posted. However, the program is finalized to calculate the maximum flow of a given drainage basin for a given return period, depending on the duration of the rain.

Quote

Aren't _PrintString coordinates automatically translated to Window coordinates like the graphics pset, line, circle.

no, unfortunately they aren't...

SMcNeill · « **Reply #5 on:** February 20, 2021, 12:04:58 pm »

You’re in SCREEN 0, where _PRINTSTRING is nothing more than a shortcut for LOCATE x, y: PRINT.

Here’s the relevant c-snippet for you:

Code: C++: [Select]

       void sub__printstring(float x,float y,qbs* text,int32 i,int32 passed){
            .... STUFF
            if (im->text){
                int oldx = func_pos(0), oldy = func_csrlin();
                qbg_sub_locate(y, x, 0, 0, 0, 3);
                qbs_print(text, 0);
                qbg_sub_locate(oldy, oldx, 0, 0, 0, 3);
                goto printstring_exit;
            }
            ..... STUFF

If you’re in a text screen, simply use _PRINTSTRING as a LOCATE, PRINT, then restore the previous LOCATE position.

If _PRINTSTRING doesn’t work, just go back to LOCATE: PRINT

Edit: Nevermind... I see your SCREEN statement down on line 70something... You’re not trying anything in a text screen after all.

bartok · « **Reply #6 on:** February 20, 2021, 01:06:24 pm »

SMcNeill,
yes, in fact I am in graphic mode.

It is not possible it is so complicated to put a text in a graph!:D

(I try to avoid the use of GOTO).

bplus · « **Reply #7 on:** February 20, 2021, 01:23:25 pm »

Found my old test code.

YES you MUST use PMAP for x, y conversion for both MOUSE and for _PRINTSTRING

demo

Code: QB64: [Select]

OPTION _EXPLICIT
_TITLE "Test Using Window for Cartesian Coordinate System x = -100 to 100, y = -100 to 100"
'It seems all graphics commands convert x, y to window system BUT...
'Mouse and _PrintString do not convert! BUT...
'Somebody setup a PMAP system that will do these conversions both to grapghics coordinate system and back
' convert mouse qbx, qby to graphics x, y use
' PMAP(qbx, 2), PMAP(qby, 3)
' And to print something at the graphics location use
' PMAP(graphicsX, 0), PMAP(graphicsY, 1) to _PRINTSTRING to a graphics location
 
CONST xmax = 700, ymax = 700, red = &HFFFF0000, grn = &HFF009900, blu = &HFF0000AA
CONST tlx = -100, tly = 100, brx = 100, bry = -100 ' Cartesian Coordinate System corners for WINDOW command
SCREEN _NEWIMAGE(xmax, ymax, 32)
_SCREENMOVE 300, 40
 
DIM mx, my, a, r, s$
 
WINDOW (tlx, tly)-(brx, bry) ' converts QB csreen to Cartesian Coodianate System
WHILE _KEYDOWN(27) = 0
    CLS
    WHILE _MOUSEINPUT: WEND
    mx = INT(PMAP(_MOUSEX, 2)): my = INT(PMAP(_MOUSEY, 3)) 'covert mouse to Cart Cood using PMAP
    a = atan360(my, mx) 'mouse angle to origin
    r = INT((mx * mx + my * my) ^ .5)
    LINE (0, 0)-(mx, my), grn 'hypotenuse = radius
    LINE (0, 0)-(mx, 0), blu ' r*cos
    LINE (mx, 0)-(mx, my), red ' r*sin
    arc 0, 0, 10, 0, _R2D(a), &HFFFFFF00 'yellow arc
    s$ = "Mouse (" + _TRIM$(STR$(mx)) + ", " + _TRIM$(STR$(my)) + "), Radius: "
    s$ = s$ + _TRIM$(STR$(r)) + ", Degrees: " + _TRIM$(STR$(_R2D(a) \ 1))
    _PRINTSTRING (PMAP(0, 0), PMAP(-1, 1)), s$
    _PRINTSTRING (PMAP(-95, 0), PMAP(95, 1)), "COS = x/r = " + _TRIM$(STR$(mx / r))
    _PRINTSTRING (PMAP(-95, 0), PMAP(89, 1)), "SIN = y/r = " + _TRIM$(STR$(my / r))
    IF mx <> 0 THEN _PRINTSTRING (PMAP(-95, 0), PMAP(83, 1)), "TAN = y/x = " + _TRIM$(STR$(my / mx)) 'EDIT
    _DISPLAY
    _LIMIT 60
WEND
 
' A regular graphic draw still works correctly in a Cartesian Window System!
'note: degrees start due East = 0 and go clockwise: South = 90, West = 180, North = 270
SUB arc (x, y, r, degStart, degStop, c~&)
 
    DIM rs, re, a, ax, ay, lastx, lasty
    'x, y origin, r = radius, c = color
 
    'degStart is first angle clockwise from due East = 0 degrees
    ' arc will start drawing there and clockwise until degStop angle reached, unless in Cartesain Window
 
    IF degStop < degStart THEN
        arc x, y, r, degStart, 360, c~&
        arc x, y, r, 0, degStop, c~&
    ELSE
        rs = _D2R(degStart): re = _D2R(degStop)
        FOR a = rs TO re STEP 1 / (7 * r)
            ax = x + r * COS(a)
            ay = y + r * SIN(a)
            IF a <> rs THEN LINE (lastx, lasty)-(ax, ay), c~&
            lastx = ax: lasty = ay
        NEXT
    END IF
END SUB
 
'need to match degrees going around clockwise up to full circle
FUNCTION atan360 (y, x)
    DIM test
    test = _ATAN2(y, x)
    IF test < 0 THEN atan360 = _PI(2) + test ELSE atan360 = test
END FUNCTION
 
 

bartok · « **Reply #8 on:** February 20, 2021, 01:46:08 pm »

bplus,
thank you very much! I did not have time yet to try PMAP after your message, but it was already my purpose to try it. I didn't know the command PMAP before today.

bartok · « **Reply #9 on:** February 21, 2021, 04:01:32 am »

Thank's you bplus, with PMAP it works better!

But, as you can see in the code above on line 43, I have to add "-7" in order to have the strings "--" fitting. I don't know why! In line 41 PMAP gets the y screen coordinates of WINDOW y coordinates of the line drawn in line 39. So the string "--" printed with _PRINTSTRING in line 43 should match using y calculated by PMAP without this "-7"...

Code: QB64: [Select]

CONST ore! = 6.723612
CONST oreM! = 6.723612
CONST QM! = 29.88063
 
CONST dxy% = 30
CONST rosso = _RGB32(255, 0, 0)
CONST bianco = _RGB32(255, 255, 255)
CONST giallo = _RGB32(255, 255, 0)
 
DIM L%, H%
DIM grafico&
DIM fx! 'all'interno del comando WINDOW e VIEW permette di disegnare in pixel sull'asse x e nelle circonferenze.
DIM fy! 'all'interno del comando WINDOW e VIEW permette di disegnare in pixel sull'asse y.
DIM dx!, dy!
DIM tacca%
DIM x%, y%
 
H% = _DESKTOPHEIGHT * 2 / 3
L% = H% * 1.62
 
grafico& = _NEWIMAGE(L%, H%, 32)
fx! = L% / (ore! * 1.1) '=168.3349 'pixel/ora
fy! = H% / (QM! * 1.1) '=23.3657 'pixel/mc
dx! = dxy% / fx! '=0.1782162:dx! e' la lunghezza dentro WINDOWS per avere un numero di pixel=dxy%.
dy! = dxy% / fy! '=1.283933
tacca% = QM! \ 5
 
_DEST grafico&
SCREEN grafico&
LINE (0, 0)-(L% - 1, H% - 1), rosso, B
WINDOW (0, 0)-(ore! * 1.1 + dx!, QM! * 1.1 + dy!) 'scala ascisse e ordinate in base alle ore e alla portata, estendendole del 10%.
LINE (dx!, QM! * 1.1)-(dx!, dy!): LINE -(ore! * 1.1, dy!), bianco
PSET (dx!, QM! * 1.1!), bianco: DRAW "F20": PSET (dx!, QM! * 1.1), bianco: DRAW "G20" ': LOCATE 7, 65: PRINT "y"
PSET (ore! * 1.1, dy!), bianco: DRAW "G20": PSET (ore! * 1.1, dy!), bianco: DRAW "H20" ': LOCATE 25, 112: PRINT "x"
SLEEP
i% = 1
i% = 1
WHILE i% * tacca% <= QM!
    LINE (dx! - 5 / fx!, dy! + i% * tacca%)-(dx! + 5 / fx!, dy! + i% * tacca%): SLEEP
    x% = PMAP(dx! - 5 / fx!, 0)
    y% = PMAP(dy! + i% * tacca%, 1)
    PRINT x%, y%: SLEEP
    _PRINTSTRING (x% + 10, y% - 7), "--": SLEEP '----------------------------------------------------> WHY 7??
    i% = i% + 1
WEND
WINDOW
 

bartok · « **Reply #10 on:** February 21, 2021, 05:38:33 am »

Ok, solved!

PMAP works perfectly with _PRINTSTRING. In this case "--" didn't match the line because the line is drawn at the top and "--" in the middle (_--)-->up side down.
But this is not the solution without using PMAP, because in the preview tries the "--" changed the distance with the line. So PMAP is necessary.

OldMoses · « **Reply #11 on:** February 21, 2021, 09:20:12 am »

I find this interesting as I have not, thus far, investigated PMAP.

It would seem that it is essentially FUNCTION map! that I posted earlier, only optimized for screen ops, and much less typing.

You couldn't use it, like you can map!, for general computations, but it's much easier for graphics. You don't have to do that much range figuring.

Having learned about a new trick, I'll have to do some experiments now...;)

bplus · « **Reply #12 on:** February 21, 2021, 01:23:56 pm »

Yeah WINDOW is the way to go especially for math apps that you want standard 4 quads upper right #1 and going Counter-clockwise 2, 3, 4 with angle increases.

Anyway with that command (set correctly of course) angles Increase going counter-clockwise and y up is up and x up is right! The way you learned it in school before Basic ruined your mind by flipping it upside down and making angles increase clockwise ;-))

Trouble is I don't know if anyone uses it enough to report bugs when working with all the new extensions installed with QB64 ie how z axis might work with GL 3D?

bartok · « **Reply #13 on:** February 21, 2021, 05:21:58 pm »

Quote from: bplus on February 21, 2021, 01:23:56 pm

Trouble is I don't know if anyone uses it enough to report bugs when working with all the new extensions installed with QB64 ie how z axis might work with GL 3D?

I am a beginner, so I think that my level is not enough hight to report bugs, but maybe it wouldn't be bad if _PRINTSTRING worked also inside WINDOW. But perhaps there is a reason if it doesn't. For the 3D, maybe some games programmer. I don't think my graphics needs will go beyond 2D.

bplus · « **Reply #14 on:** February 21, 2021, 06:45:55 pm »

Code: QB64: [Select]

OPTION _EXPLICIT
_TITLE "But _PrintString Works Fine in a Winodow!"
CONST xmax = 512, ymax = 400
CONST Top_Left_X = -100, Top_Left_Y = 100, Bottom_Right_X = 100, Bottom_Right_Y = -100 ' Cartesian Coordinate System corners for WINDOW command
SCREEN _NEWIMAGE(xmax, ymax, 32)
_SCREENMOVE 300, 40
WINDOW (Top_Left_X, Top_Left_Y)-(Bottom_Right_X, Bottom_Right_Y) ' converts QB csreen to Cartesian Coodianate System
_PRINTSTRING (PMAP(-95, 0), PMAP(60, 1)), "I am a beginner, so I think that my level is not enough high"
_PRINTSTRING (PMAP(-95, 0), PMAP(30, 1)), "to report bugs, but maybe it wouldn't be bad if _PRINTSTRING"
_PRINTSTRING (PMAP(-95, 0), PMAP(0, 1)), "worked also inside WINDOW. But perhaps there is a reason if "
_PRINTSTRING (PMAP(-95, 0), PMAP(-30, 1)), "it doesn't. For the 3D, maybe some games programmer. I don't"
_PRINTSTRING (PMAP(-95, 0), PMAP(-60, 1)), " think my graphics needs will go beyond 2D."
SLEEP
 
 
 

News:

Author Topic: Problem to print values on the axis inside and outside WINDOW. (Read 6406 times)

bartok

Problem to print values on the axis inside and outside WINDOW.

OldMoses

Re: Problem to print values on the axis inside and outside WINDOW.

bplus

Re: Problem to print values on the axis inside and outside WINDOW.

bartok

Re: Problem to print values on the axis inside and outside WINDOW.

bartok

Re: Problem to print values on the axis inside and outside WINDOW.

SMcNeill

Re: Problem to print values on the axis inside and outside WINDOW.

bartok

Re: Problem to print values on the axis inside and outside WINDOW.

bplus

Re: Problem to print values on the axis inside and outside WINDOW.

bartok

Re: Problem to print values on the axis inside and outside WINDOW.

bartok

Re: Problem to print values on the axis inside and outside WINDOW.

bartok

Re: Problem to print values on the axis inside and outside WINDOW.

OldMoses

Re: Problem to print values on the axis inside and outside WINDOW.

bplus

Re: Problem to print values on the axis inside and outside WINDOW.

bartok

Re: Problem to print values on the axis inside and outside WINDOW.

bplus

Re: Problem to print values on the axis inside and outside WINDOW.