Playing with regions (Win API) to make unusual shaped windows

[Dav]

Trying to make unusual shaped windows, maybe use an image as the window, so playing around with creating regions using the Windows API.   Could make an interesting splash screen at least.  This is a limited example of it, but it's working so far.  I'm a novice at these api functions.  Advice greatly welcomed.

(Sorry linux & mac friends, the code is windows only)

- Dav

Code: QB64: [Select]

1. '================
2. 'WindowRegion.bas
3. '================
4. 'Uses Windows API to create a non-standard looking window.
5. 'Using this you could use an image as the entire window instead.
6. 'Coded by Dav, JULY/2020
7.  
8. 'I used API information found on this page....
9. 'http://allapi.mentalis.org/apilist/apilist.php
10.  
11. DECLARE DYNAMIC LIBRARY "user32"
12.     'sets a created window region
13.     'http://allapi.mentalis.org/apilist/SetWindowRgn.shtml
14.     FUNCTION SetWindowRgn& (BYVAL hwnd&, BYVAL hrgn&, BYVAL bredraw%)
15. END DECLARE
16.  
17. DECLARE DYNAMIC LIBRARY "gdi32"
18.     'creates a rectangular region
19.     'http://allapi.mentalis.org/apilist/CreateRectRgn.shtml
20.     FUNCTION CreateRectRgn& (BYVAL x1&, BYVAL y1&, BYVAL x2&, BYVAL y2&)
21.     'creates an elliptical region
22.     'http://allapi.mentalis.org/apilist/CreateEllipticRgn.shtml
23.     FUNCTION CreateEllipticRgn& (BYVAL x1&, BYVAL y1&, BYVAL x2&, BYVAL y2&)
24.     'creates a rectangular region with rounded corners
25.     'http://allapi.mentalis.org/apilist/CreateRoundRectRgn.shtml
26.     FUNCTION CreateRoundRectRgn& (BYVAL x1&, BYVAL y1&, BYVAL x2&, BYVAL y2&, BYVAL x3&, BYVAL y3&)
27. END DECLARE
28.  
29. controls& = BASIMAGE1& 'Make Minimize & Exit controls image
30.  
31. hwnd& = _WINDOWHANDLE 'need the windows handle to play with it
32.  
33. 'Create a rounded rectangular region...
34. rgn& = CreateRoundRectRgn(30, 30, 650, 650, 240, 240)
35.  
36. 'you can try these also...
37. 'rgn& = CreateEllipticRgn(30, 30, 650, 650)
38. 'rgn& = CreateRectRgn(30, 30, 650, 650)
39.  
40. 'Set the created region...
41. try& = SetWindowRgn(hwnd&, rgn&, 0)
42. 'Returns zero if failed...
43. IF try& = 0 THEN
44.     PRINT "Failed...": END
45. END IF
46.  
47. 'Setup screen....
48. SCREEN _NEWIMAGE(680, 680, 32)
49. 'Draw a top highlighted bar
50. LINE (0, 0)-(680, 80), _RGB(196, 196, 196), BF
51. 'draw minimize and exit image
52. _PUTIMAGE (350, 30), controls&
53.  
54.  
55. 'NOTE: Currently I haven't put in a way to drag the window,
56. 'but there is a way to do that and I will try to put it in later.
57.  
58. DO
59.  
60.     p = _MOUSEINPUT
61.     mx = _MOUSEX: my = _MOUSEY
62.  
63.     LOCATE 12, 12: PRINT mx, my
64.  
65.     'see if user clicked minimized area
66.     IF _MOUSEBUTTON(1) AND mx > 350 AND mx < 387 AND my > 29 AND my < 66 THEN
67.         'wait until button up to continue
68.         DO: p = _MOUSEINPUT
69.             IF _MOUSEBUTTON(1) = 0 THEN EXIT DO
70.         LOOP
71.         'minimize program
72.         _SCREENICON
73.     END IF
74.  
75.     'see if user clicked exit area
76.     IF _MOUSEBUTTON(1) AND mx > 390 AND mx < 420 AND my > 29 AND my < 66 THEN
77.         IF _MOUSEBUTTON(1) = -1 THEN
78.             SYSTEM
79.         END IF
80.     END IF
81.  
82. LOOP UNTIL INKEY$ = CHR$(27)
83. SYSTEM
84.  
85.  
86. 'This function creates the control image.
87. 'It was made with my BASIMAGE.BAS program .
88. FUNCTION BASIMAGE1& 'controls.png
89.     v& = _NEWIMAGE(80, 40, 32)
90.     DIM m AS _MEM: m = _MEMIMAGE(v&)
91.     A$ = ""
92.     A$ = A$ + "haIkH_oCCM5007_l#P28JF6a`HbL3iIKY?hEO#aOHKJ04W^9ciLDX::aXbn1"
93.     A$ = A$ + "U]iFfD7?4#4T7jLZK4#A5:<L;Z0^T]Q#L6aU\HbRVmO04PO081n]c>WcUc]g"
94.     A$ = A$ + "KkmNJ[m2SOhfT?inXWk]GnN_]gFZ\b:1E:c_=a4C\ZbZaS9Q>6UkWde_7jhF"
95.     A$ = A$ + ";K6]_KcJ\nkQW7=P3<Jm[S^nC#Gmn_[J8g?Y_OS?hmHmdQ^_X6Oh11oUGjY?"
96.     A$ = A$ + "H8_6]nM^cokP6Jk5B\WcZ^Fn7<W[k5PVJML#c]lTUlH\jKL4<Qjg8>jU1lJT"
97.     A$ = A$ + "7fW3`HoDo2Jd1hk9go^^Qki2JhNNQFoZj\o6XV6O^?[ZU9bmCjkg#Mn3l<LG"
98.     A$ = A$ + "o8[1i0]l#G_3NN#gM2ne^_QXnSNkaYnjU5nlEo>`W_Xe__lD33nZ_mI2:_]F"
99.     A$ = A$ + "6VVg<FgPFo9[jI<>mOc>?]aCfVR?d8RB^OBOoLdJCHmeFcH3LYFMjb]cj>Oo"
100.     A$ = A$ + "5an5>^37olE^T7=P0Xe_SDAoPSNRa54i_MQNPFoF\F<6J\TiY=N4J]C\nMmj"
101.     A$ = A$ + "ZQA3e2^Ame2^McWSE?GXAFT>c5Yi8>Jo2\j71fOG9di3Jm[db^9hPOjS5T5C"
102.     A$ = A$ + "k5cC=Q<6JSS\_Tkg:Oo^fIn6\>Zn<HMMfZahfET^K\>\KeD32B\^;DkkUC_Y"
103.     A$ = A$ + "e?Kf_9h07kADIfh79JK8mQfcI4^mNZKbmKi_OT6BjWKM4Rd#aJY_d#YZOLK8"
104.     A$ = A$ + "]FiJg#<UUgg>ajGKOfaIenWO2`E?mGcS[GOBdI]EaX^Za`m^nJhQL];g[O9M"
105.     A$ = A$ + "WdI?e_R?lX2ZTb7SW\Q]01eU5GLAAQ_V;cmPi;]C^O;?mcVY\LbRA#9iH2cF"
106.     A$ = A$ + ">VaC;eZI6iV3`N^F0fgREFUo^_=?79_]QMhlg6XR]W??7]`l17K75h6Jm;^="
107.     A$ = A$ + "o5PgBK7n4=Yad`iWONgPOO;liO3eGSQV[jLNXXC]5ZTkWdg_DEX0C=B0:0J2"
108.     A$ = A$ + ":0FY5LPlXM=1aCJQ4<;MQ52;m:35H8l`0Y7QB<3[=LNB?Z805THlPMZ:IZmC"
109.     A$ = A$ + "QRg3X8ZFm9a]Yg7gYiVK>gPFOLKJG`aeRh2Z1A9DoD_DkD1UbBCE]D;E50cD"
110.     A$ = A$ + "Nc783JmEcBhfG^=6eGmAbdEjm[#PR`Jf[4C\5RQJd\c>[X#?ojOUg1SF[Tkg"
111.     A$ = A$ + ":Co8_oUd=bba7IX2noZ`OT`jS4c0\QXgOSJXDd?Bg#VIVIl8bHme6:g?Y_OZ"
112.     A$ = A$ + "hd>ETkS0i]OGNOi1ihf0WkahakOXllDAJgdC?]PldcQfNNkCoXOYjBoFHQ5T"
113.     A$ = A$ + "DTnY3nIQYkEmKWRNOBdmAA#k_YVJ:g#N]8SQfh8k;5AdTLoFQk7K_LU7^?f;"
114.     A$ = A$ + "3bO7I0kFFA6>8ce6Q7jg^015Mc2R\_VLb9M3ncJCX8<dHS?aR`X=NT0OEin]"
115.     A$ = A$ + "Bg?]`FaU^PHT#D:UlkoJ=ihafj6S1\KE91n#=Y#]O[K3E0D^aV4DBYl1H2mj"
116.     A$ = A$ + "PF?kHS]AWKCbkFha3G?BX`aj[m;k`F3F61706IIS:3Q_823c4lkLPH6nMOck"
117.     A$ = A$ + "eSQWRP=1I?`^`e7[C=HOje`cWT^F#aIXSJoN]=OL#\jn>ob6Dg6?AcMN?lkM"
118.     A$ = A$ + "mVOo[Lol_nI?3mHFP=97XmVJB<DW2HO#fdZ6[HMJhaVnd0UH#;;K`FDBVja8"
119.     A$ = A$ + "kcBcb0?fc>MFU2]OCIB]OYJhTPD\NIOFRFJGdeWXi;b:NS]`KI?A^OBOo>XU"
120.     A$ = A$ + "\UL70f5GGGIXYiH4k#8F=1:?GcDkGfF?5HkkoNnU2]OGNcSD`;9QjgZ9[6?V"
121.     A$ = A$ + "4jHD^OBCoT9ko3o7Ml:S%%%0"
122.     btemp$ = ""
123.     FOR i& = 1 TO LEN(A$) STEP 4: B$ = MID$(A$, i&, 4)
124.         IF INSTR(1, B$, "%") THEN
125.             FOR C% = 1 TO LEN(B$): F$ = MID$(B$, C%, 1)
126.                 IF F$ <> "%" THEN C$ = C$ + F$
127.             NEXT: B$ = C$: END IF: FOR j = 1 TO LEN(B$)
128.             IF MID$(B$, j, 1) = "#" THEN
129.         MID$(B$, j) = "@": END IF: NEXT
130.         FOR t% = LEN(B$) TO 1 STEP -1
131.             B& = B& * 64 + ASC(MID$(B$, t%)) - 48
132.             NEXT: X$ = "": FOR t% = 1 TO LEN(B$) - 1
133.             X$ = X$ + CHR$(B& AND 255): B& = B& \ 256
134.     NEXT: btemp$ = btemp$ + X$: NEXT
135.     btemp$ = _INFLATE$(btemp$)
136.     _MEMPUT m, m.OFFSET, btemp$: _MEMFREE m
137.     BASIMAGE1& = _COPYIMAGE(v&): _FREEIMAGE v&
138. END FUNCTION
139.  
140.  

[loudar]

Wait damn, this is actually really f****** cool!!! I will 100% use this. Thank you so much.

EDIT: I've now added it to Datanet and added my own x at the top left, though the minimizing function seems to do something odd with the resizing detection, so I left it out for now.

 

[SpriggsySpriggs]

I seem to not be able to move the window after it is created. Is this normal?

[loudar]

@SpriggsySpriggs Yes it is. It removes the top bar created by Windows, so you'd have to code your own. I did that (except the minimize function) just now!

3*fontheight is the size of the top bar i chose, but use your own values of course :D Because I center this program in the middle at startup, I use the difference between the start and the end mousex/mousey to calculate the new position. When I display it everytime it changes, it goes a little crazy, so that's why I only display afterwards.

Code: QB64: [Select]

1.         mouseinput = _MOUSEINPUT
2.         mousebutton = _MOUSEBUTTON(1)
3.         mousex = _MOUSEX
4.         mousey = _MOUSEY
5.         IF mouseinput = -1 THEN
6.             IF mousebutton = -1 THEN
7.                 IF mousey < 3 * fontheight THEN
8.                     DO
9.                         mouseinput = _MOUSEINPUT
10.                         mousebutton = _MOUSEBUTTON(1)
11.                     LOOP UNTIL mousebutton <> -1
12.                     _SCREENMOVE _DESKTOPWIDTH / 2 - (_WIDTH / 2) + (_MOUSEX - mousex), _DESKTOPHEIGHT / 2 - (_HEIGHT / 2) + (_MOUSEY - mousey)
13.                 END IF
14.             END IF
15.         END IF

[Ashish]

Its amazing @Dav
Thanks for sharing the code. :-)

[Dav]

Here's an updated version that allows moving of the program window anywhere on the desktop.  Click in the highlighted area to move the window.  I used an API call to get mouse x/y for dragging the window - it seemed to move much smoother that way.   

- Dav

Code: QB64: [Select]

1. '================
2. 'WindowRegion.bas v1.1
3. '================
4. 'Uses Windows API to create a non-standard looking window.
5. 'Using this you could use an image as the entire window instead.
6. 'Coded by Dav, JULY/2020
7.  
8. 'I used API information found on this page....
9. 'http://allapi.mentalis.org/apilist/apilist.php
10.  
11.  
12. TYPE POINTAPI
13.     x AS LONG
14.     y AS LONG
15. END TYPE
16. DIM apixy AS POINTAPI 'mouse x/y for the GetCursorPos function
17.  
18. DECLARE DYNAMIC LIBRARY "user32"
19.     'sets a created window region
20.     'http://allapi.mentalis.org/apilist/SetWindowRgn.shtml
21.     FUNCTION SetWindowRgn& (BYVAL hwnd&, BYVAL hrgn&, BYVAL bredraw%)
22.     'get current mouse x/y position
23.     'http://allapi.mentalis.org/apilist/GetCursorPos.shtml
24.     FUNCTION GetCursorPos% (lpPoint AS POINTAPI)
25. END DECLARE
26.  
27.  
28. DECLARE DYNAMIC LIBRARY "gdi32"
29.     'creates a rectangular region
30.     'http://allapi.mentalis.org/apilist/CreateRectRgn.shtml
31.     FUNCTION CreateRectRgn& (BYVAL x1&, BYVAL y1&, BYVAL x2&, BYVAL y2&)
32.     'creates an elliptical region
33.     'http://allapi.mentalis.org/apilist/CreateEllipticRgn.shtml
34.     FUNCTION CreateEllipticRgn& (BYVAL x1&, BYVAL y1&, BYVAL x2&, BYVAL y2&)
35.     'creates a rectangular region with rounded corners
36.     'http://allapi.mentalis.org/apilist/CreateRoundRectRgn.shtml
37.     FUNCTION CreateRoundRectRgn& (BYVAL x1&, BYVAL y1&, BYVAL x2&, BYVAL y2&, BYVAL x3&, BYVAL y3&)
38. END DECLARE
39.  
40. controls& = BASIMAGE1& 'Make Minimize & Exit controls image
41. _ICON controls& 'might as well make it the program icon too...
42.  
43. hwnd& = _WINDOWHANDLE 'need the windows handle to play with it
44.  
45. 'Create a rounded rectangular region...
46. rgn& = CreateRoundRectRgn(30, 30, 650, 650, 240, 240)
47.  
48. 'you can try these also...
49. 'rgn& = CreateEllipticRgn(30, 30, 650, 650)
50. 'rgn& = CreateRectRgn(30, 30, 650, 650)
51.  
52. 'Set the created region...
53. try& = SetWindowRgn(hwnd&, rgn&, 0)
54. 'Returns zero if failed...
55. IF try& = 0 THEN
56.     PRINT "Failed...": END
57. END IF
58.  
59. 'Setup screen....
60. SCREEN _NEWIMAGE(680, 680, 32)
61. FOR y = 1 TO 680
62.     LINE (0, y)-(680, y), _RGB(c, c, 64), BF
63.     c = c + 1: IF c > 32 THEN c = 0
64. NEXT
65.  
66. 'Draw a top highlighted bar
67. LINE (0, 0)-(680, 80), _RGB(64, 64, 196), BF
68. 'draw minimize and exit image
69. _PUTIMAGE (500, 30), controls&
70.  
71. DO
72.  
73.     p = _MOUSEINPUT
74.     mx = _MOUSEX: my = _MOUSEY
75.  
76.     'LOCATE 12, 12: PRINT mx, my; _MOUSEBUTTON(1); 'testing info
77.  
78.     IF _MOUSEBUTTON(1) AND mx < 500 AND mx > 0 AND my < 80 AND mx > 0 THEN
79.  
80.         'get orig mouse x/y using api
81.         tmp = GetCursorPos(apixy)
82.         origx = apixy.x: origy = apixy.y
83.  
84.         DO
85.             p = _MOUSEINPUT: IF _MOUSEBUTTON(1) = 0 THEN EXIT DO
86.  
87.             'poll mouse x/y
88.             tmp = GetCursorPos(apixy)
89.             mx = apixy.x: my = apixy.y
90.  
91.             _SCREENMOVE _SCREENX - (origx - mx), _SCREENY + (my - origy)
92.  
93.             origx = mx: origy = my
94.  
95.         LOOP
96.  
97.  
98.     END IF
99.  
100.     'see if user clicked minimized area
101.     IF _MOUSEBUTTON(1) AND mx > 500 AND mx < 540 AND my > 29 AND my < 66 THEN
102.         'wait until button up to continue
103.         DO: p = _MOUSEINPUT
104.             IF _MOUSEBUTTON(1) = 0 THEN EXIT DO
105.         LOOP
106.         'minimize program
107.         _SCREENICON
108.     END IF
109.  
110.     'see if user clicked exit area
111.     IF _MOUSEBUTTON(1) AND mx > 540 AND mx < 580 AND my > 29 AND my < 66 THEN
112.         IF _MOUSEBUTTON(1) = -1 THEN
113.             SYSTEM
114.         END IF
115.     END IF
116.  
117. LOOP UNTIL INKEY$ = CHR$(27)
118. SYSTEM
119.  
120.  
121. 'This function creates the control image.
122. 'It was made with my BASIMAGE.BAS program .
123. FUNCTION BASIMAGE1& 'controls.png
124.     v& = _NEWIMAGE(80, 40, 32)
125.     DIM m AS _MEM: m = _MEMIMAGE(v&)
126.     A$ = ""
127.     A$ = A$ + "haIkH_oCCM5007_l#P28JF6a`HbL3iIKY?hEO#aOHKJ04W^9ciLDX::aXbn1"
128.     A$ = A$ + "U]iFfD7?4#4T7jLZK4#A5:<L;Z0^T]Q#L6aU\HbRVmO04PO081n]c>WcUc]g"
129.     A$ = A$ + "KkmNJ[m2SOhfT?inXWk]GnN_]gFZ\b:1E:c_=a4C\ZbZaS9Q>6UkWde_7jhF"
130.     A$ = A$ + ";K6]_KcJ\nkQW7=P3<Jm[S^nC#Gmn_[J8g?Y_OS?hmHmdQ^_X6Oh11oUGjY?"
131.     A$ = A$ + "H8_6]nM^cokP6Jk5B\WcZ^Fn7<W[k5PVJML#c]lTUlH\jKL4<Qjg8>jU1lJT"
132.     A$ = A$ + "7fW3`HoDo2Jd1hk9go^^Qki2JhNNQFoZj\o6XV6O^?[ZU9bmCjkg#Mn3l<LG"
133.     A$ = A$ + "o8[1i0]l#G_3NN#gM2ne^_QXnSNkaYnjU5nlEo>`W_Xe__lD33nZ_mI2:_]F"
134.     A$ = A$ + "6VVg<FgPFo9[jI<>mOc>?]aCfVR?d8RB^OBOoLdJCHmeFcH3LYFMjb]cj>Oo"
135.     A$ = A$ + "5an5>^37olE^T7=P0Xe_SDAoPSNRa54i_MQNPFoF\F<6J\TiY=N4J]C\nMmj"
136.     A$ = A$ + "ZQA3e2^Ame2^McWSE?GXAFT>c5Yi8>Jo2\j71fOG9di3Jm[db^9hPOjS5T5C"
137.     A$ = A$ + "k5cC=Q<6JSS\_Tkg:Oo^fIn6\>Zn<HMMfZahfET^K\>\KeD32B\^;DkkUC_Y"
138.     A$ = A$ + "e?Kf_9h07kADIfh79JK8mQfcI4^mNZKbmKi_OT6BjWKM4Rd#aJY_d#YZOLK8"
139.     A$ = A$ + "]FiJg#<UUgg>ajGKOfaIenWO2`E?mGcS[GOBdI]EaX^Za`m^nJhQL];g[O9M"
140.     A$ = A$ + "WdI?e_R?lX2ZTb7SW\Q]01eU5GLAAQ_V;cmPi;]C^O;?mcVY\LbRA#9iH2cF"
141.     A$ = A$ + ">VaC;eZI6iV3`N^F0fgREFUo^_=?79_]QMhlg6XR]W??7]`l17K75h6Jm;^="
142.     A$ = A$ + "o5PgBK7n4=Yad`iWONgPOO;liO3eGSQV[jLNXXC]5ZTkWdg_DEX0C=B0:0J2"
143.     A$ = A$ + ":0FY5LPlXM=1aCJQ4<;MQ52;m:35H8l`0Y7QB<3[=LNB?Z805THlPMZ:IZmC"
144.     A$ = A$ + "QRg3X8ZFm9a]Yg7gYiVK>gPFOLKJG`aeRh2Z1A9DoD_DkD1UbBCE]D;E50cD"
145.     A$ = A$ + "Nc783JmEcBhfG^=6eGmAbdEjm[#PR`Jf[4C\5RQJd\c>[X#?ojOUg1SF[Tkg"
146.     A$ = A$ + ":Co8_oUd=bba7IX2noZ`OT`jS4c0\QXgOSJXDd?Bg#VIVIl8bHme6:g?Y_OZ"
147.     A$ = A$ + "hd>ETkS0i]OGNOi1ihf0WkahakOXllDAJgdC?]PldcQfNNkCoXOYjBoFHQ5T"
148.     A$ = A$ + "DTnY3nIQYkEmKWRNOBdmAA#k_YVJ:g#N]8SQfh8k;5AdTLoFQk7K_LU7^?f;"
149.     A$ = A$ + "3bO7I0kFFA6>8ce6Q7jg^015Mc2R\_VLb9M3ncJCX8<dHS?aR`X=NT0OEin]"
150.     A$ = A$ + "Bg?]`FaU^PHT#D:UlkoJ=ihafj6S1\KE91n#=Y#]O[K3E0D^aV4DBYl1H2mj"
151.     A$ = A$ + "PF?kHS]AWKCbkFha3G?BX`aj[m;k`F3F61706IIS:3Q_823c4lkLPH6nMOck"
152.     A$ = A$ + "eSQWRP=1I?`^`e7[C=HOje`cWT^F#aIXSJoN]=OL#\jn>ob6Dg6?AcMN?lkM"
153.     A$ = A$ + "mVOo[Lol_nI?3mHFP=97XmVJB<DW2HO#fdZ6[HMJhaVnd0UH#;;K`FDBVja8"
154.     A$ = A$ + "kcBcb0?fc>MFU2]OCIB]OYJhTPD\NIOFRFJGdeWXi;b:NS]`KI?A^OBOo>XU"
155.     A$ = A$ + "\UL70f5GGGIXYiH4k#8F=1:?GcDkGfF?5HkkoNnU2]OGNcSD`;9QjgZ9[6?V"
156.     A$ = A$ + "4jHD^OBCoT9ko3o7Ml:S%%%0"
157.     btemp$ = ""
158.     FOR i& = 1 TO LEN(A$) STEP 4: B$ = MID$(A$, i&, 4)
159.         IF INSTR(1, B$, "%") THEN
160.             FOR C% = 1 TO LEN(B$): F$ = MID$(B$, C%, 1)
161.                 IF F$ <> "%" THEN C$ = C$ + F$
162.             NEXT: B$ = C$: END IF: FOR j = 1 TO LEN(B$)
163.             IF MID$(B$, j, 1) = "#" THEN
164.         MID$(B$, j) = "@": END IF: NEXT
165.         FOR t% = LEN(B$) TO 1 STEP -1
166.             B& = B& * 64 + ASC(MID$(B$, t%)) - 48
167.             NEXT: X$ = "": FOR t% = 1 TO LEN(B$) - 1
168.             X$ = X$ + CHR$(B& AND 255): B& = B& \ 256
169.     NEXT: btemp$ = btemp$ + X$: NEXT
170.     btemp$ = _INFLATE$(btemp$)
171.     _MEMPUT m, m.OFFSET, btemp$: _MEMFREE m
172.     BASIMAGE1& = _COPYIMAGE(v&): _FREEIMAGE v&
173. END FUNCTION
174.  

 

[Dav]

Fixed code in last post, removed unnecessary computations for screen moving.

- Dav