Pandemic simulation (simple particle system)

[FellippeHeitor]

A simple particle system written in QB64, which can serve of basis for cloning the video seen on https://www.reddit.com/r/dataisbeautiful/comments/hpigft/oc_simple_pandemic_simulation/?utm_source=share&utm_medium=ios_app&utm_name=iossmf

The code written in this video:

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(800, 600, 32)
2.  
3. RANDOMIZE TIMER
4.  
5. TYPE object
6.     x AS SINGLE
7.     y AS SINGLE
8.     xv AS SINGLE
9.     yv AS SINGLE
10.     state AS _BYTE
11.     size AS INTEGER
12. END TYPE
13.  
14. DIM SHARED o(500) AS object
15.  
16. 'generate individuals
17. FOR i = 1 TO UBOUND(o)
18.     o(i).x = RND * _WIDTH
19.     o(i).y = RND * _HEIGHT
20.     o(i).xv = 1 - RND * 2
21.     o(i).yv = 1 - RND * 2
22.     o(i).state = 1 'healthy
23.     o(i).size = 10
24. NEXT
25.  
26. infected = _CEIL(RND * UBOUND(o))
27. o(infected).state = 2 'infected
28.  
29. DIM c(1 TO 2) AS _UNSIGNED LONG
30. c(1) = _RGB32(11, 255, 0)
31. c(2) = _RGB32(200, 67, 17)
32.  
33. DO
34.     CLS
35.     FOR i = 1 TO UBOUND(o)
36.         move o(i)
37.         IF o(i).state = 2 THEN spread o(i)
38.         CircleFill o(i).x, o(i).y, o(i).size, c(o(i).state)
39.     NEXT
40.  
41.     _DISPLAY
42.     _LIMIT 120
43. LOOP
44. SYSTEM
45.  
46. SUB spread (obj AS object)
47.     FOR i = 1 TO UBOUND(o)
48.         IF dist(obj, o(i)) < obj.size * 2 THEN
49.             o(i).state = 2
50.         END IF
51.     NEXT
52. END SUB
53.  
54. FUNCTION dist! (o1 AS object, o2 AS object)
55.     x1! = o1.x
56.     y1! = o1.y
57.     x2! = o2.x
58.     y2! = o2.y
59.     dist! = _HYPOT((x2! - x1!), (y2! - y1!))
60. END FUNCTION
61.  
62. SUB move (obj AS object)
63.     obj.x = obj.x + obj.xv
64.     IF obj.x < 0 OR obj.x > _WIDTH THEN obj.xv = obj.xv * -1
65.  
66.     obj.y = obj.y + obj.yv
67.     IF obj.y < 0 OR obj.y > _HEIGHT THEN obj.yv = obj.yv * -1
68. END SUB
69.  
70. SUB CircleFill (CX AS INTEGER, CY AS INTEGER, R AS INTEGER, C AS _UNSIGNED LONG)
71.     ' CX = center x coordinate
72.     ' CY = center y coordinate
73.     '  R = radius
74.     '  C = fill color
75.     DIM Radius AS INTEGER, RadiusError AS INTEGER
76.     DIM X AS INTEGER, Y AS INTEGER
77.     Radius = ABS(R)
78.     RadiusError = -Radius
79.     X = Radius
80.     Y = 0
81.     IF Radius = 0 THEN PSET (CX, CY), C: EXIT SUB
82.     LINE (CX - X, CY)-(CX + X, CY), C, BF
83.     WHILE X > Y
84.         RadiusError = RadiusError + Y * 2 + 1
85.         IF RadiusError >= 0 THEN
86.             IF X <> Y + 1 THEN
87.                 LINE (CX - Y, CY - X)-(CX + Y, CY - X), C, BF
88.                 LINE (CX - Y, CY + X)-(CX + Y, CY + X), C, BF
89.             END IF
90.             X = X - 1
91.             RadiusError = RadiusError - X * 2
92.         END IF
93.         Y = Y + 1
94.         LINE (CX - X, CY - Y)-(CX + X, CY - Y), C, BF
95.         LINE (CX - X, CY + Y)-(CX + X, CY + Y), C, BF
96.     WEND
97. END SUB
98.  

Loudar's mods here in our forum: https://www.qb64.org/forum/index.php?topic=2827.msg120934#msg120934

[bplus]

Pretty much same as particle system used in this Game Exercise:
https://www.qb64.org/forum/index.php?topic=2812.msg120831#msg120831

[FellippeHeitor]

True!

[Kiara87]

True!

thank you friend it can be a great exercise

[johnno56]

Cool... Reminded me of the old "Forest Fire" simulator. Nice job!

[FellippeHeitor]

Thanks @Kiara87 and @johnno56

[bplus]

Hi all, I fixed the spread so that it does not slow down as more cells get infected, I changed a couple other minor things.

Press space bar to rerun the sim with new setup.

Code: QB64: [Select]

1. _TITLE "Pandemic Sim & Particles Demo" 'b+ mod Fellippe's  2020-07-23
2. ' ref 2020-07-22   https://www.qb64.org/forum/index.php?topic=2839.msg121033#msg121033
3.  
4. SCREEN _NEWIMAGE(800, 600, 32) ' create a graphics screen
5. _DELAY .25 '                     give time for screen to load
6. _SCREENMOVE _MIDDLE '            before moving it
7. RANDOMIZE TIMER '                for different results each run
8.  
9. CONST objSize = 5 'the size of all our objects is constant
10.  
11. TYPE object
12.     x AS SINGLE '         screen location x coordinate
13.     y AS SINGLE '         screen location y coordinate
14.     xv AS SINGLE '        velocity parallel to x axis, this is the x component of the movement vector
15.     yv AS SINGLE '        velocity parallel to y axis, this is the y component of the movement vector
16.     state AS _BYTE '      healthy = 1, infected = 2
17. END TYPE
18.  
19. DIM SHARED o(200) AS object
20.  
21. DIM SHARED c(1 TO 2) AS _UNSIGNED LONG ' colors for healthy cell 1 and infected cell 2
22. c(1) = _RGB32(11, 255, 0)
23. c(2) = _RGB32(200, 67, 17)
24.  
25. restart:
26. generate
27. infected = _CEIL(RND * UBOUND(o)) '   pick a random cell  use _CEIL to round up, don't want 0 infected
28. o(infected).state = 2 '               infect it
29. DO
30.     IF INKEY$ = " " THEN GOTO restart
31.     CLS
32.     move
33.     spread
34.     show
35.     _DISPLAY
36.     _LIMIT 120
37. LOOP
38. SYSTEM
39.  
40. SUB generate 'individuals
41.     FOR i = 1 TO UBOUND(o)
42.         o(i).x = RND * _WIDTH
43.         o(i).y = RND * _HEIGHT
44.         o(i).xv = 1 - RND * 2
45.         o(i).yv = 1 - RND * 2
46.         o(i).state = 1 'healthy
47.     NEXT
48. END SUB
49.  
50. SUB move
51.     FOR i = 1 TO UBOUND(o) ' i = 1 to TO UBOUND(o)
52.         o(i).x = o(i).x + o(i).xv
53.         IF o(i).x < 0 OR o(i).x > _WIDTH THEN o(i).xv = o(i).xv * -1 ' change direction when out of bounds
54.         o(i).y = o(i).y + o(i).yv
55.         IF o(i).y < 0 OR o(i).y > _HEIGHT THEN o(i).yv = o(i).yv * -1 ' change direction when out of bounds
56.     NEXT
57. END SUB
58.  
59. SUB spread
60.     FOR i = 1 TO UBOUND(o) - 1 ' compare every cell to every other if too close and infected then all around are
61.         FOR j = i + 1 TO UBOUND(o)
62.             IF _HYPOT(o(j).x - o(i).x, o(j).y - o(i).y) < objSize * 2 THEN 'check distance 2 cells touching
63.                 IF o(i).state = 2 OR o(j).state = 2 THEN o(i).state = 2: o(j).state = 2 ' set both to infected
64.                 ' note: just setting both states to infected is faster than ckecking and changing only the healthy
65.             END IF
66.         NEXT
67.     NEXT
68. END SUB
69.  
70. SUB show
71.     FOR i = 1 TO UBOUND(o)
72.         FOR r = 0 TO objSize STEP .25 'Ken's way to circle fill without extra subroutine
73.             CIRCLE (o(i).x, o(i).y), r, c(o(i).state)
74.         NEXT
75.     NEXT
76. END SUB
77.  
78.  

Funny story, I watched Fellippe's video yesterday around lunch time, looked in here a couple of times but spent most of day reading. I went to bed and as soon as I started to relax it hit me how easy it was to fix the slow down as cells got infected.

[FellippeHeitor]

That's cool, bplus! Thanks for the new ideas ;-)

About the late-night eureka moment, I can identify!

  [ You are not allowed to view this attachment ]  

[johnno56]

Aww... Now you guys are just showing off... We mortals have to be content with trying to problem solve whilst we are still out of bed... *sigh*

[SMcNeill]

Aww... Now you guys are just showing off... We mortals have to be content with trying to problem solve whilst we are still out of bed... *sigh*

Whereas we Steve’s simply are too good to have any problems to begin with...   ;D

[OldMoses]

This was so intriguing that I decided to play around with it myself, adding immunity, random population health, strain virulence, turns to death and turns required to achieve immunity before death. All such parameters are just pulled out of my tinfoil hat.

EDIT: Oops back to the drawing board on that one. It will end up with more dead than it started with....LOL

It must be the blue zombie virus...

Code: QB64: [Select]

1. _TITLE "Pandemic Sim & Particles Demo" 'OldMoses' mod of b+ mod Fellippe's  2020-07-23
2. ' ref 2020-07-22   https://www.qb64.org/forum/index.php?topic=2839.msg121033#msg121033
3.  
4. SCREEN _NEWIMAGE(800, 600, 32) ' create a graphics screen
5. _DELAY .25 '                     give time for screen to load
6. _SCREENMOVE _MIDDLE '            before moving it
7. RANDOMIZE TIMER '                for different results each run
8.  
9. CONST objSize = 5 'the size of all our objects is constant
10.  
11. TYPE object
12.     x AS SINGLE '         screen location x coordinate
13.     y AS SINGLE '         screen location y coordinate
14.     xv AS SINGLE '        velocity parallel to x axis, this is the x component of the movement vector
15.     yv AS SINGLE '        velocity parallel to y axis, this is the y component of the movement vector
16.     state AS _BYTE '      healthy = 1, infected = 2, 3 = immune
17.     health AS _BYTE
18.     sick AS _BYTE
19.     dead AS _BYTE
20. END TYPE
21.  
22. DIM SHARED o(200) AS object
23.  
24. DIM SHARED c(1 TO 3) AS _UNSIGNED LONG ' colors for healthy cell 1 and infected cell 2
25. c(1) = _RGB32(11, 255, 0)
26. c(2) = _RGB32(200, 67, 17)
27. c(3) = _RGB32(11, 67, 200)
28.  
29. restart:
30. generate
31. infected = _CEIL(RND * UBOUND(o)) '   pick a random cell  use _CEIL to round up, don't want 0 infected
32. o(infected).state = 2 '               infect it
33. DO
34.     IF INKEY$ = " " THEN GOTO restart
35.     CLS
36.     move
37.     spread
38.     show
39.     _DISPLAY
40.     _LIMIT 120
41. LOOP
42. SYSTEM
43.  
44. SUB generate 'individuals
45.     FOR i = 1 TO UBOUND(o)
46.         o(i).x = RND * _WIDTH
47.         o(i).y = RND * _HEIGHT
48.         o(i).xv = 1 - RND * 2
49.         o(i).yv = 1 - RND * 2
50.         o(i).state = 1 'healthy
51.         o(i).health = INT(RND * 90) + 10
52.         o(i).sick = 0
53.         o(i).dead = 3
54.     NEXT
55. END SUB
56.  
57. SUB move
58.     FOR i = 1 TO UBOUND(o) ' i = 1 to TO UBOUND(o)
59.         o(i).x = o(i).x + o(i).xv
60.         IF o(i).x < 0 OR o(i).x > _WIDTH THEN o(i).xv = o(i).xv * -1 ' change direction when out of bounds
61.         o(i).y = o(i).y + o(i).yv
62.         IF o(i).y < 0 OR o(i).y > _HEIGHT THEN o(i).yv = o(i).yv * -1 ' change direction when out of bounds
63.         IF o(i).state = 2 THEN
64.             virulence% = 90 ' INT(RND * 90) + 1
65.             o(i).health = o(i).health - virulence%
66.             IF virulence% > o(i).health THEN o(i).dead = o(i).dead - 1
67.             o(i).sick = o(i).sick + 1
68.             IF o(i).sick > 10 AND o(i).dead > 0 THEN
69.                 o(i).state = 3
70.             END IF
71.         END IF
72.     NEXT
73. END SUB
74.  
75. SUB spread
76.     FOR i = 1 TO UBOUND(o) - 1 ' compare every cell to every other if too close and infected then all around are
77.         FOR j = i + 1 TO UBOUND(o)
78.             IF _HYPOT(o(j).x - o(i).x, o(j).y - o(i).y) < objSize * 2 THEN 'check distance 2 cells touching
79.                 IF o(i).state <> 3 OR o(j).state <> 3 THEN
80.                     IF o(i).state = 2 OR o(j).state = 2 THEN o(i).state = 2: o(j).state = 2 ' set both to infected
81.                     ' note: just setting both states to infected is faster than ckecking and changing only the healthy
82.                 END IF
83.             END IF
84.         NEXT
85.     NEXT
86. END SUB
87.  
88. SUB show
89.     FOR i = 1 TO UBOUND(o)
90.         IF o(i).dead > 0 THEN
91.             FOR r = 0 TO objSize STEP .25 'Ken's way to circle fill without extra subroutine
92.                 CIRCLE (o(i).x, o(i).y), r, c(o(i).state)
93.             NEXT
94.         END IF
95.     NEXT
96. END SUB
97.  
98.  
99.  

[FellippeHeitor]

Lol @ blue zombie virus. Thanks for your contribution, OldMoses!

[TempodiBasic]

That's cool, bplus! Thanks for the new ideas ;-)

About the late-night eureka moment, I can identify!

  [ You are not allowed to view this attachment ]

LOL
it is an our little trueness... when we put in the oven the problem it will be cooked!

[Dav]

I like your video tutorials Fellippe.  You present them well.  Have you done one on using the QB64 IDE?  Changing settings, etc.  I think it would be a good introduction and help for new QB64 users.

Nice job on the simulator.

- Dav

[FellippeHeitor]

That'd be a good idea indeed, Dav. Thank you very much!