A quick program for folks to test

[SMcNeill]

@Bert22306, @johnno56

Give the following version a run, guys, and see what you get:

Code: QB64: [Select]

1. $CONSOLE:ONLY
2. _DEST _CONSOLE
3.  
4. ip$ = GetPublicIP$
5. PRINT "Your IP Address is:"; ip$
6. PRINT
7. Lat_Long ip$, lat, lon
8. PRINT "Your Latitude and Longitude is: "; lat, lon
9. PRINT
10. PRINT "For your location, the following is true for Xmas day:"
11. SunStuff lat, lon, 12, 25, 2020
12.  
13.  
14. SUB DownloadURL (link$, file$)
15.     f = FREEFILE
16.     OPEN file$ FOR OUTPUT AS #f: CLOSE #f 'erase any old file of the same name
17.     $IF WIN THEN
18.         out$ = "powershell.exe -c " + CHR$(34) + "Invoke-Webrequest '" + link$ + "' -OutFile '" + file$ + "'" + CHR$(34)
19.     $ELSE
20.         out$ = "wget " + chr$(34) + link$ + " -O " + file$ + chr$(34)
21.     $END IF
22.     SHELL _HIDE out$
23. END SUB
24.  
25.  
26. FUNCTION GetPublicIP$
27.     f = FREEFILE
28.     OPEN "tempPIP.txt" FOR OUTPUT AS #f: CLOSE f
29.     SHELL _HIDE "cmd /c nslookup myip.opendns.com resolver1.opendns.com>tempPIP.txt"
30.  
31.     OPEN "tempPIP.txt" FOR INPUT AS #f
32.     IF LOF(f) THEN
33.         DO
34.             LINE INPUT #f, temp$
35.             IF temp$ <> "" THEN last$ = temp$ 'there's a blank line after the data we need.
36.             '                                 Ignore it.  What we want is the last line of info generated here.
37.         LOOP UNTIL EOF(1)
38.     END IF
39.     CLOSE f
40.     l = _INSTRREV(last$, "Address:")
41.     IF l THEN GetPublicIP$ = MID$(last$, l + 10)
42.     KILL "tempPIP.txt"
43. END FUNCTION
44.  
45. SUB Lat_Long (ip$, lat, lon)
46.     f = FREEFILE
47.     DownloadURL "ip-api.com/line/" + ip$ + "?fields=lat,lon", "temp.txt"
48.     OPEN "temp.txt" FOR INPUT AS #f
49.  
50.     IF LOF(f) = 0 THEN CLOSE f: EXIT SUB 'something didn't download.  this info isn't available to parse.
51.  
52.     INPUT #f, lat
53.     INPUT #f, lon
54.     CLOSE f
55. END SUB
56.  
57. SUB SunStuff (lat, lon, month, day, year)
58.     d$ = _TRIM$(STR$(year)) + _TRIM$(STR$(month)) + _TRIM$(STR$(day))
59.     link$ = "https://api.sunrise-sunset.org/json?lat=" + _TRIM$(STR$(lat)) + "&lng="
60.     link$ = link$ + _TRIM$(STR$(lon)) + "&date=" + d$
61.     DownloadURL link$, "temp.txt"
62.     f = FREEFILE
63.     OPEN "temp.txt" FOR BINARY AS #f
64.  
65.     IF LOF(f) = 0 THEN CLOSE f: EXIT SUB 'something didn't download.  this info isn't available to parse.
66.  
67.     t$ = SPACE$(LOF(f))
68.     GET #1, 1, t$
69.     CLOSE f
70.  
71.     'strip off unwanted stuff
72.     l = INSTR(t$, ":{"): t$ = MID$(t$, l + 2)
73.     DO
74.         l = INSTR(t$, CHR$(34))
75.         t$ = LEFT$(t$, l - 1) + MID$(t$, l + 1)
76.     LOOP UNTIL l = 0
77.     DO
78.         l = INSTR(t$, "_")
79.         t$ = LEFT$(t$, l - 1) + " " + MID$(t$, l + 1)
80.     LOOP UNTIL l = 0
81.     t$ = _TRIM$(t$)
82.     t$ = LEFT$(t$, LEN(t$) - 1)
83.  
84.     DO
85.         l = INSTR(t$, ",")
86.         IF l = 0 THEN EXIT DO
87.         whole$ = LEFT$(t$, l)
88.         l$ = LEFT$(whole$, INSTR(whole$, ":") - 1)
89.         r$ = MID$(whole$, INSTR(whole$, ":") + 1)
90.         r$ = LEFT$(r$, LEN(r$) - 1)
91.         PRINT l$; " is "; r$
92.         t$ = MID$(t$, l + 1)
93.     LOOP
94. END SUB
95.  

For Bert, I'm hoping that you'll basically run but see a whole lot of nothing, as we should error trap now for non-existent files.  You could always try running it as admin and see if that makes a difference on your work machine, but I imagine it's some sort of system limitation.  Powershell is only available from windows 7 up, so if your enterprise machines don't give proper permissions, or run on an older version of windows, then they're definitely not going to work.  A test just to make certain things fail properly, without crashing, would be nice in this case.  :)

For Johnno, I'm hoping that you get the same results now that everyone else does.  If not, uncomment out that _HIDE statement in the download SUB and let me know what the output is that you see.  wget comes with Linux (I think), so unless my syntax is wrong, or something, I'm thinking it should work for you.  If it does, I'll have a nice simple tool to add to my toolbox for downloading stuff from the web, which works with https files and is cross-compatible with our various OSes.  :D

For everyone else, it should run as before, without any changes.  At least, I hope it does...

[SMcNeill]

And if all works well, the following version should now make adjustments to the time to account for your local time zone and current daylight saving time. 

Code: QB64: [Select]

1. TYPE Sun_Data_type
2.     field AS STRING
3.     value AS STRING
4. END TYPE
5.  
6. REDIM SHARED Sun(0) AS Sun_Data_type
7.  
8. $CONSOLE:ONLY
9. _DEST _CONSOLE
10.  
11.  
12.  
13. ip$ = GetPublicIP$
14. PRINT "Your IP Address is:"; ip$
15. PRINT
16. Lat_Long ip$, lat, lon
17. PRINT "Your Latitude and Longitude is: "; lat, lon
18. PRINT
19.  
20. SunStuff lat, lon, 12, 25, 2020
21. PRINT "For your location, the following is true for Xmas day:"
22. FOR i = 1 TO UBOUND(Sun)
23.     PRINT Sun(i).field; " = "; Sun(i).value
24. NEXT
25.  
26.  
27. FUNCTION GetHour (fromTime$)
28.     'time should be hh:mm:ss WhateverM
29.     l = INSTR(fromTime$, ":") '1st :
30.     GetHour = VAL(LEFT$(fromTime$, l))
31. END SUB
32.  
33. FUNCTION GetMinute (fromTime$)
34.     'time should be hh:mm:ss WhateverM
35.     l = INSTR(fromTime$, ":") '1st :
36.     GetMinute = VAL(MID$(fromTime$, l + 1))
37. END SUB
38.  
39.  
40. FUNCTION GetSecond (fromTime$)
41.     'time should be hh:mm:ss WhateverM
42.     l = INSTR(fromTime$, ":") '1st :
43.     l = INSTR(l + 1, fromTime$, ":") '2nd :
44.     GetSecond = VAL(MID$(fromTime$, l + 1))
45. END SUB
46.  
47.  
48. FUNCTION GetTimeOffset
49.     $IF WIN THEN
50.         TYPE SYSTEMTIME
51.             wYear AS _UNSIGNED INTEGER
52.             wMonth AS _UNSIGNED INTEGER
53.             wDayOfWeek AS _UNSIGNED INTEGER
54.             wDay AS _UNSIGNED INTEGER
55.             wHour AS _UNSIGNED INTEGER
56.             wMinute AS _UNSIGNED INTEGER
57.             wSecond AS _UNSIGNED INTEGER
58.             wMilliseconds AS _UNSIGNED INTEGER
59.         END TYPE
60.  
61.         TYPE TIME_ZONE_INFORMATION
62.             Bias AS LONG
63.             StandardName AS STRING * 64 'WCHAR      StandardName[32];
64.             StandardDate AS SYSTEMTIME
65.             StandardBias AS LONG
66.             DaylightName AS STRING * 64 'WCHAR      DaylightName[32];
67.             DaylightDate AS SYSTEMTIME
68.             DaylightBias AS LONG
69.         END TYPE
70.  
71.         DECLARE DYNAMIC LIBRARY "Kernel32"
72.             SUB GetTimeZoneInformation (t AS TIME_ZONE_INFORMATION)
73.         END DECLARE
74.  
75.         DIM t AS TIME_ZONE_INFORMATION
76.         GetTimeZoneInformation t
77.         GetTimeOffset = t.Bias
78.     $END IF
79. END SUB
80.  
81.  
82. SUB DownloadURL (link$, file$)
83.     f = FREEFILE
84.     OPEN file$ FOR OUTPUT AS #f: CLOSE #f 'erase any old file of the same name
85.     $IF WIN THEN
86.         out$ = "powershell.exe -c " + CHR$(34) + "Invoke-Webrequest '" + link$ + "' -OutFile '" + file$ + "'" + CHR$(34)
87.     $ELSE
88.         out$ = "wget " + chr$(34) + link$ + " -O " + file$ + chr$(34)
89.     $END IF
90.     SHELL _HIDE out$
91. END SUB
92.  
93.  
94. FUNCTION GetPublicIP$
95.     f = FREEFILE
96.     OPEN "tempPIP.txt" FOR OUTPUT AS #f: CLOSE f
97.     SHELL _HIDE "cmd /c nslookup myip.opendns.com resolver1.opendns.com>tempPIP.txt"
98.  
99.     OPEN "tempPIP.txt" FOR INPUT AS #f
100.     IF LOF(f) THEN
101.         DO
102.             LINE INPUT #f, temp$
103.             IF temp$ <> "" THEN last$ = temp$ 'there's a blank line after the data we need.
104.             '                                 Ignore it.  What we want is the last line of info generated here.
105.         LOOP UNTIL EOF(1)
106.         l = _INSTRREV(last$, "Address:")
107.         IF l THEN GetPublicIP$ = MID$(last$, l + 10)
108.     END IF
109.     CLOSE f
110.     KILL "tempPIP.txt"
111. END FUNCTION
112.  
113. SUB Lat_Long (ip$, lat, lon)
114.     f = FREEFILE
115.     DownloadURL "ip-api.com/line/" + ip$ + "?fields=lat,lon", "temp.txt"
116.     OPEN "temp.txt" FOR INPUT AS #f
117.  
118.     IF LOF(f) = 0 THEN CLOSE f: EXIT SUB 'something didn't download.  this info isn't available to parse.
119.  
120.     INPUT #f, lat
121.     INPUT #f, lon
122.     CLOSE f
123. END SUB
124.  
125. SUB SunStuff (lat, lon, month, day, year)
126.     d$ = _TRIM$(STR$(year)) + _TRIM$(STR$(month)) + _TRIM$(STR$(day))
127.     link$ = "https://api.sunrise-sunset.org/json?lat=" + _TRIM$(STR$(lat)) + "&lng="
128.     link$ = link$ + _TRIM$(STR$(lon)) + "&date=" + d$
129.     DownloadURL link$, "temp.txt"
130.     f = FREEFILE
131.     OPEN "temp.txt" FOR BINARY AS #f
132.  
133.     IF LOF(f) = 0 THEN CLOSE f: EXIT SUB 'something didn't download.  this info isn't available to parse.
134.  
135.     t$ = SPACE$(LOF(f))
136.     GET #1, 1, t$
137.     CLOSE f
138.  
139.     'strip off unwanted stuff
140.     l = INSTR(t$, ":{"): t$ = MID$(t$, l + 2) 'junk left of our initial data
141.     DO
142.         l = INSTR(t$, CHR$(34))
143.         t$ = LEFT$(t$, l - 1) + MID$(t$, l + 1) 'remove all quotes completely from this data
144.     LOOP UNTIL l = 0
145.     DO
146.         l = INSTR(t$, "_")
147.         t$ = LEFT$(t$, l - 1) + " " + MID$(t$, l + 1) 'change all underscores to spaces in this data
148.     LOOP UNTIL l = 0
149.     t$ = _TRIM$(t$)
150.     t$ = LEFT$(t$, LEN(t$) - 12) 'remove the last end of data }
151.     PRINT t$
152.  
153.     'parse it down to field, data
154.     DO
155.         l = INSTR(t$, ",")
156.         IF l = 0 THEN EXIT DO
157.         count = count + 1
158.         REDIM _PRESERVE Sun(count) AS Sun_Data_type
159.         whole$ = LEFT$(t$, l)
160.         Sun(count).field = LEFT$(whole$, INSTR(whole$, ":") - 1)
161.         r$ = MID$(whole$, INSTR(whole$, ":") + 1)
162.         r$ = LEFT$(r$, LEN(r$) - 1)
163.         IF RIGHT$(r$, 1) = "M" THEN m$ = RIGHT$(r$, 3) ELSE m$ = ""
164.         h = GetHour(r$) - GetTimeOffset / 60: m = GetMinute(r$): s = GetSecond(r$)
165.         IF h < 1 THEN h = h + 12 'adjust for AM/PM difference, if ever necessary
166.         IF h > 12 THEN h = h - 12 'adjust for AM/PM difference, if ever necessary
167.         Sun(count).value = _TRIM$(STR$(h)) + ":" + _TRIM$(STR$(m)) + ":" + _TRIM$(STR$(s)) + m$
168.         t$ = MID$(t$, l + 1)
169.     LOOP
170. END SUB
171.  

Since the plan is to only have this information available on a TODAY basis, and not for any given day, I'm not going to try and detect for what days are modified by daylight savings time, and what aren't.  I'm just going to use the overall modifier that our system gives us, and go with that.  If you need something different, then I'll leave it up to you to sort out when to apply the DST modifier and when not to.

[jack]

seems to work ok
but I would prefer calculating the sunrise/set locally instead of accessing the web, also, I am not fond of using the shell and temporary files
here's code that calculates the sunrise/set https://skyandtelescope.org/wp-content/uploads/sunup.bas

[doppler]

So in Australia we have longer Xmas days than you.

Yea, but everything is upside down.

[jack]

I refactored the code

Code: QB64: [Select]

1. '
2. '   This program by Roger W. Sinnott calculates the times of sunrise
3. '   and sunset on any date, accurate to the minute within several
4. '   centuries of the present.  It correctly describes what happens in the
5. '   arctic and antarctic regions, where the Sun may not rise or set on
6. '   a given date.  Enter north latitudes positive, west longitudes
7. '   negative.  For the time zone, enter the number of hours west of
8. '   Greenwich (e.g., 5 for EST, 4 for EDT).  The calculation is
9. '   discussed in Sky & Telescope for August 1994, page 84.
10.  
11. Declare Sub FA(Byref X As Single, Byref Y As Single, Byref T As Single)
12. '        Sunrise-Sunset
13. '        Constants
14. DIM A(2) AS SINGLE, D(2) AS SINGLE, DR AS SINGLE, K1 AS SINGLE
15. DIM P1 AS SINGLE, P2 AS SINGLE, B5 AS SINGLE, L5 AS SINGLE
16. DIM H AS SINGLE, Z0 AS SINGLE, Y AS SINGLE, M AS SINGLE
17. DIM D3 AS SINGLE, G AS SINGLE, D1 AS SINGLE, F AS SINGLE
18. DIM J AS SINGLE, S AS SINGLE, A1 AS SINGLE, J3 AS SINGLE
19. DIM T AS SINGLE, TT AS SINGLE, T0 AS SINGLE, Z1 AS SINGLE
20. DIM C AS SINGLE, Z AS SINGLE, M8 AS SINGLE, W8 AS SINGLE
21. DIM A0 AS SINGLE, D0 AS SINGLE, DA AS SINGLE, DD AS SINGLE
22. DIM C0 AS SINGLE, P AS SINGLE, A2 AS SINGLE, D2 AS SINGLE
23. DIM L0 AS SINGLE, H0 AS SINGLE, H1 AS SINGLE, V0 AS SINGLE
24. DIM L2 AS SINGLE, H2 AS SINGLE, V1 AS SINGLE, V2 AS SINGLE
25. DIM B AS SINGLE, E AS SINGLE, T3 AS SINGLE, H3 AS SINGLE
26. DIM M3 AS SINGLE, H7 AS SINGLE, N7 AS SINGLE, AZ AS SINGLE
27. DIM D7 AS SINGLE
28. DIM S1 AS STRING, R1 AS STRING, M1 AS STRING, M2 AS STRING
29. DIM M3s AS STRING, M4 AS STRING
30. P1 = 3.14159265
31. P2 = 2 * P1
32. DR = P1 / 180
33. K1 = 15 * DR * 1.0027379
34. S1 = "Sunset at  "
35. R1 = "Sunrise at "
36. M1 = "No sunrise this date"
37. M2 = "No sunset this date"
38. M3s = "Sun down all day"
39. M4 = "Sun up all day"
40.  
41. INPUT "Lat, Long (deg)"; B5, L5
42. INPUT "Time zone (hrs)"; H
43. L5 = L5 / 360
44. Z0 = H / 24
45. '
46. '     Calendar --> JD
47. Y = 2020
48. M = 12
49. D3 = 25 'INPUT "Year, Month, Day";Y,M,D3
50. G = 1
51. IF Y < 1583 THEN G = 0
52. D1 = INT(D3)
53. F = D3 - D1 - .5
54. J = -INT(7 * (INT((M + 9) / 12) + Y) / 4)
55. IF G <> 0 THEN
56.     S = SGN(M - 9)
57.     A1 = ABS(M - 9)
58.     J3 = INT(Y + S * INT(A1 / 7))
59.     J3 = -INT((INT(J3 / 100) + 1) * 3 / 4)
60. END IF
61. J = J + INT(275 * M / 9) + D1 + G * J3
62. J = J + 1721027 + 2 * G + 367 * Y
63. IF F < 0 THEN
64.     F = F + 1
65.     J = J - 1
66. END IF
67. T = (J - 2451545) + F
68. TT = T / 36525 + 1 ' TT = centuries
69. '               from 1900.0
70. '     LST at 0h zone time
71. T0 = T / 36525
72. S = 24110.5 + 8640184.813 * T0
73. S = S + 86636.6 * Z0 + 86400 * L5
74. S = S / 86400
75. S = S - INT(S)
76. T0 = S * 360 * DR
77. T = T + Z0
78. '
79. '       Get Sun's Position
80. CALL FA(A(1), D(1), T)
81. T = T + 1
82. CALL FA(A(2), D(2), T)
83. IF A(2) < A(1) THEN A(2) = A(2) + P2
84. Z1 = DR * 90.833 ' Zenith dist.
85. S = SIN(B5 * DR)
86. C = COS(B5 * DR)
87. Z = COS(Z1)
88. M8 = 0
89. W8 = 0
90. PRINT
91. A0 = A(1)
92. D0 = D(1)
93. DA = A(2) - A(1)
94. DD = D(2) - D(1)
95. FOR C0 = 0 TO 23
96.     P = (C0 + 1) / 24
97.     A2 = A(1) + P * DA
98.     D2 = D(1) + P * DD
99.     '
100.     '  Test an hour for an event
101.     L0 = T0 + C0 * K1
102.     L2 = L0 + K1
103.     H0 = L0 - A0
104.     H2 = L2 - A2
105.     H1 = (H2 + H0) / 2 '  Hour angle,
106.     D1 = (D2 + D0) / 2 '  declination,
107.     '                at half hour
108.     IF C0 <= 0 THEN
109.         V0 = S * SIN(D0) + C * COS(D0) * COS(H0) - Z
110.     END IF
111.     V2 = S * SIN(D2) + C * COS(D2) * COS(H2) - Z
112.     IF SGN(V0) <> SGN(V2) THEN
113.         V1 = S * SIN(D1) + C * COS(D1) * COS(H1) - Z
114.         A1 = 2 * V2 - 4 * V1 + 2 * V0
115.         B = 4 * V1 - 3 * V0 - V2
116.         D3 = B * B - 4 * A1 * V0
117.         IF D3 >= 0 THEN
118.             D3 = SQR(D3)
119.             IF V0 < 0 AND V2 > 0 THEN PRINT R1;
120.             IF V0 < 0 AND V2 > 0 THEN M8 = 1
121.             IF V0 > 0 AND V2 < 0 THEN PRINT S1;
122.             IF V0 > 0 AND V2 < 0 THEN W8 = 1
123.             E = (-B + D3) / (2 * A1)
124.             IF E > 1 OR E < 0 THEN E = (-B - D3) / (2 * A1)
125.             T3 = C0 + E + 1 / 120: ' Round off
126.             H3 = INT(T3)
127.             M3 = INT((T3 - H3) * 60)
128.             PRINT USING "##:##"; H3; M3;
129.             H7 = H0 + E * (H2 - H0)
130.             N7 = -COS(D1) * SIN(H7)
131.             D7 = C * SIN(D1) - S * COS(D1) * COS(H7)
132.             AZ = ATN(N7 / D7) / DR
133.             IF D7 < 0 THEN AZ = AZ + 180
134.             IF AZ < 0 THEN AZ = AZ + 360
135.             IF AZ > 360 THEN AZ = AZ - 360
136.             PRINT USING ",  azimuth ###.#"; AZ
137.         END IF
138.     END IF
139.     A0 = A2
140.     D0 = D2
141.     V0 = V2
142. NEXT
143. '  Special msg?
144. '
145. '   Special-message routine
146. IF M8 <> 0 AND W8 <> 0 THEN
147.     IF M8 = 0 THEN PRINT M1
148.     IF W8 = 0 THEN PRINT M2
149. ELSE
150.     IF V2 < 0 THEN PRINT M3s
151.     IF V2 > 0 THEN PRINT M4
152. END IF
153. END
154. '
155.  
156. SUB FA (A5 AS SINGLE, D5 AS SINGLE, T AS SINGLE)
157.     '   Fundamental arguments
158.     '     (Van Flandern &
159.     '     Pulkkinen, 1979)
160.     DIM P2 AS SINGLE, L AS SINGLE, V AS SINGLE, U AS SINGLE
161.     DIM W AS SINGLE, S AS SINGLE, R5 AS SINGLE, G AS SINGLE
162.     DIM TT AS SINGLE
163.     P2 = 6.283185307179586
164.     L = .779072 + .00273790931 * T
165.     G = .993126 + .0027377785 * T
166.     L = L - INT(L): G = G - INT(G)
167.     L = L * P2: G = G * P2
168.     V = .39785 * SIN(L)
169.     V = V - .01000 * SIN(L - G)
170.     V = V + .00333 * SIN(L + G)
171.     V = V - .00021 * TT * SIN(L)
172.     U = 1 - .03349 * COS(G)
173.     U = U - .00014 * COS(2 * L)
174.     U = U + .00008 * COS(L)
175.     W = -.00010 - .04129 * SIN(2 * L)
176.     W = W + .03211 * SIN(G)
177.     W = W + .00104 * SIN(2 * L - G)
178.     W = W - .00035 * SIN(2 * L + G)
179.     W = W - .00008 * TT * SIN(G)
180.     '
181.     '    Compute Sun's RA and Dec
182.     S = W / SQR(U - V * V)
183.     A5 = L + ATN(S / SQR(1 - S * S))
184.     S = V / SQR(U): D5 = ATN(S / SQR(1 - S * S))
185.     R5 = 1.00021 * SQR(U)
186. END SUB
187.  

[Bert22306]

@Bert22306, @johnno56

Give the following version a run, guys, and see what you get:

. . .

For Bert, I'm hoping that you'll basically run but see a whole lot of nothing, as we should error trap now for non-existent files.  You could always try running it as admin and see if that makes a difference on your work machine, but I imagine it's some sort of system limitation.  Powershell is only available from windows 7 up, so if your enterprise machines don't give proper permissions, or run on an older version of windows, then they're definitely not going to work.  A test just to make certain things fail properly, without crashing, would be nice in this case.  :)

Sorry for the delay in responding. Wife kept me busy for Christmas.

This time, I again got the private IP address behind my NAT, as opposed to the public IP address facing the enterprise. But not much more than that:

"Your latitude and longitude is 0 0

"For your location, the following is true for Christmas day:"

"Press any key to continue"

Of course, with Christmas day having passed, I'm not sure what to expect. But you said it. These corporate machines are pretty tightly locked up. They used to trust me with admin privileges, until this last refresh. No more. I should try it on my own machine, when I get a chance.

[johnno56]

Steve,

The 'file not found' went away. But did not display anything. Commented out the first two lines (console) and reran.

See attached for output.

Regards

J

  [ You are not allowed to view this attachment ]  

[SMcNeill]

Steve,

The 'file not found' went away. But did not display anything. Commented out the first two lines (console) and reran.

Does this work from the command line for you:

nslookup myip.opendns.com resolver1.opendns.com

It should give you a couple of lines of information about what your public IP address is.  On windows, we get 4 lines and a blank line.  What's the output look like for Linux?


Second question: Do you have wget installed?  Even if it doesn't find your IP, you should still be able to get sun data for Lat/Long 0, 0.

Make one quick change and test it for me.  In the Download routine, change:

        OUT$ = "wget " + CHR$(34) + link$ + " -O " + file$ + CHR$(34)

To:

        OUT$ = "wget " + CHR$(34) + link$ + CHR$(34) + " -O "+ CHR$(34) + file$ + CHR$(34)

As long as you have wget on your machine, I'm thinking the problem is probably something simple which we might be able to save with quotes in the proper place to deliminate our fields.

Heck, you might even try:

        OUT$ = "wget "  + link$  + " -O " + file$

I'm not on a Linux system, so I can't readily test things for them, but I imagine the glitch here is really something rather simple.  It's not that hard to shell out of wget and have it download a webpage to a file for you.  At least, not usually.  :P

[Bert22306]

And if all works well, the following version should now make adjustments to the time to account for your local time zone and current daylight saving time.

On my own Win10 PC, this works. Up top, the times (datybreak, llocal noon, etc.) seem to be given in GMT (roughly 5 hours ahead). I'll nit: the top info, before the Christmas Day info, would probably benefit from line breaks.

[SMcNeill]

On my own Win10 PC, this works. Up top, the times (datybreak, llocal noon, etc.) seem to be given in GMT (roughly 5 hours ahead). I'll nit: the top info, before the Christmas Day info, would probably benefit from line breaks.

Did you try the version at Reply #16?  It should detect your PC's time offset and adjust accordingly for it.  ;)

I'm thinking most of the Windows issues have been sorted out.  Now, if I could only figure out what the heck was wrong with it on Linux for johnno.

[johnno56]

Steve,

Limited success.

  [ You are not allowed to view this attachment ]  

wget was one of the first programs installed when I upgraded the OS.

  [ You are not allowed to view this attachment ]  

Actual location is: -38.0828828   145.281849

[zaadstra]

Yours won't run, as it relies on window's Powershell to download info from the web.  I'll need to add a Linux method to do the same, and then it'll work for you.

Wget (command line) exists for Windows too - I use it a lot in QB64 to grab a webpage.   If you need to rely on an external program this might be wget, it makes your code a bit more platform independent.

Here is a site with some explanation and a download link to a recent version: https://builtvisible.com/download-your-website-with-wget/