ASCII Editor (2 demos included) | to be integrated into ASCII Terrain Engine

[Virtusoroca]

To be integrated into ASCII Terrain Engine (for Game Developers)
- Still rough but usable
- Provides a canvas of 100 x 50 characters/tiles
- Configure the brush with keyboard (font and back colors, size, ASCII code)
- Fill in the canvas using mouse clicks
- Left click to place tiles with no blocking property (game)
- Left click to place tiles with blocking property (game)
- Toggle between Design and Structure screens
- Load and Save CSV files (format: Xcoord, Ycoord, Fcolor, Bcolor, Block)
- 2 demos included: Haunted and Dungeon
- Unpack on QB64 rott and hit run

Code: QB64: [Select]

1. 'ÉÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ»
2. 'º ÛÛÛÛÛÛÛÛÛÛÛÛÛÛÛ      ASCII TERRAIN ENGINE     ÛÛßßÛÛ ÛÛßßÛÛ º
3. 'º ÛÛ     Û     ÛÛ        ® Editor Module ¯      ÛÛ ÞÛÛ ÛÛÛÛÛ  º
4. 'º ÛÛ  Û  Û  Û  ÛÛ  (to be integreated in v.1.3) ÛÛÜÞÛÛ ÛÛÜÜÛÛ º
5. 'º    Û  Û  Û        Still rough but usable      ßß          º
6. 'º ÛÛ  Û  Û  Û  ÛÛ          ------------         ÛÛßßßß ÛÛ  ÛÛ º
7. 'º ÛÛ  Û     Û  ÛÛ  By Virtusoroca-Brazil, 2020  ÛÛßßÛÛ ÛÛÜÜÛÛ º
8. 'º ÛÛÛÛÛÛÛÛÛÛÛÛÛÛÛ          Made in QB64         ÛÛÜÜÛÛ     ÛÛ º
9. 'ÈÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍͼ
10.  
11. SCREEN _NEWIMAGE(1000, 800, 256)
12.  
13. DIM SHARED KeyPress AS STRING
14. DIM SHARED ScreenMode AS STRING
15. DIM SHARED CurrentFontColor AS INTEGER
16. DIM SHARED CurrentBackColor AS INTEGER
17. DIM SHARED CurrentASCII AS INTEGER
18. DIM SHARED CurrentSize AS INTEGER
19. DIM SHARED FilePath AS STRING
20. DIM SHARED FileName AS STRING
21.  
22.  
23. TYPE Tiles
24.     x AS INTEGER
25.     y AS INTEGER
26.     a AS INTEGER
27.     fc AS INTEGER
28.     bc AS INTEGER
29.     s AS INTEGER
30.     b AS INTEGER
31. END TYPE
32.  
33. DIM SHARED Tile(50, 100) AS Tiles
34.  
35. CurrentFontColor = 7
36. CurrentBackColor = 0
37. CurrentASCII = 219
38. CurrentBlock = 0
39. CurrentSize = 1
40. ScreenMode = "Design"
41. FilePath = "./ATE_editor_files/"
42.  
43. LoadMapDefaut
44. PrintMapDesign
45. DO
46.     KeyPress = UCASE$(INKEY$)
47.     WHILE _MOUSEINPUT
48.         MouseX = INT(_MOUSEY / 16) + 1: MouseY = INT(_MOUSEX / 8) + 1
49.         IF MouseX < 0 THEN MouseX = 0
50.         IF MouseX > 50 THEN MouseX = 50
51.         IF MouseY < 0 THEN MouseY = 0
52.         IF MouseY > 100 THEN MouseY = 100
53.         SELECT CASE _MOUSEBUTTON(1)
54.             CASE -1
55.                 FOR A = MouseX TO MouseX + CurrentSize - 1
56.                     FOR B = MouseY TO MouseY + CurrentSize - 1
57.                         Tile(A, B).fc = CurrentFontColor
58.                         Tile(A, B).bc = CurrentBackColor
59.                         Tile(A, B).a = CurrentASCII
60.                         Tile(A, B).b = 0
61.                         LOCATE A, B: COLOR CurrentFontColor, CurrentBackColor: PRINT CHR$(CurrentASCII);
62.                     NEXT
63.                 NEXT
64.         END SELECT
65.         SELECT CASE _MOUSEBUTTON(2)
66.             CASE -1
67.                 FOR A = MouseX TO MouseX + CurrentSize - 1
68.                     FOR B = MouseY TO MouseY + CurrentSize - 1
69.                         Tile(A, B).fc = CurrentFontColor
70.                         Tile(A, B).bc = CurrentBackColor
71.                         Tile(A, B).a = CurrentASCII
72.                         Tile(A, B).b = 1
73.                         LOCATE A, B: COLOR CurrentFontColor, CurrentBackColor: PRINT CHR$(CurrentASCII);
74.                     NEXT
75.                 NEXT
76.         END SELECT
77.     WEND
78.     PrintMainMenu
79.     ProcessOptions
80. LOOP UNTIL KeyPress = "Q"
81.  
82. SUB PrintMainMenu
83.     COLOR 15, 0: LocalY = 101
84.     FOR LocalX1 = 1 TO 50: LOCATE LocalX1, LocalY: PRINT "º";: NEXT
85.     LocalX2 = 1: LocalY2 = 103
86.     COLOR 15, 0
87.     LOCATE LocalX2 + 0, LocalY2: PRINT "CURRENT STATUS"
88.     COLOR 7, 0
89.     LOCATE LocalX2 + 2, LocalY2: PRINT "ScreenMode: "; ScreenMode
90.     LOCATE LocalX2 + 3, LocalY2: PRINT "FontColor: "; CurrentFontColor
91.     LOCATE LocalX2 + 4, LocalY2: PRINT "BackColor: "; CurrentBackColor
92.     LOCATE LocalX2 + 5, LocalY2: PRINT "Character:  "; CHR$(CurrentASCII)
93.     LOCATE LocalX2 + 6, LocalY2: PRINT "BrushSize: "; CurrentSize
94.     LOCATE LocalX2 + 7, LocalY2: PRINT "Preview:    ";: COLOR CurrentFontColor, CurrentBackColor: PRINT CHR$(CurrentASCII);: COLOR 7, 0
95.     LOCATE LocalX2 + 9, LocalY2: PRINT "File: ";
96.     IF FileName = "" THEN PRINT "Not Saved" ELSE PRINT FileName
97.     LOCATE LocalX2 + 35, LocalY2: PRINT "MouseClick = PlaceTile";
98.     LOCATE LocalX2 + 36, LocalY2: PRINT "LeftClick  = no Block ";
99.     LOCATE LocalX2 + 37, LocalY2: PRINT "RightClick = w/ Block"
100.     LOCATE LocalX2 + 39, LocalY2: PRINT "A = AsciiCode";
101.     LOCATE LocalX2 + 40, LocalY2: PRINT "F = FontColor";
102.     LOCATE LocalX2 + 41, LocalY2: PRINT "B = BackColor";
103.     LOCATE LocalX2 + 42, LocalY2: PRINT "Z = BrushSize";
104.     LOCATE LocalX2 + 43, LocalY2: PRINT "D = DesignScreen";
105.     LOCATE LocalX2 + 44, LocalY2: PRINT "X = StructureScreen";
106.     LOCATE LocalX2 + 45, LocalY2: PRINT "N = NewProject";
107.     LOCATE LocalX2 + 46, LocalY2: PRINT "L = LoadFile";
108.     LOCATE LocalX2 + 47, LocalY2: PRINT "S = SaveFile";
109.     LOCATE LocalX2 + 48, LocalY2: PRINT "Q = Quit";
110. END SUB
111.  
112. SUB ProcessOptions
113.     LocalX = 13: LocalY = 103: LOCATE LocalX, LocalY: COLOR 7, 0
114.     SELECT CASE KeyPress
115.         CASE "A": INPUT "AsciiCode: ", CurrentASCII: CLS: PrintMapDesign
116.         CASE "F": INPUT "FontColor: ", CurrentFontColor: CLS: PrintMapDesign
117.         CASE "B": INPUT "BackColor: ", CurrentBackColor: CLS: PrintMapDesign
118.         CASE "Z": INPUT "BrushSize: ", CurrentSize
119.         CASE "D": ScreenMode = "Design": PrintMapDesign
120.         CASE "X": ScreenMode = "Structure": PrintMapStructure
121.         CASE "N": LoadMapDefaut
122.         CASE "S": SaveMapFile
123.         CASE "L": LoadMapFile
124.     END SELECT
125. END SUB
126.  
127. SUB PrintMapDesign
128.     CLS
129.     FOR A = 1 TO 50
130.         FOR B = 1 TO 100
131.             COLOR Tile(A, B).fc, Tile(A, B).bc
132.             LOCATE Tile(A, B).x, Tile(A, B).y
133.             PRINT CHR$(Tile(A, B).a);
134.         NEXT
135.     NEXT
136. END SUB
137.  
138. SUB PrintMapStructure
139.     CLS: COLOR 7, 0
140.     FOR A = 1 TO 50
141.         FOR B = 1 TO 100
142.             SELECT CASE Tile(A, B).b
143.                 CASE 1
144.                     LOCATE Tile(A, B).x, Tile(A, B).y
145.                     PRINT "1"
146.             END SELECT
147.         NEXT
148.     NEXT
149. END SUB
150.  
151. SUB SaveMapFile
152.     LOCATE 13, 103: COLOR 7, 0: INPUT "SaveFile: ", FileName
153.     OPEN FilePath + FileName FOR OUTPUT AS #1
154.     FOR A = 1 TO 50
155.         FOR B = 1 TO 100
156.             WRITE #1, Tile(A, B).x, Tile(A, B).y, Tile(A, B).fc, Tile(A, B).bc, Tile(A, B).a, Tile(A, B).b
157.         NEXT
158.     NEXT
159.     CLOSE #1
160.     CLS: PrintMapDesign
161. END SUB
162.  
163. SUB LoadMapFile
164.     LOCATE 13, 103: COLOR 7, 0: INPUT "LoadFile: ", FileName
165.     OPEN FilePath + FileName FOR INPUT AS #1
166.     FOR A = 1 TO 50
167.         FOR B = 1 TO 100
168.             INPUT #1, Tile(A, B).x, Tile(A, B).y, Tile(A, B).fc, Tile(A, B).bc, Tile(A, B).a, Tile(A, B).b
169.         NEXT
170.     NEXT
171.     CLOSE #1
172.     CLS: PrintMapDesign
173. END SUB
174.  
175. SUB LoadMapDefaut
176.     CLS
177.     FOR A = 1 TO 50
178.         FOR B = 1 TO 100
179.             Tile(A, B).x = A
180.             Tile(A, B).y = B
181.             Tile(A, B).a = 0
182.             Tile(A, B).fc = 7
183.             Tile(A, B).bc = 0
184.             Tile(A, B).b = 0
185.         NEXT
186.     NEXT
187. END SUB
188.  
189.  

[Pete]

See? I keep telling you guys. SCREEN 0, the only screen anyone would ever need! Great haunted house, although the colonoscopy results in the second demo lack suficient clarity for a definitive diagnosis. I'll hold back on adding any additional ASCII humor.

I love old school! Thanks for posting this.

Pete

[TerryRitchie]

This is good stuff!

[Ashish]

Really very nice! :)
But my desktop screen is only 1360x768. So, program screen is too big for me.

[Pete]

Really very nice! :)
But my desktop screen is only 1360x768. So, program screen is too big for me.

What happens if you use Alt+F to full screen it?

Pete

Change your resolution, change your life. desktopappartments.com

[FellippeHeitor]

What happens if you use Alt+F to full screen it?

Pete

Change your resolution, change your life. desktopappartments.com

Alt+Enter

[Virtusoroca]

Hi everyone. Thanks for checking out the code!

First, a quick correction. CSV format of the file holds: Xcoord, Ycoord, Fcolor, Bcolor, ASCII CODE, block property (1=yes). Forgot the ASCII in privious post.

@Pete and @TerryRitchie, thanks for de comments and im glad you enjoyed it! Trying to build a game engine by a "modular" approach. As a QBasic native Im coping with timing events and other things. Hoping to move ahead gradually.

@Ashish and @FellippeHeitor, do you recommend I downgrade the screen size? Maybe its a bit out of standard?

On Discord, !Loudar made some suggestions too. I will improve this code then integrate the hole thing into the ASCII Terrain Engine. Then you will be able to edit your terrain and assets on the fly, as you play them in another screen.

Keep you guys posted. Thanks agian!

[Ashish]

What happens if you use Alt+F to full screen it?

As Fellippe said, you are probably talking about Alt+Enter. Are you currently playing video games? :P

@Virtusoroca As you wish. But, I will surely going to follow Pete's suggestion.

[Virtusoroca]

Thanks @Ashish! I will keep the resolution for now then.

Below, the CSV files of 2 other demos I made: Horizon and BlindFire.

Thinking of a point/click shooter game with that theme.

Going old school, full throtlle! @TerryRitchie @Pete

Hey @OldMoses this might interest you.

This editor is not compatible with the Terrain Engine yet.

But Im planning the next version of the Engine to have this editor as an integrated module.

Thanks again everyone!

[Virtusoroca]

ASCII Editor v2.0

Download the pack and unzip at QB64 root
Pack: BAS + EXE + 6 demos + font file

New: ZoomIn and ZoomOut
Fixed: Error when brush size > 1 hits the border
Fixed: Control characters allowed

Tip: Load your files from ASCII Generator: https://www.qb64.org/forum/index.php?topic=2649.msg118624#msg118624

Note1:  Special characters may not appear in zoom other than 16, 14 and 8. But data is ok in the file
Note2:  Not compatible yet with ASCII Terrain Engine: https://www.qb64.org/forum/index.php?topic=2547.msg117823#msg117823

Let me know you opinion if you try! :)

Code: QB64: [Select]

1. 'ÉÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ»
2. 'º ÛÛÛÛÛÛÛÛÛÛÛÛÛÛÛ      ASCII TERRAIN ENGINE     ÛÛßßÛÛ ÛÛßßÛÛ º
3. 'º ÛÛ     Û     ÛÛ     ® Editor Module v2.0 ¯    ÛÛ ÞÛÛ ÛÛÛÛÛ  º
4. 'º ÛÛ  Û  Û  Û  ÛÛ   (to be integreated in ATE)  ÛÛÜÞÛÛ ÛÛÜÜÛÛ º
5. 'º    Û  Û  Û        Still rough but usable      ßß          º
6. 'º ÛÛ  Û  Û  Û  ÛÛ          ------------         ÛÛßßßß ÛÛ  ÛÛ º
7. 'º ÛÛ  Û     Û  ÛÛ  By Virtusoroca-Brazil, 2020  ÛÛßßÛÛ ÛÛÜÜÛÛ º
8. 'º ÛÛÛÛÛÛÛÛÛÛÛÛÛÛÛ          Made in QB64         ÛÛÜÜÛÛ     ÛÛ º
9. 'ÈÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍͼ
10. 'ÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ 1.    SYSTEM SETTINGS
11. _CONTROLCHR OFF '                                                      Allows ASCII Control Characters to be printed
12. OPTION BASE 1 '                                                        Sets the begining of arrays at 1
13. SCREEN _NEWIMAGE(1280, 800, 256) '                                     Set Screen to 1280x800 resolution, 256 colors
14. 'ÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ 2.    SUBPROCEDURES
15. DECLARE SUB PrintMainMenu'                                             Prints options and settings on screen
16. DECLARE SUB PrintPallete'                                              Prints color and ASCII palletes on screen
17. DECLARE SUB HandleOptions'                                             Handles keyboard input (controls program flow)
18. DECLARE SUB DrawOnCanvas'                                              Handles mouse input on canvas
19. DECLARE SUB PrintImageDesign'                                          Prints image represented by its design (ASCII code)
20. DECLARE SUB PrintImageStructure'                                       Prints image represented by its structure (0s and 1s for block property)
21. DECLARE SUB SaveImageFile'                                             Saves image in CSV format file
22. DECLARE SUB LoadImageFile'                                             Load image from CSV file
23. DECLARE SUB LoadImageDefault'                                          Starts new project reloading default canvas
24. DECLARE SUB ReloadFont'                                                Reloads font size as zoom increases or descreases
25. 'ÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ 3.    VARIABLES
26. 'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ 3.1.  Basic variables declaration
27. DIM SHARED KeyPress AS STRING
28. DIM SHARED ScreenMode AS STRING
29. DIM SHARED CurrentFontColor AS INTEGER
30. DIM SHARED CurrentBackColor AS INTEGER
31. DIM SHARED CurrentASCII AS INTEGER
32. DIM SHARED CurrentSize AS INTEGER
33. DIM SHARED FilePath AS STRING
34. DIM SHARED FileName AS STRING
35. DIM SHARED FontResized AS LONG
36. DIM SHARED FontSize AS INTEGER
37. DIM SHARED MenuTextY AS INTEGER
38. DIM SHARED Pallete AS INTEGER
39. DIM SHARED MouseX AS INTEGER
40. DIM SHARED MouseY AS INTEGER
41. 'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ 3.2.  Basic variables default settings
42. Pallete = 0
43. CurrentFontColor = 7
44. CurrentBackColor = 0
45. CurrentASCII = 219
46. CurrentBlock = 0
47. CurrentSize = 1
48. ScreenMode = "Design"
49. FilePath = "./ATE_editor_files/"
50. FontSize = 16
51. FontResized = _LOADFONT("PerfectDOSVGA437Win.ttf", FontSize, "monospace")
52. 'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ 3.3.  Type variables declaration
53. TYPE Tiles
54.     x AS INTEGER ' X Coordinate
55.     y AS INTEGER ' Y Coordinate
56.     a AS INTEGER ' Ascii code
57.     fc AS INTEGER 'FontColor
58.     bc AS INTEGER 'BackColor
59.     b AS INTEGER ' Block property (game)
60. END TYPE
61. 'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ 3.4.  Type arrays declaration and default settings
62. DIM SHARED Tile(50, 100) AS Tiles
63. 'ÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ 4.    MAIN PROCEDURE
64. LoadImageDefault
65. PrintImageDesign
66. DO
67.     KeyPress = UCASE$(INKEY$)
68.     WHILE _MOUSEINPUT
69.         ReloadFont FontSize
70.         MouseX = INT(_MOUSEY / _FONTHEIGHT) + 1
71.         MouseY = INT(_MOUSEX / _FONTWIDTH) + 1
72.         DrawOnCanvas
73.     WEND
74.     PrintMainMenu
75.     PrintPallete
76.     HandleOptions
77.     _DISPLAY
78. LOOP UNTIL KeyPress = "Q"
79. 'ÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ 5.    SUBPROCEDURES
80. 'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ 5.1.  DrawOnCanvas
81. SUB DrawOnCanvas
82.     IF (MouseX > 0 AND MouseX < 50) AND (MouseY > 0 AND MouseY < 100) THEN
83.         SELECT CASE _MOUSEBUTTON(1)
84.             CASE -1
85.                 IF MouseX < 1 THEN MouseX = 1
86.                 IF MouseX >= 50 THEN MouseX = 50
87.                 IF MouseY < 1 THEN MouseY = 1
88.                 IF MouseY >= 100 THEN MouseY = 100
89.                 CheckX = MouseX + CurrentSize - 1
90.                 CheckY = MouseY + CurrentSize - 1
91.                 IF CheckX < 1 THEN CheckX = 1
92.                 IF CheckX >= 50 THEN CheckX = 50
93.                 IF CheckY < 1 THEN CheckY = 1
94.                 IF CheckY >= 100 THEN CheckY = 100
95.                 FOR A = MouseX TO CheckX
96.                     FOR B = MouseY TO CheckY
97.                         Tile(A, B).fc = CurrentFontColor
98.                         Tile(A, B).bc = CurrentBackColor
99.                         Tile(A, B).a = CurrentASCII
100.                         Tile(A, B).b = 0
101.                         LOCATE A, B: COLOR CurrentFontColor, CurrentBackColor: PRINT CHR$(CurrentASCII);
102.                     NEXT
103.                 NEXT
104.         END SELECT
105.         SELECT CASE _MOUSEBUTTON(2)
106.             CASE -1
107.                 FOR A = MouseX TO MouseX + CurrentSize - 1
108.                     FOR B = MouseY TO MouseY + CurrentSize - 1
109.                         Tile(A, B).fc = CurrentFontColor
110.                         Tile(A, B).bc = CurrentBackColor
111.                         Tile(A, B).a = CurrentASCII
112.                         Tile(A, B).b = 1
113.                         LOCATE A, B: COLOR CurrentFontColor, CurrentBackColor: PRINT CHR$(CurrentASCII);
114.                     NEXT
115.                 NEXT
116.         END SELECT
117.     END IF
118. END SUB
119. 'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ 5.2.  PrintMainMenu
120. SUB PrintMainMenu
121.     _FONT 16
122.     COLOR 15, 0: MenuColumnY = INT(1200 / 8) * 0.70
123.     FOR MenuColumnX = 1 TO 50: LOCATE MenuColumnX, MenuColumnY: PRINT "º";: NEXT
124.     MenuTextX = 1: MenuTextY = MenuColumnY + 2
125.     COLOR 15, 0
126.     LOCATE MenuTextX + 0, MenuTextY: PRINT "CURRENT STATUS"
127.     COLOR 7, 0
128.     LOCATE MenuTextX + 2, MenuTextY: PRINT "ScreenMode: "; ScreenMode
129.     LOCATE MenuTextX + 3, MenuTextY: PRINT "Character:  "; CHR$(CurrentASCII)
130.     LOCATE MenuTextX + 4, MenuTextY: PRINT "FontColor: "; CurrentFontColor
131.     LOCATE MenuTextX + 5, MenuTextY: PRINT "BackColor: "; CurrentBackColor
132.     LOCATE MenuTextX + 6, MenuTextY: PRINT "Preview:    ";: COLOR CurrentFontColor, CurrentBackColor: PRINT CHR$(CurrentASCII);: COLOR 7, 0
133.     LOCATE MenuTextX + 7, MenuTextY: PRINT "BrushSize: "; CurrentSize
134.     LOCATE MenuTextX + 8, MenuTextY: PRINT "FontSize:  "; FontSize
135.     LOCATE MenuTextX + 11, MenuTextY: PRINT "File: ";
136.     IF FileName = "" THEN PRINT "Not Saved" ELSE PRINT FileName
137.     LOCATE MenuTextX + 34, MenuTextY: PRINT "MouseClick = PlaceTile";
138.     LOCATE MenuTextX + 35, MenuTextY: PRINT "LeftClick  = no Block ";
139.     LOCATE MenuTextX + 36, MenuTextY: PRINT "RightClick = w/ Block"
140.     LOCATE MenuTextX + 37, MenuTextY: PRINT "A = AsciiCode";
141.     LOCATE MenuTextX + 38, MenuTextY: PRINT "F = FontColor";
142.     LOCATE MenuTextX + 39, MenuTextY: PRINT "B = BackColor";
143.     LOCATE MenuTextX + 40, MenuTextY: PRINT "Z = BrushSize";
144.     LOCATE MenuTextX + 41, MenuTextY: PRINT "- = ZoomOut";
145.     LOCATE MenuTextX + 42, MenuTextY: PRINT "+ = ZoomIn";
146.     LOCATE MenuTextX + 43, MenuTextY: PRINT "D = DesignScreen";
147.     LOCATE MenuTextX + 44, MenuTextY: PRINT "X = StructureScreen";
148.     LOCATE MenuTextX + 45, MenuTextY: PRINT "N = NewProject";
149.     LOCATE MenuTextX + 46, MenuTextY: PRINT "L = LoadFile";
150.     LOCATE MenuTextX + 47, MenuTextY: PRINT "S = SaveFile";
151.     LOCATE MenuTextX + 48, MenuTextY: PRINT "Q = Quit";
152. END SUB
153. 'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ 5.3.  HandleOption
154. SUB HandleOptions
155.     _FONT 16
156.     MenuInputX = 13: MenuColumnY = INT(1200 / 8) * 0.70: MenuTextY = MenuColumnY + 2
157.     LOCATE MenuInputX, MenuTextY: COLOR 7, 0
158.     SELECT CASE KeyPress
159.         CASE "A": INPUT "AsciiCode: ", CurrentASCII: PrintImageDesign
160.         CASE "F": INPUT "FontColor: ", CurrentFontColor: PrintImageDesign
161.         CASE "B": INPUT "BackColor: ", CurrentBackColor: PrintImageDesign
162.         CASE "Z": INPUT "BrushSize: ", CurrentSize
163.         CASE "D": CLS: ScreenMode = "Design": PrintImageDesign
164.         CASE "X": CLS: ScreenMode = "Structure": PrintImageStructure
165.         CASE "N": ScreenMode = "Design": LoadImageDefault
166.         CASE "S": ScreenMode = "Design": SaveImageFile
167.         CASE "L": ScreenMode = "Design": LoadImageFile
168.         CASE "+"
169.             FontSize = FontSize + 1
170.             IF FontSize > 16 THEN FontSize = 16
171.             IF ScreenMode = "Design" THEN PrintImageDesign ELSE PrintImageStructure
172.         CASE "-"
173.             FontSize = FontSize - 1
174.             IF FontSize < 1 THEN FontSize = 1
175.             IF ScreenMode = "Design" THEN PrintImageDesign ELSE PrintImageStructure
176.     END SELECT
177. END SUB
178. 'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ 5.4.  PrintImageDesign
179. SUB PrintImageDesign
180.     CLS
181.     ReloadFont FontSize
182.     FOR A = 1 TO 50
183.         FOR B = 1 TO 100
184.             COLOR Tile(A, B).fc, Tile(A, B).bc
185.             LOCATE Tile(A, B).x, Tile(A, B).y
186.             PRINT CHR$(Tile(A, B).a);
187.             IF B = 100 THEN: LOCATE A, B + 1: PRINT "Û";
188.             IF FontSize < 16 THEN
189.                 IF A = 50 THEN: LOCATE A + 1, B: PRINT "Û";
190.                 LOCATE A + 1, B + 1: PRINT "Û";
191.             END IF
192.         NEXT
193.     NEXT
194. END SUB
195. 'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ 5.5.  PrintImageStructute
196. SUB PrintImageStructure
197.     CLS: COLOR 7, 0
198.     ReloadFont FontSize
199.     FOR A = 1 TO 50
200.         FOR B = 1 TO 100
201.             IF FontSize < 16 THEN
202.                 IF B = 100 THEN: LOCATE A, B + 1: PRINT "Û";
203.                 IF A = 50 THEN: LOCATE A + 1, B: PRINT "Û";
204.                 LOCATE A + 1, B + 1: PRINT "Û";
205.             END IF
206.             SELECT CASE Tile(A, B).b
207.                 CASE 1
208.                     LOCATE Tile(A, B).x, Tile(A, B).y
209.                     PRINT "1";
210.                 CASE 0
211.                     LOCATE Tile(A, B).x, Tile(A, B).y
212.                     PRINT " ";
213.             END SELECT
214.         NEXT
215.     NEXT
216. END SUB
217. 'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ 5.6.  SaveImageFile
218. SUB SaveImageFile
219.     LOCATE 13, MenuTextY: COLOR 7, 0: INPUT "SaveFile: ", FileName
220.     OPEN FilePath + FileName FOR OUTPUT AS #1
221.     FOR A = 1 TO 50
222.         FOR B = 1 TO 100
223.             WRITE #1, Tile(A, B).x, Tile(A, B).y, Tile(A, B).fc, Tile(A, B).bc, Tile(A, B).a, Tile(A, B).b
224.         NEXT
225.     NEXT
226.     CLOSE #1
227.     CLS: PrintImageDesign
228. END SUB
229. 'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ 5.7.  LoadImageFile
230. SUB LoadImageFile
231.     LOCATE 13, MenuTextY: COLOR 7, 0: INPUT "LoadFile: ", FileName
232.     OPEN FilePath + FileName FOR INPUT AS #1
233.     FOR A = 1 TO 50
234.         FOR B = 1 TO 100
235.             INPUT #1, Tile(A, B).x, Tile(A, B).y, Tile(A, B).fc, Tile(A, B).bc, Tile(A, B).a, Tile(A, B).b
236.         NEXT
237.     NEXT
238.     CLOSE #1
239.     CLS: PrintImageDesign
240. END SUB
241. 'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ 5.8.  LoadImageDefault
242. SUB LoadImageDefault
243.     CLS
244.     FOR A = 1 TO 50
245.         FOR B = 1 TO 100
246.             Tile(A, B).x = A
247.             Tile(A, B).y = B
248.             Tile(A, B).a = 0
249.             Tile(A, B).fc = 7
250.             Tile(A, B).bc = 0
251.             Tile(A, B).b = 0
252.         NEXT
253.     NEXT
254. END SUB
255. 'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ 5.9.  RealoadFont
256. SUB ReloadFont (FontSize)
257.     IF FontSize = 16 OR FontSize = 14 OR FontSize = 8 THEN
258.         _FONT FontSize
259.     ELSE
260.         FontResized = _LOADFONT("PerfectDOSVGA437Win.ttf", FontSize, "monospace")
261.         _FONT FontResized
262.     END IF
263. END SUB
264. 'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ 5.10. PrintPallete
265. SUB PrintPallete
266.     IF Pallete = 1 THEN
267.         X = 14: MenuColorY = MenuTextY
268.         'Colors 0 to 15
269.         LOCATE X, MenuColorY
270.         FOR A = 0 TO 15
271.             COLOR A: PRINT "Û";
272.         NEXT
273.         X = X + 1
274.         'Colors 16 to 31
275.         LOCATE X, MenuColorY
276.         FOR A = 16 TO 31
277.             COLOR A: PRINT "Û";
278.         NEXT
279.         'Colors 32 to 255
280.         X = X + 1: L = 1
281.         FOR A = 32 TO 255
282.             IF MenuColorY = MenuTextY + 24 THEN
283.                 X = X + 1
284.                 MenuColorY = MenuTextY
285.             END IF
286.             LOCATE X, MenuColorY
287.             COLOR A: PRINT "Û";: MenuColorY = MenuColorY + 1
288.         NEXT
289.         MenuAsciiY = MenuTextY
290.         'Ascii 0 to 255
291.         FOR A = 0 TO 255
292.             IF MenuAsciiY = MenuTextY + 24 THEN
293.                 X = X + 1
294.                 MenuAsciiY = MenuTextY
295.             END IF
296.             LOCATE X, MenuAsciiY
297.             COLOR 7: PRINT CHR$(A);: MenuAsciiY = MenuAsciiY + 1
298.         NEXT
299.     END IF
300. END SUB
301. 'ÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ 6.   END OF PROGRAM

[Ashish]

Nice work. :D

[Virtusoroca]

Thanks @Ashish! See the attachments: work in progress, defining the pallette. Thinking of a mini game ;D

[Virtusoroca]

Final art work, with drawing blocks: codes 178, 177 and 176.
A small gift for you, my friend @Ashish :D

The attachments include de CSV file of the image
It can be embeded into the code usind DATA/READ
Format: CoordX, CoordY, FontColor, BackColor, ASCIIcode, BlockProperty (0/1)

[Ashish]

@Virtusoroca That's very impressive ❤

[bplus]

@Virtusoroca That's very impressive ❤

+1

It is artwork! Are you using image converting to Ascii?