BMP picture viewer

[NOVARSEG]

OK maybe all my pics were 1024 pixels wide and  . . . . . .another was 1072

1024 * 3 /4 = 768  = no padding
1072 * 3 /4  = 804 = no padding

imagine that
  update coming

[SMcNeill]

Ya but I did not have to adjust for "padding" in my code . If there are padding bytes at the end of a scan line then the padding byte don't contain pixel data.  The file pointer (GET, point, . . .) is supposed to point to pixel data only

In a, say, 1024 * 768  24 bit BMP there are exactly 1024 * 3 bytes per scan line. That is what my code is saying.  If there was actually padding bytes at the end of a scan line then surely I would have found them.

As I mentioned, the padding is only there in images whose width is not evenly divisible by four.

Most full screen images have no padding: 320, 480, 640, 720, 1024 are all evenly divisible by 4.  Where you normally see the padding is when folks take a screenshot of a potion of the screen.  (Say from 0,0 to 638, 372 — that 638 isn’t evenly divisible by 4 and thus has padding at the end of the line.)

[NOVARSEG]

Steve 

code update coming

[STxAxTIC]

You guys are using this thread like a chatroom. Not illegal, but you realize Discord would be much more efficient?

Steve, you're my only hope. Drag them in.

[bplus]

You guys are using this thread like a chatroom. Not illegal, but you realize Discord would be much more efficient?

Steve, you're my only hope. Drag them in.

Somebody forgot definition of a forum.

[STxAxTIC]

Yeah, I'm raising the question of *who*.

[SMcNeill]

Discord is no good for sharing larger snippets of code.  Forums are much better places for stuff like that.

Here's the complete version of what you guys want:

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(1024, 800, 32)
2. handle = loadBMP24("non4.bmp")
3. _PUTIMAGE , handle
4.  
5. FUNCTION loadBMP24& (Filename$)
6.     DIM OF AS _UNSIGNED LONG
7.     DIM L AS _UNSIGNED LONG
8.     DIM W AS _UNSIGNED LONG
9.     DIM H AS _UNSIGNED LONG
10.     DIM I AS _UNSIGNED INTEGER
11.     DIM R AS _UNSIGNED LONG
12.     DIM C AS _UNSIGNED LONG
13.     DIM N AS _UNSIGNED LONG
14.     DIM a AS _MEM
15.     DIM handle AS LONG
16.     DIM dh AS LONG
17.     DIM tt AS STRING * 4
18.     DIM t AS STRING * 3
19.  
20.     IF RIGHT$(UCASE$(Filename$), 4) <> ".BMP" THEN EXIT FUNCTION
21.     PRINT Filename$
22.     OPEN Filename$ FOR BINARY AS #1
23.     GET #1, 11, OF
24.     GET #1, 15, L
25.     GET #1, , W
26.     GET #1, , H
27.     GET #1, , I
28.     GET #1, , I 'get I twice ???
29.     IF I <> 24 THEN EXIT FUNCTION
30.     handle = _NEWIMAGE(W, H, 32)
31.     a = _MEMIMAGE(handle)
32.     IF ((W * 3) MOD 4) <> 0 THEN '’need padding pixels
33.         Padding$ = SPACE$((4 - ((W * 3) MOD 4)))
34.     END IF
35.     SEEK #1, OF + 1 'go to the offset where the data starts
36.     FOR R = H - 1 TO 0 STEP -1 'from the bottom to top
37.         FOR C = 0 TO W - 1 'left to right
38.             GET #1, , t 'get the data sequentially
39.             tt = t + CHR$(255)
40.             _MEMPUT a, a.OFFSET + (W * R + C) * 4, tt
41.         NEXT C
42.         GET #1, , Padding$ 'Get the padding at the end of the line
43.     NEXT R
44.     CLOSE
45.  
46.  
47.     'dh = _NEWIMAGE(W, H, 32)
48.     '_PUTIMAGE (0, 0), handle, dh
49.  
50.     loadBMP24& = handle
51.     _MEMFREE a
52. END SUB
53.  
54.  

I posted the changes needed above, but didn't actually plug it into the whole thing until now.  Sorry.  Today's my mom's 81st birthday, and I was enjoying the evening with her and the rest of the family for a change.

One thing which I think is also important to change here:

Why copy the image over to another image of the exact same size, then return the handle to that image, without ever freeing the first image?  You guys have a rather  serious memory leak in your code here, and it's much simpler to just pass the handle on directly, without worrying about the middleman dh.  See the changes down at the last few lines in the routine, before you exit.

[NOVARSEG]

Happy 81 Steve's Mom!

There is a lot in this thread to go over.  So I converted one of my 1024 pixel wide pics to 1023 pixels wide and my code crashed. Sorry about that.

[bplus]

Why copy the image over to another image of the exact same size, then return the handle to that image, without ever freeing the first image?  You guys have a rather  serious memory leak in your code here, and it's much simpler to just pass the handle on directly, without worrying about the middleman dh.  See the changes down at the last few lines in the routine, before you exit.

Yeah that was me, just trying to get the thing to work as a Function returning a handle of a loaded image.

If this were a chat room I'd ask if that was a cobweb hanging off the bottom of the Starship model and I'd say congrats to Steve's mother and mention I took my 89 year old mother for COVID vaccination today and maybe mention nothing sticks in her memory so I have the same set of questions over and over... but if this were a chatroom you wouldn't have the image to check and say, "No, I think that is just a plain old hair."

I had that dang code working, went to clean up with the new Dim As _Unsigned Long all those variables into one line take out commented out code and when I was done, a blank screen.

So thanks Steve for writing up the revised sub because my cleanup refused to work right and it's even better without the extra handle and memory leaking code!

 

[NOVARSEG]

Some new code
 3 more pictures and an EXE to download

Fixed the padding bug.

Code: QB64: [Select]

1. _TITLE "BMP slide show.   Press ESC to exit"
2.  
3.  
4. DECLARE CUSTOMTYPE LIBRARY ".\direntry"
5.     FUNCTION load_dir& (s AS STRING)
6.     FUNCTION has_next_entry& ()
7.     SUB close_dir ()
8.     SUB get_next_entry (s AS STRING, flags AS LONG, file_size AS LONG)
9. END DECLARE
10.  
11. DIM flags AS LONG
12. DIM length AS LONG
13. DIM NAM AS STRING
14. DIM F(100) AS STRING
15. DIM Fcount AS INTEGER
16. DIM Fmax AS INTEGER
17. DIM L AS _UNSIGNED LONG
18. DIM I AS _UNSIGNED INTEGER
19. DIM C AS _UNSIGNED LONG
20. DIM H AS _UNSIGNED LONG
21. DIM W AS _UNSIGNED LONG
22. DIM R AS _UNSIGNED LONG
23. DIM OF AS _UNSIGNED LONG
24. DIM N AS _UNSIGNED LONG
25. DIM tt AS STRING * 4
26. DIM t AS STRING * 3
27. DIM handle AS LONG
28. DIM t1 AS SINGLE
29. DIM t2 AS SINGLE
30. DIM pad AS INTEGER
31.  
32.  
33. 'To view BMP pictures in the root drive or a particular folder (example)
34. 'IF load_dir("C:" + CHR$(0)) <> -1 THEN _FULLSCREEN: PRINT: PRINT "Path name does not exist": SLEEP: END
35. 'IF load_dir("C:\QB64" + CHR$(0)) <> -1 THEN _FULLSCREEN: PRINT: PRINT "Path name does not exist": SLEEP: END
36.  
37. 'To view BMP pictures in the directory (folder) from where the EXE is run (current)
38. IF load_dir("." + CHR$(0)) <> -1 THEN _FULLSCREEN: PRINT: PRINT "Path name does not exist": SLEEP: END
39.  
40. 'To view BMP pictures in the parent directory (folder) from where the EXE is run (current)
41. 'IF load_dir(".." + CHR$(0)) <> -1 THEN _FULLSCREEN: PRINT: PRINT "Path name does not exist": SLEEP: END
42.  
43.  
44. DO
45.     length = has_next_entry
46.     IF length = -1 THEN
47.         '_FULLSCREEN
48.         PRINT "NO more files to process"
49.         EXIT DO
50.     END IF
51.  
52.     IF length > -1 THEN
53.         NAM = SPACE$(length)
54.         get_next_entry NAM, flags, file_size
55.  
56.  
57.         IF (flags XOR 2) = 0 AND UCASE$(RIGHT$(NAM, 3)) = "BMP" THEN
58.             PRINT NAM + "                  "
59.             Fcount = Fcount + 1
60.             F(Fcount) = NAM
61.         END IF
62.  
63.     END IF
64.  
65. LOOP
66. Fmax = Fcount
67.  
68. close_dir
69.  
70. Fcount = 0
71.  
72. DO
73.     N = 0
74.  
75.     Fcount = Fcount + 1
76.     OPEN F(Fcount) FOR BINARY AS #1
77.  
78.     GET #1, 11, OF
79.     'PRINT "Offset to picture data"; OF
80.  
81.     GET #1, 15, L
82.     ' PRINT "Header size "; L
83.  
84.     GET #1, , W
85.     ' PRINT "image width "; W
86.  
87.     GET #1, , H
88.     'PRINT "image height "; H
89.  
90.     GET #1, , I
91.  
92.     GET #1, , I 'bits per pixel. Must = 24 for the program to work.
93.  
94.     IF I <> 24 THEN
95.         _FULLSCREEN
96.         CLS
97.         PRINT "width "; W; "    Height "; H; "    Bits per pixel "; I
98.         PRINT Fcount
99.         PRINT F(Fcount); " is not a 24 bit per pixel BMP"
100.         DO
101.             IF INKEY$ <> "" THEN _FULLSCREEN OFF: CLS: EXIT DO
102.         LOOP
103.         CLOSE: GOTO LL1
104.     END IF
105.  
106.     DIM a AS _MEM
107.     handle = _NEWIMAGE(W, H, 32)
108.     a = _MEMIMAGE(handle)
109.  
110.     pad = 4 - (W * 3) MOD 4
111.  
112.     IF pad = 4 THEN pad = 0 'pad = multiple of 4
113.  
114.     FOR R = H - 1 TO 0 STEP -1
115.  
116.         FOR C = 1 TO W * 3 STEP 3
117.             GET #1, R * (W * 3 + pad) + C + OF, t
118.             tt = t + CHR$(255)
119.             _MEMPUT a, a.OFFSET + N, tt
120.             N = N + 4
121.         NEXT C
122.  
123.     NEXT R
124.  
125.     SCREEN _NEWIMAGE(W, H, 32)
126.     _PUTIMAGE (0, 0), handle
127.     _MEMFREE a
128.  
129.  
130.     t1 = TIMER
131.     DO
132.         _LIMIT 100
133.         t2 = TIMER
134.         IF t2 - t1 > 2 THEN EXIT DO
135.         i$ = INKEY$
136.         IF i$ = CHR$(27) THEN END
137.     LOOP
138.     LL1:
139.  
140.     CLOSE
141.  
142.     IF Fcount = Fmax THEN Fcount = 0
143. LOOP
144.  
145. END

[NOVARSEG]

So I will explain why this works

pad = 4 - (W * 3) MOD 4
 
    IF pad = 4 THEN pad = 0    'pad = multiple of 4
 
    FOR R = H - 1 TO 0 STEP -1
 
        FOR C = 1 TO W * 3 STEP 3
            GET #1, R * (W * 3 + pad) + C + OF, t
            tt = t + CHR$(255)
            _MEMPUT a, a.OFFSET + N, tt
            N = N + 4
        NEXT C
 
    NEXT R

FOR R = H - 1 TO 0 STEP -1

if say H = 768 then R is from 767 to 0  or 768 rows.

row 0  final
row 1
row 2
. . .
row 767   start


 The key thing here is the final row value R = 0 so
when R = 0


0 * (W * 3 + pad) + C + OF  = C + OF = the correct offset into row 0

There are (W * 3 + pad ) bytes per row. so when R = 1 then

 (W * 3 + pad) + C + OF  = the correct offset into row 1

with (W * 3 + pad) being the bytes in the preceding row 0

when R = 2 then

2 * (W * 3 + pad) + C + OF  = the correct offset into row 2
with  2 * (W * 3 + pad) = the total bytes of row 0 + row 1

and so on.

in reality the code down counts but the offset will still work out the same

[NOVARSEG]

Working on next update

from   https://stackoverflow.com/questions/9296059/read-pixel-value-in-bmp-file

Some bitmaps can be written with a negative height, so when you try to allocate your image data buffer, your code will crash with std::bad_alloc. Bitmaps with negative height means that the image data is stored top to bottom instead of the traditional bottom to top. Therefore, a slightly better version of the top level answer is (still not including portability for systems with different endianness and size of bytes):

[NOVARSEG]

Code update

Works with negative height BMPs too.

EXE attached.

Code: QB64: [Select]

1. _TITLE "BMP slide show.   Press ESC to exit"
2.  
3.  
4. DECLARE CUSTOMTYPE LIBRARY ".\direntry"
5.     FUNCTION load_dir& (s AS STRING)
6.     FUNCTION has_next_entry& ()
7.     SUB close_dir ()
8.     SUB get_next_entry (s AS STRING, flags AS LONG, file_size AS LONG)
9. END DECLARE
10.  
11. DIM flags AS LONG
12. DIM length AS LONG
13. DIM NAM AS STRING
14. DIM F(100) AS STRING
15. DIM Fcount AS INTEGER
16. DIM Fmax AS INTEGER
17. DIM L AS _UNSIGNED LONG
18. DIM I AS _UNSIGNED INTEGER
19. DIM C AS _UNSIGNED LONG
20. DIM H AS LONG
21. DIM W AS LONG
22. DIM R AS _UNSIGNED LONG
23. DIM OF AS _UNSIGNED LONG
24. DIM N AS _UNSIGNED LONG
25. DIM tt AS STRING * 4
26. DIM t AS STRING * 3
27. DIM handle AS LONG
28. DIM t1 AS SINGLE
29. DIM t2 AS SINGLE
30. DIM pad AS INTEGER
31.  
32.  
33. 'To view BMP pictures in the root drive or a particular folder (example)
34. 'IF load_dir("C:" + CHR$(0)) <> -1 THEN _FULLSCREEN: PRINT: PRINT "Path name does not exist": SLEEP: END
35. 'IF load_dir("C:\QB64" + CHR$(0)) <> -1 THEN _FULLSCREEN: PRINT: PRINT "Path name does not exist": SLEEP: END
36.  
37. 'To view BMP pictures in the directory (folder) from where the EXE is run (current)
38. IF load_dir("." + CHR$(0)) <> -1 THEN _FULLSCREEN: PRINT: PRINT "Path name does not exist": SLEEP: END
39.  
40. 'To view BMP pictures in the parent directory (folder) from where the EXE is run (current)
41. 'IF load_dir(".." + CHR$(0)) <> -1 THEN _FULLSCREEN: PRINT: PRINT "Path name does not exist": SLEEP: END
42.  
43.  
44. DO
45.     length = has_next_entry
46.     IF length = -1 THEN
47.         PRINT "No more files to process"
48.         EXIT DO
49.     END IF
50.  
51.     IF length > -1 THEN
52.         NAM = SPACE$(length)
53.         get_next_entry NAM, flags, file_size
54.  
55.         IF (flags XOR 2) = 0 AND UCASE$(RIGHT$(NAM, 3)) = "BMP" THEN
56.             PRINT NAM + "                              "
57.             Fcount = Fcount + 1
58.             F(Fcount) = NAM
59.         END IF
60.  
61.     END IF
62.  
63. LOOP
64.  
65. Fmax = Fcount
66. close_dir
67. Fcount = 0
68.  
69. DO
70.     N = 0
71.  
72.     Fcount = Fcount + 1
73.     OPEN F(Fcount) FOR BINARY AS #1
74.  
75.     GET #1, 11, OF
76.     'PRINT "Offset to picture data"; OF
77.  
78.     GET #1, 15, L
79.     'PRINT "Header size "; L
80.  
81.     GET #1, , W
82.     'PRINT "image width "; W
83.  
84.     GET #1, , H
85.     'PRINT "image height "; H
86.  
87.     GET #1, , I 'biPlanes. Specifies the number of color planes on the target device.
88.  
89.     GET #1, , I 'bits per pixel. Must = 24 for the program to work.
90.  
91.     IF I <> 24 THEN
92.         CLS
93.         PRINT "width "; W; "    Height "; H; "    Bits per pixel "; I
94.         PRINT Fcount
95.         PRINT F(Fcount); " is not a 24 bit per pixel BMP"
96.         DO
97.             IF INKEY$ <> "" THEN CLS: EXIT DO
98.         LOOP
99.         GOTO LL1
100.     END IF
101.  
102.     DIM a AS _MEM
103.     handle = _NEWIMAGE(W, ABS(H), 32)
104.     a = _MEMIMAGE(handle)
105.  
106.     pad = 4 - (W * 3) MOD 4
107.  
108.     IF pad = 4 THEN pad = 0 'pad = multiple of 4
109.  
110.     IF H < 0 THEN
111.  
112.         FOR R = 0 TO ABS(H) - 1
113.  
114.             FOR C = 1 TO W * 3 STEP 3
115.                 GET #1, R * (W * 3 + pad) + C + OF, t
116.                 tt = t + CHR$(255)
117.                 _MEMPUT a, a.OFFSET + N, tt
118.                 N = N + 4
119.             NEXT C
120.  
121.         NEXT R
122.  
123.     END IF
124.  
125.  
126.     IF H > 0 THEN
127.  
128.         FOR R = H - 1 TO 0 STEP -1
129.  
130.             FOR C = 1 TO W * 3 STEP 3
131.                 GET #1, R * (W * 3 + pad) + C + OF, t
132.                 tt = t + CHR$(255)
133.                 _MEMPUT a, a.OFFSET + N, tt
134.                 N = N + 4
135.             NEXT C
136.  
137.         NEXT R
138.  
139.     END IF
140.  
141.  
142.     SCREEN _NEWIMAGE(W, (ABS(H)), 32)
143.     _PUTIMAGE (0, 0), handle
144.     _MEMFREE a
145.  
146.  
147.     t1 = TIMER
148.     DO
149.         _LIMIT 100
150.         t2 = TIMER
151.         IF t2 - t1 > 2 THEN EXIT DO
152.         i$ = INKEY$
153.         IF i$ = CHR$(27) THEN END
154.     LOOP
155.     LL1:
156.  
157.     CLOSE
158.  
159.     IF Fcount = Fmax THEN Fcount = 0
160. LOOP
161.  
162. END

[_vince]

Nice, FYI this used to be my GOTO reference for whenever I needed to do anything with BMPs, explains the padding nonsense and some compression:
http://www.petesqbsite.com/sections/tutorials/zines/qbcm/12-bmps.html

Hey, Steve, are you fairly active on discord? Anyone know?

[SMcNeill]

Hey, Steve, are you fairly active on discord? Anyone know?

I go and come a lot.  The last week or so, I've been in fairly often, but for the next week or so, I probably won't be.  It's time for me to go get mom and take care of her again for a bit to give my sister a break.  ;)