Rectangles

[Petr]

In future i add here more hardware accelerated demos.

This code create in hardware screen layer N - rectangle textured using MAPTRIANGLE.

Code: QB64: [Select]

1. '100.000 frames demo
2.  
3. SCREEN _NEWIMAGE(640, 480, 32)
4. J& = _SCREENIMAGE
5. I& = _COPYIMAGE(J&, 33) '                                                             use hardware acceleration
6. _FREEIMAGE J&
7. T = TIMER
8. FOR x = 1 TO 100000
9.     Rectangle 320, 240, 4 + a, 240, I& 'X axis, Y axis, Vertex numbers, Radius, Texture&
10.  
11.     _DISPLAY
12.     a = a + .0001
13. NEXT
14. PRINT TIMER - T
15. END
16.  
17.  
18.  
19. SUB Rectangle (X AS INTEGER, Y AS INTEGER, N AS INTEGER, Radius AS INTEGER, Source AS LONG)
20.     bod = 628 / N
21.     FOR g! = 0 TO 4 * _PI STEP 0.01
22.         IF h MOD bod = 0 THEN
23.             IF oldx = 0 THEN oldx = X: oldy = Y
24.             _MAPTRIANGLE (oldx, oldy)-(X + SIN(g!) * Radius, Y + COS(g!) * Radius)-(X, Y), Source& TO(oldx, oldy)-(X + SIN(g!) * Radius, Y + COS(g!) * Radius)-(X, Y)
25.             oldx = X + SIN(g!) * Radius: oldy = Y + COS(g!) * Radius
26.         END IF
27.         h = h + 1
28.     NEXT g!
29. END SUB
30.  
31.  

[bplus]

Hi Petr,

You really threw me off by calling these rectangles.

I would call them regular polygons of an image (of a copy of the screen).

Nice work with _MAPTRIANGLE.

[johnno56]

Umm... I ran the program and all I got was a black window. Ran it several times with the same result. The last time I ran it, I waited - just in case I was too impatient... and a number appeared on the screen. Ran it again to confirm. Screen stayed black for maybe 20 seconds then displayed '20.93359' (without the quotes) and the program terminated.

All I did was 'cut and paste' and F5 to run...

J

[FellippeHeitor]

I get (and have a feeling bplus got it too) a circle with an image of the desktop, as if made by a cookie cutter.

[FellippeHeitor]

Btw, this code is for Windows only (because of _SCREENIMAGE), so in Linux you probably won't see anything after all.

[bplus]

OK Johnno, Petr did this:

Code: QB64: [Select]

1. _TITLE "Polygon Image Demo"
2. 'by bplus started 2018-06-22
3.  
4. CONST xmax = 800
5. CONST ymax = 600
6. SCREEN _NEWIMAGE(xmax, ymax, 32)
7. _SCREENMOVE 100, 20
8.  
9. stars& = _LOADIMAGE("stars.png")
10. _PUTIMAGE , stars&, 0
11. _DELAY 1
12. FOR n = 3 TO 12
13.     CLS
14.     polygonImage stars&, xmax / 2, ymax / 2, 300, n
15.     _DISPLAY
16.     _DELAY 1
17. NEXT
18. SUB polygonImage (ImageHandle&, xOrigin, yOrigin, radius, nVertex)
19.     polyAngle = _PI(2) / nVertex
20.     x1 = xOrigin + radius * COS(polyAngle)
21.     y1 = yOrigin + radius * SIN(polyAngle)
22.     FOR i = 2 TO nVertex + 1
23.         x2 = xOrigin + radius * COS(i * polyAngle)
24.         y2 = yOrigin + radius * SIN(i * polyAngle)
25.         _MAPTRIANGLE (xOrigin, yOrigin)-(x1, y1)-(x2, y2), ImageHandle& TO(xOrigin, yOrigin)-(x1, y1)-(x2, y2), 0
26.         x1 = x2: y1 = y2
27.     NEXT
28. END SUB
29.  

Only with an image of the desktop and in a much more complicated way.

[johnno56]

Btw, this code is for Windows only (because of _SCREENIMAGE), so in Linux you probably won't see anything after all.

Understood.

[bplus]

On the other hand if we are just cookie cutting a circle out of an image this is much shorter time:

Code: QB64: [Select]

1. _TITLE "Polygon Image Demo"
2. 'by bplus started 2018-06-22
3.  
4. CONST xmax = 800
5. CONST ymax = 600
6. SCREEN _NEWIMAGE(xmax, ymax, 32)
7. _SCREENMOVE 100, 20
8.  
9. stars& = _LOADIMAGE("stars.png")
10. _PUTIMAGE , stars&, 0
11. _DELAY 1
12. start## = TIMER
13. CLS
14. polygonImage stars&, xmax / 2, ymax / 2, 300, 50
15. PRINT TIMER - start##
16.  
17. SUB polygonImage (ImageHandle&, xOrigin, yOrigin, radius, nVertex)
18.     polyAngle = _PI(2) / nVertex
19.     x1 = xOrigin + radius * COS(polyAngle)
20.     y1 = yOrigin + radius * SIN(polyAngle)
21.     FOR i = 2 TO nVertex + 1
22.         x2 = xOrigin + radius * COS(i * polyAngle)
23.         y2 = yOrigin + radius * SIN(i * polyAngle)
24.         _MAPTRIANGLE (xOrigin, yOrigin)-(x1, y1)-(x2, y2), ImageHandle& TO(xOrigin, yOrigin)-(x1, y1)-(x2, y2), 0
25.         x1 = x2: y1 = y2
26.     NEXT
27. END SUB
28.  

BTW I wonder how a circle fill with this method stacks up against Steve's.

[bplus]

BTW I wonder how a circle fill with this method stacks up against Steve's.

Terribly!

[FellippeHeitor]

On the other hand if we are just cookie cutting a circle out of an image this is much shorter time.

Hold my beer:

Code: QB64: [Select]

1. cookieCutter& = _NEWIMAGE(1600, 1200, 32)
2. _DEST cookieCutter&
3. CLS
4. CIRCLE (_WIDTH / 2, _HEIGHT / 2), 250, _RGB32(255, 0, 255)
5. PAINT (_WIDTH / 2, _HEIGHT / 2), _RGB32(255, 0, 255)
6. _CLEARCOLOR _RGB32(255, 0, 255)
7.  
8. stars& = _LOADIMAGE("stars.png", 32)
9. SCREEN _NEWIMAGE(800, 600, 32)
10.  
11. DO
12.     WHILE _MOUSEINPUT: WEND
13.     _PUTIMAGE (0, 0), stars&
14.     _PUTIMAGE (_MOUSEX - 800, _MOUSEY - 600), cookieCutter&
15.     _DISPLAY
16.     _LIMIT 30
17. LOOP
18.  

[_vince]

BTW I wonder how a circle fill with this method stacks up against Steve's.

Terribly!

Such is life

[bplus]

Still here is the cookie:

Code: QB64: [Select]

1. _TITLE "Polygon Image Demo 2"
2. 'by bplus started 2018-06-22
3.  
4. CONST xmax = 800
5. CONST ymax = 600
6. SCREEN _NEWIMAGE(xmax, ymax, 32)
7. _SCREENMOVE 100, 20
8.  
9. stars& = _LOADIMAGE("stars.png")
10. stuff& = _NEWIMAGE(xmax, ymax, 32)
11. _DEST stuff&
12. FOR i = 1 TO 100
13.     CIRCLE (RND * xmax, RND * ymax), RND * 100, _RGB32(RND * 255, RND * 255, RND * 255)
14. NEXT
15. _DEST 0
16. DO
17.     CLS
18.     _SOURCE stuff&
19.     _PUTIMAGE
20.     WHILE _MOUSEINPUT: WEND
21.     polygonImage stars&, _MOUSEX, _MOUSEY, 250, 50
22.     _DISPLAY
23.     _LIMIT 30
24. LOOP
25.  
26.  
27. SUB polygonImage (ImageHandle&, xOrigin, yOrigin, radius, nVertex)
28.     polyAngle = _PI(2) / nVertex
29.     x1 = xOrigin + radius * COS(polyAngle)
30.     y1 = yOrigin + radius * SIN(polyAngle)
31.     FOR i = 2 TO nVertex + 1
32.         x2 = xOrigin + radius * COS(i * polyAngle)
33.         y2 = yOrigin + radius * SIN(i * polyAngle)
34.         _MAPTRIANGLE (xOrigin, yOrigin)-(x1, y1)-(x2, y2), ImageHandle& TO(xOrigin, yOrigin)-(x1, y1)-(x2, y2), 0
35.         x1 = x2: y1 = y2
36.     NEXT
37. END SUB
38.  
39.  

[Petr]

Thank you all for posts, I'll add another code in the near future. Last night of my time I was no longer in the forum, but now I go to bury the guinea pigs of my children, that died in the evening. I'm pleased with your interest in this program, which shows how many ways one thing can do and their differences in speed. My N - polygon I wrote for the use I will show in the next program.