Maybe SpriggsySpriggs would know how to get Win API Recycle Bin in a QB64 prog?

[Pete]

I wrote a routine years ago that archives older files with the same name. It simple makes an "archives" folder in the local directory, and takes the file to be archived, adds a date and time recycled stamp to the name, and then moves it into the archive folder. What would be better is a way to get QB64 to call the Windows API to somehow get a named file placed into the recycle bin, without doing so manually. Anyone ever accomplish this and care to share?

Pete

[Dav]

I posted one on the old forum. I'll see if I can dig it up. I have it on a CD somewhere.

- Dav

[Pete]

Thanks for having a look, Dav. Funny, I was just mentioning to Bob, at QBF, the number of times members have asked questions here, only to find there was a program or code posted and lost at .net, which would have addressed the post.

Pete

[SpriggsySpriggs]

That sounds quite a bit like what I did for my job. I had files that were dated and if my program detected that those files matched the date of today and were found when the program ran, it moved them to a folder called "EDI Archive". It didn't use any API, just simply SHELL with the command prompt commands to move files. I'll look into this, though

[SpriggsySpriggs]

@Pete This is probably the API that would be used:
https://docs.microsoft.com/en-us/windows/win32/api/shellapi/nf-shellapi-shfileoperationa

[SpriggsySpriggs]

@Pete Here is working code that sends a file to the recycle bin using the API I mentioned above! Cheers! You can use either the full path of the file or you can trash an entire directory. I put the flag for FOF_WANTNUKEWARNING which means that if it will delete the file permanently rather than trash it then it will give a confirmation dialog. The confirmation dialog does work which is quite nice.

Updated 10:52 PM I also added the other functions of SHFileOperationA since they also use confirmation dialogs when something is going to be overwritten or deleted permanently.

Code: QB64: [Select]

1. $CONSOLE:ONLY
2. _DEST _CONSOLE
3.  
4. 'To - From, From - To Flags
5. CONST FO_MOVE = &H1
6. CONST FO_COPY = &H2
7. CONST FO_DELETE = &H3
8. CONST FO_RENAME = &H4
9.  
10. 'File Op Flags
11. CONST FOF_MULTIDESTFILES = &H1
12. CONST FOF_CONFIRMMOUSE = &H2
13. CONST FOF_SILENT = &H4
14. CONST FOF_RENAMEONCOLLISION = &H8
15. CONST FOF_NOCONFIRMATION = &H10
16. CONST FOF_WANTMAPPINGHANDLE = &H20
17. CONST FOF_ALLOWUNDO = &H40
18. CONST FOF_FILESONLY = &H80
19. CONST FOF_SIMPLEPROGRESS = &H100
20. CONST FOF_NOCONFIRMMKDIR = &H200
21. CONST FOF_NOERRORUI = &H400
22. CONST FOF_NOCOPYSECURITYATTRIBS = &H800
23. CONST FOF_NORECURSION = &H1000
24. CONST FOF_NO_CONNECTED_ELEMENTS = &H2000
25. CONST FOF_WANTNUKEWARNING = &H4000
26. CONST FOF_NORECURSEREPARSE = &H8000
27. CONST FOF_NO_UI = FOF_SILENT
28.  
29. 'Return Values
30. CONST DE_SAMEFILE = &H71
31. CONST DE_MANYSRC1DEST = &H72
32. CONST DE_DIFFDIR = &H73
33. CONST DE_ROOTDIR = &H74
34. CONST DE_OPCANCELLED = &H75
35. CONST DE_DESTSUBTREE = &H76
36. CONST DE_ACCESSDENIEDSRC = &H78
37. CONST DE_PATHTOODEEP = &H79
38. CONST DE_MANYDEST = &H7A
39. CONST DE_INVALIDFILES = &H7C
40. CONST DE_DESTSAMETREE = &H7D
41. CONST DE_FLDDESTISFILE = &H7E
42. CONST DE_FILEDESTISFLD = &H80
43. CONST DE_FILENAMETOOLONG = &H81
44. CONST DE_DEST_IS_CDROM = &H82
45. CONST DE_DEST_IS_DVD = &H83
46. CONST DE_DEST_IS_CDRECORD = &H84
47. CONST DE_FILE_TOO_LARGE = &H85
48. CONST DE_SRC_IS_CDROM = &H86
49. CONST DE_SRC_IS_DVD = &H87
50. CONST DE_SRC_IS_CDRECORD = &H88
51. CONST DE_ERROR_MAX = &HB7
52. CONST UNKNOWN = &H402
53. CONST ERRORONDEST = &H10000
54. CONST DE_ROOTDIR_ERRORONDEST = &H10074
55.  
56. TYPE SHFILEOPSTRUCTA
57.     hwnd AS _OFFSET
58.     $IF 64BIT THEN
59.         wfunc AS _UNSIGNED _INTEGER64 'To - From, From - To Flags
60.     $ELSE
61.         wfunc AS _UNSIGNED LONG
62.     $END IF
63.     pFrom AS _OFFSET
64.     pTo AS _OFFSET
65.     fFlags AS LONG
66.     fAnyOperationsAborted AS _BYTE
67.     hNameMappings AS _OFFSET
68.     lpszProgressTitle AS _OFFSET
69. END TYPE
70.  
71. DECLARE DYNAMIC LIBRARY "Shell32"
72.     FUNCTION FileOperation% ALIAS SHFileOperationA (lpFileOp AS SHFILEOPSTRUCTA)
73. END DECLARE
74.  
75. 'Test code
76. IF _FILEEXISTS(_DIR$("desktop") + "this is a test.txt") = 0 THEN
77.     OPEN _DIR$("desktop") + "this is a test.txt" FOR OUTPUT AS #1
78.     CLOSE #1
79. END IF
80. PRINT Copy(_DIR$("desktop") + "this is a test.txt", _DIR$("desktop") + "this is a test as well.txt")
81. _DELAY 2
82. PRINT Rename(_DIR$("desktop") + "this is a test as well.txt", _DIR$("desktop") + "this is a test also.txt")
83. _DELAY 2
84. PRINT Recycle(_DIR$("desktop") + "this is a test also.txt")
85. SLEEP
86.  
87. FUNCTION Recycle% (file AS STRING)
88.     DIM lpFileOp AS SHFILEOPSTRUCTA
89.     DIM doublenull AS STRING
90.     doublenull = CHR$(0) + CHR$(0)
91.     file = file + doublenull
92.     lpFileOp.hwnd = _WINDOWHANDLE
93.     lpFileOp.wfunc = FO_DELETE
94.     lpFileOp.pFrom = _OFFSET(file)
95.     lpFileOp.fFlags = FOF_ALLOWUNDO + FOF_WANTNUKEWARNING
96.     Recycle = FileOperation(lpFileOp)
97. END FUNCTION
98.  
99. FUNCTION Copy% (file AS STRING, dest AS STRING)
100.     DIM lpFileOp AS SHFILEOPSTRUCTA
101.     DIM doublenull AS STRING
102.     doublenull = CHR$(0) + CHR$(0)
103.     file = file + doublenull
104.     dest = dest + doublenull
105.     lpFileOp.hwnd = _WINDOWHANDLE
106.     lpFileOp.wfunc = FO_COPY
107.     lpFileOp.pFrom = _OFFSET(file)
108.     lpFileOp.pTo = _OFFSET(dest)
109.     lpFileOp.fFlags = FOF_ALLOWUNDO
110.     Copy = FileOperation(lpFileOp)
111. END FUNCTION
112.  
113. FUNCTION Move% (file AS STRING, dest AS STRING)
114.     DIM lpFileOp AS SHFILEOPSTRUCTA
115.     DIM doublenull AS STRING
116.     doublenull = CHR$(0) + CHR$(0)
117.     file = file + doublenull
118.     dest = dest + doublenull
119.     lpFileOp.hwnd = _WINDOWHANDLE
120.     lpFileOp.wfunc = FO_MOVE
121.     lpFileOp.pFrom = _OFFSET(file)
122.     lpFileOp.pTo = _OFFSET(dest)
123.     lpFileOp.fFlags = FOF_ALLOWUNDO
124.     Move = FileOperation(lpFileOp)
125. END FUNCTION
126.  
127. FUNCTION Rename% (file AS STRING, newname AS STRING)
128.     DIM lpFileOp AS SHFILEOPSTRUCTA
129.     DIM doublenull AS STRING
130.     doublenull = CHR$(0) + CHR$(0)
131.     file = file + doublenull
132.     newname = newname + doublenull
133.     lpFileOp.hwnd = _WINDOWHANDLE
134.     lpFileOp.wfunc = FO_RENAME
135.     lpFileOp.pFrom = _OFFSET(file)
136.     lpFileOp.pTo = _OFFSET(newname)
137.     lpFileOp.fFlags = FOF_ALLOWUNDO
138.     Rename = FileOperation(lpFileOp)
139. END FUNCTION

[SpriggsySpriggs]

@Pete , Here is my latest source which allows for Rename, Copy, Move, Recycle and even Empty Recycle bin all using WinAPI (Edit 1:31 AM 09/23/2020 It now also has the ability to show how many bytes the recycle bin is currently occupying on disk and how many files are contained. It's also inside my API Collection zip but I've attached it here for you. I hope this is what you are looking for.

[Pete]

Nice! I had a look, and I'll give the recycle bin a try, tomorrow. I simply need to edit out the empty recycle bin part, as I want to retain the contents in the bin. I also need to download some of Clippy's files, so I have somethings to trash!

I'm glad this appears to be a nice addition to your collection of Win api functions, as it looks like it was a fair amount of work to do for a request. I certainly appreciate it!

Pete

[SpriggsySpriggs]

This was actually my first WinAPI addition to my collection! All the others were online REST and HTTP APIs. I had always had very little luck with WinAPI (in this capacity) and had stayed far away but you really got me a good one to work on so that's great! Got me to branch out a bit!

[Pete]

They can be a pain. I think Dav inspierd me to make two or three, but the only one I can recall I posted here: https://www.qb64.org/forum/index.php?topic=1365.msg105588#msg105588

I miss the days when I could remember my entire genetic sequence. Now, on a good day, I'm lucky if I can remember my name.

John

[bplus]

@Pete , Here is my latest source which allows for Rename, Copy, Move, Recycle and even Empty Recycle bin all using WinAPI (Edit 1:31 AM 09/23/2020 It now also has the ability to show how many bytes the recycle bin is currently occupying on disk and how many files are contained. It's also inside my API Collection zip but I've attached it here for you. I hope this is what you are looking for.

I am curious have you tested these with .ogg files?

[SpriggsySpriggs]

I am curious have you tested these with .ogg files?

@bplus I have a couple ogg files handy. How do you want me to test them?
I tested Copy, Rename, Move, Recycle, and Empty Recycle Bin on them with no issues whatsoever. Handled them like anything else.

Code: QB64: [Select]

1. PRINT Copy(_DIR$("desktop") + "distant.ogg", _DIR$("desktop") + "distant2.ogg")
2. _DELAY 2
3. PRINT Rename(_DIR$("desktop") + "distant2.ogg", _DIR$("desktop") + "distant3.ogg")
4. _DELAY 2
5. PRINT Recycle(_DIR$("desktop") + "distant3.ogg")
6. _DELAY 2
7. PRINT GetRecycleInfo
8. _DELAY 2
9. PRINT Move(_DIR$("desktop") + "distant.ogg", _DIR$("desktop") + "QB64 x64\distant.ogg")
10. _DELAY 2
11. PRINT EmptyBin

[Dav]

@SpriggsySpriggs, looks like a good job there. I've found Win APIs to often be a challenge getting them to work in QB64, but a fun challenge.

@Pete, I've looked through a bunch of my cd's  haven't found my version yet. I think it was called SOFTKILL.BAS (wish it was in my recycle bin) but Spriggsy versions looks like a better one than I remember mine being.

- Dav

[bplus]

@bplus I have a couple ogg files handy. How do you want me to test them?
I tested Copy, Rename, Move, Recycle, and Empty Recycle Bin on them with no issues whatsoever. Handled them like anything else.

Code: QB64: [Select]

1. PRINT Copy(_DIR$("desktop") + "distant.ogg", _DIR$("desktop") + "distant2.ogg")
2. _DELAY 2
3. PRINT Rename(_DIR$("desktop") + "distant2.ogg", _DIR$("desktop") + "distant3.ogg")
4. _DELAY 2
5. PRINT Recycle(_DIR$("desktop") + "distant3.ogg")
6. _DELAY 2
7. PRINT GetRecycleInfo
8. _DELAY 2
9. PRINT Move(_DIR$("desktop") + "distant.ogg", _DIR$("desktop") + "QB64 x64\distant.ogg")
10. _DELAY 2
11. PRINT EmptyBin

I know copying them is no problem but removing them can be or removing a folder that contains them might be the test. Yes removing a folder loaded up with them is the best test.

Now if you are up to date with .ogg files then you have the special extension patch so they may work in File Explorer, and testing would be mute point. But I am curious if File Explorer is using API calls (which is where I'd place my bet) or working under it's own code power.

[SpriggsySpriggs]

I know copying them is no problem but removing them can be or removing a folder that contains them might be the test. Yes removing a folder loaded up with them is the best test.
Now if you are up to date with .ogg files then you have the special extension patch so they may work in File Explorer, and testing would be mute point. But I am curious if File Explorer is using API calls (which is where I'd place my bet) or working under it's own code power.

@bplus Ok I'll test it next with a folder containing .ogg files to see how it does. The confirmation dialogs that appear (if any) are the same ones you see when doing file operations in File Explorer so I reckon this is just invoking the same methods that are used in deleting, copying, etc in File Explorer. My computer is running Windows 10 64 Bit build 2004.