Difference in CPU Usage in Hardware vs Software images

[SMcNeill]

I'm back home, and had a little time today to play around with the PC for a bit, so I thought I'd take a quick moment to write up a simple little demo of how and why folks might want to make use of hardware images.  We really don't see them made use of in programs much, and it's honestly a shame, as you can see from below:

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(_DESKTOPWIDTH, _DESKTOPHEIGHT, 32)
2. _SCREENMOVE 0, 0
3. CLS
4. x = 18
5. DO
6.     LINE (x, 0)-STEP(14, _HEIGHT), &H2CFFFFFF, BF
7.     LINE (x + 1, 0)-STEP(12, _HEIGHT), &H83FFFFFF, BF
8.     LINE (x + 3, 0)-STEP(8, _HEIGHT), &H03FFFFFF, BF
9.     x = x + 32
10. LOOP UNTIL x >= _WIDTH
11. y = 18
12. DO
13.     LINE (0, y)-STEP(_WIDTH, 14), &H2CFFFFFF, BF
14.     LINE (0, y + 1)-STEP(_WIDTH, 12), &H83FFFFFF, BF
15.     LINE (0, y + 3)-STEP(_WIDTH, 8), &H03FFFFFF, BF
16.     y = y + 32
17. LOOP UNTIL y >= _HEIGHT
18. CI = _COPYIMAGE(0)
19. 'CI = _COPYIMAGE(0, 33)
20. x = 0: y = 0
21. l = 300
22. DO
23.     CLS
24.     _PUTIMAGE (x, y), CI
25.     IF x < 0 THEN _PUTIMAGE (_WIDTH + x, y), CI, 0, (0, 0)-(-x, _HEIGHT)
26.     IF y < 0 THEN _PUTIMAGE (x, _HEIGHT + y), CI, 0, (0, 0)-(_WIDTH, -y)
27.     IF x < 0 AND y < 0 THEN _PUTIMAGE (_WIDTH + x, _HEIGHT + y), CI, 0, (0, 0)-(-x, -y)
28.     IF x < -_WIDTH THEN x = 0
29.     IF y < -_HEIGHT THEN y = 0
30.     change = INT(RND * 2)
31.     IF change THEN x = x - 1 ELSE y = y - 1
32.     IF ABS(TIMER - INT(TIMER)) < .1 THEN l = INT(RND * 300) + 30
33.     _LIMIT l
34.     _DISPLAY
35. LOOP UNTIL _KEYHIT = 27

Now this is nothing more than a simple little screen pattern which we scroll diagonally up and left across the screen.  To start with, we run it in normal, software graphical mode, so you guys can pop open task manager and look at the CPU usage of our program.

Let it run for a bit and watch the CPU usage -- I've got a variable limit in here (you can tell by how fast the screen scrolls), so you can get a range of how much processing power your machine does on it with limits somewhere between 30 and 330.

On my PC, task manager tells me it's using from 8 to 14% CPU power -- which is enough to crank my fans up on my PC and make them sound like an airplane engine starting up!


And then, we go into the IDE and unremark out the line with the COPYIMAGE in it, and we remark the line below it:

'CI = _COPYIMAGE(0)
CI = _COPYIMAGE(0, 33)

This says we're now going to be using a hardware image for our main program.  Once again, at this point, compile, run and watch the results for about a minute or so.  There's no RANDOMIZER TIMER in this, so we're going to be getting the *exact* same LIMITs as what we had last time...

... And yet, all we're seeing here is from 0.8 to 2.1% CPU usage!!

Exact same program, with only one small change -- hardware over software images -- and yet it now has almost no effect on CPU usage.  My fans never crank on.  My airplane stays parked in my chassis, and life is GOOD!!


And here's to hoping that we'll be seeing more folks asking questions and playing around with hardware images in the future.  *Cheers!*

[Pete]

We interrupt this message to bring you these hot deals from ebay...

Buy it Now: Used QB64 laptops, with QB64 Version prior to _LIMIT and hardware image abilities installed! Laptop has many features and comes complete with built in smoke detector.

[bartok]

conceptually, what is the difference between hardware and software images?

[SMcNeill]

conceptually, what is the difference between hardware and software images?

Hardware images process on your GPU.  Software images on your CPU.

[bartok]

ok, I got it.

[bplus]

Thanks I did not know that about CPU usage, though I don't use _COPYIMAGE, the only other place is _LOADIMAGE?

So by default we should use Hardware images unless... what?

[SMcNeill]

So by default we should use Hardware images unless... what?

Unless you need to be altering them constantly.  We can't access hardware images directly, so we draw and build a software image, and then display the hardware images.

But, they can also be used to do things such as this hybrid graphic-text screen:

Code: QB64: [Select]

1. LOCATE 1, 1
2. COLOR 31
3. PRINT "Hello World"
4.  
5.  
6. temp = _NEWIMAGE(200, 200, 32)
7. _DEST temp
8. CIRCLE (100, 100), 75, _RGB32(255, 255, 0)
9. PAINT (100, 100), _RGB32(255, 255, 0)
10. temp_hw = _COPYIMAGE(temp, 33)
11. _FREEIMAGE temp
12.  
13. DO
14.     _LIMIT 10
15.     _PUTIMAGE (100, 100), temp_hw
16.     _DISPLAY
17. LOOP UNTIL _KEYHIT
18.  
19. PRINT "One thing to notice about hardware images --"
20. PRINT "they're completely seperate from our software screens,"
21. PRINT "which means we can use them even with SCREEN 0!"
22. _DISPLAY
23.