Parametric Clock

[STxAxTIC]

Alright, this is prolly the last clock I'll make for a while. You've seen the idea twice this week already from me alone, with plenty of others doing their clock things. Tis the season I guess.

So this clock draws a "face" (subject to change), and then draws the "hands" in real time. The hour hand is always anchored at the center of the window, and points as an hour hand does. The minute hand is tied to the end of the hour hand, but still pivots to follow the orientation of a standard clock, pointing to the correct minute. So too does the second hand, but this attaches to the end of the minute hand. In so-called "12-hour Mode", this ends up looking like a regular clock as shown.

Pay close attention to the background, or so-called clock face. I discussed heavily (on a nearby earth rotations thread) why the looping structure only has 11-fold symmetry on a 12-hour clock face, which I hope is clear by now. The way I generate the clock face is like this: Before the main loop, start with a black background and run the clock through an entire cycle, only plotting the "second" hand. Keep that image as the background, you can see plenty of "nodes" where the second hand overlaps itself at different times. Needless to say, the minute hand traces along the nodes.

With this model, we can play with non-12-hour clocks. Suppose we maintain the idea that there are 60 minutes per hour, and 60 seconds per minute, but let the number of hours on the clock vary. Of course, the most familiar version of this is 24-hour military time:

Fair enough, but how about non-typical clocks? Indeed, it all works. Using the keyboard (LEFT/RIGHT arrows), I can select from many modes, for instance, a 5-hour clock:

Oh yeah, since you boys (bplus, vince) were talking cardioid clocks, set a two-hour mode for a true cardioid:

If you go all the way down to a one-hour cycle, you basically just have a 60-minute timer. The hour hand and minute hand lock phase:

... And of course, the code:

EDIT: UPARROW/DOWNARROW enable/disable stopwatch mode.
EDIT2: Random colors, removed 24-mode

Code: QB64: [Select]

1. OPTION _EXPLICIT
2.  
3. DO UNTIL _SCREENEXISTS: LOOP
4. _TITLE "Parametric Clock"
5.  
6. DIM SHARED MainScreen AS LONG
7. DIM SHARED BackScreen AS LONG
8. MainScreen = _NEWIMAGE(600, 600, 32)
9. BackScreen = _NEWIMAGE(600, 600, 32)
10. SCREEN MainScreen
11.  
12. RANDOMIZE TIMER
13.  
14. DIM SHARED pi AS DOUBLE
15. DIM SHARED phi AS DOUBLE
16. pi = 4 * ATN(1)
17. phi = (1 + SQR(5)) / 2
18.  
19. TYPE TimeValue
20.     Hour AS INTEGER
21.     Minute AS INTEGER
22.     Second AS DOUBLE
23. END TYPE
24.  
25. TYPE Vector
26.     x AS DOUBLE
27.     y AS DOUBLE
28. END TYPE
29.  
30. TYPE ClockHand
31.     Center AS Vector
32.     HandPosition AS Vector
33.     Length AS DOUBLE
34.     Angle AS DOUBLE
35.     Shade AS _UNSIGNED LONG
36. END TYPE
37.  
38. DIM SHARED TheTime AS TimeValue
39. DIM SHARED HourHand AS ClockHand
40. DIM SHARED MinuteHand AS ClockHand
41. DIM SHARED SecondHand AS ClockHand
42.  
43. DIM SHARED Mode AS INTEGER
44. DIM SHARED ModeList(12) AS INTEGER
45. DIM SHARED TimeShift AS DOUBLE
46. TimeShift = 0
47.  
48. HourHand.Center.x = 0
49. HourHand.Center.y = 0
50. HourHand.Length = 150
51. SecondHand.Length = HourHand.Length / (phi ^ 2)
52. MinuteHand.Length = HourHand.Length / (phi)
53. HourHand.Shade = _RGBA(200, 50, 50, 255)
54. MinuteHand.Shade = _RGBA(65, 105, 225, 255)
55. SecondHand.Shade = _RGBA(255, 165, 0, 255)
56.  
57. CALL InitializeModes
58. Mode = 12
59.  
60. CALL PrepareClockface(0)
61. DO
62.     CALL KeyProcess
63.     CALL UpdateTime(TIMER + TimeShift)
64.     CALL UpdateClock
65.     CLS
66.     _PUTIMAGE (0, 0)-(_WIDTH, _HEIGHT), BackScreen, MainScreen, (0, 0)-(_WIDTH, _HEIGHT)
67.     CALL DrawModeList
68.     CALL DrawClockHands
69.     CALL DrawDigitalClock
70.     _DISPLAY
71.     _LIMIT 60
72. LOOP
73.  
74. SYSTEM
75.  
76. SUB InitializeModes
77.     DIM k AS INTEGER
78.     FOR k = 1 TO 12
79.         ModeList(k) = k
80.     NEXT
81. END SUB
82.  
83. SUB PrepareClockface (col AS _UNSIGNED LONG)
84.     DIM k AS LONG
85.     DIM p AS DOUBLE
86.     p = RND
87.     IF (col = 0) THEN col = _RGBA(255 * p, 255 * RND * 155, 255 * (1 - p), 30)
88.     _DEST BackScreen
89.     CLS
90.     CALL ccircle(0, 0, HourHand.Length, HourHand.Shade)
91.     FOR k = 0 TO (Mode * 3600) - (1) STEP (1)
92.         CALL UpdateTime(k)
93.         CALL UpdateClock
94.         CALL lineSmooth(SecondHand.Center.x, SecondHand.Center.y, SecondHand.HandPosition.x, SecondHand.HandPosition.y, col)
95.     NEXT
96.     FOR k = 0 TO (Mode * 3600) - (3600) STEP (3600)
97.         CALL UpdateTime(k)
98.         CALL UpdateClock
99.         CALL ccircle(HourHand.HandPosition.x, HourHand.HandPosition.y, 6, HourHand.Shade)
100.         CALL ccirclefill(HourHand.HandPosition.x, HourHand.HandPosition.y, 5, _RGBA(0, 0, 0, 255))
101.     NEXT
102.     _DEST MainScreen
103. END SUB
104.  
105. SUB KeyProcess
106.     IF (_KEYDOWN(19200) = -1) THEN
107.         CALL DecreaseMode
108.         CALL PrepareClockface(0)
109.         _DELAY .1 * 1 / Mode
110.     END IF
111.     IF (_KEYDOWN(19712) = -1) THEN
112.         CALL IncreaseMode
113.         CALL PrepareClockface(0)
114.         _DELAY .1 * 1 / Mode
115.     END IF
116.     IF (_KEYDOWN(20480) = -1) THEN
117.         TimeShift = 0
118.     END IF
119.     IF (_KEYDOWN(18432) = -1) THEN
120.         TimeShift = -TIMER
121.     END IF
122.     _KEYCLEAR
123. END SUB
124.  
125. SUB UpdateTime (t AS DOUBLE)
126.     IF (t < 3600) THEN
127.         TheTime.Hour = Mode
128.     ELSE
129.         TheTime.Hour = t \ 3600
130.         t = t - TheTime.Hour * 3600
131.     END IF
132.     TheTime.Hour = TheTime.Hour MOD Mode
133.     IF (TheTime.Hour = 0) THEN TheTime.Hour = Mode
134.     TheTime.Minute = t \ 60
135.     t = t - TheTime.Minute * 60
136.     TheTime.Second = t
137. END SUB
138.  
139. SUB UpdateClock
140.     HourHand.Angle = -((TheTime.Hour + (TheTime.Minute / 60) + (TheTime.Second / 3600)) / Mode) * 2 * pi + (pi / 2)
141.     MinuteHand.Angle = -((TheTime.Minute / 60) + (TheTime.Second / 3600)) * 2 * pi + (pi / 2)
142.     SecondHand.Angle = -(TheTime.Second / 60) * 2 * pi + (pi / 2)
143.     HourHand.HandPosition.x = HourHand.Center.x + HourHand.Length * COS(HourHand.Angle)
144.     HourHand.HandPosition.y = HourHand.Center.y + HourHand.Length * SIN(HourHand.Angle)
145.     MinuteHand.Center.x = HourHand.HandPosition.x
146.     MinuteHand.Center.y = HourHand.HandPosition.y
147.     MinuteHand.HandPosition.x = MinuteHand.Center.x + MinuteHand.Length * COS(MinuteHand.Angle)
148.     MinuteHand.HandPosition.y = MinuteHand.Center.y + MinuteHand.Length * SIN(MinuteHand.Angle)
149.     SecondHand.Center.x = MinuteHand.HandPosition.x
150.     SecondHand.Center.y = MinuteHand.HandPosition.y
151.     SecondHand.HandPosition.x = SecondHand.Center.x + SecondHand.Length * COS(SecondHand.Angle)
152.     SecondHand.HandPosition.y = SecondHand.Center.y + SecondHand.Length * SIN(SecondHand.Angle)
153. END SUB
154.  
155. SUB DrawModeList
156.     DIM k AS INTEGER
157.     FOR k = 1 TO UBOUND(ModeList)
158.         IF (Mode = k) THEN
159.             COLOR _RGBA(255, 255, 0, 255), _RGBA(0, 0, 255, 255)
160.         ELSE
161.             COLOR _RGBA(100, 100, 100, 255), _RGBA(0, 0, 0, 0)
162.         END IF
163.         _PRINTSTRING ((4 + 5 * k) * 8, _HEIGHT - (1) * 16), LTRIM$(RTRIM$(STR$(ModeList(k))))
164.     NEXT
165.     COLOR _RGBA(200, 200, 0, 255), _RGBA(0, 0, 0, 0)
166.     _PRINTSTRING ((4 + 1) * 8, _HEIGHT - (1) * 16), ">"
167.     _PRINTSTRING ((4 + 5 * (UBOUND(ModeList) + 1)) * 8, _HEIGHT - (1) * 16), "<"
168. END SUB
169.  
170. SUB IncreaseMode
171.     IF (Mode < 12) THEN
172.         Mode = Mode + 1
173.     ELSE
174.         Mode = 1
175.     END IF
176. END SUB
177.  
178. SUB DecreaseMode
179.     IF (Mode = 1) THEN
180.         Mode = 12
181.     ELSE
182.         Mode = Mode - 1
183.     END IF
184. END SUB
185.  
186. SUB DrawClockHands
187.     DIM k AS DOUBLE
188.     DIM ctmp AS _UNSIGNED LONG
189.     FOR k = 0 TO 1 STEP .01
190.         ctmp = ColorMix(_RGBA(0, 0, 0, 255), HourHand.Shade, k)
191.         ctmp = _RGBA(_RED32(ctmp), _GREEN32(ctmp), _BLUE32(ctmp), k * _ALPHA32(ctmp))
192.         CALL ccirclefill(HourHand.Center.x + (k * HourHand.Length) * COS(HourHand.Angle), HourHand.Center.y + (k * HourHand.Length) * SIN(HourHand.Angle), k * 4, ctmp)
193.     NEXT
194.     FOR k = 0 TO 1 STEP .01
195.         ctmp = ColorMix(HourHand.Shade, MinuteHand.Shade, k)
196.         ctmp = _RGBA(_RED32(ctmp), _GREEN32(ctmp), _BLUE32(ctmp), _ALPHA32(ctmp))
197.         CALL ccirclefill(MinuteHand.Center.x + (k * MinuteHand.Length) * COS(MinuteHand.Angle), MinuteHand.Center.y + (k * MinuteHand.Length) * SIN(MinuteHand.Angle), 4 - 1 * k, ctmp)
198.     NEXT
199.     FOR k = 0 TO 1 STEP .005
200.         ctmp = ColorMix(MinuteHand.Shade, SecondHand.Shade, k)
201.         ctmp = _RGBA(_RED32(ctmp), _GREEN32(ctmp), _BLUE32(ctmp), _ALPHA32(ctmp))
202.         CALL ccirclefill(SecondHand.Center.x + (k * SecondHand.Length) * COS(SecondHand.Angle), SecondHand.Center.y + (k * SecondHand.Length) * SIN(SecondHand.Angle), 3 * (1 - k), ctmp)
203.     NEXT
204.     CALL ccircle(HourHand.HandPosition.x, HourHand.HandPosition.y, 5, _RGBA(255, 255, 255, 255))
205.     CALL ccircle(MinuteHand.HandPosition.x, MinuteHand.HandPosition.y, 3, _RGBA(255, 255, 255, 255))
206. END SUB
207.  
208. SUB DrawDigitalClock
209.     DIM t AS STRING
210.     COLOR _RGBA(200, 200, 0, 255), _RGBA(0, 0, 0, 0)
211.     t = TIME$
212.     LOCATE 1, (_WIDTH / 8) / 2 - LEN(t) / 2
213.     PRINT t
214. END SUB
215.  
216. FUNCTION ColorMix~& (Shade1 AS _UNSIGNED LONG, Shade2 AS _UNSIGNED LONG, param AS DOUBLE)
217.     ColorMix~& = _RGB32((1 - param) * _RED32(Shade1) + param * _RED32(Shade2), (1 - param) * _GREEN32(Shade1) + param * _GREEN32(Shade2), (1 - param) * _BLUE32(Shade1) + param * _BLUE32(Shade2))
218. END FUNCTION
219.  
220. SUB cpset (x1, y1, col AS _UNSIGNED LONG)
221.     PSET (_WIDTH / 2 + x1, -y1 + _HEIGHT / 2), col
222. END SUB
223.  
224. SUB cline (x1 AS DOUBLE, y1 AS DOUBLE, x2 AS DOUBLE, y2 AS DOUBLE, col AS _UNSIGNED LONG)
225.     LINE (_WIDTH / 2 + x1, -y1 + _HEIGHT / 2)-(_WIDTH / 2 + x2, -y2 + _HEIGHT / 2), col
226. END SUB
227.  
228. SUB ccircle (x1 AS DOUBLE, y1 AS DOUBLE, rad AS DOUBLE, col AS _UNSIGNED LONG)
229.     CIRCLE (_WIDTH / 2 + x1, -y1 + _HEIGHT / 2), rad, col
230. END SUB
231.  
232. SUB ccirclefill (x1 AS DOUBLE, y1 AS DOUBLE, rad AS DOUBLE, col AS _UNSIGNED LONG)
233.     CALL CircleFill(_WIDTH / 2 + x1, -y1 + _HEIGHT / 2, rad, col)
234. END SUB
235.  
236. SUB CircleFill (CX AS INTEGER, CY AS INTEGER, R AS INTEGER, C AS _UNSIGNED LONG)
237.     ' CX = center x coordinate
238.     ' CY = center y coordinate
239.     '  R = radius
240.     '  C = fill color
241.     DIM Radius AS INTEGER, RadiusError AS INTEGER
242.     DIM X AS INTEGER, Y AS INTEGER
243.     Radius = ABS(R)
244.     RadiusError = -Radius
245.     X = Radius
246.     Y = 0
247.     IF Radius = 0 THEN PSET (CX, CY), C: EXIT SUB
248.     LINE (CX - X, CY)-(CX + X, CY), C, BF
249.     WHILE X > Y
250.         RadiusError = RadiusError + Y * 2 + 1
251.         IF RadiusError >= 0 THEN
252.             IF X <> Y + 1 THEN
253.                 LINE (CX - Y, CY - X)-(CX + Y, CY - X), C, BF
254.                 LINE (CX - Y, CY + X)-(CX + Y, CY + X), C, BF
255.             END IF
256.             X = X - 1
257.             RadiusError = RadiusError - X * 2
258.         END IF
259.         Y = Y + 1
260.         LINE (CX - X, CY - Y)-(CX + X, CY - Y), C, BF
261.         LINE (CX - X, CY + Y)-(CX + X, CY + Y), C, BF
262.     WEND
263. END SUB
264.  
265. SUB lineSmooth (x0, y0, x1, y1, c AS _UNSIGNED LONG)
266.     'translated by FellippeHeitor from
267.     'https://en.wikipedia.org/w/index.php?title=Xiaolin_Wu%27s_line_algorithm&oldid=852445548
268.     'correction alpha channel by STxAxTIC (11/2020)
269.  
270.     DIM plX AS INTEGER, plY AS INTEGER, plI
271.  
272.     DIM steep AS _BYTE
273.     steep = ABS(y1 - y0) > ABS(x1 - x0)
274.  
275.     IF steep THEN
276.         SWAP x0, y0
277.         SWAP x1, y1
278.     END IF
279.  
280.     IF x0 > x1 THEN
281.         SWAP x0, x1
282.         SWAP y0, y1
283.     END IF
284.  
285.     DIM dx, dy, gradient
286.     dx = x1 - x0
287.     dy = y1 - y0
288.     gradient = dy / dx
289.  
290.     IF dx = 0 THEN
291.         gradient = 1
292.     END IF
293.  
294.     'handle first endpoint
295.     DIM xend, yend, xgap, xpxl1, ypxl1
296.     xend = _ROUND(x0)
297.     yend = y0 + gradient * (xend - x0)
298.     xgap = (1 - ((x0 + .5) - INT(x0 + .5)))
299.     xpxl1 = xend 'this will be used in the main loop
300.     ypxl1 = INT(yend)
301.     IF steep THEN
302.         plX = ypxl1
303.         plY = xpxl1
304.         plI = (1 - (yend - INT(yend))) * xgap
305.         GOSUB plot
306.  
307.         plX = ypxl1 + 1
308.         plY = xpxl1
309.         plI = (yend - INT(yend)) * xgap
310.         GOSUB plot
311.     ELSE
312.         plX = xpxl1
313.         plY = ypxl1
314.         plI = (1 - (yend - INT(yend))) * xgap
315.         GOSUB plot
316.  
317.         plX = xpxl1
318.         plY = ypxl1 + 1
319.         plI = (yend - INT(yend)) * xgap
320.         GOSUB plot
321.     END IF
322.  
323.     DIM intery
324.     intery = yend + gradient 'first y-intersection for the main loop
325.  
326.     'handle second endpoint
327.     DIM xpxl2, ypxl2
328.     xend = _ROUND(x1)
329.     yend = y1 + gradient * (xend - x1)
330.     xgap = ((x1 + .5) - INT(x1 + .5))
331.     xpxl2 = xend 'this will be used in the main loop
332.     ypxl2 = INT(yend)
333.     IF steep THEN
334.         plX = ypxl2
335.         plY = xpxl2
336.         plI = (1 - (yend - INT(yend))) * xgap
337.         GOSUB plot
338.  
339.         plX = ypxl2 + 1
340.         plY = xpxl2
341.         plI = (yend - INT(yend)) * xgap
342.         GOSUB plot
343.     ELSE
344.         plX = xpxl2
345.         plY = ypxl2
346.         plI = (1 - (yend - INT(yend))) * xgap
347.         GOSUB plot
348.  
349.         plX = xpxl2
350.         plY = ypxl2 + 1
351.         plI = (yend - INT(yend)) * xgap
352.         GOSUB plot
353.     END IF
354.  
355.     'main loop
356.     DIM x
357.     IF steep THEN
358.         FOR x = xpxl1 + 1 TO xpxl2 - 1
359.             plX = INT(intery)
360.             plY = x
361.             plI = (1 - (intery - INT(intery)))
362.             GOSUB plot
363.  
364.             plX = INT(intery) + 1
365.             plY = x
366.             plI = (intery - INT(intery))
367.             GOSUB plot
368.  
369.             intery = intery + gradient
370.         NEXT
371.     ELSE
372.         FOR x = xpxl1 + 1 TO xpxl2 - 1
373.             plX = x
374.             plY = INT(intery)
375.             plI = (1 - (intery - INT(intery)))
376.             GOSUB plot
377.  
378.             plX = x
379.             plY = INT(intery) + 1
380.             plI = (intery - INT(intery))
381.             GOSUB plot
382.  
383.             intery = intery + gradient
384.         NEXT
385.     END IF
386.  
387.     EXIT SUB
388.  
389.     plot:
390.     ' Change to regular PSET for standard coordinate orientation.
391.     CALL cpset(plX, plY, _RGB32(_RED32(c), _GREEN32(c), _BLUE32(c), plI * _ALPHA32(c)))
392.     RETURN
393. END SUB
394.  

[bplus]

I don't know if jointed or joined arm clocks will every catch on but I do like the clock face design!

Here is my version of 12 hours clock with 4 regular analog so you can compare angles:

Code: QB64: [Select]

1. _TITLE "Jointed arms clock with 4 regular analog to compare angles" 'b+ 2020-11-22
2. ' inspsired by STx Parametric clock specially the faces  https://www.qb64.org/forum/index.php?topic=3277.msg125579#msg125579
3. ' I wish to see what a large circle joint at center would look like, first can I get similar face? yes sorta
4.  
5. CONST xmax = 710, ymax = 710, CX = xmax / 2, CY = ymax / 2, hhr0 = 20, hhr1 = 10, mhr1 = 5, shr1 = 3, hh = 200, mh = 100, sh = 50
6. SCREEN _NEWIMAGE(xmax, ymax, 32)
7. _DELAY .25
8. _SCREENMOVE _MIDDLE
9. CLS
10. face& = _NEWIMAGE(_WIDTH, _HEIGHT, 32)
11. ' face
12. FOR vi = 1 TO 43200
13.     h = vi / 3600
14.     hha = h / 12 * _PI(2) - _PI(.5)
15.     mha = (h - INT(h)) * _PI(2) - _PI(.5) '  + (vi MOD 60) / 3600 ? add or not seems better without
16.     sha = (vi MOD 60) / 60 * _PI(2) - _PI(.5)
17.     hhx = CX + hh * COS((hha)): hhy = CY + hh * SIN((hha))
18.     mhx = hhx + mh * COS((mha)): mhy = hhy + mh * SIN((mha))
19.     shx = mhx + sh * COS((sha)): shy = mhy + sh * SIN((sha))
20.     PSET (shx, shy), &HFFFF0000
21.     PSET (mhx, mhy), &HFF008800
22. NEXT
23. CIRCLE (CX, CY), hh, &HFF0000BB
24. FOR a = 0 TO _PI(2) STEP _PI(1 / 6)
25.     fcirc CX + hh * COS(a), CY + hh * SIN(a), 3, &HFF0000BB
26. NEXT
27. _PUTIMAGE , 0, face&
28. ' clock hands
29. FOR vi = 1 TO 43200
30.     _PUTIMAGE , face&, 0
31.     h = VAL(MID$(TIME$, 1, 2))
32.     IF h > 12 THEN h = h - 12
33.     m = VAL(MID$(TIME$, 4, 2))
34.     s = VAL(MID$(TIME$, 7, 2))
35.     hha = (h + (m / 60)) / 12 * _PI(2) - _PI(.5)
36.     mha = (m / 60 + (s / 3600)) * _PI(2) - _PI(.5)
37.     sha = s / 60 * _PI(2) - _PI(.5)
38.     hhx = CX + hh * COS((hha)): hhy = CY + hh * SIN((hha))
39.     mhx = hhx + mh * COS((mha)): mhy = hhy + mh * SIN((mha))
40.     shx = mhx + sh * COS((sha)): shy = mhy + sh * SIN((sha))
41.     drawPully CX, CY, hhr0, hhx, hhy, hhr1, &H88FFFFFF '&HFF8888BB
42.     drawPully hhx, hhy, hhr1, mhx, mhy, mhr1, &H88FFFFFF ' &HFF8808888
43.     drawPully mhx, mhy, mhr1, shx, shy, shr1, &H88FFFFFF '&HFFFF4444
44.     clock 65, 65, 60
45.     clock _WIDTH - 65, 65, 60
46.     clock 65, _HEIGHT - 65, 60
47.     clock _WIDTH - 65, _HEIGHT - 65, 60
48.     _DISPLAY
49.     _LIMIT 30
50. NEXT
51.  
52. SUB fcirc (CX AS INTEGER, CY AS INTEGER, R AS INTEGER, C AS _UNSIGNED LONG)
53.     DIM Radius AS INTEGER, RadiusError AS INTEGER
54.     DIM X AS INTEGER, Y AS INTEGER
55.     Radius = ABS(R): RadiusError = -Radius: X = Radius: Y = 0
56.     IF Radius = 0 THEN PSET (CX, CY), C: EXIT SUB
57.     LINE (CX - X, CY)-(CX + X, CY), C, BF
58.     WHILE X > Y
59.         RadiusError = RadiusError + Y * 2 + 1
60.         IF RadiusError >= 0 THEN
61.             IF X <> Y + 1 THEN
62.                 LINE (CX - Y, CY - X)-(CX + Y, CY - X), C, BF
63.                 LINE (CX - Y, CY + X)-(CX + Y, CY + X), C, BF
64.             END IF
65.             X = X - 1
66.             RadiusError = RadiusError - X * 2
67.         END IF
68.         Y = Y + 1
69.         LINE (CX - X, CY - Y)-(CX + X, CY - Y), C, BF
70.         LINE (CX - X, CY + Y)-(CX + X, CY + Y), C, BF
71.     WEND
72. END SUB
73.  
74. SUB drawPully (x1, y1, r1, x2, y2, r2, c AS _UNSIGNED LONG)
75.     DIM a, a1, a2, x3, x4, x5, x6, y3, y4, y5, y6
76.     a = _ATAN2(y2 - y1, x2 - x1)
77.     a1 = a + _PI(1 / 2)
78.     a2 = a - _PI(1 / 2)
79.     x3 = x1 + r1 * COS(a1): y3 = y1 + r1 * SIN(a1)
80.     x4 = x1 + r1 * COS(a2): y4 = y1 + r1 * SIN(a2)
81.     x5 = x2 + r2 * COS(a1): y5 = y2 + r2 * SIN(a1)
82.     x6 = x2 + r2 * COS(a2): y6 = y2 + r2 * SIN(a2)
83.     LINE (x3, y3)-(x5, y5), c
84.     LINE (x4, y4)-(x6, y6), c
85.     CIRCLE (x1, y1), r1, c
86.     CIRCLE (x2, y2), r2, c
87. END SUB
88.  
89. ' for regular analog
90. SUB clock (x, y, r)
91.     FOR a = 0 TO 359 STEP 6
92.         IF a MOD 30 = 0 THEN r1 = 1 / 30 * r ELSE r1 = 1 / 75 * r
93.         CIRCLE (x + r * COS(_D2R(a)), y + r * SIN(_D2R(a))), r1
94.         PAINT (x + r * COS(_D2R(a)), y + r * SIN(_D2R(a))), _RGB32(100, 100, 100), _RGB32(255, 255, 255)
95.     NEXT
96.     IF VAL(LEFT$(TIME$, 2)) + (VAL(MID$(TIME$, 4, 2)) / 60) >= 12 THEN hrs = VAL(LEFT$(TIME$, 2)) + (VAL(MID$(TIME$, 4, 2)) / 60) - 12 ELSE hrs = VAL(LEFT$(TIME$, 2)) + (VAL(MID$(TIME$, 4, 2)) / 60)
97.     ftri x + 1 / 15 * r * COS(VAL(MID$(TIME$, 4, 2)) * _PI(1 / 30) - _PI(1 / 2) + _PI(1 / 2)), y + 1 / 15 * r * SIN(VAL(MID$(TIME$, 4, 2)) * _PI(1 / 30) - _PI(1 / 2) + _PI(1 / 2)), x + 1 / 15 * r * COS(VAL(MID$(TIME$, 4, 2)) * _PI(1 / 30) - _PI(1 / 2) - _PI(1 / 2)), y + 1 / 15 * r * SIN(VAL(MID$(TIME$, 4, 2)) * _PI(1 / 30) - _PI(1 / 2) - _PI(1 / 2)), x + r * COS(VAL(MID$(TIME$, 4, 2)) * _PI(1 / 30) - _PI(1 / 2)), y + r * SIN(VAL(MID$(TIME$, 4, 2)) * _PI(1 / 30) - _PI(1 / 2)), _RGB32(255, 0, 0)
98.     ftri x + 1 / 10 * r * COS(hrs * _PI(1 / 6) - _PI(1 / 2) + _PI(1 / 2)), y + 1 / 10 * r * SIN(hrs * _PI(1 / 6) - _PI(1 / 2) + _PI(1 / 2)), x + 1 / 10 * r * COS(hrs * _PI(1 / 6) - _PI(1 / 2) - _PI(1 / 2)), y + 1 / 10 * r * SIN(hrs * _PI(1 / 6) - _PI(1 / 2) - _PI(1 / 2)), x + 2 / 3 * r * COS(hrs * _PI(1 / 6) - _PI(1 / 2)), y + 2 / 3 * r * SIN(hrs * _PI(1 / 6) - _PI(1 / 2)), _RGB32(0, 0, 255)
99.     LINE (x, y)-(x + r * COS(VAL(RIGHT$(TIME$, 2)) * _PI(1 / 30) - _PI(1 / 2)), y + r * SIN(VAL(RIGHT$(TIME$, 2)) * _PI(1 / 30) - _PI(1 / 2))), _RGB32(255, 255, 0)
100.     CIRCLE (x, y), 1 / 10 * r, _RGB32(255, 255, 255)
101.     PAINT (x + 1 / 75 * r, y + 1 / 75 * r), _RGB32(100, 100, 100), _RGB32(255, 255, 255)
102.     CIRCLE (x, y), 1 / 30 * r, _RGB32(0, 0, 0)
103. END SUB
104.  
105. SUB ftri (x1, y1, x2, y2, x3, y3, K AS _UNSIGNED LONG)
106.     a& = _NEWIMAGE(1, 1, 32)
107.     _DEST a&
108.     PSET (0, 0), K
109.     _DEST 0
110.     _MAPTRIANGLE _SEAMLESS(0, 0)-(0, 0)-(0, 0), a& TO(x1, y1)-(x2, y2)-(x3, y3)
111.     _FREEIMAGE a& '<<< this is important!
112. END SUB
113.  
114.  

 

[STxAxTIC]

Say, I like that "pulley" system for the clock hand display. My next tweak was going to have more definitive clock hands and that was gonna basically be it. Nice.

If I end up ripping the pulley code I'll return your inspiration credit!

Thanks for playing with it.

[STxAxTIC]

Yes, the pulley was a nice touch.

My code came out a bit shorter (calls for anti-aliased lines):

Code: QB64: [Select]

1. SUB DrawPulley (x1, y1, rad1, x2, y2, rad2, col AS _UNSIGNED LONG)
2.     'Inspiration credit: {(bplus)(qb64.org)(2020-11-22)}
3.     DIM ang AS DOUBLE
4.     ang = _ATAN2(y2 - y1, x2 - x1) + pi / 2
5.     CALL lineSmooth(x1 + rad1 * COS(ang), y1 + rad1 * SIN(ang), x2 + rad2 * COS(ang), y2 + rad2 * SIN(ang), col)
6.     CALL lineSmooth(x1 - rad1 * COS(ang), y1 - rad1 * SIN(ang), x2 - rad2 * COS(ang), y2 - rad2 * SIN(ang), col)
7.     CALL ccircle(x1, y1, rad1, col)
8.     CALL ccircle(x2, y2, rad2, col)
9. END SUB

Next is full code, then a screenshot:

Code: QB64: [Select]

1. OPTION _EXPLICIT
2.  
3. DO UNTIL _SCREENEXISTS: LOOP
4. _TITLE "Parametric Clock"
5.  
6. DIM SHARED MainScreen AS LONG
7. DIM SHARED BackScreen AS LONG
8. MainScreen = _NEWIMAGE(600, 600, 32)
9. BackScreen = _NEWIMAGE(600, 600, 32)
10. SCREEN MainScreen
11.  
12. RANDOMIZE TIMER
13.  
14. DIM SHARED pi AS DOUBLE
15. DIM SHARED phi AS DOUBLE
16. pi = 4 * ATN(1)
17. phi = (1 + SQR(5)) / 2
18.  
19. TYPE TimeValue
20.     Hour AS INTEGER
21.     Minute AS INTEGER
22.     Second AS DOUBLE
23. END TYPE
24.  
25. TYPE Vector
26.     x AS DOUBLE
27.     y AS DOUBLE
28. END TYPE
29.  
30. TYPE ClockHand
31.     Center AS Vector
32.     HandPosition AS Vector
33.     Length AS DOUBLE
34.     Angle AS DOUBLE
35.     Shade AS _UNSIGNED LONG
36. END TYPE
37.  
38. DIM SHARED TheTime AS TimeValue
39. DIM SHARED HourHand AS ClockHand
40. DIM SHARED MinuteHand AS ClockHand
41. DIM SHARED SecondHand AS ClockHand
42.  
43. DIM SHARED Mode AS INTEGER
44. DIM SHARED ModeList(12) AS INTEGER
45. DIM SHARED TimeShift AS DOUBLE
46. TimeShift = 0
47.  
48. HourHand.Center.x = 0
49. HourHand.Center.y = 0
50. HourHand.Length = 150
51. SecondHand.Length = HourHand.Length / (phi ^ 2)
52. MinuteHand.Length = HourHand.Length / (phi)
53. HourHand.Shade = _RGBA(200, 50, 50, 255)
54. MinuteHand.Shade = _RGBA(65, 105, 225, 255)
55. SecondHand.Shade = _RGBA(255, 165, 0, 255)
56.  
57. CALL InitializeModes
58. Mode = 12
59.  
60. CALL PrepareClockface(1)
61. DO
62.     CALL KeyProcess
63.     CALL UpdateTime(TIMER + TimeShift)
64.     CALL UpdateClock
65.     CALL DrawEverything
66.     _KEYCLEAR
67.     _LIMIT 60
68. LOOP
69.  
70. SYSTEM
71.  
72. SUB InitializeModes
73.     DIM k AS INTEGER
74.     FOR k = 1 TO 12
75.         ModeList(k) = k
76.     NEXT
77. END SUB
78.  
79. SUB PrepareClockface (metric AS INTEGER)
80.     DIM p AS DOUBLE
81.     DIM q AS LONG
82.     _DEST BackScreen
83.     CLS
84.     CALL ccircle(0, 0, HourHand.Length, HourHand.Shade)
85.     p = RND
86.     FOR q = 0 TO ((Mode * 3600) - (metric)) STEP (metric)
87.         CALL UpdateTime(q)
88.         CALL UpdateClock
89.         CALL lineSmooth(SecondHand.Center.x, SecondHand.Center.y, SecondHand.HandPosition.x, SecondHand.HandPosition.y, _RGBA(255 * p, 255 * RND * 155, 255 * (1 - p), 30))
90.     NEXT
91.     FOR q = 0 TO ((Mode * 3600) - (3600)) STEP (3600)
92.         CALL UpdateTime(q)
93.         CALL UpdateClock
94.         CALL ccircle(HourHand.HandPosition.x, HourHand.HandPosition.y, 6, HourHand.Shade)
95.         CALL ccirclefill(HourHand.HandPosition.x, HourHand.HandPosition.y, 5, _RGBA(0, 0, 0, 255))
96.     NEXT
97.     _DEST MainScreen
98. END SUB
99.  
100. SUB KeyProcess
101.     IF (_KEYDOWN(19200) = -1) THEN
102.         CALL DecreaseMode
103.         CALL PrepareClockface(1)
104.         _DELAY .1
105.     END IF
106.     IF (_KEYDOWN(19712) = -1) THEN
107.         CALL IncreaseMode
108.         CALL PrepareClockface(1)
109.         _DELAY .1
110.     END IF
111.     IF (_KEYDOWN(20480) = -1) THEN
112.         TimeShift = 0
113.         CALL PrepareClockface(1 + INT(RND * 5))
114.         _DELAY .1
115.     END IF
116.     IF (_KEYDOWN(18432) = -1) THEN
117.         TimeShift = -TIMER
118.     END IF
119. END SUB
120.  
121. SUB UpdateTime (t AS DOUBLE)
122.     IF (t < 3600) THEN
123.         TheTime.Hour = Mode
124.     ELSE
125.         TheTime.Hour = t \ 3600
126.         t = t - TheTime.Hour * 3600
127.     END IF
128.     TheTime.Hour = TheTime.Hour MOD Mode
129.     IF (TheTime.Hour = 0) THEN TheTime.Hour = Mode
130.     TheTime.Minute = t \ 60
131.     t = t - TheTime.Minute * 60
132.     TheTime.Second = t
133. END SUB
134.  
135. SUB UpdateClock
136.     HourHand.Angle = -((TheTime.Hour + (TheTime.Minute / 60) + (TheTime.Second / 3600)) / Mode) * 2 * pi + (pi / 2)
137.     MinuteHand.Angle = -((TheTime.Minute / 60) + (TheTime.Second / 3600)) * 2 * pi + (pi / 2)
138.     SecondHand.Angle = -(TheTime.Second / 60) * 2 * pi + (pi / 2)
139.     HourHand.HandPosition.x = HourHand.Center.x + HourHand.Length * COS(HourHand.Angle)
140.     HourHand.HandPosition.y = HourHand.Center.y + HourHand.Length * SIN(HourHand.Angle)
141.     MinuteHand.Center.x = HourHand.HandPosition.x
142.     MinuteHand.Center.y = HourHand.HandPosition.y
143.     MinuteHand.HandPosition.x = MinuteHand.Center.x + MinuteHand.Length * COS(MinuteHand.Angle)
144.     MinuteHand.HandPosition.y = MinuteHand.Center.y + MinuteHand.Length * SIN(MinuteHand.Angle)
145.     SecondHand.Center.x = MinuteHand.HandPosition.x
146.     SecondHand.Center.y = MinuteHand.HandPosition.y
147.     SecondHand.HandPosition.x = SecondHand.Center.x + SecondHand.Length * COS(SecondHand.Angle)
148.     SecondHand.HandPosition.y = SecondHand.Center.y + SecondHand.Length * SIN(SecondHand.Angle)
149. END SUB
150.  
151. SUB DrawEverything
152.     CLS
153.     _PUTIMAGE (0, 0)-(_WIDTH, _HEIGHT), BackScreen, MainScreen, (0, 0)-(_WIDTH, _HEIGHT)
154.     CALL DrawModeList
155.     CALL DrawClockHands
156.     CALL DrawDigitalClock
157.     _DISPLAY
158. END SUB
159.  
160. SUB DrawModeList
161.     DIM k AS INTEGER
162.     FOR k = 1 TO UBOUND(ModeList)
163.         IF (Mode = k) THEN
164.             COLOR _RGBA(255, 255, 0, 255), _RGBA(0, 0, 255, 255)
165.         ELSE
166.             COLOR _RGBA(100, 100, 100, 255), _RGBA(0, 0, 0, 0)
167.         END IF
168.         _PRINTSTRING ((4 + 5 * k) * 8, _HEIGHT - (1) * 16), LTRIM$(RTRIM$(STR$(ModeList(k))))
169.     NEXT
170.     COLOR _RGBA(200, 200, 0, 255), _RGBA(0, 0, 0, 0)
171.     _PRINTSTRING ((4 + 1) * 8, _HEIGHT - (1) * 16), ">"
172.     _PRINTSTRING ((4 + 5 * (UBOUND(ModeList) + 1)) * 8, _HEIGHT - (1) * 16), "<"
173. END SUB
174.  
175. SUB IncreaseMode
176.     IF (Mode < 12) THEN
177.         Mode = Mode + 1
178.     ELSE
179.         Mode = 1
180.     END IF
181. END SUB
182.  
183. SUB DecreaseMode
184.     IF (Mode = 1) THEN
185.         Mode = 12
186.     ELSE
187.         Mode = Mode - 1
188.     END IF
189. END SUB
190.  
191. SUB DrawClockHands
192.     DIM k AS DOUBLE
193.     DIM ctmp AS _UNSIGNED LONG
194.     FOR k = 0 TO 1 STEP .01
195.         ctmp = ColorMix(_RGBA(0, 0, 255, 255), HourHand.Shade, k)
196.         ctmp = _RGBA(_RED32(ctmp), _GREEN32(ctmp), _BLUE32(ctmp), k * _ALPHA32(ctmp))
197.         CALL ccirclefill(HourHand.Center.x + (k * HourHand.Length) * COS(HourHand.Angle), HourHand.Center.y + (k * HourHand.Length) * SIN(HourHand.Angle), k * 10, ctmp)
198.     NEXT
199.     FOR k = 0 TO 1 STEP .01
200.         ctmp = ColorMix(HourHand.Shade, MinuteHand.Shade, k)
201.         ctmp = _RGBA(_RED32(ctmp), _GREEN32(ctmp), _BLUE32(ctmp), _ALPHA32(ctmp))
202.         CALL ccirclefill(MinuteHand.Center.x + (k * MinuteHand.Length) * COS(MinuteHand.Angle), MinuteHand.Center.y + (k * MinuteHand.Length) * SIN(MinuteHand.Angle), 10 - 1 * k, ctmp)
203.     NEXT
204.     FOR k = 0 TO 1 STEP .005
205.         ctmp = ColorMix(MinuteHand.Shade, SecondHand.Shade, k)
206.         ctmp = _RGBA(_RED32(ctmp), _GREEN32(ctmp), _BLUE32(ctmp), _ALPHA32(ctmp))
207.         CALL ccirclefill(SecondHand.Center.x + (k * SecondHand.Length) * COS(SecondHand.Angle), SecondHand.Center.y + (k * SecondHand.Length) * SIN(SecondHand.Angle), 9 * (1 - k), ctmp)
208.     NEXT
209.  
210.     CALL DrawPulley(HourHand.Center.x, HourHand.Center.x, 0, HourHand.HandPosition.x, HourHand.HandPosition.y, 10, _RGBA(255, 255, 255, 255))
211.     CALL DrawPulley(HourHand.HandPosition.x, HourHand.HandPosition.y, 10, MinuteHand.HandPosition.x, MinuteHand.HandPosition.y, 9, _RGBA(255, 255, 255, 255))
212.     CALL DrawPulley(MinuteHand.HandPosition.x, MinuteHand.HandPosition.y, 9, SecondHand.HandPosition.x, SecondHand.HandPosition.y, 0, _RGBA(255, 255, 255, 255))
213.  
214. END SUB
215.  
216. SUB DrawDigitalClock
217.     DIM t AS STRING
218.     COLOR _RGBA(200, 200, 0, 255), _RGBA(0, 0, 0, 0)
219.     t = TIME$
220.     LOCATE 1, (_WIDTH / 8) / 2 - LEN(t) / 2
221.     PRINT t
222. END SUB
223.  
224. FUNCTION ColorMix~& (Shade1 AS _UNSIGNED LONG, Shade2 AS _UNSIGNED LONG, param AS DOUBLE)
225.     ColorMix~& = _RGB32((1 - param) * _RED32(Shade1) + param * _RED32(Shade2), (1 - param) * _GREEN32(Shade1) + param * _GREEN32(Shade2), (1 - param) * _BLUE32(Shade1) + param * _BLUE32(Shade2))
226. END FUNCTION
227.  
228. SUB cpset (x1, y1, col AS _UNSIGNED LONG)
229.     PSET (_WIDTH / 2 + x1, -y1 + _HEIGHT / 2), col
230. END SUB
231.  
232. SUB cline (x1 AS DOUBLE, y1 AS DOUBLE, x2 AS DOUBLE, y2 AS DOUBLE, col AS _UNSIGNED LONG)
233.     LINE (_WIDTH / 2 + x1, -y1 + _HEIGHT / 2)-(_WIDTH / 2 + x2, -y2 + _HEIGHT / 2), col
234. END SUB
235.  
236. SUB ccircle (x1 AS DOUBLE, y1 AS DOUBLE, rad AS DOUBLE, col AS _UNSIGNED LONG)
237.     CIRCLE (_WIDTH / 2 + x1, -y1 + _HEIGHT / 2), rad, col
238. END SUB
239.  
240. SUB ccirclefill (x1 AS DOUBLE, y1 AS DOUBLE, rad AS DOUBLE, col AS _UNSIGNED LONG)
241.     CALL CircleFill(_WIDTH / 2 + x1, -y1 + _HEIGHT / 2, rad, col)
242. END SUB
243.  
244. SUB CircleFill (CX AS INTEGER, CY AS INTEGER, R AS INTEGER, C AS _UNSIGNED LONG)
245.     ' CX = center x coordinate
246.     ' CY = center y coordinate
247.     '  R = radius
248.     '  C = fill color
249.     DIM Radius AS INTEGER, RadiusError AS INTEGER
250.     DIM X AS INTEGER, Y AS INTEGER
251.     Radius = ABS(R)
252.     RadiusError = -Radius
253.     X = Radius
254.     Y = 0
255.     IF Radius = 0 THEN PSET (CX, CY), C: EXIT SUB
256.     LINE (CX - X, CY)-(CX + X, CY), C, BF
257.     WHILE X > Y
258.         RadiusError = RadiusError + Y * 2 + 1
259.         IF RadiusError >= 0 THEN
260.             IF X <> Y + 1 THEN
261.                 LINE (CX - Y, CY - X)-(CX + Y, CY - X), C, BF
262.                 LINE (CX - Y, CY + X)-(CX + Y, CY + X), C, BF
263.             END IF
264.             X = X - 1
265.             RadiusError = RadiusError - X * 2
266.         END IF
267.         Y = Y + 1
268.         LINE (CX - X, CY - Y)-(CX + X, CY - Y), C, BF
269.         LINE (CX - X, CY + Y)-(CX + X, CY + Y), C, BF
270.     WEND
271. END SUB
272.  
273. SUB DrawPulley (x1, y1, rad1, x2, y2, rad2, col AS _UNSIGNED LONG)
274.     'Inspiration credit: {(bplus)(qb64.org)(2020-11-22)}
275.     DIM ang AS DOUBLE
276.     ang = _ATAN2(y2 - y1, x2 - x1) + pi / 2
277.     CALL lineSmooth(x1 + rad1 * COS(ang), y1 + rad1 * SIN(ang), x2 + rad2 * COS(ang), y2 + rad2 * SIN(ang), col)
278.     CALL lineSmooth(x1 - rad1 * COS(ang), y1 - rad1 * SIN(ang), x2 - rad2 * COS(ang), y2 - rad2 * SIN(ang), col)
279.     CALL ccircle(x1, y1, rad1, col)
280.     CALL ccircle(x2, y2, rad2, col)
281. END SUB
282.  
283. SUB lineSmooth (x0, y0, x1, y1, c AS _UNSIGNED LONG)
284.     'translated by FellippeHeitor from
285.     'https://en.wikipedia.org/w/index.php?title=Xiaolin_Wu%27s_line_algorithm&oldid=852445548
286.     'correction alpha channel by STxAxTIC (11/2020)
287.  
288.     DIM plX AS INTEGER, plY AS INTEGER, plI
289.  
290.     DIM steep AS _BYTE
291.     steep = ABS(y1 - y0) > ABS(x1 - x0)
292.  
293.     IF steep THEN
294.         SWAP x0, y0
295.         SWAP x1, y1
296.     END IF
297.  
298.     IF x0 > x1 THEN
299.         SWAP x0, x1
300.         SWAP y0, y1
301.     END IF
302.  
303.     DIM dx, dy, gradient
304.     dx = x1 - x0
305.     dy = y1 - y0
306.     gradient = dy / dx
307.  
308.     IF dx = 0 THEN
309.         gradient = 1
310.     END IF
311.  
312.     'handle first endpoint
313.     DIM xend, yend, xgap, xpxl1, ypxl1
314.     xend = _ROUND(x0)
315.     yend = y0 + gradient * (xend - x0)
316.     xgap = (1 - ((x0 + .5) - INT(x0 + .5)))
317.     xpxl1 = xend 'this will be used in the main loop
318.     ypxl1 = INT(yend)
319.     IF steep THEN
320.         plX = ypxl1
321.         plY = xpxl1
322.         plI = (1 - (yend - INT(yend))) * xgap
323.         GOSUB plot
324.  
325.         plX = ypxl1 + 1
326.         plY = xpxl1
327.         plI = (yend - INT(yend)) * xgap
328.         GOSUB plot
329.     ELSE
330.         plX = xpxl1
331.         plY = ypxl1
332.         plI = (1 - (yend - INT(yend))) * xgap
333.         GOSUB plot
334.  
335.         plX = xpxl1
336.         plY = ypxl1 + 1
337.         plI = (yend - INT(yend)) * xgap
338.         GOSUB plot
339.     END IF
340.  
341.     DIM intery
342.     intery = yend + gradient 'first y-intersection for the main loop
343.  
344.     'handle second endpoint
345.     DIM xpxl2, ypxl2
346.     xend = _ROUND(x1)
347.     yend = y1 + gradient * (xend - x1)
348.     xgap = ((x1 + .5) - INT(x1 + .5))
349.     xpxl2 = xend 'this will be used in the main loop
350.     ypxl2 = INT(yend)
351.     IF steep THEN
352.         plX = ypxl2
353.         plY = xpxl2
354.         plI = (1 - (yend - INT(yend))) * xgap
355.         GOSUB plot
356.  
357.         plX = ypxl2 + 1
358.         plY = xpxl2
359.         plI = (yend - INT(yend)) * xgap
360.         GOSUB plot
361.     ELSE
362.         plX = xpxl2
363.         plY = ypxl2
364.         plI = (1 - (yend - INT(yend))) * xgap
365.         GOSUB plot
366.  
367.         plX = xpxl2
368.         plY = ypxl2 + 1
369.         plI = (yend - INT(yend)) * xgap
370.         GOSUB plot
371.     END IF
372.  
373.     'main loop
374.     DIM x
375.     IF steep THEN
376.         FOR x = xpxl1 + 1 TO xpxl2 - 1
377.             plX = INT(intery)
378.             plY = x
379.             plI = (1 - (intery - INT(intery)))
380.             GOSUB plot
381.  
382.             plX = INT(intery) + 1
383.             plY = x
384.             plI = (intery - INT(intery))
385.             GOSUB plot
386.  
387.             intery = intery + gradient
388.         NEXT
389.     ELSE
390.         FOR x = xpxl1 + 1 TO xpxl2 - 1
391.             plX = x
392.             plY = INT(intery)
393.             plI = (1 - (intery - INT(intery)))
394.             GOSUB plot
395.  
396.             plX = x
397.             plY = INT(intery) + 1
398.             plI = (intery - INT(intery))
399.             GOSUB plot
400.  
401.             intery = intery + gradient
402.         NEXT
403.     END IF
404.  
405.     EXIT SUB
406.  
407.     plot:
408.     ' Change to regular PSET for standard coordinate orientation.
409.     CALL cpset(plX, plY, _RGB32(_RED32(c), _GREEN32(c), _BLUE32(c), plI * _ALPHA32(c)))
410.     RETURN
411. END SUB

[FellippeHeitor]

Gorgeous work, STx. I'll take it as a work of art, as the whole philosophy/logic goes over my head, but it's gorgeous to look at nonetheless.

[bplus]

Facelift:

Code: QB64: [Select]

1. _TITLE "Jointed arms clock 2" 'b+ 2020-11-22
2. ' inspsired by STx Parametric clock specially the faces  https://www.qb64.org/forum/index.php?topic=3277.msg125579#msg125579
3. ' I wish to see what a large circle joint at center would look like, first can I get similar face? yes sorta
4. ' 2020-11-23 More work on clock face, drawPully less LOC
5.  
6. CONST xmax = 710, ymax = 710, CX = xmax / 2, CY = ymax / 2, hhr0 = 20, hhr1 = 10, mhr1 = 5, shr1 = 0, hh = 180, mh = 110, sh = 36
7. SCREEN _NEWIMAGE(xmax, ymax, 32)
8. _DELAY .25
9. _SCREENMOVE _MIDDLE
10. CLS
11. face& = _NEWIMAGE(_WIDTH, _HEIGHT, 32)
12. FOR vi = 1 TO 43200
13.     h = vi / 3600
14.     hha = h / 12 * _PI(2) - _PI(.5)
15.     mha = (h - INT(h)) * _PI(2) - _PI(.5)
16.     sha = (vi MOD 60) / 60 * _PI(2) - _PI(.5)
17.     hhx = CX + hh * COS((hha)): hhy = CY + hh * SIN((hha))
18.     mhx = hhx + mh * COS((mha)): mhy = hhy + mh * SIN((mha))
19.     shx = mhx + sh * COS((sha)): shy = mhy + sh * SIN((sha))
20.     drawPully mhx, mhy, mhr1, shx, shy, shr1, &H2300FF88
21. NEXT
22. _PUTIMAGE , 0, face&
23. DO
24.     _PUTIMAGE , face&, 0
25.     h = VAL(MID$(TIME$, 1, 2))
26.     IF h > 12 THEN h = h - 12
27.     m = VAL(MID$(TIME$, 4, 2))
28.     s = VAL(MID$(TIME$, 7, 2))
29.     hha = (h + (m / 60)) / 12 * _PI(2) - _PI(.5)
30.     mha = (m / 60 + (s / 3600)) * _PI(2) - _PI(.5)
31.     sha = s / 60 * _PI(2) - _PI(.5)
32.     hhx = CX + hh * COS((hha)): hhy = CY + hh * SIN((hha))
33.     mhx = hhx + mh * COS((mha)): mhy = hhy + mh * SIN((mha))
34.     shx = mhx + sh * COS((sha)): shy = mhy + sh * SIN((sha))
35.     drawPully CX, CY, hhr0, hhx, hhy, hhr1, &HFFFFFFFF
36.     drawPully hhx, hhy, hhr1, mhx, mhy, mhr1, &HFFFFFFFF
37.     drawPully mhx, mhy, mhr1, shx, shy, shr1, &HFFFFFFFF
38.     _DISPLAY
39.     _LIMIT 30
40. LOOP UNTIL _KEYDOWN(27)
41.  
42. SUB drawPully (x1, y1, r1, x2, y2, r2, c AS _UNSIGNED LONG) ' drawPully with less LOC, thanks STx
43.     a = _ATAN2(y2 - y1, x2 - x1) + _PI(.5)
44.     LINE (x1 + r1 * COS(a), y1 + r1 * SIN(a))-(x2 + r2 * COS(a), y2 + r2 * SIN(a)), c
45.     LINE (x1 + r1 * COS(a - _PI), y1 + r1 * SIN(a - _PI))-(x2 + r2 * COS(a - _PI), y2 + r2 * SIN(a - _PI)), c
46.     CIRCLE (x1, y1), r1, c
47.     CIRCLE (x2, y2), r2, c
48. END SUB
49.  

EDIT: dang I was doing clock in a FOR loop!
EDIT 2: drawPully with less LOC!

[STxAxTIC]

Thanks for the kind complements @Fellippe, you are QB64's gentleman!

@bplus:
Something that may have seen like an esoteric decision was the choice of clock hand length, and why I need the golden ratio in my code. Alas, it's so the second and minute hands can stack up to perfectly cover the hour hand (almost shown below).

Code: QB64: [Select]

1. SecondHand.Length = HourHand.Length / (phi ^ 2)
2. MinuteHand.Length = HourHand.Length / (phi)

[bplus]

Alas, it's so the second and minute hands can stack up to perfectly cover the hour hand (almost shown below).

Oh cool! But do you need Golden Ratio? Just If Hour hand = 3 * Seconds and Minute hand = 2 * Seconds Then Hour = Minute + Second

Well anyway, I am catching up with modes and color changes. Pick modes by single digit key press or mouse click the o'clock:

Code: QB64: [Select]

1. _TITLE "Jointed arms clock #3: Any changes color, digits change hours: 0 = 12 or click mouse at 1, 2, 3... o'clock" 'b+ started 2020-11-22
2. ' inspsired by STx Parametric clock specially the faces  https://www.qb64.org/forum/index.php?topic=3277.msg125579#msg125579
3. ' I wish to see what a large circle joint at center would look like, first can I get similar face? yes sorta
4. ' 2020-11-23 More work on clock face, less LOC for drawPully, add modes and color changes
5.  
6. RANDOMIZE TIMER
7. CONST xmax = 710, ymax = 710, CX = xmax / 2, CY = ymax / 2, hhr0 = 20, hhr1 = 10, mhr1 = 5, shr1 = 0, hh = 180, mh = 110, sh = 36
8. DIM SHARED face AS LONG, mode AS LONG
9. SCREEN _NEWIMAGE(xmax, ymax, 32)
10. _DELAY .25
11. _SCREENMOVE _MIDDLE
12. face = _NEWIMAGE(_WIDTH, _HEIGHT, 32)
13. makeAFace
14. DO
15.     k$ = INKEY$
16.     IF LEN(k$) THEN
17.         IF INSTR("0123456789", k$) THEN mode = VAL(k$)
18.         makeAFace
19.     END IF
20.     WHILE _MOUSEINPUT: WEND
21.     IF _MOUSEBUTTON(1) THEN
22.         a = _R2D(_ATAN2(_MOUSEY - CY, _MOUSEX - CX)) + 90 + 15
23.         IF a < 0 THEN a = a + 360
24.         IF a > 360 THEN a = a - 360
25.         a = INT(a / 30)
26.         IF a >= 0 AND a <= 12 THEN mode = a: makeAFace
27.     END IF
28.     _PUTIMAGE , face&, 0
29.     h = VAL(MID$(TIME$, 1, 2)) MOD mode
30.     m = VAL(MID$(TIME$, 4, 2))
31.     s = VAL(MID$(TIME$, 7, 2))
32.     hha = (h + (m / 60)) / mode * _PI(2) - _PI(.5)
33.     mha = (m / 60 + (s / 3600)) * _PI(2) - _PI(.5)
34.     sha = s / 60 * _PI(2) - _PI(.5)
35.     hhx = CX + hh * COS((hha)): hhy = CY + hh * SIN((hha))
36.     mhx = hhx + mh * COS((mha)): mhy = hhy + mh * SIN((mha))
37.     shx = mhx + ((12 - mode) * 3 + sh) * COS((sha)): shy = mhy + ((12 - mode) * 3 + sh) * SIN((sha))
38.     drawPully CX, CY, hhr0, hhx, hhy, hhr1, &HFFFFFFFF
39.     drawPully hhx, hhy, hhr1, mhx, mhy, mhr1, &HFFFFFFFF
40.     drawPully mhx, mhy, mhr1, shx, shy, shr1, &HFFFFFFFF
41.     _DISPLAY
42.     _LIMIT 30
43. LOOP UNTIL _KEYDOWN(27)
44.  
45. SUB drawPully (x1, y1, r1, x2, y2, r2, c AS _UNSIGNED LONG)
46.     a = _ATAN2(y2 - y1, x2 - x1) + _PI(.5)
47.     LINE (x1 + r1 * COS(a), y1 + r1 * SIN(a))-(x2 + r2 * COS(a), y2 + r2 * SIN(a)), c
48.     LINE (x1 + r1 * COS(a - _PI), y1 + r1 * SIN(a - _PI))-(x2 + r2 * COS(a - _PI), y2 + r2 * SIN(a - _PI)), c
49.     CIRCLE (x1, y1), r1, c
50.     CIRCLE (x2, y2), r2, c
51. END SUB
52.  
53. SUB makeAFace
54.     DIM colr AS _UNSIGNED LONG
55.     colr = _RGB32((RND < .5) * -1 * (RND * 128 + 127), RND * 128 + 127, (RND < .5) * -1 * (RND * 128 + 127), &H23)
56.     IF mode = 0 THEN mode = 12
57.     CLS
58.     FOR vi = 1 TO mode * 3600
59.         h = vi / 3600
60.         hha = h / mode * _PI(2) - _PI(.5)
61.         mha = (h - INT(h)) * _PI(2) - _PI(.5)
62.         sha = (vi MOD 60) / 60 * _PI(2) - _PI(.5)
63.         hhx = CX + hh * COS((hha)): hhy = CY + hh * SIN((hha))
64.         mhx = hhx + mh * COS((mha)): mhy = hhy + mh * SIN((mha))
65.         shx = mhx + ((12 - mode) * 3 + sh) * COS((sha)): shy = mhy + ((12 - mode) * 3 + sh) * SIN((sha))
66.         drawPully mhx, mhy, mhr1, shx, shy, shr1, colr
67.     NEXT
68.     _PUTIMAGE , 0, face&
69. END SUB
70.  

 

Edit: half of 30 is 15 (12 clock hour angles), not 18, fixed and title with instructions now fits title bar.

[STxAxTIC]

Good question, the golden mean isn't needed if we create only a few hands - I guess this choice is a relic from an earlier version that had a millisecond hand too, and getting all hands to match up was, well, a perfect application of the golden mean. Now yeah, I guess as long as length(second)+length(minute)=length(hour), one can use any values. I would need a fourth hand to make it "necessary".

EDIT: Ah, nice work with the mode switching! A wild __cardioid clock__ appears!

EDIT EDIT: Best answer goes to bplus for getting deeply engaged in the issue. Nice tight code too.

[bplus]

Good question, the golden mean isn't needed if we create only a few hands - I guess this choice is a relic from an earlier version that had a millisecond hand too, and getting all hands to match up was, well, a perfect application of the golden mean. Now yeah, I guess as long as length(second)+length(minute)=length(hour), one can use any values. I would need a fourth hand to make it "necessary".

EDIT: Ah, nice work with the mode switching! A wild __cardioid clock__ appears!

EDIT EDIT: Best answer goes to bplus for getting deeply engaged in the issue. Nice tight code too.

Wow thanks, coming from you that means allot! But I am still catching up to your colored clock hands, last night I started work and rework on a number of tools to attempt that FX of color transitioning. BTW I found trouble with my version of arc trying to draw the shape of a pully without the circle in inner part. I hope to transition from transparent center hour hand out to solid minute hand join/joint. And we haven't even thought about those straight line edges on pully. Yeah, deeply engaged.

[bplus]

One more time with new hands:

Code: QB64: [Select]

1. _TITLE "Jointed arms clock #4: Any changes color, digits change hours: 0 = 12 or click mouse at 1, 2, 3... o'clock" 'b+ started 2020-11-22
2. ' inspsired by STx Parametric clock specially the faces  https://www.qb64.org/forum/index.php?topic=3277.msg125579#msg125579
3. ' I wish to see what a large circle joint at center would look like, first can I get similar face? yes sorta
4. ' 2020-11-23 More work on clock face, less LOC for drawPully, add modes and color changes
5. ' 2020-11-24 add stuff to make different arms
6.  
7. RANDOMIZE TIMER
8. CONST xmax = 710, ymax = 710, CX = xmax / 2, CY = ymax / 2, hhr0 = 20, hhr1 = 10, mhr1 = 5, shr1 = 0, hh = 180, mh = 110, sh = 36
9. DIM SHARED face AS LONG, mode AS LONG, colr AS _UNSIGNED LONG, hourHand&, minHand&, secHand&
10. SCREEN _NEWIMAGE(xmax, ymax, 32)
11. _DELAY .25
12. _SCREENMOVE _MIDDLE
13. face = _NEWIMAGE(_WIDTH, _HEIGHT, 32)
14. makeAFace
15. DO
16.     k$ = INKEY$
17.     IF LEN(k$) THEN
18.         IF INSTR("0123456789", k$) THEN mode = VAL(k$)
19.         makeAFace
20.     END IF
21.     WHILE _MOUSEINPUT: WEND
22.     IF _MOUSEBUTTON(1) THEN
23.         a = _R2D(_ATAN2(_MOUSEY - CY, _MOUSEX - CX)) + 90 + 15
24.         IF a < 0 THEN a = a + 360
25.         IF a > 360 THEN a = a - 360
26.         a = INT(a / 30)
27.         IF a >= 0 AND a <= 12 THEN mode = a: makeAFace
28.     END IF
29.     _PUTIMAGE , face&, 0
30.     h = VAL(MID$(TIME$, 1, 2)) MOD mode
31.     m = VAL(MID$(TIME$, 4, 2))
32.     s = VAL(MID$(TIME$, 7, 2))
33.     hha = (h + (m / 60)) / mode * _PI(2) - _PI(.5)
34.     mha = (m / 60 + (s / 3600)) * _PI(2) - _PI(.5)
35.     sha = s / 60 * _PI(2) - _PI(.5)
36.     hhx = CX + hh * COS((hha)): hhy = CY + hh * SIN((hha))
37.     mhx = hhx + mh * COS((mha)): mhy = hhy + mh * SIN((mha))
38.     shx = mhx + ((12 - mode) * 3 + sh) * COS((sha)): shy = mhy + ((12 - mode) * 3 + sh) * SIN((sha))
39.     'drawPully CX, CY, hhr0, hhx, hhy, hhr1, &HFFFFFFFF
40.     'drawPully hhx, hhy, hhr1, mhx, mhy, mhr1, &HFFFFFFFF
41.     'drawPully mhx, mhy, mhr1, shx, shy, shr1, &HFFFFFFFF
42.     RotoZoom3 CX, CY, hourHand&, 1, 1, hha
43.     RotoZoom3 hhx, hhy, minHand&, 1, 1, mha
44.     RotoZoom3 mhx, mhy, secHand&, 1, 1, sha
45.     _DISPLAY
46.     _LIMIT 30
47. LOOP UNTIL _KEYDOWN(27)
48.  
49. SUB drawPully (x1, y1, r1, x2, y2, r2, c AS _UNSIGNED LONG)
50.     a = _ATAN2(y2 - y1, x2 - x1) + _PI(.5)
51.     LINE (x1 + r1 * COS(a), y1 + r1 * SIN(a))-(x2 + r2 * COS(a), y2 + r2 * SIN(a)), c
52.     LINE (x1 + r1 * COS(a - _PI), y1 + r1 * SIN(a - _PI))-(x2 + r2 * COS(a - _PI), y2 + r2 * SIN(a - _PI)), c
53.     CIRCLE (x1, y1), r1, c
54.     CIRCLE (x2, y2), r2, c
55. END SUB
56.  
57. SUB makeAFace
58.     colr = _RGB32((RND < .5) * -1 * (RND * 128 + 127), RND * 128 + 127, (RND < .5) * -1 * (RND * 128 + 127), &H23)
59.     IF mode = 0 THEN mode = 12
60.     CLS
61.     FOR vi = 1 TO mode * 3600
62.         h = vi / 3600
63.         hha = h / mode * _PI(2) - _PI(.5)
64.         mha = (h - INT(h)) * _PI(2) - _PI(.5)
65.         sha = (vi MOD 60) / 60 * _PI(2) - _PI(.5)
66.         hhx = CX + hh * COS((hha)): hhy = CY + hh * SIN((hha))
67.         mhx = hhx + mh * COS((mha)): mhy = hhy + mh * SIN((mha))
68.         shx = mhx + ((12 - mode) * 3 + sh) * COS((sha)): shy = mhy + ((12 - mode) * 3 + sh) * SIN((sha))
69.         drawPully mhx, mhy, mhr1, shx, shy, shr1, colr
70.     NEXT
71.     _PUTIMAGE , 0, face&
72.     'arms look better with the draw color for the face on the edges, it hides raggity border edges.
73.     ' otherwise we could just draw these once at the beginning of program.
74.     makeArmImage hourHand&, hh, hhr0, hhr1, &HFFFFFFFF, &H88000000
75.     makeArmImage minHand&, mh, hhr1, mhr1, &HFFFFFFFF, &H88000000
76.     makeArmImage secHand&, sh, mhr1, shr1, &HFFFFFFFF, &H88000000
77. END SUB
78.  
79. SUB makeArmImage (hdl&, length, r1, r2, c1 AS _UNSIGNED LONG, c2 AS _UNSIGNED LONG)
80.     ' intend to use this with rotozoom so have to make image rotate-able in middle
81.     ' arm image starts big in middle and points right to smaller radius r2
82.     ' hdl& image handle to use
83.     ' length  run of origins of half circles
84.     ' c1 is color on left in middle = bigger joint , c2 is color on right
85.     DIM width, height, wd2, hd2, x1, y1, x2, y2, a
86.     width = 2 * (r2 + length) + 2: height = 2 * r1 + 2: wd2 = width / 2: hd2 = height / 2
87.     hdl& = _NEWIMAGE(width + 2, height + 2, 32)
88.     _DEST hdl&
89.     _SOURCE hdl&
90.     x1 = wd2: y1 = hd2: x2 = wd2 + length: y2 = hd2: a = _PI(.5)
91.     LINE (x1 + r1 * COS(a), y1 + r1 * SIN(a))-(x2 + r2 * COS(a), y2 + r2 * SIN(a)), colr
92.     LINE (x1 + r1 * COS(a - _PI), y1 + r1 * SIN(a - _PI))-(x2 + r2 * COS(a - _PI), y2 + r2 * SIN(a - _PI)), colr
93.     arc x1, y1, r1, _PI(.5), _PI(1.5), colr
94.     arc x2, y2, r2, _PI(1.5), _PI(.5), colr
95.     paint4 x1, y1, c1, c2
96.     _DEST 0
97.     _SOURCE 0
98. END SUB
99.  
100. 'use radians
101. SUB arc (x, y, r, raBegin, raEnd, c AS _UNSIGNED LONG) ' updated 2020-11-24
102.     ' raStart is first angle clockwise from due East = 0 degrees
103.     ' arc will start drawing there and clockwise until raStop angle reached
104.     'x, y origin, r = radius, c = color
105.     DIM raStart, raStop, dStart, dStop, al, a
106.  
107.     ' Last time I tried to use this SUB it hung the program, possible causes:
108.     ' Make sure raStart and raStop are between 0 and 2pi.
109.     ' This sub does not have to be recursive, use GOSUB to do drawing to execute arc in one call.
110.  
111.     'make copies before changing
112.     raStart = raBegin: raStop = raEnd
113.     WHILE raStart < 0: raStart = raStart + _PI(2): WEND
114.     WHILE raStart >= _PI(2): raStart = raStart - _PI(2): WEND
115.     WHILE raStop < 0: raStop = raStop + _PI(2): WEND
116.     WHILE raStop >= _PI(2): raStop = raStop - _PI(2): WEND
117.  
118.     IF raStop < raStart THEN
119.         dStart = raStart: dStop = _PI(2) - .00001
120.         GOSUB drawArc
121.         dStart = 0: dStop = raStop
122.         GOSUB drawArc
123.     ELSE
124.         dStart = raStart: dStop = raStop
125.         GOSUB drawArc
126.     END IF
127.     EXIT SUB
128.     drawArc: ' I am going back to lines instead of pset
129.     al = 2 * _PI * r * (dStop - dStart) / _PI(2)
130.     FOR a = dStart TO dStop STEP 1 / al
131.         IF a > dStart THEN LINE (lastx, lasty)-(x + r * COS(a), y + r * SIN(a)), c
132.         lastx = x + r * COS(a): lasty = y + r * SIN(a)
133.     NEXT
134.     RETURN
135. END SUB
136.  
137. SUB cAnalysis (c AS _UNSIGNED LONG, outRed, outGrn, outBlu, outAlp)
138.     outRed = _RED32(c): outGrn = _GREEN32(c): outBlu = _BLUE32(c): outAlp = _ALPHA32(c)
139. END SUB
140.  
141. FUNCTION Ink~& (c1 AS _UNSIGNED LONG, c2 AS _UNSIGNED LONG, fr##)
142.     DIM R1, G1, B1, A1, R2, G2, B2, A2
143.     cAnalysis c1, R1, G1, B1, A1
144.     cAnalysis c2, R2, G2, B2, A2
145.     Ink~& = _RGB32(R1 + (R2 - R1) * fr##, G1 + (G2 - G1) * fr##, B1 + (B2 - B1) * fr##, A1 + (A2 - A1) * fr##)
146. END FUNCTION
147.  
148. SUB paint4 (x0, y0, c1 AS _UNSIGNED LONG, c2 AS _UNSIGNED LONG) ' needs max, min functions
149.     DIM fillColor AS _UNSIGNED LONG, W, H, parentF, tick, ystart, ystop, xstart, xstop, x, y
150.     fillColor = POINT(x0, y0)
151.     'PRINT fillColor
152.     W = _WIDTH - 1: H = _HEIGHT - 1
153.     DIM temp(W, H)
154.     temp(x0, y0) = 1: parentF = 1
155.     PSET (x0, y0), Ink~&(c1, c2, ABS((y0 - _HEIGHT / 2) / (_HEIGHT / 2)))
156.     WHILE parentF = 1
157.         parentF = 0: tick = tick + 1
158.         ystart = max(y0 - tick, 0): ystop = min(y0 + tick, H)
159.         y = ystart
160.         WHILE y <= ystop
161.             xstart = max(x0 - tick, 0): xstop = min(x0 + tick, W)
162.             x = xstart
163.             WHILE x <= xstop
164.                 IF POINT(x, y) = fillColor AND temp(x, y) = 0 THEN
165.                     IF temp(max(0, x - 1), y) THEN
166.                         temp(x, y) = 1: parentF = 1: PSET (x, y), Ink~&(c1, c2, ABS((y - _HEIGHT / 2) / (_HEIGHT / 2)))
167.                     ELSEIF temp(min(x + 1, W), y) THEN
168.                         temp(x, y) = 1: parentF = 1: PSET (x, y), Ink~&(c1, c2, ABS((y - _HEIGHT / 2) / (_HEIGHT / 2)))
169.                     ELSEIF temp(x, max(y - 1, 0)) THEN
170.                         temp(x, y) = 1: parentF = 1: PSET (x, y), Ink~&(c1, c2, ABS((y - _HEIGHT / 2) / (_HEIGHT / 2)))
171.                     ELSEIF temp(x, min(y + 1, H)) THEN
172.                         temp(x, y) = 1: parentF = 1: PSET (x, y), Ink~&(c1, c2, ABS((y - _HEIGHT / 2) / (_HEIGHT / 2)))
173.                     END IF
174.                 END IF
175.                 x = x + 1
176.             WEND
177.             y = y + 1
178.         WEND
179.     WEND
180. END SUB
181.  
182. FUNCTION min (n1, n2)
183.     IF n1 > n2 THEN min = n2 ELSE min = n1
184. END FUNCTION
185.  
186. FUNCTION max (n1, n2)
187.     IF n1 < n2 THEN max = n2 ELSE max = n1
188. END FUNCTION
189.  
190. ' Description:
191. ' Started from a mod of Galleon's in Wiki that both scales and rotates an image.
192. ' This version scales the x-axis and y-axis independently allowing rotations of image just by changing X or Y Scales
193. ' making this tightly coded routine a very powerful and versatile image tool.
194. SUB RotoZoom3 (X AS LONG, Y AS LONG, Image AS LONG, xScale AS SINGLE, yScale AS SINGLE, radianRotation AS SINGLE)
195.     ' This assumes you have set your drawing location with _DEST or default to screen.
196.     ' X, Y - is where you want to put the middle of the image
197.     ' Image - is the handle assigned with _LOADIMAGE
198.     ' xScale, yScale - are shrinkage < 1 or magnification > 1 on the given axis, 1 just uses image size.
199.     ' These are multipliers so .5 will create image .5 size on given axis and 2 for twice image size.
200.     ' radianRotation is the Angle in Radian units to rotate the image
201.     ' note: Radian units for rotation because it matches angle units of other Basic Trig functions
202.     '       and saves a little time converting from degree.
203.     '       Use the _D2R() function if you prefer to work in degree units for angles.
204.  
205.     DIM px(3) AS SINGLE: DIM py(3) AS SINGLE ' simple arrays for x, y to hold the 4 corners of image
206.     DIM W&, H&, sinr!, cosr!, i&, x2&, y2& '   variables for image manipulation
207.     W& = _WIDTH(Image&): H& = _HEIGHT(Image&)
208.     px(0) = -W& / 2: py(0) = -H& / 2 'left top corner
209.     px(1) = -W& / 2: py(1) = H& / 2 ' left bottom corner
210.     px(2) = W& / 2: py(2) = H& / 2 '  right bottom
211.     px(3) = W& / 2: py(3) = -H& / 2 ' right top
212.     sinr! = SIN(-radianRotation): cosr! = COS(-radianRotation) ' rotation helpers
213.     FOR i& = 0 TO 3 ' calc new point locations with rotation and zoom
214.         x2& = xScale * (px(i&) * cosr! + sinr! * py(i&)) + X: y2& = yScale * (py(i&) * cosr! - px(i&) * sinr!) + Y
215.         px(i&) = x2&: py(i&) = y2&
216.     NEXT
217.     _MAPTRIANGLE _SEAMLESS(0, 0)-(0, H& - 1)-(W& - 1, H& - 1), Image TO(px(0), py(0))-(px(1), py(1))-(px(2), py(2))
218.     _MAPTRIANGLE _SEAMLESS(0, 0)-(W& - 1, 0)-(W& - 1, H& - 1), Image TO(px(0), py(0))-(px(3), py(3))-(px(2), py(2))
219. END SUB
220.  
221.  

BTW paint4 is filling with a midrange color between two colors based on location in screen.

 

[STxAxTIC]

Had to raise the bar.

Behold, the tenth-second hand (I hate it).

Press uparrow to increase time
Press downarrow to decrease time
Press left/right arrow to change mode (not new)
Press Space for stopwatch mode
Press R to reset to normal time

Also got rid of TIME$ dependence completely, all TIMER now.

Code: QB64: [Select]

1. OPTION _EXPLICIT
2.  
3. DO UNTIL _SCREENEXISTS: LOOP
4. _TITLE "Parametric Clock"
5.  
6. DIM SHARED MainScreen AS LONG
7. DIM SHARED BackScreen AS LONG
8. MainScreen = _NEWIMAGE(600, 600, 32)
9. BackScreen = _NEWIMAGE(600, 600, 32)
10. SCREEN MainScreen
11.  
12. RANDOMIZE TIMER
13.  
14. DIM SHARED pi AS DOUBLE
15. DIM SHARED phi AS DOUBLE
16. pi = 4 * ATN(1)
17. phi = (1 + SQR(5)) / 2
18.  
19. TYPE TimeValue
20.     Hour AS INTEGER
21.     Minute AS INTEGER
22.     Second AS DOUBLE
23.     TenthSecond AS DOUBLE
24. END TYPE
25.  
26. TYPE Vector
27.     x AS DOUBLE
28.     y AS DOUBLE
29. END TYPE
30.  
31. TYPE ClockHand
32.     Center AS Vector
33.     HandPosition AS Vector
34.     Length AS DOUBLE
35.     Angle AS DOUBLE
36.     Shade AS _UNSIGNED LONG
37. END TYPE
38.  
39. DIM SHARED TheTime AS TimeValue
40. DIM SHARED HourHand AS ClockHand
41. DIM SHARED MinuteHand AS ClockHand
42. DIM SHARED SecondHand AS ClockHand
43. DIM SHARED TenthSecondHand AS ClockHand
44.  
45. DIM SHARED Mode AS INTEGER
46. DIM SHARED ModeList(12) AS INTEGER
47. DIM SHARED TimeShift AS DOUBLE
48. TimeShift = 0
49.  
50. HourHand.Center.x = 0
51. HourHand.Center.y = 0
52. HourHand.Length = 150
53. MinuteHand.Length = HourHand.Length / (phi)
54. SecondHand.Length = HourHand.Length / (phi ^ 2)
55. TenthSecondHand.Length = HourHand.Length / (phi ^ 3)
56. HourHand.Shade = _RGBA(200, 50, 50, 255)
57. MinuteHand.Shade = _RGBA(65, 105, 225, 255)
58. SecondHand.Shade = _RGBA(255, 165, 0, 255)
59. TenthSecondHand.Shade = _RGBA(138, 43, 226, 255)
60.  
61. CALL InitializeModes
62. Mode = 12
63.  
64. CALL PrepareClockface(1)
65. DO
66.     CALL KeyProcess
67.     CALL UpdateTime(TIMER + TimeShift)
68.     CALL UpdateClock
69.     CALL DrawEverything
70.     _KEYCLEAR
71.     _LIMIT 60
72. LOOP
73.  
74. SYSTEM
75.  
76. SUB InitializeModes
77.     DIM k AS INTEGER
78.     FOR k = 1 TO 12
79.         ModeList(k) = k
80.     NEXT
81. END SUB
82.  
83. SUB PrepareClockface (metric AS INTEGER)
84.     DIM p AS DOUBLE
85.     DIM q AS LONG
86.     _DEST BackScreen
87.     CLS
88.     CALL ccircle(0, 0, HourHand.Length, HourHand.Shade)
89.     p = RND
90.     FOR q = 0 TO ((Mode * 3600) - (metric)) STEP (metric)
91.         CALL UpdateTime(q)
92.         CALL UpdateClock
93.         CALL lineSmooth(SecondHand.Center.x, SecondHand.Center.y, SecondHand.HandPosition.x, SecondHand.HandPosition.y, _RGBA(255 * p, 255 * RND * 155, 255 * (1 - p), 30))
94.     NEXT
95.     FOR q = 0 TO ((Mode * 3600) - (3600)) STEP (3600)
96.         CALL UpdateTime(q)
97.         CALL UpdateClock
98.         CALL ccircle(HourHand.HandPosition.x, HourHand.HandPosition.y, 6, HourHand.Shade)
99.         CALL ccirclefill(HourHand.HandPosition.x, HourHand.HandPosition.y, 5, _RGBA(0, 0, 0, 255))
100.     NEXT
101.     _DEST MainScreen
102. END SUB
103.  
104. SUB KeyProcess
105.     IF (_KEYDOWN(32) = -1) THEN ' Space
106.         TimeShift = -TIMER
107.     END IF
108.     IF ((_KEYDOWN(114) = -1) OR (_KEYDOWN(84) = -1)) THEN ' r or R
109.         TimeShift = 0
110.     END IF
111.     IF (_KEYDOWN(19200) = -1) THEN ' Leftarrow
112.         CALL DecreaseMode
113.         CALL PrepareClockface(1)
114.         _DELAY .1
115.     END IF
116.     IF (_KEYDOWN(19712) = -1) THEN ' Rightarrow
117.         CALL IncreaseMode
118.         CALL PrepareClockface(1)
119.         _DELAY .1
120.     END IF
121.     IF (_KEYDOWN(18432) = -1) THEN
122.         TimeShift = TimeShift + 60 ' Uparrow
123.     END IF
124.     IF (_KEYDOWN(20480) = -1) THEN ' Downarrow
125.         TimeShift = TimeShift - 60
126.     END IF
127. END SUB
128.  
129. SUB UpdateTime (z AS DOUBLE)
130.     DIM t AS DOUBLE
131.     t = z
132.     TheTime.Hour = INT(t / 3600)
133.     t = t - TheTime.Hour * 3600
134.     TheTime.Hour = TheTime.Hour MOD Mode
135.     IF (TheTime.Hour = 0) THEN TheTime.Hour = Mode
136.     TheTime.Minute = INT(t / 60)
137.     t = t - TheTime.Minute * 60
138.     TheTime.Second = t
139.     TheTime.TenthSecond = TheTime.Second - INT(TheTime.Second)
140. END SUB
141.  
142. SUB UpdateClock
143.     HourHand.Angle = -((TheTime.Hour + (TheTime.Minute / 60) + (TheTime.Second / 3600)) / Mode) * 2 * pi + (pi / 2)
144.     MinuteHand.Angle = -((TheTime.Minute / 60) + (TheTime.Second / 3600)) * 2 * pi + (pi / 2)
145.     SecondHand.Angle = -(TheTime.Second / 60) * 2 * pi + (pi / 2)
146.     TenthSecondHand.Angle = -(TheTime.TenthSecond) * 2 * pi + (pi / 2)
147.  
148.     HourHand.HandPosition.x = HourHand.Center.x + HourHand.Length * COS(HourHand.Angle)
149.     HourHand.HandPosition.y = HourHand.Center.y + HourHand.Length * SIN(HourHand.Angle)
150.     MinuteHand.Center.x = HourHand.HandPosition.x
151.     MinuteHand.Center.y = HourHand.HandPosition.y
152.     MinuteHand.HandPosition.x = MinuteHand.Center.x + MinuteHand.Length * COS(MinuteHand.Angle)
153.     MinuteHand.HandPosition.y = MinuteHand.Center.y + MinuteHand.Length * SIN(MinuteHand.Angle)
154.     SecondHand.Center.x = MinuteHand.HandPosition.x
155.     SecondHand.Center.y = MinuteHand.HandPosition.y
156.     SecondHand.HandPosition.x = SecondHand.Center.x + SecondHand.Length * COS(SecondHand.Angle)
157.     SecondHand.HandPosition.y = SecondHand.Center.y + SecondHand.Length * SIN(SecondHand.Angle)
158.  
159.     TenthSecondHand.Center.x = SecondHand.HandPosition.x
160.     TenthSecondHand.Center.y = SecondHand.HandPosition.y
161.     TenthSecondHand.HandPosition.x = TenthSecondHand.Center.x + TenthSecondHand.Length * COS(TenthSecondHand.Angle)
162.     TenthSecondHand.HandPosition.y = TenthSecondHand.Center.y + TenthSecondHand.Length * SIN(TenthSecondHand.Angle)
163.  
164. END SUB
165.  
166. SUB DrawEverything
167.     CLS
168.     _PUTIMAGE (0, 0)-(_WIDTH, _HEIGHT), BackScreen, MainScreen, (0, 0)-(_WIDTH, _HEIGHT)
169.     CALL DrawModeList
170.     CALL DrawHUD
171.     CALL DrawClockHands
172.     CALL DrawDigitalClock
173.     _DISPLAY
174. END SUB
175.  
176. SUB DrawModeList
177.     DIM k AS INTEGER
178.     FOR k = 1 TO UBOUND(ModeList)
179.         IF (Mode = k) THEN
180.             COLOR _RGBA(255, 255, 0, 255), _RGBA(0, 0, 255, 255)
181.         ELSE
182.             COLOR _RGBA(100, 100, 100, 255), _RGBA(0, 0, 0, 0)
183.         END IF
184.         _PRINTSTRING ((4 + 5 * k) * 8, _HEIGHT - (1) * 16), LTRIM$(RTRIM$(STR$(ModeList(k))))
185.     NEXT
186.     COLOR _RGBA(200, 200, 0, 255), _RGBA(0, 0, 0, 0)
187.     _PRINTSTRING ((4 + 1) * 8, _HEIGHT - (1) * 16), ">"
188.     _PRINTSTRING ((4 + 5 * (UBOUND(ModeList) + 1)) * 8, _HEIGHT - (1) * 16), "<"
189. END SUB
190.  
191. SUB IncreaseMode
192.     IF (Mode < 12) THEN
193.         Mode = Mode + 1
194.     ELSE
195.         Mode = 1
196.     END IF
197. END SUB
198.  
199. SUB DecreaseMode
200.     IF (Mode = 1) THEN
201.         Mode = 12
202.     ELSE
203.         Mode = Mode - 1
204.     END IF
205. END SUB
206.  
207. SUB DrawClockHands
208.     DIM k AS DOUBLE
209.     DIM ctmp AS _UNSIGNED LONG
210.     DIM SeedLength AS DOUBLE
211.     SeedLength = 12
212.     FOR k = 0 TO 1 STEP .01
213.         ctmp = ColorMix(_RGBA(0, 0, 255, 255), HourHand.Shade, k)
214.         ctmp = _RGBA(_RED32(ctmp), _GREEN32(ctmp), _BLUE32(ctmp), k * _ALPHA32(ctmp))
215.         CALL ccirclefill(HourHand.Center.x + (k * HourHand.Length) * COS(HourHand.Angle), HourHand.Center.y + (k * HourHand.Length) * SIN(HourHand.Angle), k * SeedLength, ctmp)
216.     NEXT
217.     FOR k = 0 TO 1 STEP .01
218.         ctmp = ColorMix(HourHand.Shade, MinuteHand.Shade, k)
219.         ctmp = _RGBA(_RED32(ctmp), _GREEN32(ctmp), _BLUE32(ctmp), _ALPHA32(ctmp))
220.         CALL ccirclefill(MinuteHand.Center.x + (k * MinuteHand.Length) * COS(MinuteHand.Angle), MinuteHand.Center.y + (k * MinuteHand.Length) * SIN(MinuteHand.Angle), SeedLength * (1 - k / phi), ctmp)
221.     NEXT
222.     FOR k = 0 TO 1 STEP .005
223.         ctmp = ColorMix(MinuteHand.Shade, SecondHand.Shade, k)
224.         ctmp = _RGBA(_RED32(ctmp), _GREEN32(ctmp), _BLUE32(ctmp), _ALPHA32(ctmp))
225.         CALL ccirclefill(SecondHand.Center.x + (k * SecondHand.Length) * COS(SecondHand.Angle), SecondHand.Center.y + (k * SecondHand.Length) * SIN(SecondHand.Angle), (SeedLength * (1 - 1 / phi)) * (1 - k), ctmp)
226.     NEXT
227.     FOR k = 0 TO 1 STEP .005
228.         ctmp = ColorMix(SecondHand.Shade, TenthSecondHand.Shade, k)
229.         ctmp = _RGBA(_RED32(ctmp), _GREEN32(ctmp), _BLUE32(ctmp), _ALPHA32(ctmp))
230.         CALL ccirclefill(TenthSecondHand.Center.x + (k * TenthSecondHand.Length) * COS(TenthSecondHand.Angle), TenthSecondHand.Center.y + (k * TenthSecondHand.Length) * SIN(TenthSecondHand.Angle), (SeedLength * (1 - 1 / phi)) * (1 - k), ctmp)
231.     NEXT
232.  
233.     CALL DrawPulley(HourHand.Center.x, HourHand.Center.x, 0, HourHand.HandPosition.x, HourHand.HandPosition.y, SeedLength + 2, _RGBA(255, 255, 255, 255))
234.     CALL DrawPulley(HourHand.HandPosition.x, HourHand.HandPosition.y, SeedLength + 2, MinuteHand.HandPosition.x, MinuteHand.HandPosition.y, (SeedLength * (1 - 1 / phi)) + 1, _RGBA(255, 255, 255, 255))
235.     CALL DrawPulley(MinuteHand.HandPosition.x, MinuteHand.HandPosition.y, (SeedLength * (1 - 1 / phi)) + 1, SecondHand.HandPosition.x, SecondHand.HandPosition.y, 0, _RGBA(255, 255, 255, 255))
236.     CALL DrawPulley(SecondHand.HandPosition.x, SecondHand.HandPosition.y, (SeedLength * (1 - 1 / phi)) + 1, TenthSecondHand.HandPosition.x, TenthSecondHand.HandPosition.y, 0, _RGBA(255, 255, 255, 255))
237. END SUB
238.  
239. SUB DrawDigitalClock
240.     DIM t AS STRING
241.     COLOR _RGBA(200, 200, 0, 255), _RGBA(0, 0, 0, 0)
242.     DIM h AS STRING
243.     DIM m AS STRING
244.     DIM s AS STRING
245.     DIM n AS STRING
246.     h = LTRIM$(RTRIM$(STR$(TheTime.Hour)))
247.     IF LEN(h) = 1 THEN h = "0" + h
248.     m = LTRIM$(RTRIM$(STR$(TheTime.Minute)))
249.     IF LEN(m) = 1 THEN m = "0" + m
250.     s = LTRIM$(RTRIM$(STR$(INT(TheTime.Second))))
251.     IF LEN(s) = 1 THEN s = "0" + s
252.     n = LTRIM$(RTRIM$(STR$((INT(10 * TheTime.TenthSecond)))))
253.     t = h + ":" + m + ":" + s + ":" + n
254.     LOCATE 1, (_WIDTH / 8) / 2 - LEN(t) / 2
255.     PRINT t
256. END SUB
257.  
258. SUB DrawHUD
259.     COLOR _RGBA(0, 200, 200, 255), _RGBA(0, 0, 0, 0)
260.     LOCATE 1, 2: PRINT "SPACE = Stopwatch"
261.     LOCATE 2, 2: PRINT "    R = Reset"
262.     LOCATE 1, 59: PRINT "UpArrow = Time +"
263.     LOCATE 2, 59: PRINT "DnArrow = Time -"
264. END SUB
265.  
266. FUNCTION ColorMix~& (Shade1 AS _UNSIGNED LONG, Shade2 AS _UNSIGNED LONG, param AS DOUBLE)
267.     ColorMix~& = _RGB32((1 - param) * _RED32(Shade1) + param * _RED32(Shade2), (1 - param) * _GREEN32(Shade1) + param * _GREEN32(Shade2), (1 - param) * _BLUE32(Shade1) + param * _BLUE32(Shade2))
268. END FUNCTION
269.  
270. SUB cpset (x1, y1, col AS _UNSIGNED LONG)
271.     PSET (_WIDTH / 2 + x1, -y1 + _HEIGHT / 2), col
272. END SUB
273.  
274. SUB cline (x1 AS DOUBLE, y1 AS DOUBLE, x2 AS DOUBLE, y2 AS DOUBLE, col AS _UNSIGNED LONG)
275.     LINE (_WIDTH / 2 + x1, -y1 + _HEIGHT / 2)-(_WIDTH / 2 + x2, -y2 + _HEIGHT / 2), col
276. END SUB
277.  
278. SUB ccircle (x1 AS DOUBLE, y1 AS DOUBLE, rad AS DOUBLE, col AS _UNSIGNED LONG)
279.     CIRCLE (_WIDTH / 2 + x1, -y1 + _HEIGHT / 2), rad, col
280. END SUB
281.  
282. SUB ccirclefill (x1 AS DOUBLE, y1 AS DOUBLE, rad AS DOUBLE, col AS _UNSIGNED LONG)
283.     CALL CircleFill(_WIDTH / 2 + x1, -y1 + _HEIGHT / 2, rad, col)
284. END SUB
285.  
286. SUB CircleFill (CX AS INTEGER, CY AS INTEGER, R AS INTEGER, C AS _UNSIGNED LONG)
287.     ' CX = center x coordinate
288.     ' CY = center y coordinate
289.     '  R = radius
290.     '  C = fill color
291.     DIM Radius AS INTEGER, RadiusError AS INTEGER
292.     DIM X AS INTEGER, Y AS INTEGER
293.     Radius = ABS(R)
294.     RadiusError = -Radius
295.     X = Radius
296.     Y = 0
297.     IF Radius = 0 THEN PSET (CX, CY), C: EXIT SUB
298.     LINE (CX - X, CY)-(CX + X, CY), C, BF
299.     WHILE X > Y
300.         RadiusError = RadiusError + Y * 2 + 1
301.         IF RadiusError >= 0 THEN
302.             IF X <> Y + 1 THEN
303.                 LINE (CX - Y, CY - X)-(CX + Y, CY - X), C, BF
304.                 LINE (CX - Y, CY + X)-(CX + Y, CY + X), C, BF
305.             END IF
306.             X = X - 1
307.             RadiusError = RadiusError - X * 2
308.         END IF
309.         Y = Y + 1
310.         LINE (CX - X, CY - Y)-(CX + X, CY - Y), C, BF
311.         LINE (CX - X, CY + Y)-(CX + X, CY + Y), C, BF
312.     WEND
313. END SUB
314.  
315. SUB DrawPulley (x1 AS DOUBLE, y1 AS DOUBLE, rad1 AS DOUBLE, x2 AS DOUBLE, y2 AS DOUBLE, rad2 AS DOUBLE, col AS _UNSIGNED LONG)
316.     'Inspiration credit: {(bplus)(qb64.org)(2020-11-22)}
317.     DIM ang AS DOUBLE
318.     ang = _ATAN2(y2 - y1, x2 - x1) + pi / 2
319.     CALL lineSmooth(x1 + rad1 * COS(ang), y1 + rad1 * SIN(ang), x2 + rad2 * COS(ang), y2 + rad2 * SIN(ang), col)
320.     CALL lineSmooth(x1 - rad1 * COS(ang), y1 - rad1 * SIN(ang), x2 - rad2 * COS(ang), y2 - rad2 * SIN(ang), col)
321.     CALL ccircle(x1, y1, rad1, col)
322.     CALL ccircle(x2, y2, rad2, col)
323. END SUB
324.  
325. SUB lineSmooth (x0, y0, x1, y1, c AS _UNSIGNED LONG)
326.     'Inspiration credit: {(FellippeHeitor)(qb64.org)(2020)}
327.     '                    {https://en.wikipedia.org/w/index.php?title=Xiaolin_Wu%27s_line_algorithm&oldid=852445548}
328.     'Edit: {(STxAxTIC)(2020-11-20)(Correction to alpha channel.)}
329.  
330.     DIM plX AS INTEGER, plY AS INTEGER, plI
331.  
332.     DIM steep AS _BYTE
333.     steep = ABS(y1 - y0) > ABS(x1 - x0)
334.  
335.     IF steep THEN
336.         SWAP x0, y0
337.         SWAP x1, y1
338.     END IF
339.  
340.     IF x0 > x1 THEN
341.         SWAP x0, x1
342.         SWAP y0, y1
343.     END IF
344.  
345.     DIM dx, dy, gradient
346.     dx = x1 - x0
347.     dy = y1 - y0
348.     gradient = dy / dx
349.  
350.     IF dx = 0 THEN
351.         gradient = 1
352.     END IF
353.  
354.     'handle first endpoint
355.     DIM xend, yend, xgap, xpxl1, ypxl1
356.     xend = _ROUND(x0)
357.     yend = y0 + gradient * (xend - x0)
358.     xgap = (1 - ((x0 + .5) - INT(x0 + .5)))
359.     xpxl1 = xend 'this will be used in the main loop
360.     ypxl1 = INT(yend)
361.     IF steep THEN
362.         plX = ypxl1
363.         plY = xpxl1
364.         plI = (1 - (yend - INT(yend))) * xgap
365.         GOSUB plot
366.  
367.         plX = ypxl1 + 1
368.         plY = xpxl1
369.         plI = (yend - INT(yend)) * xgap
370.         GOSUB plot
371.     ELSE
372.         plX = xpxl1
373.         plY = ypxl1
374.         plI = (1 - (yend - INT(yend))) * xgap
375.         GOSUB plot
376.  
377.         plX = xpxl1
378.         plY = ypxl1 + 1
379.         plI = (yend - INT(yend)) * xgap
380.         GOSUB plot
381.     END IF
382.  
383.     DIM intery
384.     intery = yend + gradient 'first y-intersection for the main loop
385.  
386.     'handle second endpoint
387.     DIM xpxl2, ypxl2
388.     xend = _ROUND(x1)
389.     yend = y1 + gradient * (xend - x1)
390.     xgap = ((x1 + .5) - INT(x1 + .5))
391.     xpxl2 = xend 'this will be used in the main loop
392.     ypxl2 = INT(yend)
393.     IF steep THEN
394.         plX = ypxl2
395.         plY = xpxl2
396.         plI = (1 - (yend - INT(yend))) * xgap
397.         GOSUB plot
398.  
399.         plX = ypxl2 + 1
400.         plY = xpxl2
401.         plI = (yend - INT(yend)) * xgap
402.         GOSUB plot
403.     ELSE
404.         plX = xpxl2
405.         plY = ypxl2
406.         plI = (1 - (yend - INT(yend))) * xgap
407.         GOSUB plot
408.  
409.         plX = xpxl2
410.         plY = ypxl2 + 1
411.         plI = (yend - INT(yend)) * xgap
412.         GOSUB plot
413.     END IF
414.  
415.     'main loop
416.     DIM x
417.     IF steep THEN
418.         FOR x = xpxl1 + 1 TO xpxl2 - 1
419.             plX = INT(intery)
420.             plY = x
421.             plI = (1 - (intery - INT(intery)))
422.             GOSUB plot
423.  
424.             plX = INT(intery) + 1
425.             plY = x
426.             plI = (intery - INT(intery))
427.             GOSUB plot
428.  
429.             intery = intery + gradient
430.         NEXT
431.     ELSE
432.         FOR x = xpxl1 + 1 TO xpxl2 - 1
433.             plX = x
434.             plY = INT(intery)
435.             plI = (1 - (intery - INT(intery)))
436.             GOSUB plot
437.  
438.             plX = x
439.             plY = INT(intery) + 1
440.             plI = (intery - INT(intery))
441.             GOSUB plot
442.  
443.             intery = intery + gradient
444.         NEXT
445.     END IF
446.  
447.     EXIT SUB
448.  
449.     plot:
450.     ' Change to regular PSET for standard coordinate orientation.
451.     CALL cpset(plX, plY, _RGB32(_RED32(c), _GREEN32(c), _BLUE32(c), plI * _ALPHA32(c)))
452.     RETURN
453. END SUB