Sequence

[carloscordeiro]

Good evening everyone
Come again on this forum, ask for help on this program to show sequence starting with 3 until 09 dozens.
I spent two nights trying to get him to show and count how many times a sequence of 03 dozens or more came out. I did it shows, but I'm having a hard time getting him to count the strings.
Follow code for anyone who can help me.
Sequencia_11 is exactly what I want, but I'm having trouble making him count each sequence.
Sequencia_01 counts the sequences, but does not show all sequences on the screen.
Thank you very much, for all the attention I've had at other times.

Carlos,

[bplus]

Hi @carloscordeiro

Are you just trying to add up the numbers in a record or data line in that txt file?

[carloscordeiro]

Thank you Bplus for responding.

I'm not just trying to add up the numbers of a record or data line in that txt file. I am trying to know in each line or record, how many 3 tens sequences there are in each line or record
Example: line "01 04 06 07 08 09 10 11 12 14 16 17 22 23 24" in this line there is a sequence of 07 tens and another of 3 tens or more. I want to do this for all lines in the.txt file.

I managed to do it with prime numbers using the same file.txt. Unfortunately I am having difficulty with the same sequence of numbers.
I'll send the prime number for you to get an idea.

[bplus]

Yes, I figured out that you were looking for runs:

Here is the best one:
 

Dang you want all of the runs > 2 from each line, I just counted the best in each line.
Back to drawing board :)

[carloscordeiro]

This, I want to show the sequences on the screen, regardless of the tens and together shows how many came out. As in prime numbers.
My difficulty is to show the sequence and count them at the same time

[bplus]

Hi @carloscordeiro

Do you have a method to your coloring madness? How about a color for each sequence length so it's color coded?

[bplus]

News flash the highest sequence is 14!
 

[bplus]

OK here we go!

This is a two part program. The first has to be run only once to Analyze the Seque.txt data file. It writes a Seque Analysis.txt file that has all the data you need ready to display.

Code: QB64: [Select]

1. OPEN "Seque.txt" FOR INPUT AS #1
2. OPEN "seque analysis.txt" FOR OUTPUT AS #2 'counts seq and start position
3. DIM sq(1 TO 15) AS INTEGER
4. WHILE NOT EOF(1)
5.     seq = 1: starts = 1: saveseq = 0: lineNum = lineNum + 1: lc$ = SPACE$(15)
6.     LINE INPUT #1, fl$
7.     FOR i = 1 TO 15
8.         n = VAL(MID$(fl$, i * 3 - 2, 3))
9.         PRINT n;
10.         IF i > 1 THEN
11.             IF n = lastn + 1 THEN 'start ofr cont seq
12.                 seq = seq + 1
13.             ELSE 'seq ended if it even started
14.                 sq(seq) = sq(seq) + 1
15.                 MID$(lc$, starts, seq) = STRING$(seq, HEX$(seq))
16.                 seq = 1
17.                 starts = i
18.             END IF
19.         END IF
20.         lastn = n
21.     NEXT
22.     sq(seq) = sq(seq) + 1
23.     MID$(lc$, starts, seq) = STRING$(seq, HEX$(seq))
24.     PRINT lc$
25.     b$ = ""
26.     FOR i = 1 TO 15
27.         b$ = b$ + STR$(sq(i))
28.     NEXT
29.     PRINT #2, fl$ + " " + lc$ + b$
30.     'PRINT "asleep"
31.     'SLEEP
32. WEND
33. 'PRINT #2, "Highest sequence is " + _TRIM$(STR$(highseq)) + " on line #" + _TRIM$(STR$(saveLineNum))
34. CLOSE
35. PRINT "File: seque analysis.txt is ready!"
36.  
37. 'hint
38. 'FOR i = 0 TO 15
39. '    PRINT HEX$(i), VAL("&H" + HEX$(i))
40. 'NEXT
41.  
42.  

I count 35 lines :)



Now this next file is for the big Color Coded show, it has a color for ever sequence number for 1 to 15 just like screen 12! But we need more room to list the sequence count status every line makes to the cumulative total.

Anyway here is code for the Show:

Code: QB64: [Select]

1. _TITLE "sequence show" ' b+ 2020=09-07
2. DIM d(1 TO 2029) AS STRING
3. SCREEN _NEWIMAGE(1200, 720, 12)
4. _DELAY .25
5. _SCREENMOVE _MIDDLE
6. OPEN "seque analysis.txt" FOR INPUT AS #1
7. FOR i = 1 TO 2029
8.     LINE INPUT #1, d(i)
9. NEXT
10. CLOSE #1
11. 'PRINT d(2029)  ' good
12. page = 0
13. nextPage:
14. CLS
15. FOR p = 1 TO 40
16.     IF page + p < 2030 THEN
17.         n$ = _TRIM$(STR$(page + p))
18.         blank$ = SPACE$(6)
19.         MID$(blank$, 2, LEN(n$)) = n$
20.         COLOR 15
21.         PRINT blank$;
22.         fl$ = MID$(d(page + p), 1, 45)
23.         cs$ = MID$(d(page + p), 46, 15)
24.         sc$ = MID$(d(page + p), 62)
25.         FOR i = 1 TO 15
26.             COLOR VAL("&H" + MID$(cs$, i, 1))
27.             PRINT MID$(fl$, i * 3 - 2, 3);
28.         NEXT
29.         REDIM dat$(0)
30.         Split sc$, " ", dat$()
31.         PRINT SPACE$(3);
32.         FOR i = LBOUND(dat$) TO UBOUND(dat$)
33.             COLOR i + 1
34.             blank$ = SPACE$(6)
35.             MID$(blank$, 1, LEN(dat$(i))) = dat$(i)
36.             PRINT blank$;
37.         NEXT
38.         PRINT
39.     ELSE
40.         COLOR 15
41.         PRINT SPACE$(64) + "*** End of Data ***"
42.         EXIT FOR
43.     END IF
44. NEXT
45. PRINT
46. PRINT SPACE$(55) + "press u for page Up, d for page Down "
47. _DISPLAY
48. getpage:
49. pageDir$ = ""
50. WHILE UCASE$(pageDir$) <> "U" AND UCASE$(pageDir$) <> "D"
51.     pageDir$ = INKEY$
52.     _LIMIT 60
53. WEND
54. IF UCASE$(pageDir$) = "U" THEN
55.     IF page - 40 >= 0 THEN page = page - 40 ELSE BEEP
56. ELSEIF UCASE$(pageDir$) = "D" THEN
57.     IF page + 40 <= 2040 THEN page = page + 40 ELSE BEEP
58. ELSE
59.     IF pageDir$ <> "" THEN BEEP
60.     GOTO getpage
61. END IF
62. GOTO nextPage
63.  
64. SUB Split (SplitMeString AS STRING, delim AS STRING, loadMeArray() AS STRING)
65.     DIM curpos AS LONG, arrpos AS LONG, LD AS LONG, dpos AS LONG 'fix use the Lbound the array already has
66.     curpos = 1: arrpos = LBOUND(loadMeArray): LD = LEN(delim)
67.     dpos = INSTR(curpos, SplitMeString, delim)
68.     DO UNTIL dpos = 0
69.         loadMeArray(arrpos) = MID$(SplitMeString, curpos, dpos - curpos)
70.         arrpos = arrpos + 1
71.         IF arrpos > UBOUND(loadMeArray) THEN REDIM _PRESERVE loadMeArray(LBOUND(loadMeArray) TO UBOUND(loadMeArray) + 1000) AS STRING
72.         curpos = dpos + LD
73.         dpos = INSTR(curpos, SplitMeString, delim)
74.     LOOP
75.     loadMeArray(arrpos) = MID$(SplitMeString, curpos)
76.     REDIM _PRESERVE loadMeArray(LBOUND(loadMeArray) TO arrpos) AS STRING 'get the ubound correct
77. END SUB
78.  
79. 'hint
80. 'FOR i = 0 TO 15
81. '    PRINT HEX$(i), VAL("&H" + HEX$(i))
82. 'NEXT
83.  
84.  

That program ran a little longer as I had to bring in the big gun, Split SUB ;-))

And here is what the final page on the Big Screen looks like:
 

[carloscordeiro]

Hi Bplus
You understood what I want, it was perfect.  Now I wanted to change the appearance of the screen a little
As it is an advanced schedule, I am not familiar. I can only create simple programs.
I want to change the list of times a sequence goes out to an accountant.
Leave only the file numbers with the colors running on the screen.

(((((((Hello @carloscordeiro.

Do you have a method for your crazy coloring? How about a color for each string length so that it is color-coded?)))))))

I hadn't thought about this hypothesis, I was putting the colors at random.

I really liked the size of the screen, it got a lot of space, but a learning experience.

I'll try to draw the screen here and send it to you if there is a possibility to put a counter.

[bplus]

Hi Bplus
You understood what I want, it was perfect.  Now I wanted to change the appearance of the screen a little
As it is an advanced schedule, I am not familiar. I can only create simple programs.
I want to change the list of times a sequence goes out to an accountant.
Leave only the file numbers with the colors running on the screen.

(((((((Hello @carloscordeiro.

Do you have a method for your crazy coloring? How about a color for each string length so that it is color-coded?)))))))

I hadn't thought about this hypothesis, I was putting the colors at random.

I really liked the size of the screen, it got a lot of space, but a learning experience.

I'll try to draw the screen here and send it to you if there is a possibility to put a counter.

Hey @carloscordeiro

Have you figured out what the numbers on the right side are. They are cumulative totals of ALL sequence lengths including 1, 2, 3, .... all color coded to the QB color = length.

We could also do totals for each line. Then maybe do a cumulative total by a page number at the bottom of page?

[carloscordeiro]

It would be like the attached image that I want to show.
I only drew 3 lines, but it would be for all lines

[carloscordeiro]

I also wanted a standard color for the numbers that are not in the sequence, I mean, outside the sequences.

[carloscordeiro]

Image counter correction

[bplus]

Looks like you have it your way!

Here is what I did:

Code: QB64: [Select]

1. _TITLE "sequence show mod #2" ' b+ 2020=09-07
2. DIM d(1 TO 2029) AS STRING
3. SCREEN _NEWIMAGE(700, 740, 12)
4. _DELAY .25
5. _SCREENMOVE 200, 0
6. OPEN "seque analysis.txt" FOR INPUT AS #1
7. FOR i = 1 TO 2029
8.     LINE INPUT #1, d(i)
9. NEXT
10. CLOSE #1
11. 'PRINT d(2029)  ' good
12. page = 0
13. nextPage:
14. CLS
15. FOR p = 1 TO 40
16.     IF page + p < 2030 THEN
17.         n$ = _TRIM$(STR$(page + p))
18.         blank$ = SPACE$(6)
19.         MID$(blank$, 2, LEN(n$)) = n$
20.         COLOR 15
21.         PRINT blank$;
22.         fl$ = MID$(d(page + p), 1, 45)
23.         cs$ = MID$(d(page + p), 46, 15)
24.         sc$ = MID$(d(page + p), 62)
25.         IF page = 0 AND p = 1 THEN
26.             sc2$ = ""
27.         ELSE
28.             sc2$ = MID$(d(page + p - 1), 62)
29.         END IF
30.         FOR i = 1 TO 15
31.             COLOR VAL("&H" + MID$(cs$, i, 1))
32.             PRINT MID$(fl$, i * 3 - 2, 3);
33.         NEXT
34.         REDIM dat$(0), dat2$(0)
35.         Split sc$, " ", dat$()
36.         IF sc2$ <> "" THEN Split sc2$, " ", dat2$()
37.         PRINT SPACE$(3);
38.         FOR i = LBOUND(dat$) TO UBOUND(dat$)
39.             COLOR i + 1
40.             blank$ = SPACE$(2)
41.             IF sc2$ <> "" THEN
42.                 diff$ = _TRIM$(STR$(VAL(dat$(i)) - VAL(dat2$(i))))
43.                 MID$(blank$, 1, LEN(diff$)) = diff$
44.             ELSE
45.                 MID$(blank$, 1, LEN(dat$(i))) = dat$(i)
46.             END IF
47.             PRINT blank$;
48.         NEXT
49.         PRINT
50.     ELSE
51.         COLOR 15
52.         PRINT SPACE$(34) + "*** End of Data ***"
53.         EXIT FOR
54.     END IF
55. NEXT
56. PRINT
57. FOR i = 1 TO 15
58.     COLOR i
59.     blank$ = SPACE$(10)
60.     s$ = "seq of " + _TRIM$(STR$(i))
61.     MID$(blank$, 2, LEN(s$)) = s$
62.     PRINT blank$;
63.     IF i = 8 THEN PRINT
64. NEXT
65. PRINT: PRINT
66. PRINT SPACE$(25) + "press u for page Up, d for page Down ";
67. _DISPLAY
68. getpage:
69. pageDir$ = ""
70. WHILE UCASE$(pageDir$) <> "U" AND UCASE$(pageDir$) <> "D"
71.     pageDir$ = INKEY$
72.     _LIMIT 60
73. WEND
74. IF UCASE$(pageDir$) = "U" THEN
75.     IF page - 40 >= 0 THEN page = page - 40 ELSE BEEP
76. ELSEIF UCASE$(pageDir$) = "D" THEN
77.     IF page + 40 <= 2040 THEN page = page + 40 ELSE BEEP
78. ELSE
79.     IF pageDir$ <> "" THEN BEEP
80.     GOTO getpage
81. END IF
82. GOTO nextPage
83.  
84. SUB Split (SplitMeString AS STRING, delim AS STRING, loadMeArray() AS STRING)
85.     DIM curpos AS LONG, arrpos AS LONG, LD AS LONG, dpos AS LONG 'fix use the Lbound the array already has
86.     curpos = 1: arrpos = LBOUND(loadMeArray): LD = LEN(delim)
87.     dpos = INSTR(curpos, SplitMeString, delim)
88.     DO UNTIL dpos = 0
89.         loadMeArray(arrpos) = MID$(SplitMeString, curpos, dpos - curpos)
90.         arrpos = arrpos + 1
91.         IF arrpos > UBOUND(loadMeArray) THEN REDIM _PRESERVE loadMeArray(LBOUND(loadMeArray) TO UBOUND(loadMeArray) + 1000) AS STRING
92.         curpos = dpos + LD
93.         dpos = INSTR(curpos, SplitMeString, delim)
94.     LOOP
95.     loadMeArray(arrpos) = MID$(SplitMeString, curpos)
96.     REDIM _PRESERVE loadMeArray(LBOUND(loadMeArray) TO arrpos) AS STRING 'get the ubound correct
97. END SUB
98.  
99. 'hint
100. 'FOR i = 0 TO 15
101. '    PRINT HEX$(i), VAL("&H" + HEX$(i))
102. 'NEXT
103.  
104.  

 

[carloscordeiro]

I didn't do Bplus, this is just a drawing I did on the windows paintd

I just added the columns in to be displayed

Insert the counter to be able to draw, so you would have an idea of what I want