Problem whith PCOPY

[Juanjogomez]

Hi.
I have a problem copying the above screen using PCOPY.
I have always worked with Screen 0 and the PCOPY command has been used regularly to copy the current screen with the data, paint a second screen over it to introduce other data, and then restore the previous screen with another PCOPY; but when I have tried it defining a new screen and loading an image, trying to restore the previous screen with PCOPY does not. It comes out in black.
What am I doing wrong?
Thank you

This is then program:

Code: QB64: [Select]

1. CLS
2. LOCATE 10, 10: PRINT "This is the first screen"
3. LOCATE 12, 20: PRINT "Press a key to load image"
4.  
5. x$ = INPUT$(1)
6.  
7. PCOPY 0, 1
8.  
9. SCREEN _NEWIMAGE(2100, 1900, 32)
10. WIDTH 150, 40
11.  
12. i& = _LOADIMAGE("image.jpg", 32)
13. _PUTIMAGE , i&
14. _DEST i&
15. SCREEN i&
16. PageScale = 10
17. PageHeight = 190 * PageScale
18. PageWidth = 210 * PageScale
19.  
20. PointSize = 10
21. FontHeight10 = INT(PointSize * 0.3527 * PageScale)
22. Fuente10 = _LOADFONT("c:\windows\fonts\times.ttf", FontHeight10)
23.  
24. LOCATE 14, 20: PRINT "press a key to go to the previous screen"
25.  
26. x$ = INPUT$(1)
27.  
28. _DEST 0
29. _FONT 16
30. SCREEN 0
31. _FREEIMAGE i&
32. _FREEFONT Fuente10
33.  
34. PCOPY 1, 0
35.  
36. LOCATE 20, 10: PRINT "press a key to end": x$ = INPUT$(1)

[SMcNeill]

You’re making a copy of a SCREEN 0 screen, and then tossing that text screen out and swapping over to a graphic screen with: SCREEN _NEWIMAGE(2100, 1900, 32)

[Pete]

Can't go between text and graphics screens with PCOPY, but you could make a hack...

Code: QB64: [Select]

1. CLS
2. LOCATE 10, 10: PRINT "This is the first screen"
3. LOCATE 12, 20: PRINT "Press a key to load image"
4.  
5. x$ = INPUT$(1)
6.  
7. FOR i = 1 TO _HEIGHT
8.     FOR j = 1 TO _WIDTH
9.         pcopy_string$ = pcopy_string$ + CHR$(SCREEN(i, j))
10. NEXT j, i
11.  
12. SCREEN _NEWIMAGE(2100, 1900, 32)
13. WIDTH 150, 40
14.  
15. i& = _LOADIMAGE("image.jpg", 32)
16. _PUTIMAGE , i&
17. _DEST i&
18. SCREEN i&
19. PageScale = 10
20. PageHeight = 190 * PageScale
21. PageWidth = 210 * PageScale
22.  
23. PointSize = 10
24. FontHeight10 = INT(PointSize * 0.3527 * PageScale)
25. Fuente10 = _LOADFONT("c:\windows\fonts\times.ttf", FontHeight10)
26.  
27. LOCATE 14, 20: PRINT "press a key to go to the previous screen"
28.  
29. x$ = INPUT$(1)
30.  
31. _DEST 0
32. _FONT 16
33. SCREEN 0
34. LOCATE 1, 1
35. PRINT pcopy_string$;
36. _FREEIMAGE i&
37. _FREEFONT Fuente10
38.  
39. LOCATE 20, 10: PRINT "press a key to end": x$ = INPUT$(1)
40.  

[Juanjogomez]

Thank you.
Although I do not understand if I make a copy of screen 0, load a new screen and then return to screen 0, why is the previous screen not copied with PCOPY, if it was saved in memory.

[Juanjogomez]

Pete's option is very good, but there are different colors of text on the screen and it would have to be rewritten entirely

[SMcNeill]

Use _COPYIMAGE to make a backup copy.

The problem with PCOPY is that there’s no set PFREE command.  QB64 allows us to make a limitless number of screen pages, but how would you ever free those pages from memory??

You can’t, manually, so QB64 does it automatically for you, if you switch SCREENs.  PCOPY is just for quick, temporary coping of one screen, while you’re staying in that screen.  Insert another SCREEN statement, and that temporary data cache is freed, reducing resource requirements.

What you want is to use _COPYIMAGE to make a backup of your screen, which you can restore later.  Only important thing to note here:  you need to manually _FREEIMAGE when finished with the copy.  QB64 won’t clean it up automatically for you.

[Pete]

_COPYIMAGE??? No dammit, do it the hard way!!!

Code: QB64: [Select]

1. _CONTROLCHR OFF
2. LOCATE 7, 10
3. FOR i = 1 TO 9
4.     COLOR i, 9 - i
5.     PRINT i;
6. NEXT
7. COLOR 7, 0
8.  
9. FOR i = 1 TO _HEIGHT
10.     FOR j = 1 TO _WIDTH
11.         pcopy_string$ = pcopy_string$ + CHR$(SCREEN(i, j))
12.         pcopy_color$ = pcopy_color$ + CHR$(SCREEN(i, j, 1))
13. NEXT j, i
14.  
15. x$ = INPUT$(1)
16.  
17. SCREEN _NEWIMAGE(2100, 1900, 32)
18.  
19. x$ = INPUT$(1)
20.  
21. SCREEN 0
22.  
23. FOR i = 1 TO _HEIGHT
24.     FOR j = 1 TO _WIDTH
25.         x = ASC(MID$(pcopy_color$, _WIDTH * (i - 1) + j, 1))
26.         COLOR x MOD 16, x \ 16
27.         PRINT MID$(pcopy_string$, _WIDTH * (i - 1) + j, 1);
28. NEXT j, i
29.  

Pete

[Pete]

Oh, and so Steve doesn't have a barf-a-thon over the repetitive COLOR call, do this...

Code: QB64: [Select]

1. _CONTROLCHR OFF
2. oldx = -1
3. LOCATE 7, 10
4. FOR i = 1 TO 9
5.     COLOR i, 9 - i
6.     PRINT i;
7. NEXT
8. COLOR 7, 0
9.  
10. FOR i = 1 TO _HEIGHT
11.     FOR j = 1 TO _WIDTH
12.         pcopy_string$ = pcopy_string$ + CHR$(SCREEN(i, j))
13.         pcopy_color$ = pcopy_color$ + CHR$(SCREEN(i, j, 1))
14. NEXT j, i
15.  
16. x$ = INPUT$(1)
17.  
18. SCREEN _NEWIMAGE(2100, 1900, 32)
19.  
20. x$ = INPUT$(1)
21.  
22. SCREEN 0
23.  
24. FOR i = 1 TO _HEIGHT
25.     FOR j = 1 TO _WIDTH
26.         x = ASC(MID$(pcopy_color$, _WIDTH * (i - 1) + j, 1))
27.         IF x <> oldx THEN
28.             COLOR x MOD 16, x \ 16
29.             oldx = x
30.         END IF
31.         PRINT MID$(pcopy_string$, _WIDTH * (i - 1) + j, 1);
32. NEXT j, i
33.  

Now if you will excuse me, that deer isn't going to tear itself apart with my bare hands...

Pete

[SMcNeill]

Even simpler:

_CONTROLCHR OFF
oldx = -1
LOCATE 7, 10
FOR i = 1 TO 9
    COLOR i, 9 - i
    PRINT i;
NEXT
COLOR 7, 0
 
BackUp =  _COPYIMAGE(0)
 
x$ = INPUT$(1)
 
SCREEN _NEWIMAGE(2100, 1900, 32)
 
x$ = INPUT$(1)
 
SCREEN BackUp
 

[Pete]

When will we be getting that _justdowhatiwant keyword? Even better...

DO until _igetwhatiwant
LOOP

How's that for simple? Well, I'm torn. I miss the good ol' days of having to figure this stuff out, but I appreciate the new tools in the box, too. Somewhere on my old backups, I have a 1990's something color screen saver routine. QBasic had no _CONTROLCHR OFF, so I think I just added past the control characters and subtracted that amount when calculating the colors. +31 and -31, maybe +8 and -8, or maybe I just swapped out chr$(7) with 255, using a select case. The only downside was loss of some possible highlighted color combos, but really only important if PALLET was being used. I sure wish the QBasic developers would have made _CONTROLCHR OFF back in the day.

I haven't used _COPYIMAGE in QB64, but yes, if I was making a graphics to text screen app, I would... STILL DO IT THE HARD WAY! Brooohahaha!!!!

Pete

[Juanjogomez]

Thank you. It has been very helpful

[Cobalt]

Can't go between text and graphics screens with PCOPY, but you could make a hack...

Thats right you old hack... :P

_COPYIMAGE??? No dammit, do it the hard way!!!

Pete

whats so hard about PCOPY?
Antiquated maybe, but 'hard'. Nay says I.

[Pete]

Lay off the weed and learn to read!

Pete :D

[Cobalt]

Lay off the weed and learn to read!

Pete :D

Really.... REALLY?
Is that it? Oh come on where is the snappy witticism I have come to expect from you Pete?
The fun, the pun, the wit! What happened? Dont tell me you have gotten too old?!

Seriously,
Being Screen 0  you could use DEFSEG, and PEEK to save both the character data and color data to a string. But not sure how to get the colors from screen 0 to translate back in a 32 bit screen mode. Save the brute force method of predefining them ie:

Code: QB64: [Select]

1. CONST WHITE = _RGB32(255,255,255)
2. IF C% = 15 THEN COLOR WHITE

and doing that for each color. But then you get the blinking colors. Besides some trickery how would you copy those to a 32bit screen?

Ah screw it.. come on lets just stick with SCREEN 0! Who needs more?

[bplus]

Who needs more?

I do! :) and any one who likes color graphics.

Hey just look at our avatar choices! ;-))