8x8 Connect 4: AI Challenge

[bplus]

@STxAxTIC   Oh ha! you make it look easy!

I just found an easy one when I go first in my port to JB. I thought I had that one fixed but apparently not for the symmetric side. I haven't been able to replicate that in  QB64 yet but I am rushing to get the port done.

I see a pattern in screen shots, so I should be able to confirm after Big Game tonight :)

[STxAxTIC]

here is the exact sequence just in case

[SierraKen]

I just replicated Static's moves and won, incredible!

[bplus]

Just confirmed STx Solution on my port.

If you go first and manage to get 3 on the bottom row with no blocks on either side, you won.

[johnno56]

Bplus,

Out of the three games that I played I managed to win one. Conclusion: I am only more clever than your AI... sometimes... lol

Nicely done!

[bplus]

Thanks Johnno

I have a tiny adjustment so you can do any NxN grid within reason.

Code: QB64: [Select]

1. OPTION _EXPLICIT
2. _TITLE "Connect 4 8x8: AI challenge" 'b+ 2020-12-14 rewrite
3.  
4. DEFLNG A-Z
5. CONST SQ = 60 '            square or grid cell
6. CONST N = 7 '             number of rows and columns
7. CONST SW = SQ * (N + 2) '  screen width
8. CONST SH = SQ * (N + 3) '  screen height
9. CONST NM1 = N - 1 '        N minus 1
10. CONST P = 1 '              Player is 1 on grid
11. CONST AI = -1 '            AI is -1 on grid
12. CONST XO = SQ '            x offset for grid
13. CONST YO = 2 * SQ '        y offset for grid
14.  
15. REDIM SHARED Grid(NM1, NM1) ' 0 = empty  P=1 for Player,  AI=-1  for AI so -4 is win for AI..
16. REDIM SHARED DX(7), DY(7), WinX, WinY, WinD, GameOn, Turn, AIX, AIY, GoFirst ' if find a win, draw it in ShowGrid
17. DX(0) = 1: DY(0) = 0 ': DString$(0) = "East"
18. DX(1) = 1: DY(1) = 1 ': DString$(1) = "South East"
19. DX(2) = 0: DY(2) = 1 ': DString$(2) = "South"
20. DX(3) = -1: DY(3) = 1 ': DString$(3) = "South West"
21. DX(4) = -1: DY(4) = 0 ': DString$(4) = "West"
22. DX(5) = -1: DY(5) = -1 ': DString$(5) = "North West"
23. DX(6) = 0: DY(6) = -1 ': DString$(6) = "North"
24. DX(7) = 1: DY(7) = -1 ' : DString$(7) = "North East"
25.  
26. SCREEN _NEWIMAGE(SW, SH, 32)
27. _DELAY .25
28. _SCREENMOVE _MIDDLE
29. DIM mb, mx, my, row, col, r
30. GameOn = -1: GoFirst = AI: Turn = AI
31. ShowGrid
32. WHILE GameOn
33.     IF Turn = P THEN
34.         WHILE _MOUSEINPUT: WEND
35.         mb = _MOUSEBUTTON(1): mx = _MOUSEX: my = _MOUSEY
36.         IF mb THEN 'get last place mouse button was down
37.             _DELAY .25 'for mouse release
38.             row = ((my - YO) / SQ - .5): col = ((mx - XO) / SQ - .5)
39.             IF col >= 0 AND col <= NM1 AND row >= 0 AND row <= NM1 THEN
40.                 r = GetOpenRow(col) 'find next space open on board
41.                 IF r <> N THEN
42.                     Grid(col, r) = P
43.                     Turn = AI
44.                 END IF
45.             ELSE
46.                 BEEP
47.             END IF
48.         END IF
49.     ELSE
50.         AIMove
51.         Turn = P
52.     END IF
53.     ShowGrid
54.     _DISPLAY
55.     _LIMIT 60
56. WEND
57.  
58. SUB AIMove
59.     ' What this sub does in English:
60.     ' This sub assigns the value to playing each column, then plays the best value with following caveats:
61.     ' + If it finds a winning move, it will play that immediately.
62.     ' + If it finds a spoiler move, it will play that if no winning move was found.
63.     ' + It will poisen the column's scoring, if opponent can play a winning move if AI plays this column,
64.     '   but it might be the only legal move left.  We will have to play it if no better score was found.
65.  
66.     DIM c, r, d, cntA, cntP, bestScore, startR, startC, iStep, test, goodF, i
67.     DIM openRow(NM1) ' find open rows once
68.     DIM scores(NM1) ' evaluate each column's potential
69.     AIX = -1: AIY = -1 ' set these when AI makes move, they are signal to display procedure AI's move.
70.     FOR c = 0 TO NM1
71.         openRow(c) = GetOpenRow(c)
72.         r = openRow(c)
73.         IF r <> N THEN
74.             FOR d = 0 TO 3 ' 4 directions to build connect 4's that use cell c, r
75.                 startC = c + -3 * DX(d): startR = r + -3 * DY(d)
76.                 FOR i = 0 TO 3 ' here we backup from the potential connect 4 in opposite build direction of c, r
77.                     cntA = 0: cntP = 0: goodF = -1 ' reset counts and flag for good connect 4
78.                     'from this start position run 4 steps forward to count all connects involving cell c, r
79.                     FOR iStep = 0 TO 3 ' process a potential connect 4
80.                         test = GR(startC + i * DX(d) + iStep * DX(d), startR + i * DY(d) + iStep * DY(d))
81.                         IF test = N THEN goodF = 0: EXIT FOR 'cant get connect4 from here
82.                         IF test = AI THEN cntA = cntA + 1
83.                         IF test = P THEN cntP = cntP + 1
84.                     NEXT iStep
85.                     IF goodF THEN 'evaluate the Legal Connect4 we could build with c, r
86.                         IF cntA = 3 THEN ' we are done!  winner!
87.                             AIX = c: AIY = r ' <<< this is the needed 4th cell to win tell ShowGrid last cell
88.                             Grid(c, r) = AI '  <<< this is the needed 4th cell to win, add to grid this is AI move
89.                             EXIT SUB
90.                         ELSEIF cntP = 3 THEN 'next best move spoiler!
91.                             AIX = c: AIY = r 'set the move but don't exit there might be a winner
92.                         ELSEIF cntA = 0 AND cntP = 2 THEN
93.                             scores(c) = scores(c) + 6
94.                         ELSEIF cntA = 2 AND cntP = 0 THEN ' very good offense or defense
95.                             scores(c) = scores(c) + 5 'play this to connect 3 or prevent player from Connect 3
96.                         ELSEIF cntA = 0 AND cntP = 1 THEN
97.                             scores(c) = scores(c) + 4
98.                         ELSEIF (cntA = 1 AND cntP = 0) OR (cntA = 0 AND cntP = 1) THEN 'good offense or defense
99.                             scores(c) = scores(c) + 3 ' play this to connect 2 or prevent player from Connect 2
100.                         ELSEIF (cntA = 0 AND cntP = 0) THEN ' OK it's not a wasted move as it has potential for connect4
101.                             scores(c) = scores(c) + 1 ' this is good move because this can still be a Connect 4
102.                         END IF
103.                     END IF ' in the board
104.                 NEXT i
105.             NEXT d
106.             IF Stupid(c, r) THEN scores(c) = -1000 + scores(c) ' poison because if played the human can win
107.         END IF
108.     NEXT
109.     IF AIX <> -1 THEN ' we found a spoiler so move there since we haven't found a winner
110.         Grid(AIX, AIY) = AI ' make move on grid and done!
111.         EXIT SUB
112.     ELSE
113.         bestScore = -1000 ' a negative score indicates that the player can beat AI with their next move
114.         FOR c = 0 TO NM1
115.             r = openRow(c)
116.             IF r <> N THEN
117.                 IF scores(c) > bestScore THEN bestScore = scores(c): AIY = r: AIX = c
118.             END IF
119.         NEXT
120.         IF AIX <> -1 THEN
121.             Grid(AIX, AIY) = AI ' make first best score move we found
122.         ELSE 'We have trouble!  Oh but it could be there are no moves!!!
123.             ' checkWin is run after every move by AI or Player if there were no legal moves left it should have caught that.
124.             ' Just in case it didn't here is an error stop!
125.  
126.             'note: LOCATE here is Row, Column the reverse of Just Basic
127.             BEEP: LOCATE 4, 2: PRINT "AI has failed to find a proper move, pess any to end..."
128.             SLEEP ' <<< pause until user presses a key
129.             END
130.         END IF
131.     END IF
132. END SUB
133.  
134. FUNCTION GetOpenRow (forCol)
135.     DIM i
136.     GetOpenRow = N 'assume none open
137.     IF forCol < 0 OR forCol > NM1 THEN EXIT FUNCTION
138.     FOR i = NM1 TO 0 STEP -1
139.         IF Grid(forCol, i) = 0 THEN GetOpenRow = i: EXIT FUNCTION
140.     NEXT
141. END FUNCTION
142.  
143. FUNCTION Stupid (c, r)
144.     DIM pr
145.  
146.     Grid(c, r) = AI
147.     pr = GetOpenRow(c)
148.     IF pr <> N THEN
149.         Grid(c, pr) = P
150.         IF CheckWin = 4 THEN Stupid = -1
151.         Grid(c, pr) = 0
152.     END IF
153.     Grid(c, r) = 0
154. END FUNCTION
155.  
156. FUNCTION GR (c, r) ' if c, r are out of bounds returns N else returns grid(c, r)
157.     ' need to check the grid(c, r) but only if c, r is on the board
158.     IF c < 0 OR c > NM1 OR r < 0 OR r > NM1 THEN GR = N ELSE GR = Grid(c, r)
159. END FUNCTION
160.  
161. SUB ShowGrid
162.     DIM i, r, c, check, s$, y$
163.     CLS
164.     FOR i = 0 TO N 'grid
165.         LINE (SQ * i + XO, YO)-STEP(0, N * SQ), &HFF00FF00
166.         LINE (XO, SQ * i + YO)-STEP(N * SQ, 0), &HFF00FF00
167.     NEXT
168.     FOR r = NM1 TO 0 STEP -1 'plays
169.         FOR c = 0 TO NM1
170.             'in grid rows are reversed 0 is top row
171.             IF Grid(c, r) = P THEN
172.                 LINE (c * SQ + XO + 3, r * SQ + YO + 3)-STEP(SQ - 6, SQ - 6), &HFFFF0000, BF
173.             ELSEIF Grid(c, r) = AI THEN
174.                 IF c = AIX AND r = AIY THEN 'highlite last AI move
175.                     LINE (c * SQ + XO + 3, r * SQ + YO + 3)-STEP(SQ - 6, SQ - 6), &HFF5555FF, BF
176.                 ELSE
177.                     LINE (c * SQ + XO + 3, r * SQ + YO + 3)-STEP(SQ - 6, SQ - 6), &HFF0000FF, BF
178.                 END IF
179.             END IF
180.         NEXT
181.     NEXT
182.     _DISPLAY
183.     check = CheckWin
184.     IF check THEN 'report end of round ad see if want to play again
185.         IF check = 4 OR check = -4 THEN
186.             FOR i = 0 TO 3
187.                 LINE ((WinX + i * DX(WinD)) * SQ + XO + 5, (WinY + i * DY(WinD)) * SQ + YO + 5)-STEP(SQ - 10, SQ - 10), &HFFFFFFFF, B
188.             NEXT
189.         END IF
190.         IF check = -4 THEN
191.             s$ = "AI is Winner!"
192.         ELSEIF check = 4 THEN
193.             s$ = "Human is Winner!"
194.         ELSEIF check = N THEN
195.             s$ = "Board is full, no winner." ' keep Turn the same
196.         END IF
197.         LOCATE 2, 2: PRINT s$
198.         _DISPLAY
199.         LOCATE 4, 2: INPUT "Play again? just press enter quit with any other ", y$
200.         IF y$ = "" THEN
201.             REDIM Grid(NM1, NM1)
202.             IF GoFirst = P THEN GoFirst = AI ELSE GoFirst = P
203.             Turn = GoFirst
204.         ELSE
205.             GameOn = 0
206.         END IF
207.     END IF
208. END SUB
209.  
210. FUNCTION CheckWin
211.     DIM gridFull, r, c, s, i
212.     ' return WinX, WinY, WinD along with +/- score, returns N  if grid full, 0 if no win and grid not full
213.     gridFull = N
214.     FOR r = NM1 TO 0 STEP -1 'bottom to top
215.         FOR c = 0 TO NM1
216.             IF Grid(c, r) THEN 'check if c starts a row
217.                 IF c < NM1 - 2 THEN
218.                     s = 0
219.                     FOR i = 0 TO 3
220.                         s = s + Grid(c + i, r)
221.                     NEXT
222.                     IF s = 4 OR s = -4 THEN
223.                         WinX = c: WinY = r: WinD = 0
224.                         CheckWin = s: EXIT FUNCTION
225.                     END IF
226.                 END IF
227.                 IF r > 2 THEN 'check if c starts a col
228.                     s = 0
229.                     FOR i = 0 TO 3
230.                         s = s + Grid(c, r - i)
231.                     NEXT
232.                     IF s = 4 OR s = -4 THEN
233.                         WinX = c: WinY = r: WinD = 6 'north
234.                         CheckWin = s: EXIT FUNCTION
235.                     END IF
236.                 END IF
237.                 IF r > 2 AND c < NM1 - 2 THEN 'check if c starts diagonal up to right
238.                     s = 0
239.                     FOR i = 0 TO 3
240.                         s = s + Grid(c + i, r - i)
241.                     NEXT
242.                     IF s = 4 OR s = -4 THEN ' north  east
243.                         WinX = c: WinY = r: WinD = 7
244.                         CheckWin = s: EXIT FUNCTION
245.                     END IF
246.                 END IF
247.                 IF r > 2 AND c > 2 THEN 'check if c starts a diagonal up to left
248.                     s = 0
249.                     FOR i = 0 TO 3
250.                         s = s + Grid(c - i, r - i)
251.                     NEXT
252.                     IF s = 4 OR s = -4 THEN ' north west
253.                         WinX = c: WinY = r: WinD = 5
254.                         CheckWin = s: EXIT FUNCTION
255.                     END IF
256.                 END IF
257.             ELSE
258.                 gridFull = 0 ' at least one enpty cell left
259.             END IF 'grid is something
260.         NEXT
261.     NEXT
262.     CheckWin = gridFull
263. END FUNCTION
264.  

Time for Big Game!

[bplus]

I have a mod coming for any amount of rows and columns but have to check out why the AI made a Stupid move when I was checking out a 10x6 grid. I suspect my CheckWin Function fails for rectangular shaped grids though no "Subscript out of range" error was reported.

Dang! What a game, 47 to 42, too bad Browns lost but it was a hell of a game!

[johnno56]

"What a game."? I thought the game was Connect-4... "Browns lost"? Connect-4 uses basically blue and red.

I am obviously suffering from caffeine withdrawal....

[bplus]

"What a game."? I thought the game was Connect-4... "Browns lost"? Connect-4 uses basically blue and red.

I am obviously suffering from caffeine withdrawal....

No not caffeine, American football, the game was between Cleveland Browns (Browns Town) and Baltimore Ravens.
Ravens specially vile ;-) because previous Browns owner sold team to Baltimore and we were without Browns team for awhile, we've not seen a season so far above 500 for a long time. This game was something too, not often both teams are in the 40 somethings in score.

Anyway, all this tells me the colors for Connect 4 had better be Brown (very orange brown) and Purple (a very dark and red purple almost black like raven). The grid(iron) is already green but maybe that should be white with field green fill. ;-))

[bplus]

Here is an update where you see the scoring system in the bottom row of numbers:

Code: QB64: [Select]

1. OPTION _EXPLICIT ' Connect 4 NumRows X NumCols 2020_12_15.bas update bplus
2. ' New: any number of rows or columns within reason, colors changed, STx Win against AI fix.
3.  
4. DEFLNG A-Z
5. CONST SQ = 60 '       square or grid cell
6. CONST NumCols = 8 '   number of columns
7. CONST NumRows = 8 '   you guessed it
8. CONST NCM1 = NumCols - 1 ' NumCols minus 1
9. CONST NRM1 = NumRows - 1 ' you can guess surely
10. CONST SW = SQ * (NumCols + 2) '  screen width
11. CONST SH = SQ * (NumRows + 3) '  screen height
12. CONST P = 1 '       Player is 1 on grid
13. CONST AI = -1 '     AI is -1 on grid
14. CONST XO = SQ '     x offset for grid
15. CONST YO = 2 * SQ ' y offset for grid
16.  
17. REDIM SHARED Grid(NCM1, NRM1) ' 0 = empty  P=1 for Player,  AI=-1  for AI so -4 is win for AI..
18. REDIM SHARED DX(7), DY(7), WinX, WinY, WinD, GameOn, Turn, AIX, AIY, GoFirst ' if find a win, draw it in ShowGrid
19. DX(0) = 1: DY(0) = 0 ': DString$(0) = "East"
20. DX(1) = 1: DY(1) = 1 ': DString$(1) = "South East"
21. DX(2) = 0: DY(2) = 1 ': DString$(2) = "South"
22. DX(3) = -1: DY(3) = 1 ': DString$(3) = "South West"
23. DX(4) = -1: DY(4) = 0 ': DString$(4) = "West"
24. DX(5) = -1: DY(5) = -1 ': DString$(5) = "North West"
25. DX(6) = 0: DY(6) = -1 ': DString$(6) = "North"
26. DX(7) = 1: DY(7) = -1 ' : DString$(7) = "North East"
27. REDIM SHARED Scores(NCM1)
28.  
29. SCREEN _NEWIMAGE(SW, SH, 32)
30. _SCREENMOVE 360, 60
31. DIM mb, mx, my, row, col, r
32. _TITLE "Connect 4: " + _TRIM$(STR$(NumCols)) + "x" + _TRIM$(STR$(NumRows)) + " with bplus AI"
33. GameOn = -1: GoFirst = AI: Turn = AI
34. ShowGrid
35. WHILE GameOn
36.     IF Turn = P THEN
37.         WHILE _MOUSEINPUT: WEND
38.         mb = _MOUSEBUTTON(1): mx = _MOUSEX: my = _MOUSEY
39.         IF mb THEN 'get last place mouse button was down
40.             _DELAY .25 'for mouse release
41.             row = ((my - YO) / SQ - .5): col = ((mx - XO) / SQ - .5)
42.             IF col >= 0 AND col <= NCM1 AND row >= 0 AND row < 8 THEN
43.                 'find next space open on board
44.                 r = GetOpenRow(col)
45.                 IF r <> NumRows THEN
46.                     Grid(col, r) = P
47.                     Turn = AI
48.                 END IF
49.             ELSE
50.                 BEEP
51.             END IF
52.         END IF
53.     ELSE
54.         AIMove
55.         Turn = P
56.     END IF
57.     ShowGrid
58.     _DISPLAY
59.     _LIMIT 60
60. WEND
61.  
62. SUB AIMove
63.     ' What this sub does in English:
64.     ' This sub assigns the value to playing each column, then plays the best value with following caveats:
65.     ' + If it finds a winning move, it will play that immediately.
66.     ' + If it finds a spoiler move, it will play that if no winning move was found.
67.     ' + It will poisen the column's scoring, if opponent can play a winning move if AI plays this column,
68.     '   but it might be the only legal move left.  We will have to play it if no better score was found.
69.  
70.     DIM c, r, d, cntA, cntP, bestScore, startR, startC, iStep, test, goodF, i
71.     DIM openRow(NCM1) ' find open rows once
72.     REDIM Scores(NCM1) ' evaluate each column's potential
73.     AIX = -1: AIY = -1 ' set these when AI makes move, they are signal to display procedure AI's move.
74.     FOR c = 0 TO NCM1
75.         openRow(c) = GetOpenRow(c)
76.         r = openRow(c)
77.         IF r <> NumRows THEN
78.             FOR d = 0 TO 3 ' 4 directions to build connect 4's that use cell c, r
79.                 startC = c + -3 * DX(d): startR = r + -3 * DY(d)
80.                 FOR i = 0 TO 3 ' here we backup from the potential connect 4 in opposite build direction of c, r
81.                     cntA = 0: cntP = 0: goodF = -1 ' reset counts and flag for good connect 4
82.                     'from this start position run 4 steps forward to count all connects involving cell c, r
83.                     FOR iStep = 0 TO 3 ' process a potential connect 4
84.                         test = GR(startC + i * DX(d) + iStep * DX(d), startR + i * DY(d) + iStep * DY(d))
85.                         IF test = NumRows THEN goodF = 0: EXIT FOR 'cant get connect4 from here
86.                         IF test = AI THEN cntA = cntA + 1
87.                         IF test = P THEN cntP = cntP + 1
88.                     NEXT iStep
89.                     IF goodF THEN 'evaluate the Legal Connect4 we could build with c, r
90.                         IF cntA = 3 THEN ' we are done!  winner!
91.                             AIX = c: AIY = r ' <<< this is the needed 4th cell to win tell ShowGrid last cell
92.                             Grid(c, r) = AI '  <<< this is the needed 4th cell to win, add to grid this is AI move
93.                             Scores(c) = 1000
94.                             EXIT SUB
95.                         ELSEIF cntP = 3 THEN 'next best move spoiler!
96.                             AIX = c: AIY = r 'set the move but don't exit there might be a winner
97.                             Scores(c) = 999
98.                         ELSEIF cntA = 0 AND cntP = 2 THEN
99.                             Scores(c) = Scores(c) + 8
100.                         ELSEIF cntA = 2 AND cntP = 0 THEN ' very good offense or defense
101.                             Scores(c) = Scores(c) + 4 'play this to connect 3 or prevent player from Connect 3
102.                         ELSEIF cntA = 0 AND cntP = 1 THEN
103.                             Scores(c) = Scores(c) + 4
104.                         ELSEIF (cntA = 1 AND cntP = 0) THEN 'good offense or defense
105.                             Scores(c) = Scores(c) + 2 ' play this to connect 2 or prevent player from Connect 2
106.                         ELSEIF (cntA = 0 AND cntP = 0) THEN ' OK it's not a wasted move as it has potential for connect4
107.                             Scores(c) = Scores(c) + 1 ' this is good move because this can still be a Connect 4
108.                         END IF
109.                     END IF ' in the board
110.                 NEXT i
111.             NEXT d
112.             IF Stupid(c, r) THEN Scores(c) = -1000 + Scores(c) ' poison because if played the human can win
113.         END IF
114.     NEXT
115.     IF AIX <> -1 THEN ' we found a spoiler so move there since we haven't found a winner
116.         Grid(AIX, AIY) = AI ' make move on grid and done!
117.         EXIT SUB
118.     ELSE
119.         bestScore = -1000 ' a negative score indicates that the player can beat AI with their next move
120.         FOR c = 0 TO NCM1
121.             r = openRow(c)
122.             IF r <> NumRows THEN
123.                 IF Scores(c) > bestScore THEN bestScore = Scores(c): AIY = r: AIX = c
124.             END IF
125.         NEXT
126.         IF AIX <> -1 THEN
127.             Grid(AIX, AIY) = AI ' make first best score move we found
128.         ELSE 'We have trouble!  Oh but it could be there are no moves!!!
129.             ' checkWin is run after every move by AI or Player if there were no legal moves left it should have caught that.
130.             ' Just in case it didn't here is an error stop!
131.             BEEP: LOCATE 4, 2: PRINT "AI has failed to find a proper move, pess any to end..."
132.             SLEEP ' <<< pause until user presses a key
133.             END
134.         END IF
135.     END IF
136. END SUB
137.  
138. FUNCTION GetOpenRow (forCol)
139.     DIM i
140.     GetOpenRow = NumRows 'assume none open
141.     IF forCol < 0 OR forCol > NCM1 THEN EXIT FUNCTION
142.     FOR i = NRM1 TO 0 STEP -1
143.         IF Grid(forCol, i) = 0 THEN GetOpenRow = i: EXIT FUNCTION
144.     NEXT
145. END FUNCTION
146.  
147. FUNCTION Stupid (c, r)
148.     DIM pr
149.     Grid(c, r) = AI
150.     pr = GetOpenRow(c)
151.     IF pr <> NumRows THEN
152.         Grid(c, pr) = P
153.         IF CheckWin = 4 THEN Stupid = -1
154.         Grid(c, pr) = 0
155.     END IF
156.     Grid(c, r) = 0
157. END FUNCTION
158.  
159. FUNCTION GR (c, r) ' if c, r are out of bounds returns N else returns grid(c, r)
160.     ' need to check the grid(c, r) but only if c, r is on the board
161.     IF c < 0 OR c > NCM1 OR r < 0 OR r > NRM1 THEN GR = NumRows ELSE GR = Grid(c, r)
162. END FUNCTION
163.  
164. SUB ShowGrid
165.     DIM i, r, c, check, s$, k$
166.     CLS
167.     LINE (XO, YO)-STEP(NumCols * SQ, NumRows * SQ), &HFF004400, BF
168.     FOR i = 0 TO NumCols 'grid
169.         LINE (SQ * i + XO, YO)-STEP(0, NumRows * SQ), &HFFFFFFFF
170.     NEXT
171.     FOR i = 0 TO NumRows
172.         LINE (XO, SQ * i + YO)-STEP(NumCols * SQ, 0), &HFFFFFFFF
173.     NEXT
174.     FOR r = NRM1 TO 0 STEP -1 'plays
175.         FOR c = 0 TO NCM1
176.             'in grid rows are reversed 0 is top row
177.             IF Grid(c, r) = P THEN
178.                 LINE (c * SQ + XO + 3, r * SQ + YO + 3)-STEP(SQ - 6, SQ - 6), &HFFFF2200, BF
179.             ELSEIF Grid(c, r) = AI THEN
180.                 IF c = AIX AND r = AIY THEN 'highlite last AI move
181.                     LINE (c * SQ + XO + 3, r * SQ + YO + 3)-STEP(SQ - 6, SQ - 6), &HFF660088, BF
182.                 ELSE
183.                     LINE (c * SQ + XO + 3, r * SQ + YO + 3)-STEP(SQ - 6, SQ - 6), &HFF440066, BF
184.                 END IF
185.             END IF
186.             s$ = _TRIM$(STR$(Scores(c)))
187.             _PRINTSTRING (XO + c * SQ + (60 - LEN(s$) * 8) / 2, YO + SQ * NumRows + 22), s$
188.         NEXT
189.     NEXT
190.     _DISPLAY
191.     check = CheckWin
192.     IF check THEN 'report end of round ad see if want to play again
193.         IF check = 4 OR check = -4 THEN
194.             FOR i = 0 TO 3
195.                 LINE ((WinX + i * DX(WinD)) * SQ + XO + 5, (WinY + i * DY(WinD)) * SQ + YO + 5)-STEP(SQ - 10, SQ - 10), &HFFFFFF00, B
196.             NEXT
197.         END IF
198.         IF check = -4 THEN
199.             s$ = "AI is Winner!"
200.         ELSEIF check = 4 THEN
201.             s$ = "Human is Winner!"
202.         ELSEIF check = NumRows THEN
203.             s$ = "Board is full, no winner." ' keep Turn the same
204.         END IF
205.         LOCATE 2, ((SW - LEN(s$) * 8) / 2) / 8: PRINT s$
206.         s$ = "Play again? press spacebar, any other to quit... "
207.         LOCATE 4, ((SW - LEN(s$) * 8) / 2) / 8: PRINT s$
208.         _DISPLAY
209.         WHILE LEN(k$) = 0
210.             k$ = INKEY$
211.             _LIMIT 200
212.         WEND
213.         IF k$ = " " THEN
214.             REDIM Grid(NCM1, NRM1), Scores(NCM1)
215.             IF GoFirst = P THEN GoFirst = AI ELSE GoFirst = P
216.             Turn = GoFirst
217.         ELSE
218.             GameOn = 0
219.         END IF
220.     END IF
221. END SUB
222.  
223. FUNCTION CheckWin ' return WinX, WinY, WinD along with +/- 4, returns NumRows if grid full, 0 if no win and grid not full
224.     DIM gridFull, r, c, s, i
225.  
226.     gridFull = NumRows
227.     FOR r = NRM1 TO 0 STEP -1 'bottom to top
228.         FOR c = 0 TO NCM1
229.             IF Grid(c, r) THEN 'check if c starts a row
230.                 IF c < NCM1 - 2 THEN
231.                     s = 0
232.                     FOR i = 0 TO 3
233.                         s = s + Grid(c + i, r)
234.                     NEXT
235.                     IF s = 4 OR s = -4 THEN
236.                         WinX = c: WinY = r: WinD = 0
237.                         CheckWin = s: EXIT FUNCTION
238.                     END IF
239.                 END IF
240.                 IF r > 2 THEN 'check if c starts a col
241.                     s = 0
242.                     FOR i = 0 TO 3
243.                         s = s + Grid(c, r - i)
244.                     NEXT
245.                     IF s = 4 OR s = -4 THEN
246.                         WinX = c: WinY = r: WinD = 6 'north
247.                         CheckWin = s: EXIT FUNCTION
248.                     END IF
249.                 END IF
250.                 IF r > 2 AND c < NCM1 - 2 THEN 'check if c starts diagonal up to right
251.                     s = 0
252.                     FOR i = 0 TO 3
253.                         s = s + Grid(c + i, r - i)
254.                     NEXT
255.                     IF s = 4 OR s = -4 THEN ' north  east
256.                         WinX = c: WinY = r: WinD = 7
257.                         CheckWin = s: EXIT FUNCTION
258.                     END IF
259.                 END IF
260.                 IF r > 2 AND c > 2 THEN 'check if c starts a diagonal up to left
261.                     s = 0
262.                     FOR i = 0 TO 3
263.                         s = s + Grid(c - i, r - i)
264.                     NEXT
265.                     IF s = 4 OR s = -4 THEN ' north west
266.                         WinX = c: WinY = r: WinD = 5
267.                         CheckWin = s: EXIT FUNCTION
268.                     END IF
269.                 END IF
270.             ELSE
271.                 gridFull = 0 ' at least one enpty cell left
272.             END IF 'grid is something
273.         NEXT
274.     NEXT
275.     CheckWin = gridFull
276. END FUNCTION
277.  

[bplus]

Oh sorry, I just noticed 

...STx Win against AI fix.

in comments.

Not yet, it may play different but weaker? Coming soon, game recording and feeding AI the players last move for more info to work on.

[bplus]

Well I went full circle from recording games in txt file then tried adding Steve's humongous SaveImage BI, BM and then decided it is enough to number the squares by move number and get a screen shot when you've got a winner, a bit like Stx showed when he found a winning combination.

I have ruined Stx quick game win pattern with kind of a simple instruction to play on top of the last move, all other things being equal. I suck at playing this game so not sure if the AI is stronger, much stronger or the same. It can't be weaker.

OK so after a win or tie, all the squares get numbered so if you've got a winner just take a snapshot and brag about it here, please!

Code: QB64: [Select]

1. OPTION _EXPLICIT ' Connect 4 NumRows X NumCols 2020_12_16.bas update bplus
2. DEFLNG A-Z
3. CONST SQ = 60 '       square or grid cell
4. CONST NumCols = 8 '   number of columns
5. CONST NumRows = 8 '   you guessed it
6. CONST NCM1 = NumCols - 1 ' NumCols minus 1
7. CONST NRM1 = NumRows - 1 ' you can guess surely
8. CONST SW = SQ * (NumCols + 2) '  screen width
9. CONST SH = SQ * (NumRows + 3) '  screen height
10. CONST P = 1 '       Player is 1 on grid
11. CONST AI = -1 '     AI is -1 on grid
12. CONST XO = SQ '     x offset for grid
13. CONST YO = 2 * SQ ' y offset for grid
14.  
15. REDIM SHARED Grid(NCM1, NRM1) ' 0 = empty  P=1 for Player,  AI=-1  for AI so -4 is win for AI..
16. REDIM SHARED DX(7), DY(7) ' Directions
17. DX(0) = 1: DY(0) = 0 ': DString$(0) = "East"
18. DX(1) = 1: DY(1) = 1 ': DString$(1) = "South East"
19. DX(2) = 0: DY(2) = 1 ': DString$(2) = "South"
20. DX(3) = -1: DY(3) = 1 ': DString$(3) = "South West"
21. DX(4) = -1: DY(4) = 0 ': DString$(4) = "West"
22. DX(5) = -1: DY(5) = -1 ': DString$(5) = "North West"
23. DX(6) = 0: DY(6) = -1 ': DString$(6) = "North"
24. DX(7) = 1: DY(7) = -1 ' : DString$(7) = "North East"
25. REDIM SHARED Scores(NCM1) ' rating column for AI and displaying them
26. REDIM SHARED AIX, AIY ' last move of AI for highlighting in display
27. REDIM SHARED WinX, WinY, WinD ' display Winning Connect 4
28. REDIM SHARED GameOn, Turn, GoFirst, PlayerLastMoveCol, PlayerLastMoveRow, MoveNum ' game tracking
29. REDIM SHARED Record$(NCM1, NRM1)
30.  
31. SCREEN _NEWIMAGE(SW, SH, 32)
32. _SCREENMOVE 360, 60
33. DIM mb, mx, my, row, col, r
34. _TITLE "Connect 4: " + _TRIM$(STR$(NumCols)) + "x" + _TRIM$(STR$(NumRows)) + " with AI"
35. GameOn = -1: GoFirst = AI: Turn = AI: MoveNum = 0
36. ShowGrid
37. WHILE GameOn
38.     IF Turn = P THEN
39.         WHILE _MOUSEINPUT: WEND
40.         mb = _MOUSEBUTTON(1): mx = _MOUSEX: my = _MOUSEY
41.         IF mb THEN 'get last place mouse button was down
42.             _DELAY .25 'for mouse release
43.             row = ((my - YO) / SQ - .5): col = ((mx - XO) / SQ - .5)
44.             IF col >= 0 AND col <= NCM1 AND row >= 0 AND row < 8 THEN
45.                 r = GetOpenRow(col)
46.                 IF r <> NumRows THEN
47.                     Grid(col, r) = P: Turn = AI: PlayerLastMoveCol = col: PlayerLastMoveRow = r: MoveNum = MoveNum + 1
48.                 END IF
49.             ELSE
50.                 BEEP
51.             END IF
52.         END IF
53.     ELSE
54.         AIMove
55.         Turn = P: MoveNum = MoveNum + 1
56.     END IF
57.     ShowGrid
58.     _DISPLAY
59.     _LIMIT 60
60. WEND
61.  
62. SUB AIMove
63.     ' What this sub does in English:
64.     ' This sub assigns the value to playing each column, then plays the best value with following caveats:
65.     ' + If it finds a winning move, it will play that immediately.
66.     ' + If it finds a spoiler move, it will play that if no winning move was found.
67.     ' + It will poisen the column's scoring, if opponent can play a winning move if AI plays this column,
68.     '   but it might be the only legal move left.  We will have to play it if no better score was found.
69.  
70.     DIM c, r, d, cntA, cntP, bestScore, startR, startC, iStep, test, goodF, i
71.     DIM openRow(NCM1) ' find open rows once
72.     REDIM Scores(NCM1) ' evaluate each column's potential
73.     AIX = -1: AIY = -1 ' set these when AI makes move, they are signal to display procedure AI's move.
74.     FOR c = 0 TO NCM1
75.         openRow(c) = GetOpenRow(c)
76.         r = openRow(c)
77.         IF r <> NumRows THEN
78.             FOR d = 0 TO 3 ' 4 directions to build connect 4's that use cell c, r
79.                 startC = c + -3 * DX(d): startR = r + -3 * DY(d)
80.                 FOR i = 0 TO 3 ' here we backup from the potential connect 4 in opposite build direction of c, r
81.                     cntA = 0: cntP = 0: goodF = -1 ' reset counts and flag for good connect 4
82.                     'from this start position run 4 steps forward to count all connects involving cell c, r
83.                     FOR iStep = 0 TO 3 ' process a potential connect 4
84.                         test = GR(startC + i * DX(d) + iStep * DX(d), startR + i * DY(d) + iStep * DY(d))
85.                         IF test = NumRows THEN goodF = 0: EXIT FOR 'cant get connect4 from here
86.                         IF test = AI THEN cntA = cntA + 1
87.                         IF test = P THEN cntP = cntP + 1
88.                     NEXT iStep
89.                     IF goodF THEN 'evaluate the Legal Connect4 we could build with c, r
90.                         IF cntA = 3 THEN ' we are done!  winner!
91.                             AIX = c: AIY = r ' <<< this is the needed 4th cell to win tell ShowGrid last cell
92.                             Grid(c, r) = AI '  <<< this is the needed 4th cell to win, add to grid this is AI move
93.                             Scores(c) = 1000
94.                             EXIT SUB
95.                         ELSEIF cntP = 3 THEN 'next best move spoiler!
96.                             AIX = c: AIY = r 'set the move but don't exit there might be a winner
97.                             Scores(c) = 900
98.                         ELSEIF cntA = 0 AND cntP = 2 THEN
99.                             Scores(c) = Scores(c) + 8
100.                         ELSEIF cntA = 2 AND cntP = 0 THEN ' very good offense or defense
101.                             Scores(c) = Scores(c) + 4 'play this to connect 3 or prevent player from Connect 3
102.                         ELSEIF cntA = 0 AND cntP = 1 THEN
103.                             Scores(c) = Scores(c) + 4
104.                         ELSEIF (cntA = 1 AND cntP = 0) THEN 'good offense or defense
105.                             Scores(c) = Scores(c) + 2 ' play this to connect 2 or prevent player from Connect 2
106.                         ELSEIF (cntA = 0 AND cntP = 0) THEN ' OK it's not a wasted move as it has potential for connect4
107.                             Scores(c) = Scores(c) + 1 ' this is good move because this can still be a Connect 4
108.                         END IF
109.                     END IF ' in the board
110.                 NEXT i
111.             NEXT d
112.             IF Stupid(c, r) THEN Scores(c) = -1000 + Scores(c) ' poison because if played the human can win
113.         END IF
114.     NEXT
115.     IF AIX <> -1 THEN ' we found a spoiler so move there since we haven't found a winner
116.         Grid(AIX, AIY) = AI ' make move on grid and done!
117.         EXIT SUB
118.     ELSE
119.         IF GetOpenRow(PlayerLastMoveCol) < NumRows THEN 'all things being equal play on top of player's last move
120.             bestScore = Scores(PlayerLastMoveCol): AIY = PlayerLastMoveRow - 1: AIX = PlayerLastMoveCol
121.         ELSE
122.             bestScore = -1000 ' a negative score indicates that the player can beat AI with their next move
123.         END IF
124.         FOR c = 0 TO NCM1
125.             r = openRow(c)
126.             IF r <> NumRows THEN
127.                 IF Scores(c) > bestScore THEN bestScore = Scores(c): AIY = r: AIX = c
128.             END IF
129.         NEXT
130.         IF AIX <> -1 THEN
131.             Grid(AIX, AIY) = AI ' make first best score move we found
132.         ELSE 'We have trouble!  Oh but it could be there are no moves!!!
133.             ' checkWin is run after every move by AI or Player if there were no legal moves left it should have caught that.
134.             ' Just in case it didn't here is an error stop!
135.             BEEP: LOCATE 4, 2: PRINT "AI has failed to find a proper move, press any to end..."
136.             SLEEP ' <<< pause until user presses a key
137.             END
138.         END IF
139.     END IF
140. END SUB
141.  
142. FUNCTION GetOpenRow (forCol)
143.     DIM i
144.     GetOpenRow = NumRows 'assume none open
145.     IF forCol < 0 OR forCol > NCM1 THEN EXIT FUNCTION
146.     FOR i = NRM1 TO 0 STEP -1
147.         IF Grid(forCol, i) = 0 THEN GetOpenRow = i: EXIT FUNCTION
148.     NEXT
149. END FUNCTION
150.  
151. FUNCTION Stupid (c, r)
152.     DIM pr
153.     Grid(c, r) = AI
154.     pr = GetOpenRow(c)
155.     IF pr <> NumRows THEN
156.         Grid(c, pr) = P
157.         IF CheckWin = 4 THEN Stupid = -1
158.         Grid(c, pr) = 0
159.     END IF
160.     Grid(c, r) = 0
161. END FUNCTION
162.  
163. FUNCTION GR (c, r) ' if c, r are out of bounds returns N else returns grid(c, r)
164.     ' need to check the grid(c, r) but only if c, r is on the board
165.     IF c < 0 OR c > NCM1 OR r < 0 OR r > NRM1 THEN GR = NumRows ELSE GR = Grid(c, r)
166. END FUNCTION
167.  
168. SUB ShowGrid
169.     STATIC lastMoveNum
170.     DIM i, r, c, check, s$, k$
171.     IF MoveNum <> lastMoveNum THEN ' file newest move
172.         IF MoveNum = 1 THEN REDIM Record$(NCM1, NRM1)
173.         IF Turn = -1 THEN
174.             Record$(PlayerLastMoveCol, PlayerLastMoveRow) = _TRIM$(STR$(MoveNum)) + " " + "P"
175.         ELSE
176.             Record$(AIX, AIY) = _TRIM$(STR$(MoveNum)) + " " + "A"
177.         END IF
178.         lastMoveNum = MoveNum
179.     END IF
180.     CLS
181.     LINE (XO, YO)-STEP(NumCols * SQ, NumRows * SQ), &HFF004400, BF
182.     FOR i = 0 TO NumCols 'grid
183.         LINE (SQ * i + XO, YO)-STEP(0, NumRows * SQ), &HFFFFFFFF
184.     NEXT
185.     FOR i = 0 TO NumRows
186.         LINE (XO, SQ * i + YO)-STEP(NumCols * SQ, 0), &HFFFFFFFF
187.     NEXT
188.     FOR r = NRM1 TO 0 STEP -1 ''in grid rows are reversed 0 is top row
189.         FOR c = 0 TO NCM1
190.             IF Grid(c, r) = P THEN
191.                 LINE (c * SQ + XO + 3, r * SQ + YO + 3)-STEP(SQ - 6, SQ - 6), &HFFFF2200, BF
192.             ELSEIF Grid(c, r) = AI THEN
193.                 IF c = AIX AND r = AIY THEN 'highlite last AI move
194.                     LINE (c * SQ + XO + 3, r * SQ + YO + 3)-STEP(SQ - 6, SQ - 6), &HFF680044, BF
195.                 ELSE
196.                     LINE (c * SQ + XO + 3, r * SQ + YO + 3)-STEP(SQ - 6, SQ - 6), &HFF390027, BF
197.                 END IF
198.             END IF
199.             s$ = _TRIM$(STR$(Scores(c)))
200.             _PRINTSTRING (XO + c * SQ + (60 - LEN(s$) * 8) / 2, YO + SQ * NumRows + 22), s$
201.         NEXT
202.     NEXT
203.     _DISPLAY
204.     check = CheckWin
205.     IF check THEN 'report end of round ad see if want to play again
206.         IF check = 4 OR check = -4 THEN
207.             FOR i = 0 TO 3
208.                 LINE ((WinX + i * DX(WinD)) * SQ + XO + 5, (WinY + i * DY(WinD)) * SQ + YO + 5)-STEP(SQ - 10, SQ - 10), &HFFFFFF00, B
209.             NEXT
210.         END IF
211.         FOR r = 0 TO NRM1
212.             FOR c = 0 TO NCM1
213.                 IF Record$(c, r) <> "" THEN
214.                     s$ = MID$(Record$(c, r), 1, INSTR(Record$(c, r), " ") - 1)
215.                     IF RIGHT$(Record$(c, r), 1) = "A" THEN COLOR , &HFF390027 ELSE COLOR , &HFFFF2200
216.                     _PRINTSTRING (SQ * c + XO + (SQ - LEN(s$) * 8) / 2, SQ * r + YO + 22), s$
217.                 END IF
218.             NEXT
219.             COLOR , &HFF000000
220.         NEXT
221.         IF check = -4 THEN
222.             s$ = " AI is Winner!"
223.         ELSEIF check = 4 THEN
224.             s$ = " Human is Winner!"
225.         ELSEIF check = NumRows THEN
226.             s$ = " Board is full, no winner." ' keep Turn the same
227.         END IF
228.         LOCATE 2, ((SW - LEN(s$) * 8) / 2) / 8: PRINT s$
229.         s$ = " Play again? press spacebar, any other to quit... "
230.         LOCATE 4, ((SW - LEN(s$) * 8) / 2) / 8: PRINT s$
231.         _DISPLAY
232.         WHILE LEN(k$) = 0
233.             k$ = INKEY$
234.             _LIMIT 200
235.         WEND
236.         IF k$ = " " THEN
237.             REDIM Grid(NCM1, NRM1), Scores(NCM1)
238.             IF GoFirst = P THEN GoFirst = AI ELSE GoFirst = P
239.             Turn = GoFirst: MoveNum = 0
240.         ELSE
241.             GameOn = 0
242.         END IF
243.     END IF
244. END SUB
245.  
246. FUNCTION CheckWin ' return WinX, WinY, WinD along with +/- 4, returns NumRows if grid full, 0 if no win and grid not full
247.     DIM gridFull, r, c, s, i
248.     gridFull = NumRows
249.     FOR r = NRM1 TO 0 STEP -1 'bottom to top
250.         FOR c = 0 TO NCM1
251.             IF Grid(c, r) THEN ' check if c starts a row
252.                 IF c < NCM1 - 2 THEN
253.                     s = 0
254.                     FOR i = 0 TO 3 ' east
255.                         s = s + Grid(c + i, r)
256.                     NEXT
257.                     IF s = 4 OR s = -4 THEN WinX = c: WinY = r: WinD = 0: CheckWin = s: EXIT FUNCTION
258.                 END IF
259.                 IF r > 2 THEN ' check if c starts a col
260.                     s = 0
261.                     FOR i = 0 TO 3 ' north
262.                         s = s + Grid(c, r - i)
263.                     NEXT
264.                     IF s = 4 OR s = -4 THEN WinX = c: WinY = r: WinD = 6: CheckWin = s: EXIT FUNCTION
265.                 END IF
266.                 IF r > 2 AND c < NCM1 - 2 THEN 'check if c starts diagonal up to right
267.                     s = 0
268.                     FOR i = 0 TO 3 ' north  east
269.                         s = s + Grid(c + i, r - i)
270.                     NEXT
271.                     IF s = 4 OR s = -4 THEN WinX = c: WinY = r: WinD = 7: CheckWin = s: EXIT FUNCTION
272.                 END IF
273.                 IF r > 2 AND c > 2 THEN 'check if c starts a diagonal up to left
274.                     s = 0
275.                     FOR i = 0 TO 3 ' north west
276.                         s = s + Grid(c - i, r - i)
277.                     NEXT
278.                     IF s = 4 OR s = -4 THEN WinX = c: WinY = r: WinD = 5: CheckWin = s: EXIT FUNCTION
279.                 END IF
280.             ELSE
281.                 gridFull = 0 ' at least one enpty cell left
282.             END IF 'grid is something
283.         NEXT
284.     NEXT
285.     CheckWin = gridFull
286. END FUNCTION
287.  
288.  

 

[bplus]

OK STx pattern still wins just have to play it different order:
 

[STxAxTIC]

I damn near fell alseep at my desk trying to beat this thing last night and couldn't... but then this morning I finally did, got the screenshot all ready... only to find this most recent post ^. Nice work m8.

I was gonna add too, the AI got a lot more clever with this update. Nice and aggressive!

[Dav]

Finally beat it!  I said just before... "Ok..this is my last try."

- Dav