Sandpile revisited

[bplus]

Code: QB64: [Select]

1. _TITLE "Sandpiles by Ashish, mod #3 B+ 2021-01-22 more color bigger grain"
2. ' from "Sandpiles by Ashish mod for symmetry and color by B+ 2019-03-04"
3. ' mod 3 2021-01-22 bigger grains bigger pallet
4.  
5. SCREEN _NEWIMAGE(600, 600, 32)
6. _SCREENMOVE 300, 100
7. REDIM grain(150, 150) AS _UNSIGNED LONG
8. REDIM ng(150, 150) AS _UNSIGNED LONG 'next generation grain
9. REDIM pal(8) AS _UNSIGNED LONG
10. REDIM c AS _UNSIGNED LONG
11. FOR i = 0 TO 8
12.     pal(i) = _RGB32(i * 31, i * 17, i * 8)
13. NEXT
14. grain(75, 75) = 500000: ng(75, 75) = 500000
15. DO
16.     FOR y = 1 TO 149
17.         FOR x = 1 TO 149
18.             IF grain(x, y) < 4 THEN c = pal(grain(x, y)) ELSE c = &HFFFF8844
19.             LINE (x * 4, y * 4)-STEP(4, 4), c, BF
20.             IF grain(x, y) > 4 THEN 'update next generation array NOT this generation array
21.                 ng(x - 1, y) = ng(x - 1, y) + 1
22.                 ng(x + 1, y) = ng(x + 1, y) + 1
23.                 ng(x, y + 1) = ng(x, y + 1) + 1
24.                 ng(x, y - 1) = ng(x, y - 1) + 1
25.                 ng(x, y) = ng(x, y) - 4
26.             END IF
27.     NEXT x, y
28.  
29.     'copy ng() into grain()  ' AFTER UPDATING ALL OF NG()
30.     FOR y = 0 TO 150
31.         FOR x = 0 TO 150
32.             grain(x, y) = ng(x, y)
33.         NEXT
34.     NEXT
35.     _DISPLAY
36.     '_LIMIT 60
37. LOOP WHILE grain(75, 75) > 4
38.  
39.  

[STxAxTIC]

I just stared at this for 10 minutes theorizing why the radius stops growing but then looked at the code and saw the 150's. Hehe. Nice.

[SMcNeill]

And here's the simple and efficient way to copy info from one array to the other for you:

Code: QB64: [Select]

1. _TITLE "Sandpiles by Ashish, mod #3 B+ 2021-01-22 more color bigger grain"
2. ' from "Sandpiles by Ashish mod for symmetry and color by B+ 2019-03-04"
3. ' mod 3 2021-01-22 bigger grains bigger pallet
4.  
5. SCREEN _NEWIMAGE(600, 600, 32)
6. _SCREENMOVE 300, 100
7. REDIM grain(150, 150) AS _UNSIGNED LONG
8. REDIM ng(150, 150) AS _UNSIGNED LONG 'next generation grain
9. REDIM pal(8) AS _UNSIGNED LONG
10. REDIM c AS _UNSIGNED LONG
11. DIM m(1) AS _MEM
12. m(0) = _MEM(ng()): m(1) = _MEM(grain())
13. FOR i = 0 TO 8
14.     pal(i) = _RGB32(i * 31, i * 17, i * 8)
15. NEXT
16. grain(75, 75) = 500000: ng(75, 75) = 500000
17. DO
18.     FOR y = 1 TO 149
19.         FOR x = 1 TO 149
20.             IF grain(x, y) < 4 THEN c = pal(grain(x, y)) ELSE c = &HFFFF8844
21.             LINE (x * 4, y * 4)-STEP(4, 4), c, BF
22.             IF grain(x, y) > 4 THEN 'update next generation array NOT this generation array
23.                 ng(x - 1, y) = ng(x - 1, y) + 1
24.                 ng(x + 1, y) = ng(x + 1, y) + 1
25.                 ng(x, y + 1) = ng(x, y + 1) + 1
26.                 ng(x, y - 1) = ng(x, y - 1) + 1
27.                 ng(x, y) = ng(x, y) - 4
28.             END IF
29.     NEXT x, y
30.  
31.     'copy ng() into grain()  ' AFTER UPDATING ALL OF NG()
32.     _MEMCOPY m(0), m(0).OFFSET, m(0).SIZE TO m(1), m(1).OFFSET
33.     _DISPLAY
34.     '_LIMIT 60
35. LOOP WHILE grain(75, 75) > 4

[bplus]

Oh yeah, thanks @SMcNeill  I did have that little trick ready in tool bag, forgot all about it, yeah thanks!

For experiment might try a timing this with and without the memory copy, be interesting to compare.

[bplus]

Oh before I forget, I did try using a bigger palette as you can see in code here:

Code: QB64: [Select]

1. FOR i = 0 TO 8
2.     pal(i) = _RGB32(i * 31, i * 17, i * 8)
3. NEXT
4.  

But more colors makes it run longer for each diameter for sand pile to spread out, it's more fun to see designs as pile spreads as fast as possible. I was hoping designs might be more interesting with more colors but I didn't think so but you can try by changing wait... I will rewrite.

[bplus]

Yeah more colrs slow spred and contrast begins to blend so looks more like sand and less like neat design.

Code: QB64: [Select]

1. _TITLE "Sandpiles by Ashish, mod #4 B+ 2021-01-22 more color bigger grain"
2. ' from "Sandpiles by Ashish mod for symmetry and color by B+ 2019-03-04"
3. ' mod 3 2021-01-22 bigger grains bigger pallet
4. ' mod 4 2021-01-29 mod to use more than 4 colors maybe a range, just takes 1 number as variable to test different pallet amounts
5. '        using Steve's Memory method for array copy Thanks for reminder!
6.  
7. CONST Ncolrs = 16 'number of shades of brown for sand   <<<  low numbers give high contrast for nice design and faster spred
8. SCREEN _NEWIMAGE(600, 600, 32)
9. _SCREENMOVE 300, 100
10. REDIM grain(150, 150) AS _UNSIGNED LONG
11. REDIM ng(150, 150) AS _UNSIGNED LONG 'next generation grain
12. REDIM pal(Ncolrs) AS _UNSIGNED LONG
13. REDIM c AS _UNSIGNED LONG
14. DIM m(1) AS _MEM
15. m(0) = _MEM(ng()): m(1) = _MEM(grain())
16. FOR i = 0 TO Ncolrs
17.     f = 255 / Ncolrs
18.     pal(i) = _RGB32(i * f, i * f / 2, i * f / 4)
19. NEXT
20. grain(75, 75) = 500000: ng(75, 75) = 500000
21. DO
22.     FOR y = 1 TO 149
23.         FOR x = 1 TO 149
24.             IF grain(x, y) <= Ncolrs THEN c = pal(grain(x, y)) ELSE c = &HFFFFAA66 'see update
25.             LINE (x * 4, y * 4)-STEP(4, 4), c, BF
26.             IF grain(x, y) > Ncolrs THEN 'update next generation array NOT this generation array
27.                 ng(x - 1, y) = ng(x - 1, y) + 1
28.                 ng(x + 1, y) = ng(x + 1, y) + 1
29.                 ng(x, y + 1) = ng(x, y + 1) + 1
30.                 ng(x, y - 1) = ng(x, y - 1) + 1
31.                 ng(x, y) = ng(x, y) - 4
32.             END IF
33.     NEXT x, y
34.  
35.     'copy ng() into grain()  ' AFTER UPDATING ALL OF NG()
36.     _MEMCOPY m(0), m(0).OFFSET, m(0).SIZE TO m(1), m(1).OFFSET
37.     _DISPLAY
38.     '_LIMIT 60
39. LOOP WHILE grain(75, 75) > 4
40.  
41.  

Update: this works better with a whiter top color, past the Ncolrs amount.