MYOFS2

[STxAxTIC]

Not to be confused with a neighboring post, this one is "Make your own Fibonacci Spiral".

It's not a spiral, by the way.

Code: QB64: [Select]

1. OPTION _EXPLICIT
2.  
3. DO UNTIL _SCREENEXISTS: LOOP
4. _TITLE "Fibonacci Spiral Explorer"
5.  
6. SCREEN _NEWIMAGE(800, 600, 32)
7.  
8. DIM SHARED pi AS DOUBLE
9. pi = 4 * ATN(1)
10.  
11. TYPE Vector
12.     x AS DOUBLE
13.     y AS DOUBLE
14. END TYPE
15.  
16. DIM SHARED CompassCart AS Vector
17. DIM SHARED CompassTheta AS Vector
18. DIM SHARED p AS SINGLE
19. DIM SHARED zoom AS SINGLE
20.  
21. FOR p = 0 TO 1 - .002 STEP .002
22.     zoom = 50 * (1.9 - .9 * p)
23.     CALL DrawEverything
24.     _DISPLAY
25.     _LIMIT 60
26. NEXT
27. SLEEP 1
28.  
29. DO
30.  
31.     IF (_KEYDOWN(18432) = -1) THEN ' Up-arrow
32.         zoom = zoom * (1 + 0.01)
33.     END IF
34.     IF (_KEYDOWN(20480) = -1) THEN ' Down-arrow
35.         zoom = zoom * (1 - 0.01)
36.     END IF
37.     IF (_KEYDOWN(19200) = -1) THEN ' Left-arrow
38.         IF (p > 0) THEN p = p - .005
39.         _DELAY .025
40.     END IF
41.     IF (_KEYDOWN(19712) = -1) THEN ' Right-arrow
42.         p = p + .005
43.         _DELAY .025
44.     END IF
45.     _KEYCLEAR
46.  
47.     CALL DrawEverything
48.     LOCATE 1, 50: PRINT "Adjust Parameter and Zoom with arrow keys."
49.  
50.     _DISPLAY
51.     _LIMIT 60
52. LOOP
53.  
54. SYSTEM
55.  
56. SUB DrawEverything
57.     DIM LastPoint AS Vector
58.     DIM x1 AS DOUBLE
59.     DIM y1 AS DOUBLE
60.     DIM x2 AS DOUBLE
61.     DIM y2 AS DOUBLE
62.     DIM j AS INTEGER
63.     DIM Step1 AS DOUBLE
64.     DIM Step2 AS DOUBLE
65.     DIM StepTemp AS DOUBLE
66.  
67.     CompassCart.x = 1
68.     CompassCart.y = -1
69.     CompassTheta.x = pi
70.     CompassTheta.y = 3 * pi / 2
71.     Step1 = 0
72.     Step2 = 1
73.  
74.     LastPoint.x = 0
75.     LastPoint.y = 0
76.  
77.     CLS
78.     LOCATE 1, 1: PRINT "Parameter="; p
79.     LOCATE 2, 1: PRINT "Zoom="; zoom
80.     FOR j = 1 TO 10
81.  
82.         CALL StepCompass
83.         StepTemp = Step2
84.         Step2 = p * Step2 + Step1
85.         Step1 = StepTemp
86.  
87.         x1 = LastPoint.x
88.         y1 = LastPoint.y
89.         x2 = x1 + SQR(2) * Step2 * CompassCart.x
90.         y2 = y1 + SQR(2) * Step2 * CompassCart.y
91.         CALL clineb(x1 * zoom, y1 * zoom, x2 * zoom, y2 * zoom, _RGBA(255, 255, 255, 155))
92.  
93.         IF (CompassCart.x = 1) AND (CompassCart.y = 1) THEN
94.             CALL ccircle(x1 * zoom, y2 * zoom, SQR(2) * Step2 * zoom, _RGBA(255, 0, 255, 255), CompassTheta.x, CompassTheta.y)
95.         END IF
96.         IF (CompassCart.x = -1) AND (CompassCart.y = 1) THEN
97.             CALL ccircle(x2 * zoom, y1 * zoom, SQR(2) * Step2 * zoom, _RGBA(255, 0, 255, 255), CompassTheta.x, CompassTheta.y)
98.         END IF
99.         IF (CompassCart.x = -1) AND (CompassCart.y = -1) THEN
100.             CALL ccircle(x1 * zoom, y2 * zoom, SQR(2) * Step2 * zoom, _RGBA(255, 0, 255, 255), CompassTheta.x, CompassTheta.y)
101.         END IF
102.         IF (CompassCart.x = 1) AND (CompassCart.y = -1) THEN
103.             CALL ccircle(x2 * zoom, y1 * zoom, SQR(2) * Step2 * zoom, _RGBA(255, 0, 255, 255), CompassTheta.x, CompassTheta.y)
104.         END IF
105.  
106.         LastPoint.x = x2
107.         LastPoint.y = y2
108.     NEXT
109.  
110. END SUB
111.  
112. SUB StepCompass
113.     DIM xx AS INTEGER
114.     DIM yy AS INTEGER
115.     xx = CompassCart.x
116.     yy = CompassCart.y
117.     IF (xx = 1) AND (yy = 1) THEN
118.         CompassCart.x = -1
119.         CompassCart.y = 1
120.         CompassTheta.x = 0
121.         CompassTheta.y = pi / 2
122.     END IF
123.     IF (xx = -1) AND (yy = 1) THEN
124.         CompassCart.x = -1
125.         CompassCart.y = -1
126.         CompassTheta.x = pi / 2
127.         CompassTheta.y = pi
128.     END IF
129.     IF (xx = -1) AND (yy = -1) THEN
130.         CompassCart.x = 1
131.         CompassCart.y = -1
132.         CompassTheta.x = pi
133.         CompassTheta.y = 3 * pi / 2
134.     END IF
135.     IF (xx = 1) AND (yy = -1) THEN
136.         CompassCart.x = 1
137.         CompassCart.y = 1
138.         CompassTheta.x = 3 * pi / 2
139.         CompassTheta.y = 2 * pi
140.     END IF
141. END SUB
142.  
143. SUB cpset (x1 AS DOUBLE, y1 AS DOUBLE, col AS _UNSIGNED LONG)
144.     PSET (_WIDTH / 2 + x1, -y1 + _HEIGHT / 2), col
145. END SUB
146.  
147. SUB clineb (x1 AS DOUBLE, y1 AS DOUBLE, x2 AS DOUBLE, y2 AS DOUBLE, col AS _UNSIGNED LONG)
148.     LINE (_WIDTH / 2 + x1, -y1 + _HEIGHT / 2)-(_WIDTH / 2 + x2, -y2 + _HEIGHT / 2), col, B
149. END SUB
150.  
151. SUB ccircle (x1 AS DOUBLE, y1 AS DOUBLE, rad AS DOUBLE, col AS _UNSIGNED LONG, ang1 AS DOUBLE, ang2 AS DOUBLE)
152.     CIRCLE (_WIDTH / 2 + x1, -y1 + _HEIGHT / 2), rad, col, ang1, ang2
153. END SUB

[bplus]

Definitely interesting like the other posted, MYOSF, I am bookmarking both.