Author Topic: Well here's a highlighting routine I've been fiddling with for a couple of days. (Read 4317 times)

Pete · « **on:** November 11, 2020, 05:08:24 pm »

I probably have made a half-dozen of these, over the decades, but I always love reinventing the mouse wheel. This could probably use some tweaking, and I might look up the actual highlighting algorithm for changing color I developed some years ago. This one uses a screen reading cheat to determine the highlight / unhighlight color for the text segments. That, and I cut corners by using a loop routine for r/l mouse highlighting, rather than calculating the actual string conditions. There's also a bit of a cheat using the fact that QB64 allows parameters, which exceed the number of characters in a MID$() string; meaning PRINT MID$(a$, 6, 10000) Is accepted even if the a$ string is only 10-characters long.

Code: QB64: [Select]

REM debug% = -1
margin.l = 4
margin.t = 2
 
' DEMO sample text block.-----------------------------------------------------
REDIM x$(20)
x$(1) = "qwerty"
x$(2) = "asdfg"
x$(3) = "zxcvbn"
x$(4) = "abcd"
x$(5) = "123456"
x$(6) = "qwerty"
x$(7) = "987654"
x$(8) = "mnbvcx"
x$(9) = "asdf"
x$(10) = "poiuyt"
 
FOR h = 0 TO 1
    FOR i = 1 TO 10
        x$(i + h * 10) = x$(i + h * 10) + x$(i + h * 10) + x$(i + h * 10) + x$(i + h * 10) + x$(i) + x$(i + h * 10) + x$(i + h * 10)
    NEXT
NEXT
 
'======================== Needed variables for routine and demo.
dwidth = LEN(x$(1)) + 1 ' Must always be +1 so mod formula never results in a 0 as in a string the size of dwidth mod dwidth.
page.h = 10 ' Page height.
noe% = 20 ' Number of text line entries.
'========================
 
c1% = 7: c2% = 0: h1% = 15: h2% = 1 ' Normal text and highlighted text colors.
 
h% = 0: GOSUB displaytext
 
LOCATE margin.t + 1, margin.l + 1, 1, 7, 30
' / Demo sample text block.--------------------------------------------------
 
' ===========================================================================
 
' Highlight Routine----------------------------------------------------------
row = CSRLIN - margin.t: col = POS(0) - margin.l
 
DO
    _LIMIT 30
 
    DEF SEG = 0 ' Look for Shift key press.
    IF PEEK(1047) MOD 16 = 1 OR PEEK(1047) MOD 16 = 2 THEN shift% = -1 ELSE shift% = 0
    DEF SEG
 
    IF autokey% = 0 THEN b$ = INKEY$ ELSE autokey% = 0
 
    IF lb% THEN
        null$ = INKEY$: b$ = "" ' Clear key buffer when left mouse button is held down and lock out keys.
    END IF
 
    IF LEN(b$) OR mhl% THEN ' Key press or mouse clicked / held down (mhl%).
        IF b$ = CHR$(13) AND debug% THEN CLS: RUN
        IF b$ = CHR$(27) THEN h% = 0: GOSUB displaytext: _DELAY .4: SYSTEM
 
        IF mhl% OR shift% AND INSTR("KMHPOG", MID$(b$, 2, 1)) AND LEN(b$) = 2 THEN
            hlkey% = -1 ' Left mouse button down or Shift key down with a highlighting key pressed.
            IF mark% = 0 THEN
                mark% = (row - 1) * dwidth + col: markrow% = row: markcol% = col ' Highlight cursor position markers.
                IF cutmrow% = 0 THEN cutmrow% = markrow% + scr: cutmcol% = markcol%
            END IF
        ELSE
            ' Disable highlight key when active and a key is pressed without Shift key held or
            IF hlkey% AND LEN(b$) > 0 THEN ' Highlighted text and key press. Note: Left mouse click to clear text is in another routine.
                hlkey% = 0: cutmrow% = 0: GOSUB clearmarkers ' Disable highlight and zero highlighting cursor marker.
                h% = 0: GOSUB displaytext ' Use this or some other routine to clear the highlighted text off the screen.
            END IF
        END IF
 
        IF mhl% THEN ' Left mouse button click or held highlighting.
            IF mhl1row% = oldmhl1row% THEN
                ' Lateral movement. Take no action here. Action is taken in the select case mov routine.
            ELSE ' Simulate an up or down arrow key routines for mouse highlighting when changing rows.
                IF mhl1row% < oldmhl1row% THEN b$ = CHR$(0) + "H" ' Highlight upwards.
                IF mhl1row% > oldmhl1row% THEN b$ = CHR$(0) + "P" ' Highlight downwards.
            END IF
        END IF
 
        DO
            IF mhl% THEN ' Left mouse key highlighting.
                IF row = mhl1row% THEN ' Detect when the row in the loop matches the row marked to terminate the loop.
                    SELECT CASE mhl1col% ' Now that the loop has terminated at the marked row, find the marked column.
                        CASE 0 ' Column at loop exit is already at the marked column.
                            mhl% = 0: EXIT DO
                        CASE ELSE ' Set col variable to mouse column marker and zero out that marker along with the simulated key press.
                            col = mhl1col%: mhl1col% = 0 ' New col position allows highlighter routine to highlight text on this row to this column.
                            b$ = "" ' Important. Must nullify variable to avoid case selection below.
                    END SELECT
                END IF
            END IF
 
            SELECT CASE MID$(b$, 2, 1) ' Cursor movement routine. May be replace or incorporated into outer cursor movement routines.
                CASE "H"
                    IF row > 1 THEN
                        row = row - 1
                    ELSE
                        IF scr > 0 THEN
                            IF mark% THEN
                                i% = -1: GOSUB redomarkers
                                row = row + 1: scr = scr - 1
                                h% = 2: GOSUB displaytext
                                row = row - 1
                            ELSE
                                scr = scr - 1
                                h% = 0: GOSUB displaytext
                            END IF
                        END IF
                    END IF
                CASE "P"
                    IF row < page.h THEN
                        row = row + 1
                    ELSE
                        IF row + scr < noe% THEN
                            IF mark% THEN
                                i% = 1: GOSUB redomarkers
                                row = row - 1
                                scr = scr + 1
                                h% = page.h - 1: GOSUB displaytext
                                row = row + 1
                            ELSE
                                scr = scr + 1
                                h% = 0: GOSUB displaytext
                            END IF
                        END IF
                    END IF
                CASE "M"
                    IF col < LEN(x$(row + scr)) THEN
                        col = col + 1
                    ELSE
                        IF row < page.h THEN
                            row = row + 1: col = 1
                        ELSE
                            IF row + scr < noe% THEN
                                IF mark% THEN
                                    i% = 1: GOSUB redomarkers
                                    row = row - 1: scr = scr + 1
                                    h% = page.h - 1: GOSUB displaytext
                                    row = row + 1: col = 1
                                ELSE
                                    scr = scr + 1: col = 1
                                    h% = 0: GOSUB displaytext
                                END IF
                                LOCATE margin.t + row, margin.l + col
                            END IF
                        END IF
                    END IF
                CASE "K"
                    IF col > 1 THEN
                        col = col - 1
                    ELSE
                        IF row > 1 THEN
                            row = row - 1: col = dwidth - 1
                        ELSE
                            IF scr > 0 THEN
                                IF mark% THEN
                                    i% = -1: GOSUB redomarkers
                                    row = row + 1: scr = scr - 1
                                    h% = 2: GOSUB displaytext
                                    row = row - 1: col = LEN(x$(row + scr)): IF col < dwidth - 1 THEN col = col + 1
                                ELSE
                                    scr = scr - 1
                                    col = LEN(x$(row + scr)): IF col < dwidth - 1 THEN col = col + 1
                                    h% = 0: GOSUB displaytext
                                END IF
                            END IF
                        END IF
                    END IF
                CASE "G"
                    col = 1
                CASE "O"
                    col = LEN(x$(row + scr)): IF col < dwidth - 1 THEN col = col + 1
            END SELECT
 
            LOCATE margin.t + row, margin.l + col ' Note: Both row and col variables are relative and must be added to any left or top margin variables to appear in the proper row and column positions on the screen.
 
            IF mark% THEN GOSUB highlighter
 
            IF col > LEN(x$(row + scr)) THEN
                col = LEN(x$(row + scr))
                IF col < dwidth - 1 THEN col = col + 1
                LOCATE margin.t + row, margin.l + col ' Note: Both row and col variables are relative and must be added to any left or top margin variables to appear in the proper row and column positions on the screen.
            END IF
 
        LOOP UNTIL mhl% = 0 ' Exit for key press because mhl% is zero during key presses.
    END IF
 
    WHILE _MOUSEINPUT
        mw% = mw% + _MOUSEWHEEL
    WEND
        my% = _MOUSEY
        mx% = _MOUSEX
        lb% = _MOUSEBUTTON(1)
 
    IF shift% AND mw% THEN
        IF mw% > 0 THEN
            b$ = CHR$(0) + "P"
        ELSE
            b$ = CHR$(0) + "H"
        END IF
        mw% = 0: autokey% = -1
    ELSE
        mw% = 0
    END IF
 
    IF lb% THEN ' Left mouse button pressed.
        IF mx% > margin.l AND mx% <= margin.l + dwidth - 1 THEN ' Cursor in-bounds.
            ii% = my% - margin.t
            IF ii% > page.h OR ii% <= 0 THEN
                IF ii% < 1 THEN ii% = 1
                IF ii% > page.h THEN ii% = page.h
                IF mark% THEN
                    IF ii% = 1 THEN
                        IF scr > 0 THEN
                            col = mx% - margin.l
                            LOCATE margin.t + ii%, margin.l + col
                            i% = -1: GOSUB redomarkers
                            row = row + 1: scr = scr - 1
                            h% = 2: GOSUB displaytext
                            LOCATE margin.t + ii%, margin.l + col
                            row = CSRLIN - margin.t
                        END IF
                    ELSE
                        IF ii% + scr < noe% THEN
                            col = mx% - margin.l
                            LOCATE margin.t + ii%, margin.l + col
                            i% = 1: GOSUB redomarkers
                            row = row - 1: scr = scr + 1
                            h% = page.h - 1: GOSUB displaytext
                            LOCATE margin.t + ii%, margin.l + col
                            row = CSRLIN - margin.t
                        END IF
                    END IF
                END IF
            END IF
 
            IF mhlclear% THEN ' Check to see if highlighting should be removed.
                IF shift% THEN ' Do not remove highlighted text.
                    mhlclear% = 0
                ELSE
                    cutmrow% = 0: GOSUB clearmarkers
                    h% = 0: GOSUB displaytext ' Remove highlighted text.
                END IF
            END IF
 
            IF shift% OR (ii% - 1) * dwidth + mx% - margin.l <> mhl1% AND mhl1% <> 0 THEN
                mhl% = -1 ' Left mouse key highlighting enabled when Shift key held and left mouse button click or when Shift held or not held if left mouse button is held while changing row/column (drag).
                IF oldmhl1row% = 0 THEN oldmhl1row% = row ELSE oldmhl1row% = mhl1row%
                mhl1row% = ii%: mhl1col% = mx% - margin.l: mhl1% = (ii% - 1) * dwidth + mx% - margin.l
            ELSE
                IF mhl1% <> (ii% - 1) * dwidth + mx% - margin.l THEN
                    mhl1% = (ii% - 1) * dwidth + mx% - margin.l
                    row = ii%: col = mx% - margin.l
                    LOCATE margin.t + row, margin.l + col
                END IF
            END IF
        END IF
    ELSE ' Left mouse button unpressed or released.
        mhl1% = 0 ' Left mouse button released so zero the highlighting marker.
        IF mark% THEN mhlclear% = -1 ' Will be triggered the next time the left mouse button is pressed to remove all highlighted text.
    END IF
LOOP
 
displaytext:
yy% = CSRLIN: xx% = POS(0)
IF cutmrow% THEN
    cutdrow% = row + scr: cutdcol% = col
    IF debug% THEN GOSUB debugger
    SELECT CASE cutmrow%
        CASE IS < cutdrow%: j% = cutmrow%: j1% = cutmcol%
        CASE IS = cutdrow% ' Highlighting begins and ends on same row. Ex: Left and right arrow keys.
            j% = cutmrow%
            IF cutmcol% < cutdcol% THEN j% = cutmrow%: j1% = cutmcol% ELSE j% = cutdrow%: j1% = cutdcol% ' Right arrow vs left arrow directions.
        CASE IS > cutdrow%: j% = cutdrow%: j1% = cutdcol%
    END SELECT
    jtop% = cutmrow%: jbot% = cutdrow%: IF jtop% > jbot% THEN SWAP jtop%, jbot%
    IF debug% THEN GOSUB debugger
ELSE
    j% = 0
END IF
 
FOR i% = 1 TO page.h
    LOCATE margin.t + i%, margin.l + 1
    a1$ = SPACE$(dwidth)
    MID$(a1$, 1) = x$(scr + i%)
    a2$ = x$(scr + i%): a3$ = SPACE$(dwidth - LEN(a2$))
    SELECT CASE j%
        CASE 0
            PRINT a1$;
        CASE ELSE
            IF debug% THEN GOSUB debugger
            k% = LEN(a2$)
            x1 = c1%: x2 = c2%: x3 = c1%: x4 = c2%
 
            IF i% = h% THEN
                IF cutmrow% = cutdrow% THEN ' Left/Right Highlighting on origination row.
                    x3 = h1%: x4 = h2%: k% = ABS(cutmcol% - cutdcol%)
                ELSE ' Left/Right/Up/Down Highlighting from row before scrolling row.
                    x3 = h1%: x4 = h2%
                    IF cutdrow% > cutmrow% THEN
                        j1% = 1: k% = col - 1
                    ELSE
                        ' Do nothing. Arrow left and up do not require any change in parameters here.
                    END IF
                END IF
            ELSE
                IF i% + scr > jtop% AND i% + scr < jbot% THEN
                    j1% = 1: x3 = h1%: x4 = h2%
                ELSE
                    IF i% + scr = cutmrow% THEN
                        x3 = h1%: x4 = h2%
                        IF cutdrow% < cutmrow% THEN j1% = 1: k% = cutmcol% - 1
                    END IF
                END IF
            END IF
 
            COLOR x1, x2: PRINT MID$(a2$, 1, j1% - 1);
            COLOR x3, x4: PRINT MID$(a2$, j1%, k%);
            COLOR c1%, c2%: PRINT MID$(a2$, j1% + k%, LEN(a2$) - k%) + a3$;
 
    END SELECT
NEXT
COLOR c1%, c2%
LOCATE yy%, xx%
RETURN
 
highlighter:
yy% = CSRLIN: xx% = POS(0)
COLOR h1%, h2% ' Initiate highlight color.
IF o% = 0 THEN o% = mark% ELSE o% = d% ' o% is the start marker or last marker. If zero, it is the same as the start marker (mark%) but if the highlighting process is ongoing, it is the same as the last highlighting marker (d%).
d% = (row - 1) * dwidth + col ' Relative (margin independent) cursor destination marker.
o1% = (o% - (o% MOD dwidth)) / dwidth + 1 ' Relative (margin independent) cursor row origin.
o2% = o% MOD dwidth ' Relative (margin independent) cursor column origin.
d1% = row ' Relative (margin independent) cursor row destination. Note: row is also relative (margin independent).
d2% = col ' Relative (margin independent) cursor column destination. Note: col is also relative (margin independent).
IF d% >= o% THEN mov% = 1 ELSE mov% = -1 ' Difference between origin and destination markers determine if the movement is positive (right, down) or negative (left, up).
IF debug% THEN GOSUB debugger
 
SELECT CASE mov%
    CASE 1 ' End, right, or down
        x1% = o1%: x2% = o2%: LOCATE margin.t + x1%, margin.l + x2%
        ' Highlighting on line above, from origin row.
        IF x1% = markrow% AND o1% = d1% AND mhl% THEN ' Mouse only when the origin row is the same as the original marker row and the destination row is the same as the origin row. This is right movement within the same line of text.
            i% = 0: DO UNTIL POS(0) = margin.l + d2% OR i% = LEN(x$(x1% + scr)): GOSUB getcolor: PRINT MID$(x$(x1% + scr), x2% + i%, 1);: i% = i% + 1: LOOP
        ELSEIF x1% = markrow% AND ABS(o% - d%) > 1 AND mhl% = 0 THEN ' End key press. Exclude mouse here, as down mouse highlighting is done in a conditional statement, below.
            GOSUB getcolor: PRINT MID$(x$(x1% + scr), x2%, ABS(o2% - markcol%)); ' Print from origin column to initial marker column.
            GOSUB getcolor: PRINT MID$(x$(x1% + scr), x2% + ABS(o2% - markcol%)); ' Print from initial marker column to destination column.
        ELSE ' Right arrow key, down arrow key or mouse moving down.
            GOSUB getcolor: PRINT MID$(x$(x1% + scr), x2%, ABS(o1% - d1%) * dwidth + ABS(o2% - d2%)); ' Trick method to determine length of highlighting.
        END IF
 
        IF o1% - d1% THEN ' Highlighting on current row after row above is finished.
            x1% = row: x2% = col: LOCATE margin.t + x1%, margin.l + 1
            IF x1% = markrow% AND ABS(o% - d%) > 1 THEN ' Highlight the destination row if downward move is made after an upward highlight has been made.
                IF d2% < markcol% THEN i% = d2% ELSE i% = markcol% ' Set i% to the furthest column.
                GOSUB getcolor: PRINT MID$(x$(x1% + scr), 1, i% - 1); ' unhighlight to the furthest column.
                GOSUB getcolor: PRINT MID$(x$(x1% + scr), i%, ABS(d2% - i%));
            ELSE ' Arrow down or mouse downward, either with original marker row on same line.
                GOSUB getcolor: PRINT MID$(x$(x1% + scr), 1, d2% - 1); ' Highlight from first column on current row to destination on current row.
            END IF
        END IF
 
    CASE -1 ' Home, up, or Left.
        x1% = row: x2% = col: LOCATE margin.t + x1%, margin.l + x2%
 
        IF x1% = markrow% AND o1% = d1% AND mhl% THEN ' Mouse only when the origin row is the same as the original marker row and the destination row is the same as the origin row. This is left movement within the same line of text.
            IF mx% - margin.l < LEN(x$(x1% + scr)) THEN
                i% = 0: DO UNTIL POS(0) = margin.l + o2%: GOSUB getcolor: PRINT MID$(x$(x1% + scr), x2% + i%, 1);: i% = i% + 1: LOOP
            END IF
        ELSEIF x1% = markrow% AND ABS(o% - d%) > 1 THEN ' Mouse or arrow back up to highlighted line above.
            GOSUB getcolor: PRINT MID$(x$(x1% + scr), x2%, ABS(d2% - markcol%)); ' Highlight from cursor to previously highlighted text to the right, if any.
            GOSUB getcolor: PRINT MID$(x$(x1% + scr), x2% + ABS(d2% - markcol%)); ' Unhighlight previous text to the right.
        ELSE ' Arrow left, arrow up or mouse upwards, either without any highlighting above.
            GOSUB getcolor: PRINT MID$(x$(x1% + scr), x2%, ABS(o1% - d1%) * dwidth + ABS(o2% - d2%)); ' Trick method to determine length of highlighting.
        END IF
 
        IF o1% <> d1% AND d2% <= o2% THEN ' Bottom line with arrow up or mouse upwards. Note: Mouse initially moves straight up, and moves laterally in another pass. This is why o2% always equals d2% as with an arrow up move.
            x1% = o1%: x2% = o2%: LOCATE margin.t + x1%, margin.l + 1
            IF x1% = markrow% THEN
                IF markcol% >= d2% THEN i% = d2% ELSE i% = markcol%
                GOSUB getcolor: PRINT MID$(x$(x1% + scr), 1, i% - 1);
                GOSUB getcolor: PRINT MID$(x$(x1% + scr), i%, ABS(i% - d2%));
            ELSE
                GOSUB getcolor: PRINT MID$(x$(x1% + scr), 1, d2% - 1);
            END IF
        END IF
END SELECT
COLOR c1%, c2%
LOCATE yy%, xx%
 
RETURN
 
getcolor: ' Reads the screen under the cursor and reverses the colors.
IF SCREEN(CSRLIN, POS(0), 1) <> 7 THEN COLOR c1%, c2% ELSE COLOR h1%, h2%
RETURN
 
clearmarkers:
' Clear most variables used in highlighting process. Some others are non-essential to conditions.
mark% = 0: o% = 0: mhl% = 0: mhl1% = 0: mhl1col% = 0: mhl1row% = 0: oldmhl1row% = 0: mhlclear% = 0
cutdrow% = 0
RETURN
 
debugger:
ss% = CSRLIN: tt% = POS(0)
LOCATE 1, 52
PRINT "mark% = "; mark%; markrow%; markcol%; "   "
LOCATE , 52
PRINT "origin ="; o%; o1%; o2%; "   "
LOCATE , 52
PRINT "dest =  "; d%; d1%; d2%
IF mov% > 0 THEN mov$ = "pos" ELSE IF mov% < 0 THEN mov$ = "neg" ELSE mov$ = "neutral"
LOCATE , 52
PRINT "moving   "; mov$; "   "
LOCATE , 52
PRINT "o2 - d2 ="; ABS(o1% - d1%); ABS(o2% - d2%); "   "
LOCATE , 52
PRINT "yy%   col"; yy%; xx%; "   "
LOCATE , 52
PRINT "yy% * col"; (yy% - 1) * dwidth + col; "   "
LOCATE , 52
PRINT "cutmrow% "; cutmrow%; cutmcol%; "   "
LOCATE , 52
PRINT "cutdrow% "; cutdrow%; cutdcol%; "   "
LOCATE , 52
PRINT "i j scr  "; i%; j%; scr; "   "
LOCATE , 52
PRINT "j1% k%   "; j1%; k%; "   "
LOCATE , 52
PRINT "row col  "; row; col; "   "
LOCATE , 52
PRINT "h%       "; h%; "   "
LOCATE , 52
PRINT "mhl1%    "; mhl1%; "   "
LOCATE , 52
PRINT "oldmhl1  "; oldmhl1row%; "   "
LOCATE , 52
PRINT "mhl1row% "; mhl1row%; "   "
LOCATE , 52
PRINT "mhl1col% "; mhl1col%; "   "
LOCATE ss%, tt%
RETURN
 
redomarkers:
mark% = mark% - i% * dwidth
markrow% = markrow% - i%
d% = (CSRLIN - margin.t - 1 - i%) * dwidth + POS(0) - margin.l
 
IF mhl1% THEN
    mhl1% = mhl1% - i% * dwidth
    mhl1row% = mhl1row% - i%
    oldmhl1row% = oldmhl1row% - i%
END IF
IF debug% THEN GOSUB debugger
RETURN

Pete

Edit: Added scrolling to highlighting.

Edit: Added middle wheel scroll when SHIFT key is held down and modified algorithm to allow for mixed text row lengths.

FellippeHeitor · « **Reply #1 on:** November 11, 2020, 05:16:56 pm »

Very fluid, Pete!

Pete · « **Reply #2 on:** November 11, 2020, 05:21:18 pm »

CHR$(3)

I would imagine you have made similar routines, but possibly not in SCREEN 0? I sometimes get the urge to try routines like this in graphics mode, but then I sober up, and get back to business as usual.

Pete

FellippeHeitor · « **Reply #3 on:** November 11, 2020, 05:23:16 pm »

I've had a working prototype of a graphical multiline textbox (still hidden in current InForm version, but inaccessible if you don't know where it is). Not having been able to sort a few issues had me forever postponing releasing it.

Pete · « **Reply #4 on:** November 11, 2020, 05:30:49 pm »

Well maybe seeing this little routine will help you to revisit your graphics model. These types of routines seem simple, when we use them in apps like Notepad, buggy as even it is, but coding them is surprisingly challenging. Now if you will excuse me, these three holes in the wall, I punched out yesterday, aren't going to "patch" themselves.

Pete

SMcNeill · « **Reply #5 on:** November 11, 2020, 05:37:25 pm »

One thing to watch for Pete:

WHILE _MOUSEINPUT
my% = _MOUSEY
mx% = _MOUSEX
lb% = _MOUSEBUTTON(1)
WEND

The above may adversely affect run speeds for you. My suggestion:

WHILE _MOUSEINPUT: WEND
my% = _MOUSEY
mx% = _MOUSEX
lb% = _MOUSEBUTTON(1)

Why assign and then reassign those values countless times inside a loop, when you’re only going to exit that loop with the final results??

The way you have it, slower PCs might lag up clearing the mouse input buffer — especially if the mouse moved repeatedly during a SLEEP, INPUT, or _DELAY segment of code.

Pete · « **Reply #6 on:** November 11, 2020, 05:46:05 pm »

Funnily enough, I had it the way you posted, to begin with. I changed it when having one of the mouse calls not function, until I included it within the WHILE loop. I might go back and see if that was resolved, on this initial completed routine. If so, you bet, I'd love to have it back to the : WHILE _MOUSEINPUT: WEND. I'll have a look see in a couple of minutes, and get back to the thread...

Thanks,

Pete

Edit: Aha!, Now it will work with the preferred method. It's a head scratcher what went wrong in a much earlier unfinished version. Thanks Steve!

Dav · « **Reply #7 on:** November 12, 2020, 08:42:42 am »

Nice snippet. I'm saving it. Thanks for posting.

- Dav

Pete · « **Reply #8 on:** November 15, 2020, 12:29:49 am »

Thanks Dav. I edited the original post tonight, to add scrolling while highlighting.

Pete

Richard Frost · « **Reply #9 on:** November 15, 2020, 01:08:53 am »

I've been using the wrong mouse input method too.
Yet the cat didn't get fat (catching the slow mouse).

bplus · « **Reply #10 on:** November 15, 2020, 12:03:48 pm »

Quote from: Pete on November 15, 2020, 12:29:49 am

Thanks Dav. I edited the original post tonight, to add scrolling while highlighting.

Pete

@Pete When you say you added scrolling, do you mean with _MOUSEWHEEL?

If so, did you edit with correct code?

Pete · « **Reply #11 on:** November 15, 2020, 12:24:35 pm »

To clarify what I meant by scrolling, if you hold the left mouse button key down, and start scrolling down, past the last line of text, the screen will scroll, and the highlighting will remain.

Now the scroll wheel was something I added to the scrollbar snippet, but it is not included in this highlighting snippet. I just never highlight with the mouse wheel, but I checked, and I see if the left mouse button is held down while the wheel is used, it does indeed highlight text in other apps. I guess Shift + scroll wheel doesn't, because the mouse cursor is not set in place, as when the mouse button is depressed. So if i added it, it would apparently only be in conjunction with a left mouse button hold. I might consider that, if it doesn't involve any re-writing to accomplish it.

Pete

SMcNeill · « **Reply #12 on:** November 15, 2020, 12:44:15 pm »

Shift + left-down + scroll will usually keep highlighting as you scroll, in most MS programs.

bplus · « **Reply #13 on:** November 15, 2020, 12:56:34 pm »

Quote

To clarify what I meant by scrolling, if you hold the left mouse button key down, and start scrolling down, past the last line of text, the screen will scroll, and the highlighting will remain.

Yes that works well! Wasn't it doing that originally? Oh wait, the whole screen now too, nice! Thanks

Pete · « **Reply #14 on:** November 24, 2020, 01:49:03 am »

Well this cake is done. I added mouse wheel highlighting. Just hold down a shift key and roll! The text row length varies from line to line, which did require some significant changes to the highlighting algorithm, and was necessary for any practical application. Highlighting while scrolling is also possible when the left mouse button is held with the mouse just above or below the first or last text rows. Mouse highlighting remains active even if the mouse is outside the text boundaries.

Pete

News:

Author Topic: Well here's a highlighting routine I've been fiddling with for a couple of days. (Read 4317 times)

Pete

Well here's a highlighting routine I've been fiddling with for a couple of days.

FellippeHeitor

Re: Well here's a highlighting routine I've been fiddling with for a couple of days.

Pete

Re: Well here's a highlighting routine I've been fiddling with for a couple of days.

FellippeHeitor

Re: Well here's a highlighting routine I've been fiddling with for a couple of days.

Pete

Re: Well here's a highlighting routine I've been fiddling with for a couple of days.

SMcNeill

Re: Well here's a highlighting routine I've been fiddling with for a couple of days.

Pete

Re: Well here's a highlighting routine I've been fiddling with for a couple of days.

Dav

Re: Well here's a highlighting routine I've been fiddling with for a couple of days.

Pete

Re: Well here's a highlighting routine I've been fiddling with for a couple of days.

Richard Frost

Re: Well here's a highlighting routine I've been fiddling with for a couple of days.

bplus

Re: Well here's a highlighting routine I've been fiddling with for a couple of days.

Pete

Re: Well here's a highlighting routine I've been fiddling with for a couple of days.

SMcNeill

Re: Well here's a highlighting routine I've been fiddling with for a couple of days.

bplus

Re: Well here's a highlighting routine I've been fiddling with for a couple of days.

Pete

Re: Well here's a highlighting routine I've been fiddling with for a couple of days.