External Module Player (XMP)

[Petr]

Hi RhoSigma,

Here is, why I asked about getting the total length of time. Sound devastation by stereo malfunction by the SNDRAW command is known. This program will work around this problem and finally! Stereo MOD audio is the same as from WINAMP. Thank you again. This opens up further possibilities for the QB64. I'm absolutely thrilled.

Code: QB64: [Select]

1. XMPPLAY "love.mod"
2.  
3. SUB XMPPLAY (file AS STRING)
4.     DECLARE DYNAMIC LIBRARY "xmp_demo\libxmp"
5.         FUNCTION xmp_create_context%& ()
6.         SUB xmp_free_context (BYVAL xmp_context%&)
7.         FUNCTION xmp_load_module& (BYVAL xmp_context%&, path$)
8.         SUB xmp_release_module (BYVAL xmp_context%&)
9.         FUNCTION xmp_start_player& (BYVAL xmp_context%&, BYVAL rate&, BYVAL format&)
10.         FUNCTION xmp_play_buffer& (BYVAL xmp_context%&, BYVAL buffer AS _OFFSET, BYVAL size AS _OFFSET, BYVAL loops&)
11.         SUB xmp_end_player (BYVAL xmp_context%&)
12.         SUB xmp_get_frame_info (BYVAL xmp_context%&, BYVAL info%&)
13.     END DECLARE
14.  
15.     '--- the (rudimentary) frame info type ---
16.     TYPE xmp_frame_info '      /* Current frame information */
17.         posi AS LONG '         /* Current position */
18.         pattern AS LONG '      /* Current pattern */
19.         row AS LONG '          /* Current row in pattern */
20.         num_rows AS LONG '     /* Number of rows in current pattern */
21.         frame AS LONG '        /* Current frame */
22.         speed AS LONG '        /* Current replay speed */
23.         bpm AS LONG '          /* Current bpm */
24.         time AS LONG '         /* Current module time in ms */
25.         total_time AS LONG '   /* Estimated replay time in ms*/
26.         frame_time AS LONG '   /* Frame replay time in us */
27.         'we don't use the frame buffer, as we play to an
28.         'external buffer using xmp_play_buffer&()
29.         buffer AS _OFFSET '    /* Pointer to sound buffer */
30.         buffer_size AS LONG '  /* Used buffer size */
31.         total_size AS LONG '   /* Total buffer size */
32.         '----------
33.         volume AS LONG '       /* Current master volume */
34.         loop_count AS LONG '   /* Loop counter */
35.         virt_channels AS LONG '/* Number of virtual channels */
36.         virt_used AS LONG '    /* Used virtual channels */
37.         sequence AS LONG '     /* Current sequence */
38.         'the following is not yet detailed, its just a safety
39.         'margin for now to avoid memory protection faults
40.         xmp_channel_info AS STRING * 8192 '/* Current channel information */
41.     END TYPE
42.     ctx%& = xmp_create_context%&
43.     xerr& = xmp_load_module&(ctx%&, file$ + CHR$(0))
44.     xerr2& = xmp_start_player&(ctx%&, _SNDRATE, 0)
45.     DIM xfi AS xmp_frame_info
46.     DIM m AS _MEM: m = _MEM(xfi)
47.     xmp_get_frame_info ctx%&, m.OFFSET
48.     _MEMFREE m
49.     Time& = _SNDRATE * INT(xfi.total_time / 1000) * 4
50.     DIM Buf AS _MEM
51.     Buf = _MEMNEW(Time&)
52.     buf& = xmp_play_buffer&(ctx%&, Buf.OFFSET, Buf.SIZE, 10)
53.     SAVESOUND16S Buf, Time&, "swap.wav"
54.     xmp_end_player ctx%&
55.     xmp_release_module ctx%&
56.     xmp_free_context ctx%&
57.     PRINT "done"
58.     _SNDPLAYFILE ("swap.wav")
59. END SUB
60. SUB SAVESOUND16S (arr AS _MEM, lenght AS LONG, file AS STRING) 'speed upgraded version (now much faster), first SINGLE values are recalculated as INTEGERs and THEN writed at once to file.
61.     TYPE head16
62.         chunk AS STRING * 4 '       4 bytes  (RIFF)
63.         size AS LONG '              4 bytes  (file size)
64.         fomat AS STRING * 4 '       4 bytes  (WAVE)
65.         sub1 AS STRING * 4 '        4 bytes  (fmt )
66.         subchunksize AS LONG '      4 bytes  (lo / hi), $00000010 for PCM audio
67.         format AS INTEGER '         2 bytes  (0001 = standard PCM, 0101 = IBM mu-law, 0102 = IBM a-law, 0103 = IBM AVC ADPCM)
68.         channels AS INTEGER '       2 bytes  (1 = mono, 2 = stereo)
69.         rate AS LONG '              4 bytes  (sample rate, standard is 44100)
70.         ByteRate AS LONG '          4 bytes  (= sample rate * number of channels * (bits per channel /8))
71.         Block AS INTEGER '          2 bytes  (block align = number of channels * bits per sample /8)
72.         Bits AS INTEGER '           2 bytes  (bits per sample. 8 = 8, 16 = 16)
73.         subchunk2 AS STRING * 4 '   4 bytes  ("data")  contains begin audio samples
74.         lenght AS LONG '            4 bytes  Data block size
75.     END TYPE '                     44 bytes  total
76.     DIM H16 AS head16
77.     ch = FREEFILE
78.     H16.chunk = "RIFF"
79.     H16.size = 44 + lenght 'two channels, it create 16 bit, stereo wav file, one sample use 2 bytes to one channel
80.     H16.fomat = "WAVE"
81.     H16.sub1 = "fmt "
82.     H16.subchunksize = 16
83.     H16.format = 1
84.     H16.channels = 2
85.     H16.rate = 44100
86.     H16.ByteRate = 44100 * 2 * 16 / 8
87.     H16.Block = 4
88.     H16.Bits = 16
89.     H16.subchunk2 = "data"
90.     H16.lenght = lenght
91.     IF _FILEEXISTS(file$) THEN KILL file$
92.     OPEN file$ FOR BINARY AS #ch
93.     PUT #ch, , H16
94.     sp$ = SPACE$(lenght)
95.     _MEMGET arr, arr.OFFSET, sp$
96.     PUT ch, , sp$
97.     CLOSE ch
98. END SUB
99.  

[RhoSigma]

Well Petr, that's a nice example how to use XMP as a Mod2Wav converter, glad you like it and it's useful for you :)

[Petr]

Here is an improved version. I've found that for some music files, the length of a song can't be calculated correctly. That's why I solved it by taking all the content as a song, except zeros (silence) during the analysis from the end of the song.

Again, 32bit IDE is needed.

Code: QB64: [Select]

1. XMPPLAY "blitzkrieg.mod"
2.  
3. SUB XMPPLAY (file AS STRING)
4.     DECLARE DYNAMIC LIBRARY "xmp_demo\libxmp"
5.         FUNCTION xmp_create_context%& ()
6.         SUB xmp_free_context (BYVAL xmp_context%&)
7.         FUNCTION xmp_load_module& (BYVAL xmp_context%&, path$)
8.         SUB xmp_release_module (BYVAL xmp_context%&)
9.         FUNCTION xmp_start_player& (BYVAL xmp_context%&, BYVAL rate&, BYVAL format&)
10.         FUNCTION xmp_play_buffer& (BYVAL xmp_context%&, BYVAL buffer AS _OFFSET, BYVAL size AS _OFFSET, BYVAL loops&)
11.         SUB xmp_end_player (BYVAL xmp_context%&)
12.         SUB xmp_get_frame_info (BYVAL xmp_context%&, BYVAL info%&)
13.     END DECLARE
14.  
15.     '--- the (rudimentary) frame info type ---
16.     TYPE xmp_frame_info '      /* Current frame information */
17.         posi AS LONG '         /* Current position */
18.         pattern AS LONG '      /* Current pattern */
19.         row AS LONG '          /* Current row in pattern */
20.         num_rows AS LONG '     /* Number of rows in current pattern */
21.         frame AS LONG '        /* Current frame */
22.         speed AS LONG '        /* Current replay speed */
23.         bpm AS LONG '          /* Current bpm */
24.         time AS LONG '         /* Current module time in ms */
25.         total_time AS LONG '   /* Estimated replay time in ms*/
26.         frame_time AS LONG '   /* Frame replay time in us */
27.         'we don't use the frame buffer, as we play to an
28.         'external buffer using xmp_play_buffer&()
29.         buffer AS _OFFSET '    /* Pointer to sound buffer */
30.         buffer_size AS LONG '  /* Used buffer size */
31.         total_size AS LONG '   /* Total buffer size */
32.         '----------
33.         volume AS LONG '       /* Current master volume */
34.         loop_count AS LONG '   /* Loop counter */
35.         virt_channels AS LONG '/* Number of virtual channels */
36.         virt_used AS LONG '    /* Used virtual channels */
37.         sequence AS LONG '     /* Current sequence */
38.         'the following is not yet detailed, its just a safety
39.         'margin for now to avoid memory protection faults
40.         xmp_channel_info AS STRING * 8192 '/* Current channel information */
41.     END TYPE
42.     ctx%& = xmp_create_context%&
43.     xerr& = xmp_load_module&(ctx%&, file$ + CHR$(0))
44.     xerr2& = xmp_start_player&(ctx%&, _SNDRATE, 0)
45.     DIM xfi AS xmp_frame_info
46.     DIM m AS _MEM: m = _MEM(xfi)
47.     xmp_get_frame_info ctx%&, m.OFFSET
48.     _MEMFREE m
49.  
50.     Tim& = xfi.total_time / 1000
51.     Time& = _SNDRATE * Tim& * 4
52.    
53.     DIM Buf AS _MEM
54.     Buf = _MEMNEW(Time&)
55.     buf& = xmp_play_buffer&(ctx%&, Buf.OFFSET, Buf.SIZE, 0)
56.  
57.     Time& = LastRec(Buf)
58.     PRINT "lastrec:"; LastRec(Buf)
59.     SAVESOUND16S Buf, Time&, "swap.wav"
60.     xmp_end_player ctx%&
61.     xmp_release_module ctx%&
62.     xmp_free_context ctx%&
63.     PRINT "done"
64.     _SNDPLAYFILE ("swap.wav")
65. END SUB
66.  
67. SUB SAVESOUND16S (arr AS _MEM, lenght AS LONG, file AS STRING) 'speed upgraded version (now much faster), first SINGLE values are recalculated as INTEGERs and THEN writed at once to file.
68.     TYPE head16
69.         chunk AS STRING * 4 '       4 bytes  (RIFF)
70.         size AS LONG '              4 bytes  (file size)
71.         fomat AS STRING * 4 '       4 bytes  (WAVE)
72.         sub1 AS STRING * 4 '        4 bytes  (fmt )
73.         subchunksize AS LONG '      4 bytes  (lo / hi), $00000010 for PCM audio
74.         format AS INTEGER '         2 bytes  (0001 = standard PCM, 0101 = IBM mu-law, 0102 = IBM a-law, 0103 = IBM AVC ADPCM)
75.         channels AS INTEGER '       2 bytes  (1 = mono, 2 = stereo)
76.         rate AS LONG '              4 bytes  (sample rate, standard is 44100)
77.         ByteRate AS LONG '          4 bytes  (= sample rate * number of channels * (bits per channel /8))
78.         Block AS INTEGER '          2 bytes  (block align = number of channels * bits per sample /8)
79.         Bits AS INTEGER '           2 bytes  (bits per sample. 8 = 8, 16 = 16)
80.         subchunk2 AS STRING * 4 '   4 bytes  ("data")  contains begin audio samples
81.         lenght AS LONG '            4 bytes  Data block size
82.     END TYPE '                     44 bytes  total
83.     DIM H16 AS head16
84.     ch = FREEFILE
85.     H16.chunk = "RIFF"
86.     H16.size = 44 + lenght 'two channels, it create 16 bit, stereo wav file, one sample use 2 bytes to one channel
87.     H16.fomat = "WAVE"
88.     H16.sub1 = "fmt "
89.     H16.subchunksize = 16
90.     H16.format = 1
91.     H16.channels = 2
92.     H16.rate = 44100
93.     H16.ByteRate = 44100 * 2 * 16 / 8
94.     H16.Block = 4
95.     H16.Bits = 16
96.     H16.subchunk2 = "data"
97.     H16.lenght = lenght
98.     IF _FILEEXISTS(file$) THEN KILL file$
99.     OPEN file$ FOR BINARY AS #ch
100.     PUT #ch, , H16
101.     sp$ = SPACE$(lenght)
102.     _MEMGET arr, arr.OFFSET, sp$
103.     PUT ch, , sp$
104.     CLOSE ch
105. END SUB
106.  
107. FUNCTION LastRec&& (a AS _MEM)
108.     DIM b AS _OFFSET, c AS _OFFSET
109.     b = a.SIZE - 2
110.     DO UNTIL b = 0 OR v <> 0
111.         v = _MEMGET(a, a.OFFSET + b, INTEGER)
112.         b = b - 2
113.     LOOP
114.     DIM LR AS _INTEGER64
115.     DIM LRO AS _MEM
116.     LRO = _MEM(LR)
117.     _MEMPUT LRO, LRO.OFFSET, b
118.     LastRec = LR
119.     _MEMFREE LRO
120. END FUNCTION
121.  

[RhoSigma]

Hi all,

after almost 5 years, libxmp got lots of fixes plus a couple new features and was finally updated to version 4.5.0 by the mid of this year. This was a good occasion for me to complete my wrapper library for it and to improve my demo player to showcase some of the libxmp functions and give a hint how to correctly use the wrapper library.

When porting the informations over into libxmp.bi/.bm and testing it, I found several badly described things and tried to correct/improve those with my own findings from examining the libxmp sources.

The XmpPlayer.bas file will espacially show the use of the various wrapper or helper functions in libxmp.bm, which are used to retrieve informations from the internal libxmp structures.

The player itself is almost self explanatory at runtime and programmed as an endless program loop, so simply hit the X button to quit it at any time. It is able to show various informations about the current module and also features a wave oscillator and frequency spectrum (FFT) display, the latter thanks to _vince's fabulous Fast Fourier algorithms.

Note that this program requires the 32-bit version of QB64, as libxmp is currently available as 32-bit version only, this will hopefully change in the future. So here it is, just move the extracted xmpDemo folder with its entire contents into your QB64 working folder (where qb64.exe is in), then open the QB64 IDE, untick the Save EXE in source folder option (if active (in Run Menu)), load XmpPlayer.bas from the xmpDemo folder, hit F5 and enjoy the music.

[Petr]

I struggled with it a bit (I unpacked it into another folder) and it works perfectly. Special thanks for the solution of the spectrum analyzer, which we fought here for a long time. I'm playing music now, I'll study the code. Thank you so much for sharing!