Author Topic: Opening files (Read 8302 times)

Jon Richfield · « **on:** June 08, 2020, 02:56:06 am »

Suppose I wish to process a file in a QB64 program. Of course I can read in the file name and path from the keyboard; however, often one wants to click on a file in a directory display and open the file with the program in question.
Can anyone please direct me to instructions for how to do that sort of thing.

Thanks for any suggestions.

codeguy · « **Reply #1 on:** June 08, 2020, 05:16:59 am »

You've got to use COMMAND$

https://www.qb64.org/wiki/COMMAND$

Petr · « **Reply #2 on:** June 08, 2020, 10:21:39 am »

Or do you mean a way to display a list of files and directories in QB64, select a file in that list and run some action, all in QB64? This can also be done with QB64.

You can either call a window from Windows via a library declaration to select a file, or you can write the whole thing and use DIRENTRY.H from Steve to list files and directories.

https://www.qb64.org/forum/index.php?topic=321.msg2126#msg2126

Jon Richfield · « **Reply #3 on:** June 10, 2020, 12:16:12 pm »

Thanks Petr and Codeguy. I'll have to go into this to see what best applies to my requirements.

bplus · « **Reply #4 on:** June 10, 2020, 01:30:29 pm »

If you have Windows and don't want to worry about Linux or Mac users (ie doing a cross platform app) there are easier ways.

Code: QB64: [Select]

OPTION _EXPLICIT
_TITLE "Tiny Navigator: press f to window and select a file" 'B+ started 2019-08-22
SCREEN _NEWIMAGE(1000, 600, 32)
_SCREENMOVE 100, 50
' 2019-08-22 orig post at https://www.qb64.org/forum/index.php?topic=1646.msg108682#msg108682
' 2019-08-23_13-25 try fix (to nav all directories) with one place for tmpFile, theory can't write files in some dir's
' For some reason Windows won't write to a fully pathed file in my user folder???from a SHELL command
' Try testing if dir exists "C:\temp" exists and making one if not, yes! and I can write my temp files there
' and now I can chDir anywhere!!!!
' 2019-08-23_14-25 Take Steve's Advice to use users tmp directory for temp files
' 2019-08-23_23+ Have files window working for file selection
 
DIM SHARED selectedFile AS STRING
DIM SHARED tmpDir AS STRING '  establish a permanent spot for temp files
IF ENVIRON$("TEMP") <> "" THEN 'Thanks to Steve McNeill use user temp files directory
    tmpDir = ENVIRON$("TEMP")
ELSEIF ENVIRON$("TMP") <> "" THEN
    tmpDir = ENVIRON$("TMP")
ELSE 'Thanks to Steve McNeill this should be very unlikely
    IF _DIREXISTS("C:\temp") THEN ELSE MKDIR "C:\temp"
    tmpDir = "C:\temp"
END IF
 
DIM mySelection&, done$, i, t$
DO
    COLOR _RGB32(180, 180, 255)
    CLS
    t$ = "Current Directory: " + _CWD$
    LOCATE 2, (_WIDTH / 8 - LEN(t$)) / 2: PRINT t$
    REDIM DIRs(0) AS STRING
    loadDIR DIRs()
    REDIM FILs(0) AS STRING
    loadFiles FILs()
    FOR i = 0 TO UBOUND(FILs)
        IF i < 30 THEN LOCATE i + 4, 60: PRINT FILs(i) ELSE EXIT FOR
    NEXT
    mySelection& = getArrayItemNumber&(5, 5, 50, 30, DIRs())
    CLS
    IF selectedFile <> "" THEN
        PRINT "You selected a file: "; selectedFile
        INPUT "Press enter to continue navigator, any + enter to quit... "; done$
        selectedFile = ""
    ELSEIF mySelection& <> -1719 THEN
        CHDIR DIRs(mySelection&)
    ELSE
        PRINT "Nothing selected."
        INPUT "Press enter to continue navigator, any + enter to quit... "; done$
    END IF
    _LIMIT 60
LOOP UNTIL done$ <> ""
 
SUB loadDIR (fa() AS STRING)
    DIM tmpFile AS STRING, Index%, fline$, d$
    tmpFile = tmpDir + "\DIR$INF0.INF" 'aha!, not a fully pathed file to user directory but here is good!
    SHELL _HIDE "DIR /a:d >" + tmpFile 'get directories  but have to do a little pruning
    OPEN tmpFile FOR INPUT AS #1
    Index% = -1
    DO WHILE NOT EOF(1)
        LINE INPUT #1, fline$
        IF INSTR(fline$, "<DIR>") THEN
            d$ = _TRIM$(rightOf$(fline$, "<DIR>"))
            Index% = Index% + 1
            REDIM _PRESERVE fa(Index%)
            fa(Index%) = d$
        END IF
    LOOP
    CLOSE #1
    KILL tmpFile
END SUB
 
SUB loadFiles (fa() AS STRING)
    DIM tmpFile AS STRING, Index%
    tmpFile = tmpDir + "\FILE$INF0.INF" 'aha!, not a fully pathed file to user directory but here is good!
    SHELL _HIDE "DIR *.* /a:-d /b /o:-gen > " + tmpFile
    OPEN tmpFile$ FOR INPUT AS #1
    Index% = -1
    DO WHILE NOT EOF(1)
        Index% = Index% + 1
        REDIM _PRESERVE fa(Index%) AS STRING
        LINE INPUT #1, fa(Index%)
    LOOP
    CLOSE #1
    KILL tmpFile$
END SUB
 
FUNCTION rightOf$ (source$, of$)
    IF INSTR(source$, of$) > 0 THEN rightOf$ = MID$(source$, INSTR(source$, of$) + LEN(of$))
END FUNCTION
 
' "Escape returns -1719 to allow a Cancel function and signal no slection."
FUNCTION getArrayItemNumber& (locateRow, locateColumn, boxWidth, boxHeight, arr() AS STRING)
    'Notes: locateRow, locateColumn for top right corner of selection box on screen in characters for LOCATE.
    'boxWidth and boxHeight are in character units, again for locate and print at correct places.
    'All displaying is restricted to inside the box, which has PgUP and PgDn as top and bottom lines in the display.
 
    DIM curRow AS INTEGER, curCol AS INTEGER, fg AS _UNSIGNED LONG, bg AS _UNSIGNED LONG
    DIM maxWidth AS INTEGER, maxHeight AS INTEGER, page AS INTEGER, hlite AS INTEGER, mx AS INTEGER, my AS INTEGER
    DIM lastMX AS INTEGER, lastMY AS INTEGER, row AS INTEGER, mb AS INTEGER
    DIM lba AS LONG, uba AS LONG, choice AS LONG, kh AS LONG, index AS LONG
    DIM clrStr AS STRING, b AS STRING, selNum&
 
    'save old settings to restore at end ofsub
    curRow = CSRLIN
    curCol = POS(0)
    fg = _DEFAULTCOLOR
    bg = _BACKGROUNDCOLOR
    _KEYCLEAR
 
    maxWidth = boxWidth '       number of characters in box
    maxHeight = boxHeight - 2 ' number of lines displayed of array at one time = 1 page
    lba = LBOUND(arr)
    uba = UBOUND(arr)
    page = 0
    hlite = 0 '                 line in display ready for selection by spacebar or if no number is started, enter
    clrStr$ = SPACE$(maxWidth) 'clearing a display line
 
    GOSUB update '              show the beginning of the array items for selection
 
    'signal cancel selection process, exit sub with this unlikely index to signal canel
    choice = -1719 'primes 7 and 8, not likely to be a select index of an array
 
    DO 'until get a selection or demand exit
 
        'handle the key stuff
        kh& = _KEYHIT
        IF kh& THEN
            IF kh& > 0 AND kh& < 255 THEN
                IF INSTR("0123456789", CHR$(kh&)) > 0 THEN b$ = b$ + CHR$(kh&): GOSUB update
                IF CHR$(kh&) = "f" THEN
                    REDIM FILs(0) AS STRING
                    loadFiles FILs()
                    selNum& = getArrayItemNumber&(5, 60, 60, 30, FILs())
                    COLOR _RGB32(180, 180, 255)
                    CLS 'need to signal out of file selection
                    IF selNum& >= LBOUND(FILs) AND selNum& <= UBOUND(FILs) THEN selectedFile = FILs(selNum&)
                    EXIT DO
                    'back to directory select
                END IF
 
                IF CHR$(kh&) = "c" THEN b$ = "": GOSUB update
                IF kh& = 13 THEN 'enter pressed check if number is being entered?
                    IF LEN(b$) THEN
                        IF VAL(b$) >= lba AND VAL(b$) <= uba THEN 'we have number started
                            choice = VAL(b$): EXIT DO
                        ELSE 'clear b$ to show some response to enter
                            b$ = "": GOSUB update 'clear the value that doesn't work
                        END IF
                    ELSE
                        choice = hlite + page * maxHeight + lba 'must mean to select the highlighted item
                    END IF
                END IF
                IF kh& = 27 THEN EXIT DO 'escape clause offered to Cancel selection process
                IF kh& = 32 THEN choice = hlite + page * maxHeight + lba 'best way to choose highlighted selection
                IF kh& = 8 THEN 'backspace to edit number
                    IF LEN(b$) THEN b$ = LEFT$(b$, LEN(b$) - 1): GOSUB update
                END IF
            ELSE
                SELECT CASE kh& 'choosing sections of array to display and highlighted item
                    CASE 20736 'pg dn
                        IF (page + 1) * maxHeight + lba <= uba THEN page = page + 1: GOSUB update
                    CASE 18688 'pg up
                        IF (page - 1) * maxHeight + lba >= lba THEN page = page - 1: GOSUB update
                    CASE 18432 'up
                        IF hlite - 1 < 0 THEN
                            IF page > 0 THEN
                                page = page - 1: hlite = maxHeight - 1: GOSUB update
                            END IF
                        ELSE
                            hlite = hlite - 1: GOSUB update
                        END IF
                    CASE 20480 'down
                        IF (hlite + 1) + page * maxHeight + lba <= uba THEN 'ok to move up
                            IF hlite + 1 > maxHeight - 1 THEN
                                page = page + 1: hlite = 0: GOSUB update
                            ELSE
                                hlite = hlite + 1: GOSUB update
                            END IF
                        END IF
                    CASE 18176 'home
                        page = 0: hlite = 0: GOSUB update
                    CASE 20224 ' end
                        page = INT((uba - lba) / maxHeight): hlite = maxHeight - 1: GOSUB update
                END SELECT
            END IF
        END IF
 
        'handle the mouse stuff
        WHILE _MOUSEINPUT
            IF _MOUSEWHEEL = -1 THEN 'up?
                IF hlite - 1 < 0 THEN
                    IF page > 0 THEN
                        page = page - 1: hlite = maxHeight - 1: GOSUB update
                    END IF
                ELSE
                    hlite = hlite - 1: GOSUB update
                END IF
            ELSEIF _MOUSEWHEEL = 1 THEN 'down?
                IF (hlite + 1) + page * maxHeight + lba <= uba THEN 'ok to move up
                    IF hlite + 1 > maxHeight - 1 THEN
                        page = page + 1: hlite = 0: GOSUB update
                    ELSE
                        hlite = hlite + 1: GOSUB update
                    END IF
                END IF
            END IF
        WEND
        mx = INT((_MOUSEX - locateColumn * 8) / 8) + 2: my = INT((_MOUSEY - locateRow * 16) / 16) + 2
        IF _MOUSEBUTTON(1) THEN 'click contols or select array item
            'clear mouse clicks
            mb = _MOUSEBUTTON(1)
            IF mb THEN 'clear it
                WHILE mb 'OK!
                    IF _MOUSEINPUT THEN mb = _MOUSEBUTTON(1)
                    _LIMIT 100
                WEND
            END IF
 
            IF mx >= 1 AND mx <= maxWidth AND my >= 1 AND my <= maxHeight THEN
                choice = my + page * maxHeight + lba - 1 'select item clicked
            ELSEIF mx >= 1 AND mx <= maxWidth AND my = 0 THEN 'page up or exit
                IF my = 0 AND (mx <= maxWidth AND mx >= maxWidth - 2) THEN 'exit sign
                    EXIT DO 'escape plan for mouse click top right corner of display box
                ELSE 'PgUp bar clicked
                    IF (page - 1) * maxHeight + lba >= lba THEN page = page - 1: GOSUB update
                END IF
            ELSEIF mx >= 1 AND mx <= maxWidth AND my = maxHeight + 1 THEN 'page down bar clicked
                IF (page + 1) * maxHeight + lba <= uba THEN page = page + 1: GOSUB update
            END IF
        ELSE '   mouse over highlighting, only if mouse has moved!
            IF mx >= 1 AND mx <= maxWidth AND my >= 1 AND my <= maxHeight THEN
                IF mx <> lastMX OR my <> lastMY THEN
                    IF my - 1 <> hlite AND (my - 1 + page * maxHeight + lba <= uba) THEN
                        hlite = my - 1
                        lastMX = mx: lastMY = my
                        GOSUB update
                    END IF
                END IF
            END IF
        END IF
        _LIMIT 200
    LOOP UNTIL choice >= lba AND choice <= uba
    getArrayItemNumber& = choice
    COLOR fg, bg
    'clear key presses
    _KEYCLEAR
    LOCATE curRow, curCol
    'clear mouse clicks
    mb = _MOUSEBUTTON(1)
    IF mb THEN 'clear it
        WHILE mb 'OK!
            IF _MOUSEINPUT THEN mb = _MOUSEBUTTON(1)
            _LIMIT 100
        WEND
    END IF
    EXIT SUB
 
 
    update: '--------------- display of array sections and controls on screen
 
    'fix hlite if it has dropped below last array item
    WHILE hlite + page * maxHeight + lba > uba
        hlite = hlite - 1
    WEND
 
    'main display of array items at page * maxHeight (lines high)
    FOR row = 0 TO maxHeight - 1
        IF hlite = row THEN COLOR _RGB(200, 200, 255), _RGB32(0, 0, 88) ELSE COLOR _RGB32(0, 0, 88), _RGB(200, 200, 255)
        LOCATE locateRow + row, locateColumn: PRINT clrStr$
        index = row + page * maxHeight + lba
        IF index >= lba AND index <= uba THEN
            LOCATE locateRow + row, locateColumn
            PRINT LEFT$(LTRIM$(STR$(index)) + ") " + arr(index), maxWidth)
        END IF
    NEXT
 
    'make page up and down bars to click, print PgUp / PgDn if available
    COLOR _RGB32(200, 200, 255), _RGB32(0, 100, 50)
    LOCATE locateRow - 1, locateColumn: PRINT SPACE$(maxWidth)
    IF page <> 0 THEN LOCATE locateRow - 1, locateColumn: PRINT LEFT$(" Pg Up" + SPACE$(maxWidth), maxWidth)
    LOCATE locateRow + maxHeight, locateColumn: PRINT SPACE$(maxWidth)
    IF page <> INT(uba / maxHeight) THEN
        LOCATE locateRow + maxHeight, locateColumn: PRINT LEFT$(" Pg Dn" + SPACE$(maxWidth), maxWidth)
    END IF
    'make exit sign for mouse click
    COLOR _RGB32(255, 255, 255), _RGB32(200, 100, 0)
    LOCATE locateRow - 1, locateColumn + maxWidth - 3
    PRINT " X "
 
    'if a number selection has been started show it's build = b$
    IF LEN(b$) THEN
        COLOR _RGB(255, 255, 0), _RGB32(0, 0, 0)
        LOCATE locateRow + maxHeight, locateColumn + maxWidth - LEN(b$) - 1
        PRINT b$;
    END IF
    _DISPLAY
    _LIMIT 100
    RETURN
END FUNCTION
 
 

The majority of this code is spent with selecting an item from an array, in this case an array of directories or of files when you press f. You could use simpler techniques. LoadDirs and LoadFiles are main routines for getting folders and files from current directory if I recall correctly.

Petr · « **Reply #5 on:** June 10, 2020, 03:58:00 pm »

Nicely done, BPlus.

Be careful with using DIR statement to file. Ashish and me have already found that it returns differently formatted output to a text file, depending on the system locale used. Therefore, it is better to use the Steve's library DIRENTRY.H

bplus · « **Reply #6 on:** June 10, 2020, 04:28:30 pm »

Quote from: Petr on June 10, 2020, 03:58:00 pm

Nicely done, BPlus.

Be careful with using DIR statement to file. Ashish and me have already found that it returns differently formatted output to a text file, depending on the system locale used. Therefore, it is better to use the Steve's library DIRENTRY.H

Hi @Petr,

Thanks.

Quote

... have already found that it returns differently formatted output to a text file, depending on the system locale used.

Are you guys getting file creation dates or dates of any type?

I am not getting those details with my SHELL command.

Petr · « **Reply #7 on:** June 10, 2020, 05:14:29 pm »

This was the case for obtaining file names in 8.3 and long format, and the same for directories. It was used by my player, the 8.3 format was used to access paths with unicode characters in the name.

bplus · « **Reply #8 on:** June 10, 2020, 06:26:28 pm »

Quote from: Petr on June 10, 2020, 05:14:29 pm

This was the case for obtaining file names in 8.3 and long format, and the same for directories. It was used by my player, the 8.3 format was used to access paths with unicode characters in the name.

8.3? Do you mean the old DOS 8 letters base name and 3 letters extension?

I am using *.* format ;-))

for folders

Code: QB64: [Select]

SHELL _HIDE "DIR /a:d >" + tmpFile

for files

Code: QB64: [Select]

SHELL _HIDE "DIR *.* /a:-d /b /o:-gen > " + tmpFile

Petr · « **Reply #9 on:** June 11, 2020, 11:29:07 am »

Hi again. Yes, 8.3 format. Why?

In unicode can be file name using DIR returned as: kulaœouŸk jeskynØ pln kr pn¡k….gif
This is not valid file name. So therefore is need old format for access to file.

bplus · « **Reply #10 on:** June 11, 2020, 11:41:25 am »

Quote from: Petr on June 11, 2020, 11:29:07 am

Hi again. Yes, 8.3 format. Why?

In unicode can be file name using DIR returned as: kulaœouŸk jeskynØ pln kr pn¡k….gif
This is not valid file name. So therefore is need old format for access to file.

@Petr When you say those names aren't valid, even when DIR gives you those names, that they won't work if you say in code to change directory to one of those "invalid" file names, yes?

(assuming your answer would be yes)
Man this makes me glad to be using English, English was not my favorite class is school but live long enough and everything changes, I love reading even some of the classics. Did not like Animal Farm though (just read) but I digress...

If your answer is not yes, what is the problem then? what makes you say they are invalid?

Petr · « **Reply #11 on:** June 11, 2020, 01:47:07 pm »

The problem is this (I guess I could also write it at once ...)

To get names in 8.3 format as well as names in long format I use DIR without formatting parameters. This will give me a full statement. I can display the long name correctly using MAPUNICODE, but I cannot use it for access. That's what the short name is for me.

And the thing I'm talking about all the time is that this statement has otherwise shifted columns in the statement to a file, so it can't be used internationally. Well, not directly. You must first determine the locale in which the computer is running and adjust the reading of data from the file accordingly.

I used this approach in my QB64Player program, which didn't work for Ashish, but for me, and also for people from Germany, Italy, and I think also from the United States. After analyzing why, I found that the Indian version of windows produces a DIR statement shifted by one or two characters, so a program that did not count on it then returned bad names from the file. However, if I reckoned that all file and directory names would be in English only, then I could use listings of only files and only directories and only long names, and I would not know about this problem.

Jon Richfield · « **Reply #12 on:** June 12, 2020, 02:42:24 am »

Thanks bplus,

That will take a bit of reading, but looks as though it is in the right direction.

Jon Richfield · « **Reply #13 on:** June 12, 2020, 02:45:43 am »

Quote from: bplus on June 10, 2020, 01:30:29 pm

If you have Windows and don't want to worry about Linux or Mac users (ie doing a cross platform app) there are easier ways.

.....

The majority of this code is spent with selecting an item from an array, in this case an array of directories or of files when you press f. You could use simpler techniques. LoadDirs and LoadFiles are main routines for getting folders and files from current directory if I recall correctly.

Forgive my blundering; I still haven't mastered the facilities in this forum. 😳 Everything in time 😉

jack · « **Reply #14 on:** June 12, 2020, 04:44:14 am »

@bplus
maybe you could write a file requester using GetOpenFileName (Windows)
here are some examples in C(++) https://docs.microsoft.com/en-us/windows/win32/dlgbox/using-common-dialog-boxes
I translated the open file example on that site to FB, don't how to do it in QB64, would interesting to see

News:

Author Topic: Opening files (Read 8302 times)

Jon Richfield

Opening files

codeguy

Re: Opening files

Petr

Re: Opening files

Jon Richfield

Re: Opening files

bplus

Re: Opening files

Petr

Re: Opening files

bplus

Re: Opening files

Petr

Re: Opening files

bplus

Re: Opening files

Petr

Re: Opening files

bplus

Re: Opening files

Petr

Re: Opening files

Jon Richfield

Re: Opening files

Jon Richfield

Re: Opening files

jack

Re: Opening files