Pendula

[DANILIN]

more  of pendulums: long read text

http://rosettacode.org/wiki/Animate_a_pendulum
rosettacode.org/wiki/Animate_a_pendulum

and me learn another language graphic by this page

[Ashish]

My attempt to recreate this in 3D -

Code: QB64: [Select]

1. 'Pendula in 3D : By Ashish in QB64 using OpenGL
2. 'idea from here - https://www.qb64.org/forum/index.php?topic=3056.msg123288#msg123288
3. _TITLE "Pendula in 3D"
4. SCREEN _NEWIMAGE(800, 600, 32)
5.  
6. TYPE pendulum_type
7.     ang AS SINGLE 'angle
8.     ang_factor AS SINGLE
9.     min_ang AS SINGLE
10.     max_ang AS SINGLE
11.     mass AS SINGLE
12.     clr AS _UNSIGNED LONG 'color of the sphere
13.     rad AS SINGLE 'radius of the sphere
14.     rope_length AS SINGLE 'length of the rope on which the sphere is hanging
15. END TYPE
16.  
17. DECLARE LIBRARY
18.     SUB glutSolidSphere (BYVAL radius AS DOUBLE, BYVAL slices AS LONG, BYVAL stack AS LONG) 'use to draw a sphere
19.     SUB gluLookAt (BYVAL eyeX#, BYVAL eyeY#, BYVAL eyeZ#, BYVAL centerX#, BYVAL centerY#, BYVAL centerZ#, BYVAL upX#, BYVAL upY#, BYVAL upZ#) 'for camera purpose
20. END DECLARE
21.  
22. CONST MAX_PENDULUM = 15
23.  
24. DIM SHARED pendulum(1 TO MAX_PENDULUM) AS pendulum_type, init AS _BYTE
25. DIM SHARED ix, iy, iz
26.  
27. ix = 0: iy = 1.5: iz = 2
28.  
29. FOR i = 1 TO MAX_PENDULUM
30.     pendulum(i).rad = 0.25
31.     pendulum(i).min_ang = _PI(1.25)
32.     pendulum(i).max_ang = _PI(1.75)
33.     pendulum(i).clr = _RGB(RND * 255, RND * 255, RND * 255)
34.     pendulum(i).rope_length = 2
35.     pendulum(i).mass = 3 + i * 0.5
36. NEXT
37.  
38. init = 1
39. DO
40.     FOR i = 1 TO MAX_PENDULUM
41.         pendulum(i).ang_factor = pendulum(i).ang_factor + 0.01 * pendulum(i).mass
42.         pendulum(i).ang = map(SIN(pendulum(i).ang_factor), -1, 1, pendulum(i).min_ang, pendulum(i).max_ang)
43.     NEXT
44.     _LIMIT 60
45. LOOP
46.  
47. SUB _GL ()
48.     STATIC t
49.     t = t + 0.01
50.     IF init = 0 THEN EXIT SUB
51.     _glViewport 0, 0, _WIDTH, _HEIGHT
52.    
53.     ' _glClearColor 0.3,0.3,0.3,1
54.     _glClear _GL_COLOR_BUFFER_BIT OR _GL_DEPTH_BUFFER_BIT
55.    
56.     _glEnable _GL_LIGHTING
57.     _glEnable _GL_LIGHT0
58.     _glEnable _GL_DEPTH_TEST
59.     _glEnable _GL_COLOR_MATERIAL
60.    
61.     DIM v(3) AS SINGLE
62.     v(0) = 0: v(1) = 0: v(2) = 1: v(3) = 0
63.    
64.     _glLightfv _GL_LIGHT0, _GL_POSITION, _OFFSET(v())
65.    
66.     _glMatrixMode _GL_PROJECTION
67.     _glLoadIdentity
68.     _gluPerspective 50, _WIDTH / _HEIGHT, 0.1, 25
69.    
70.     _glMatrixMode _GL_MODELVIEW
71.     _glLoadIdentity
72.    
73.     gluLookAt 0, 2, 5, 0, 0, 0, 0, 1, 0
74.    
75.     drawXZPlane 0, -2, 0, 8, 16, -1
76.    
77.     DIM z
78.     z = iz
79.     _glLineWidth 5.0
80.     FOR i = 1 TO MAX_PENDULUM
81.         _glColor3ub 255, 255, 0
82.         _glBegin _GL_LINES
83.         _glVertex3f ix, iy, z
84.         _glVertex3f ix + pendulum(i).rope_length * COS(pendulum(i).ang), iy + pendulum(i).rope_length * SIN(pendulum(i).ang), z
85.         _glEnd
86.        
87.         _glPushMatrix
88.         _glTranslatef ix + (pendulum(i).rope_length + pendulum(i).rad) * COS(pendulum(i).ang), iy + (pendulum(i).rope_length + pendulum(i).rad) * SIN(pendulum(i).ang), z
89.         _glColor3ub _RED(pendulum(i).clr), _GREEN(pendulum(i).clr), _BLUE(pendulum(i).clr)
90.         glutSolidSphere pendulum(i).rad, 50, 50
91.         _glPopMatrix
92.        
93.         z = z - 2.3 * pendulum(i).rad
94.     NEXT
95.     _glColor3ub 255, 255, 0
96.     _glBegin _GL_LINES
97.     _glVertex3f ix, iy, iz
98.     _glVertex3f ix, iy, z
99.     _glEnd
100.    
101.     _glFlush
102. END SUB
103.  
104. SUB drawXZPlane (x, y, z, w, d, n) '(x,z)->location to draw, w->width, d->depth of the plane, n->normal direction in Y direction
105.     _glBegin _GL_QUADS
106.     _glTexCoord2f 1, 0
107.     _glNormal3f 0, n, 0
108.     _glVertex3f x - (w / 2), y, z - d / 2
109.     _glTexCoord2f 1, 1
110.     _glNormal3f 0, n, 0
111.     _glVertex3f x + (w / 2), y, z - d / 2
112.     _glTexCoord2f 0, 1
113.     _glNormal3f 0, n, 0
114.     _glVertex3f x + (w / 2), y, z + d / 2
115.     _glTexCoord2f 0, 0
116.     _glNormal3f 0, n, 0
117.     _glVertex3f x - (w / 2), y, z + d / 2
118.     _glEnd
119. END SUB
120.  
121. 'from p5js.bas
122. FUNCTION map! (value!, minRange!, maxRange!, newMinRange!, newMaxRange!)
123.     map! = ((value! - minRange!) / (maxRange! - minRange!)) * (newMaxRange! - newMinRange!) + newMinRange!
124. END FUNCTION
125.  
126.  

[FellippeHeitor]

My attempt to recreate this in 3D -

Whoooooooooa!
🤩

[DANILIN]

improvement:

for colorize:
Randomize Timer

thik lines:
_glLineWidth 0.0

or symbol ':
'_glBegin _GL_LINES 

[_vince]

We've all seen the chaotic double pendulum.  I'll leave my simple Runge-Kutta one done with canned formulas from wikipedia at the end.

Challenge:  Generalize it to n-pendulum!  Triple, quadruple, whatever the user wants.  The next ball is to be attached to the previous.  It's going to be a fairly tedious system of differential equations based on the lagrangian of the system (https://en.wikipedia.org/wiki/Double_pendulum#Analysis_and_interpretation).  Probably so tedious you're going to need a large matrix and some linear algebra.  But goddamn I'll be so impressed if you do it, you'll come out of it totally competent to program everything DEs.

Here's the trivial case:

Code: QB64: [Select]

1. defsng a-z
2. pi = 3.141593
3. r = 100
4. a1 = -pi/2
5. a2 = -pi/2
6. h=0.001
7. m=1000
8. g=1000
9. sw = 640
10. sh = 480
11.  
12. dim p1 as long
13. p1 = _newimage(sw,sh,12)
14. screen _newimage(sw,sh,12)
15.  
16. do
17.         a1p = (6/(m*r^2))*(2*m*v1-3*cos(a1-a2)*m*v2)/(16-9*(cos(a1-a2))^2)
18.         a1k1 = a1p
19.         a1k2 = a1p + h*a1k1/2
20.         a1k3 = a1p + h*a1k2/2
21.         a1k4 = a1p + h*a1k3
22.         a2p = (6/(m*r^2))*(8*m*v2-3*cos(a1-a2)*m*v1)/(16-9*(cos(a1-a2))^2)
23.         a2k1 = a2p
24.         a2k2 = a2p + h*a2k1/2
25.         a2k3 = a2p + h*a2k2/2
26.         a2k4 = a2p + h*a2k3
27.         na1=a1+h*(a1k1+2*a1k2+2*a1k3+a1k4)/6
28.         na2=a2+h*(a2k1+2*a2k2+2*a2k3+a2k4)/6
29.         v1p = -0.5*r^2*(a1p*a2p*sin(a1-a2)+3*g*sin(a1)/r)
30.         v1k1 = v1p
31.         v1k2 = v1p + h*v1k1/2
32.         v1k3 = v1p + h*v1k2/2
33.         v1k4 = v1p + h*v1k3
34.         v2p = -0.5*r^2*(-a1p*a2p*sin(a1-a2)+g*sin(a2)/r)
35.         v2k1 = v2p
36.         v2k2 = v2p + h*v2k1/2
37.         v2k3 = v2p + h*v2k2/2
38.         v2k4 = v2p + h*v2k3
39.         nv1=v1+h*(v1k1+2*v1k2+2*v1k3+v1k4)/6
40.         nv2=v2+h*(v2k1+2*v2k2+2*v2k3+v2k4)/6
41.         a1=na1
42.         a2=na2
43.         v1=nv1
44.         v2=nv2
45.  
46.         _dest p1
47.         pset (sw/2+r*cos(a1-pi/2)+r*cos(a2-pi/2), sh/2-r*sin(a1-pi/2)-r*sin(a2-pi/2)),12
48.         _dest 0
49.         _putimage, p1
50.  
51.         line (sw/2, sh/2)-step(r*cos(a1-pi/2), -r*sin(a1-pi/2))
52.         circle step(0,0),5
53.         line -step(r*cos(a2-pi/2), -r*sin(a2-pi/2))
54.         circle step(0,0),5
55.  
56.         _limit 200
57.         _display
58. loop until _keyhit=27
59. system
60.  

[STxAxTIC]

That's an interesting challenge. Bonus points if all pendula are constrained to never self-intersect, so that the resulting object should be like a hanging chain and exhibit the same physics. I wonder if this is even *that* terrible to do, becau - ya know what? I'll shut up.... Nice challenge!