adding/subtracting times

[JohnUKresults]

Hi

Someone out there must have come across this before.

I need to subtract one time from another, to work out an elspased time.

The times are stored in the format hh:mm:ss.dd so are always the same length (time of day stored to 2 decimal places)

Anyone got some code which can do this?

I'll need to have the result stored in (a) the same format (i.e. to 2 decimal places) and also (b) as a number of seconds rounded up to the next full second (anything after the deimal point rounds up, not just to the nearest second), but I can probably figure that out once I've got the subtraction worked out.

It will save me having to write some convoluted code (as I'm not exactly smart with this stuff)

Many thanks for your time.

John

[bplus]

Steve started with a Timestamp thing and I was interested in checking days and time passage both here:
https://www.qb64.org/forum/index.php?topic=1638.msg108566#msg108566

I got burnt out testing Steve's fixes but this maybe helpful for you @JohnUKresults ? If you limited it to 24 hour period it would be way easier than what we were playing with! ;-))

[SpriggsySpriggs]

Here you go, @JohnUKresults
This solution shows using PowerShell. I've not parsed the return string from PowerShell but I'll leave that up to you. Have fun!
P.S. You'll probably need to run PowerShell in Administrator mode and run this below command because the default in Windows 10 is to not allow running of scripts:

Set-ExecutionPolicy RemoteSigned

Code: QB64: [Select]

1. startTime$ = "10:20:20.10"
2. endTime$ = "20:10:30.15"
3. DIM PS1 AS INTEGER
4. PS1 = FREEFILE
5. OPEN "timediff.ps1" FOR OUTPUT AS #PS1
6. PRINT #PS1, "$StartDate = [datetime]" + CHR$(34) + startTime$ + CHR$(34)
7. PRINT #PS1, "$EndDate = [datetime]" + CHR$(34) + endTime$ + CHR$(34)
8. PRINT #PS1, "New-TimeSpan -Start $StartDate -End $EndDate | Out-File -FilePath .\timediff.d -Encoding ASCII"
9. CLOSE #PS1
10. SHELL _HIDE "PowerShell .\timediff.ps1"
11. KILL "timediff.ps1"
12. DIM d AS INTEGER
13. d = FREEFILE
14. DIM timedifference AS STRING
15. OPEN "timediff.d" FOR BINARY AS #d
16. IF LOF(d) <> 0 THEN
17.     timedifference = SPACE$(LOF(d))
18.     GET #d, , timedifference
19. END IF
20. CLOSE #d
21. KILL "timediff.d"
22. PRINT timedifference

[JohnUKresults]

Many thanks

I'm trying to keep it within QB64 for various reasons, but I'll certainly have a close look at this

Regards

John

[Richard Frost]

No array, SUB, or FUNCTION, keeping it simple....

Code: QB64: [Select]

1. ' math with hh:mm:ss.dd
2.  
3. DEFINT A-Z
4. t1$ = "10:17:12.45"
5. t2$ = "11:53:52.18"
6. t$ = t1$: GOSUB woof: f1! = f!
7. t$ = t2$: GOSUB woof: f2! = f!
8. f! = f2! - f1!
9. hh = f! \ 3600
10. mm = (f! - hh * 3600) \ 60
11. s! = (f! - hh * 3600 - mm * 60)
12. s! = INT(s! * 100) / 100
13. h$ = RIGHT$("0" + LTRIM$(STR$(hh)), 2)
14. m$ = RIGHT$("0" + LTRIM$(STR$(mm)), 2)
15. s$ = RIGHT$("0" + LTRIM$(STR$(s!)), 5)
16.  
17. p = INSTR(s$, ".")
18. IF p < 3 THEN s$ = "0" + s$ '               add leading zero to seconds, if needed
19.  
20. WHILE LEN(s$) < 5 '                         add trailing zeros to seconds, if needed
21.     s$ = s$ + "0"
22. WEND
23.  
24. CLS
25. PRINT t1$
26. PRINT t2$
27. t$ = h$ + ":" + m$ + ":" + s$
28. PRINT t$
29. PRINT INT(f! + .5)
30. END
31.  
32. woof:
33. hh = VAL(MID$(t$, 1, 2))
34. mm = VAL(MID$(t$, 4, 2))
35. s! = VAL(MID$(t$, 7, 5))
36. f! = CDBL(hh) * 60 * 60 + mm * 60 + s!
37. RETURN
38.  
39.  

[bplus]

Here is R Frost work made more portable:

Code: QB64: [Select]

1. OPTION _EXPLICIT
2. _TITLE "Time difference" 'b+ mod r frost 2020-07-27
3.  
4. ' ref r frost 2020-07-27   https://www.qb64.org/forum/index.php?topic=2861.msg121256#msg121256
5. ' math with hh:mm:ss.dd
6.  
7. DIM t1$, t2$, f1!, f2!
8. 't1$ = "10:17:12.45"
9. 't2$ = "11:53:52.18"
10. t1$ = "12:00:00.25" ' from noon and 1/4 sec
11. t2$ = TIME$ '
12. f1! = timeStr2Secs!(t1$)
13. f2! = timeStr2Secs!(t2$)
14.  
15. CLS
16. PRINT "+"; t2$, f2!
17. PRINT "-"; t1$, f1!
18. PRINT "============================"
19. PRINT secs2TimeStr$(f2! - f1!), INT(f2! - f1! + .5)
20. END
21.  
22. FUNCTION timeStr2Secs! (timeStr$)
23.     DIM hh AS INTEGER, mm AS INTEGER, s!
24.     hh = VAL(MID$(timeStr$, 1, 2))
25.     mm = VAL(MID$(timeStr$, 4, 2))
26.     s! = VAL(MID$(timeStr$, 7, 5))
27.     timeStr2Secs! = hh * 60 * 60 + mm * 60 + s!
28. END FUNCTION
29.  
30. FUNCTION secs2TimeStr$ (secs!)
31.     DIM hh AS INTEGER, mm AS INTEGER, s!, h$, m$, s$
32.     hh = secs! \ 3600
33.     mm = (secs! - hh * 3600) \ 60
34.     s! = (secs! - hh * 3600 - mm * 60)
35.     s! = INT(s! * 100) / 100
36.     h$ = RIGHT$("00" + LTRIM$(STR$(hh)), 2)
37.     m$ = RIGHT$("00" + LTRIM$(STR$(mm)), 2)
38.     s$ = xDP$(s!, 2)
39.     secs2TimeStr$ = h$ + ":" + m$ + ":" + s$
40. END FUNCTION
41.  
42. FUNCTION xDP$ (x, DP)
43.     DIM test$, p AS INTEGER
44.     test$ = _TRIM$(STR$(INT(x * 10 ^ DP) / 10 ^ DP))
45.     p = INSTR(test$, ".")
46.     IF p = 0 AND DP <> 0 THEN test$ = test$ + "." + STRING$(DP, "0")
47.     IF p AND DP = 0 THEN test$ = LEFT$(test$, LEN(test$) - 1)
48.     xDP$ = test$
49. END FUNCTION
50.  
51.  

EDIT: 2nd function made more agreeable to OPTION _EXPLICIT
EDIT: fixed s$ in second function (I think).

[Dimster]

Hi JohnUKresults - Just curious about the decimal places you are using - are they fixed values for the Day? and the decimal would range from 01 being day 1 and .31 is for the 31st day of the month.  Or would the decimal be the full range of a year using 365 days ( ie say we have  July 28 = 210/365 = .57)

[bplus]

Hi JohnUKresults - Just curious about the decimal places you are using - are they fixed values for the Day? and the decimal would range from 01 being day 1 and .31 is for the 31st day of the month.  Or would the decimal be the full range of a year using 365 days ( ie say we have  July 28 = 210/365 = .57)

Hi @Dimster

You are missing:

(time of day stored to 2 decimal places)

It seems to be 2 decimal places on the seconds of the time of day. I think you can get that degree of accuracy off the TIMER function which gives seconds (and parts of them) elapsed since midnight.


Oh hey great test /demo of secsToTimeStr$() Function!

Code: QB64: [Select]

1. WHILE _KEYDOWN(27) = 0
2.     CLS
3.     PRINT secs2TimeStr$(TIMER(.001))  '<<<<<<<<<< test demo of function!
4.     PRINT TIME$
5.     _DISPLAY
6.     _LIMIT 60
7. WEND
8.  
9.  
10. FUNCTION secs2TimeStr$ (secs!)
11.     DIM hh AS INTEGER, mm AS INTEGER, s!, h$, m$, s$
12.     hh = secs! \ 3600
13.     mm = (secs! - hh * 3600) \ 60
14.     s! = (secs! - hh * 3600 - mm * 60)
15.     s! = INT(s! * 100) / 100
16.     h$ = RIGHT$("00" + LTRIM$(STR$(hh)), 2)
17.     m$ = RIGHT$("00" + LTRIM$(STR$(mm)), 2)
18.     s$ = xDP$(s!, 2)
19.     secs2TimeStr$ = h$ + ":" + m$ + ":" + s$
20. END FUNCTION
21.  
22. FUNCTION xDP$ (x, DP)
23.     DIM test$, p AS INTEGER
24.     test$ = _TRIM$(STR$(INT(x * 10 ^ DP) / 10 ^ DP))
25.     p = INSTR(test$, ".")
26.     IF p = 0 AND DP <> 0 THEN test$ = test$ + "." + STRING$(DP, "0")
27.     IF p AND DP = 0 THEN test$ = LEFT$(test$, LEN(test$) - 1)
28.     xDP$ = test$
29. END FUNCTION
30.  
31.  
32.  

[Dimster]

Ohhhh - when I saw dd - I thought that was referring to the day.

[bplus]

I miss things too (often) like I am seeing now those 2 time conversion functions can be (need to be?) improved!

[bplus]

Man this hh:mm:ss.dd timeStr$ format was real b... trying to get the string to do decimals correctly! I discovered a trick.

Code: QB64: [Select]

1. OPTION _EXPLICIT
2. _TITLE "secs2TimerStr$ test and demo" ' b+ 2020-07-28
3. ' 2020-07-28 fix leading 0 or 00 for secs, dump xDP$ function
4.  
5. PRINT secs2TimeStr$(60) '            00:01:00.00
6. PRINT: PRINT secs2TimeStr$(61) '     00:01:01.00
7. PRINT: PRINT secs2TimeStr$(0) '      00:00:00.00
8. PRINT: PRINT secs2TimeStr$(75.15) '  00:01:15.15
9. PRINT: PRINT secs2TimeStr$(60.025) ' 00:01:00.03  roundup
10. PRINT: PRINT secs2TimeStr$(60.005) ' 00:01:00.01  roundup
11. PRINT: PRINT secs2TimeStr$(60.004) ' 00:01:00.00  no roundup
12.  
13. FUNCTION secs2TimeStr$ (secs!) ' format hh:mm:ss.dd  ver 2020-07-28 fix leading 0 in seconds
14.     DIM hh AS INTEGER, mm AS INTEGER, s!, h$, m$, s$
15.     hh = secs! \ 3600
16.     mm = (secs! - hh * 3600) \ 60
17.     s! = (secs! - hh * 3600 - mm * 60)
18.     h$ = RIGHT$("00" + LTRIM$(STR$(hh)), 2)
19.     m$ = RIGHT$("00" + LTRIM$(STR$(mm)), 2)
20.     s$ = _TRIM$(STR$(100 + s! + .005)) 'get rid of the E's
21.     s$ = MID$(s$, 2, 5)
22.     secs2TimeStr$ = h$ + ":" + m$ + ":" + s$
23. END FUNCTION
24.  
25.  
26.  

[Bert22306]

I also thought, initially, that the dd referred to day. But instead, it meant "decimal." When I do this sort of thing, defining ASCII numbers and their precision, my approach is to use something more like hhmmss.ss.

Anyway, I also thought that TIMER provided seconds of the day to 2 decimal places. Instead, it appears to be 5 decimal places. Unless I'm looking at some sort of artifact.

Try this out. I didn't do any fancy formatting, using colons, but the results are simple enough. I deliberately did not round the INT functions, because in this type of use, usually, you don't to go past the whole hour, or the whole minute, or midnight, prematurely.

Code: [Select]

_TITLE "Test INT function for hours, minutes, seconds"
SCREEN _NEWIMAGE(120, 43, 0)
COLOR 1, 7
CLS
1 INPUT "Continue or exit (x to exit)"; cont$
IF cont$ = "x" THEN END
PRINT
TOD = TIMER
Hours = INT(TOD / 3600)
Minutes = INT((TOD - (Hours * 3600)) / 60)
Seconds = TOD - Hours * 3600 - Minutes * 60
PRINT "TOD seconds = "; TOD
PRINT "Hours = "; Hours; "  Minutes = "; Minutes; "  Seconds = "; Seconds
PRINT
GOTO 1
END

If you only want whole seconds, then change the Seconds line to:

Seconds = INT(TOD - Hours * 3600 - Minutes * 60)

[SMcNeill]

Anyway, I also thought that TIMER provided seconds of the day to 2 decimal places. Instead, it appears to be 5 decimal places. Unless I'm looking at some sort of artifact.

Remember guys, TIMER has an optional parameter for precision...

https://www.qb64.org/wiki/TIMER

PRINT TIMER
PRINT TIMER (0.01)
PRINT TIMER (0.0001)

[bplus]

Remember guys, TIMER has an optional parameter for precision...

https://www.qb64.org/wiki/TIMER

PRINT TIMER
PRINT TIMER (0.01)
PRINT TIMER (0.0001)

Yes and here is a demo with the better conversion function:

Code: QB64: [Select]

1. _TITLE "secs2TimeStr$ Demo 2" 'b+ 2020-07-29
2.  
3. WHILE _KEYDOWN(27) = 0
4.     CLS
5.     PRINT secs2TimeStr$(TIMER(.001)) '<<<<<<<<<< test demo of function!
6.     PRINT TIME$
7.     _DISPLAY
8.     _LIMIT 11 'some odd franction of a second
9. WEND
10.  
11.  
12. FUNCTION secs2TimeStr$ (secs!) ' format hh:mm:ss.dd  ver 2020-07-28 fix leading 0 in seconds
13.     DIM hh AS INTEGER, mm AS INTEGER, s!, h$, m$, s$
14.     hh = secs! \ 3600
15.     mm = (secs! - hh * 3600) \ 60
16.     s! = (secs! - hh * 3600 - mm * 60)
17.     h$ = RIGHT$("00" + LTRIM$(STR$(hh)), 2)
18.     m$ = RIGHT$("00" + LTRIM$(STR$(mm)), 2)
19.     s$ = _TRIM$(STR$(100 + s! + .005)) 'get rid of the E's
20.     s$ = MID$(s$, 2, 5)
21.     secs2TimeStr$ = h$ + ":" + m$ + ":" + s$
22. END FUNCTION
23.  
24.  
25.  
26.  
27.  

[JohnUKresults]

Hi guys

Thanks for all your input. All very helpful.

To clarify, the time in the reader I am accessing is stored as a full time of day with the date and then the time, with seconds to 2 decimal places, stored in a string like this:
15/03/2020 10:53:04.77

I've managed now to strip out the times, and worked out a small subroutine which slices the time up into variables for hours, minutes and seconds, then converts that all to seconds, so I can subtract one decimal number of seconds from another, and then I can convert the result back to a string (rounded up to whole seconds in that final conversion).

I can't use TIMER as I'm not accessing times on my pc - just on an external reader.

Grateful for all your very useful responses and snippets of code.

John