Bug REDIM _PRESERVE losing data?

[blametroi]

I've a two dimensional string array that I redim _preserve and the contents of the second row are lost. Sample code attached.

Line 63 "REDIM _PRESERVE definingKeywords(i-1, 2) AS STRING" is the key. Comment this out, and the print of definingKeywords(i,2) in line 82 shows the data read in earlier in the program. Uncomment it, and there's nothing showing for definingKeywords(i,2). definingKeywords(i,1) is fine throughout.

I've tried to come  up with a test program that isn't pulled out of a current project, but of course the bug does not manifest in those attempts.

EDIT: This is with the 1.5 development build 2e309e8. Recent but not the latest.

Code: QB64: [Select]

1. ' redim_error2.bas
2. '==============================================================
3. '
4. '==============================================================
5.  
6. OPTION _EXPLICIT ' i prefer it this way
7. OPTION BASE 1 ' god meant it to be this way
8. $CONSOLE:ONLY
9. _DEST _CONSOLE
10.  
11. '==============================================================
12. ' global definitions, declarations, and initialization
13. '==============================================================
14.  
15. ON ERROR GOTO handleError
16.  
17. 'constants
18. CONST START_SIZE = 500
19. CONST INCREMENT_SIZE = 250
20.  
21. 'types
22.  
23. 'shared and work
24. REDIM SHARED definingKeywords(START_SIZE, 2) AS STRING ' over allocate, will trim
25. REDIM SHARED tagTypes(START_SIZE) AS STRING ' also over allocated
26. DIM numDefiningKeywords AS INTEGER
27. DIM numTagTypes AS INTEGER
28. DIM pLabel AS INTEGER
29. DIM pInclude AS INTEGER
30. DIM pKeyword AS INTEGER
31. DIM i AS INTEGER
32. DIM delimiters AS STRING
33. DIM currentTagType AS STRING
34. DIM currentKeyword AS STRING
35.  
36. '==============================================================
37. ' mainline
38. '==============================================================
39. mainline:
40.  
41. '==============================================================
42. ' load our definitions
43. '==============================================================
44. RESTORE dataTagTypes
45. i = 1
46. DO
47.     READ currentTagType
48.     IF currentTagType = "" THEN
49.         REDIM _PRESERVE tagTypes(i - 1)
50.         EXIT DO
51.     END IF
52.     tagTypes(i) = currentTagType
53.     i = i + 1
54. LOOP
55. numTagTypes = i - 1
56.  
57. RESTORE dataDefiningKeywords
58. i = 1
59. DO
60.     READ currentKeyword, currentTagType
61.     IF currentKeyword = "" THEN
62.         'todo: redim _preserve is losing the 2nd dimension? dup and report
63.         'REDIM _PRESERVE definingKeywords(i - 1, 2) AS STRING
64.         EXIT DO
65.     END IF
66.     definingKeywords(i, 1) = currentKeyword
67.     definingKeywords(i, 2) = currentTagType
68.     PRINT definingKeywords(i, 1), definingKeywords(i, 2)
69.     IF currentKeyword = "<label>" THEN pLabel = i
70.     IF currentKeyword = "'$INCLUDE:" THEN pInclude = i
71.     i = i + 1
72. LOOP
73. numDefiningKeywords = i - 1
74.  
75. delimiters = " :;()-+*/\"
76.  
77. '===============================================================
78. ' got data?
79. '===============================================================
80.  
81. FOR i = 1 TO numDefiningKeywords
82.     PRINT definingKeywords(i, 1); ":"; definingKeywords(i, 2)
83. NEXT i
84.  
85. '===============================================================
86. ' close files, we're done
87. '===============================================================
88.  
89. END
90.  
91.  
92. '==============================================================
93. ' handle general runtime errors, can override. override
94. ' handlers should be added after this one.
95. '==============================================================
96.  
97. handleError:
98.  
99. PRINT "Error" + STR$(ERR) + " at line" + STR$(_ERRORLINE)
100. RESUME NEXT
101.  
102.  
103. '==============================================================
104. ' data blocks. if you are using data, in qb64 it needs to be
105. ' defined before any subs/functions, so group it all here. i
106. ' wish we could put each block closer to its use.
107. '==============================================================
108.  
109. dataBlocksHere:
110. DATA -9999
111.  
112. '==============================================================
113. ' qb64 keywords types.
114. '==============================================================
115.  
116. dataTagTypes:
117. DATA "constant"
118. DATA "function"
119. DATA "include"
120. DATA "label"
121. DATA "type"
122. DATA "variable"
123. DATA ""
124.  
125. '==============================================================
126. ' qb64 keywords types.
127. '
128. ' these are mostly sorted but two word variants are put in
129. ' front of a single word form, eg "dim shared" comes before
130. ' "dim". this simplifies the search. the list is short enough
131. ' that the search will be sequential.
132. '
133. ' format is keyword text in upper case, and what type of
134. ' entity this defines.
135. '==============================================================
136.  
137. dataDefiningKeywords:
138. DATA "ALIAS ","type"
139. DATA "COMMON SHARED ","variable"
140. DATA "COMMON ","variable"
141. DATA "CONST ","constant"
142. DATA "DECLARE DYNAMIC LIBRARY ","type"
143. DATA "DECLARE LIBRARY ","type"
144. DATA "DIM SHARED ","variable"
145. DATA "DIM ","variable"
146. DATA "FUNCTION ","function"
147. DATA "<label>","label": ' there is no actual keyword text, rather colon
148. DATA "REDIM _PRESERVE ","variable"
149. DATA "REDIM SHARED ","variable"
150. DATA "REDIM ","variable"
151. DATA "SHARED ","variable"
152. DATA "STATIC ","variable"
153. DATA "SUB ","function"
154. DATA "TYPE ","type"
155. DATA "'$INCLUDE:","include"
156. DATA "",""
157.  

[luke]

You're probably hitting this long-standing bug: https://github.com/QB64Team/qb64/issues/3 (ignore the most recent comment).

Flip your dimensions so you only ever resize the last dimension and see if that behaves more predictably.

[SMcNeill]

If you’re curious about what’s going on, watch Tutorial #4 here: https://www.qb64.org/forum/index.php?topic=1731.0

It’s probably more than you ever wanted to know about how information is stored in memory, and the whole video runs about 90 minutes, or so, so grab some popcorn and a soda before watching the whole thing.

[blametroi]

Thanks guys, I do love a good Heisenbug. I've got a couple of ideas how to get around this, but wanted to report it.

Regarding "more than you ever wanted to know" ... in professional life I was an assembly language programmer writing systems software. I don't go that deep anymore, but I'd like to think I can if I need to :)

I'll come up with a workaround I trust. Thanks again.