Gin Rummy Variations with Computer

[bplus]

Here is a very fast playing variation of Gin Rummy, I call Grim Rummy because "It's all about the Deadwood."

A brief help file is included in zip, very simple game against computer with 0 images or sound effects.

Code: QB64: [Select]

1. OPTION _EXPLICIT
2. _TITLE "Grim Rummy" 'b+ started 2020-04-26 post 2020-05-04  wo dev notes
3.  
4. DEFINT A-Z
5. RANDOMIZE TIMER
6. CONST xmax = 800, ymax = 400 'screen to be expanded when start card images
7.  
8. 'y Constants for locating and displaying
9. CONST deckY = 128 ' deck status line
10. CONST messageY = 160 '2 lines down from deckY
11. CONST cardOffsetX = 20
12. CONST cCardsOffsetY = 16
13. CONST pCardsOffsetY = 288 ' now in pixels
14. ' for current and future card images
15. CONST cardW = 32 'pixels
16. CONST cardH = 16 'pixels
17. CONST black = &HFF000000, white = &HFFFFFFFF, bColor = &HFF220606
18. 'some colors
19.  
20. DIM SHARED clr(3) AS _UNSIGNED LONG
21. clr(0) = &HFF00AA00 'mid green  clubs
22. clr(1) = &HFF0088CC 'cyan       diamonds
23. clr(2) = &HFFF80000 'red        hearts
24. clr(3) = &HFF0000AA 'mid blue   spades
25. ' card "s_vv" format color coded Suits 0 to 3 = C, D, H, S and _ to separate Suit from number: A, 1, 2, 3,... 10, J, Q, K
26.  
27. DIM SHARED deck$(0 TO 51), deckPointer AS INTEGER ' contains shuffled cards, deckpointer points to last card out
28. DIM SHARED discard$, turn$ 'discard$ is card always face up that both players see
29. DIM SHARED p$(12, 3), c$(12, 3)
30. DIM SHARED pDeadPts, cDeadPts, pScore, cScore, laydown, showComputerHand ' p = human or c = computer
31.  
32. 'local variables for main loop of game round and laydown section
33. DIM clicked 'human's button choice
34. DIM card$ ' used often for passing back and forth with routines
35. DIM message$ ' used for reporting results of laydown
36. DIM deadDiff ' used for reporting results of laydown
37. DIM pick$(2), pick2$(3)
38. pick$(0) = "Quit": pick$(1) = "Draw Discard": pick$(2) = "Draw from Deck"
39. pick2$(0) = "Quit": pick2$(1) = "Gin - all cards melded": pick2$(2) = "Knock - Deadwood <= 10": pick2$(3) = "Pass to Computer"
40.  
41. SCREEN _NEWIMAGE(xmax, ymax, 32)
42. _SCREENMOVE 300, 150
43. setupGame 'create deck, human is first up
44. restart:
45. resetRound
46. DO
47.     IF turn$ = "p" THEN 'player's turn
48.         clicked = getButtonNumberChoice%(pick$())
49.         IF clicked = 0 THEN
50.             SYSTEM
51.         ELSEIF clicked = 1 THEN '      Human draws discard
52.             addCard p$(), discard$ '   put the discard into the humans hand
53.             discard$ = "" '            show the discard missing because in human hand
54.         ELSEIF clicked = 2 THEN '      Human draws from deck if there are enough cards
55.             IF 52 - deckPointer < 2 THEN laydown = 5: GOTO skip ELSE addCard p$(), dealCard$
56.         END IF
57.         updateStatus '                 display all this
58.         card$ = getDiscardClick$ '     get human's discard
59.         removeCard p$(), card$ '       take this card out of human hand
60.         discard$ = card$ '             put into discard catagory
61.         updateStatus '                 show the changes
62.         clicked = getButtonNumberChoice%(pick2$())
63.         SELECT CASE clicked
64.             CASE 0: SYSTEM ' quit
65.             CASE 1: laydown = 1 ' Gin
66.             CASE 2: laydown = 2 ' Knock
67.             CASE 3: turn$ = "c" ' pass
68.         END SELECT
69.     ELSEIF turn$ = "c" THEN '     computer's turn
70.         card$ = discard$
71.         cardDiscard card$ '       decision made here usu if deadwood is reduced by 10 points then yes
72.         IF card$ = discard$ THEN 'computer passed on the discard by passing it back
73.             'draw from the deck if there are enough cards remaining
74.             IF 52 - deckPointer < 2 THEN laydown = 5: GOTO skip ELSE card$ = dealCard$
75.             cardDiscard card$
76.             discard$ = card$
77.             updateStatus
78.             yCP messageY, "Computer drew from Deck and discarded."
79.             _DELAY 2
80.             IF cDeadPts = 0 THEN
81.                 laydown = 3
82.             ELSEIF cDeadPts <= 10 THEN
83.                 laydown = 4
84.             ELSE
85.                 turn$ = "p"
86.             END IF
87.         ELSE 'computer kept discard
88.             discard$ = card$
89.             updateStatus
90.             yCP messageY, "Computer kept Discard and discarded another."
91.             _DELAY 2
92.             IF cDeadPts = 0 THEN
93.                 laydown = 3
94.             ELSEIF cDeadPts <= 10 THEN
95.                 laydown = 4
96.             ELSE
97.                 turn$ = "p"
98.             END IF
99.         END IF
100.     END IF
101.     skip:
102. LOOP UNTIL laydown
103.  
104. ' if players points exceed 100 after laydown results they win
105. showComputerHand = 1 'to show computer hand
106. SELECT CASE laydown
107.     CASE 1 ' human gin
108.         IF pDeadPts <> 0 THEN
109.             message$ = "Human lost 10 points calling Gin and not having it."
110.             pScore = pScore - 10
111.         ELSE
112.             message$ = "Human: 25 points Gin + " + ts$(cDeadPts) + " Computer's Deadwood."
113.             pScore = pScore + 25 + cDeadPts
114.         END IF
115.         turn$ = "c"
116.     CASE 2, 4 ' human knock or computer
117.         IF cDeadPts > pDeadPts THEN
118.             deadDiff = cDeadPts - pDeadPts
119.             message$ = "Human: 30 - " + ts$(52 - deckPointer) + " deck + " + ts$(deadDiff) + " deadwood = " + ts$(30 - (52 - deckPointer) + deadDiff)
120.             pScore = pScore + 30 - (52 - deckPointer) + deadDiff: turn$ = "c"
121.         ELSEIF pDeadPts > cDeadPts THEN
122.             deadDiff = pDeadPts - cDeadPts
123.             message$ = "Computer: 30 - " + ts$(52 - deckPointer) + " deck + " + ts$(deadDiff) + " deadwood = " + ts$(30 - (52 - deckPointer) + deadDiff)
124.             cScore = cScore + 30 - (52 - deckPointer) + deadDiff: turn$ = "p"
125.         ELSEIF cDeadPts = pDeadPts THEN
126.             message$ = "A Knockout tie! no score was advanced this round." 'turn is whatever it was
127.         END IF
128.     CASE 3 ' computer gin
129.         message$ = "Computer: 25 points Gin + " + ts$(pDeadPts) + " Human's deadwood."
130.         cScore = cScore + 25 + pDeadPts: turn$ = "p"
131.     CASE 5
132.         message$ = "The deck has < 2 cards, this round is Null!" ' turn is same as was
133. END SELECT
134. updateStatus
135. IF cScore >= 100 OR pScore >= 100 THEN message$ = message$ + "  Winner!"
136. yCP messageY, message$ + "  press any..."
137. SLEEP
138. IF INSTR(message$, "Winner!") THEN pScore = 0: cScore = 0
139. GOTO restart
140.  
141. SUB setupGame 'Intro to this version, create deck of cards, set turn to human
142.     DIM suit, value, i, bn
143.     DIM m$(2): m$(0) = "Quit": m$(1) = "Load Grim Rummy.txt": m$(2) = "Lets play Grim Rummy!"
144.     COLOR white, bColor 'once and for all on bColor
145.     CLS
146.     yCP 160, "'Load Grim Rummy.txt' Button will call up"
147.     yCP 180, "'Grim Rummy Variation.txt' into your favorite editor"
148.     yCP 200, "for you to refer to now or during play of Grim Rummy."
149.     yCP 300, "Cool now the coder of this game can edit es notes"
150.     yCP 320, "as e develops the game!"
151.     bn = getButtonNumberChoice(m$())
152.     IF bn = 0 THEN SYSTEM
153.     IF bn = 1 THEN SHELL _DONTWAIT "Grim Rummy Variation.txt" 'oh nice! don't have to load and show!
154.     IF deck$(0) = "" THEN 'create deck
155.         FOR suit = 1 TO 4
156.             FOR value = 1 TO 13
157.                 deck$(i) = MID$("CDHS", suit, 1) + "_" + MID$("A 2 3 4 5 6 7 8 9 10J Q K ", 2 * (value - 1) + 1, 2) 'Suit_Value
158.                 i = i + 1
159.             NEXT
160.         NEXT
161.     END IF
162.     turn$ = "p" 'player always starts game
163. END SUB
164.  
165. SUB resetRound
166.     ERASE p$, c$ 'clear hands  and rest the other globals
167.     pDeadPts = 0: cDeadPts = 0: laydown = 0: showComputerHand = 0 '< 1 for debug or cheating
168.     DIM i, r 'locals
169.     FOR i = 51 TO 1 STEP -1 'shuffle deck
170.         r = INT(RND * i)
171.         SWAP deck$(i), deck$(r)
172.     NEXT
173.     deckPointer = 0 'deal some cards out
174.     FOR i = 1 TO 10
175.         addCard p$(), dealCard$
176.         addCard c$(), dealCard$
177.     NEXT
178.     discard$ = deck$(deckPointer): deckPointer = deckPointer + 1 'set first discard$
179.     updateStatus
180. END SUB
181.  
182. SUB updateStatus
183.     COLOR white, bColor
184.     CLS
185.     show "p" '                    show updates pDeadPts  cardDiscard updates cDeadPts
186.     IF showComputerHand THEN show "c"
187.     COLOR clr(INSTR("CDHS", LEFT$(discard$, 1)) - 1) 'display discard$ in it's suit color
188.     _PRINTSTRING (411, deckY), discard$
189.     COLOR white
190.     yCP deckY, "Cards remaining: " + ts$(52 - deckPointer) + "  Discard: "
191.     yCP deckY + 128, "Human: " + ts$(pScore) + "   Computer: " + ts$(cScore)
192. END SUB
193.  
194. SUB show (player$) 'players hand is displayed 5 lines above bottom of screen in 4 lines
195.     DIM r, c, d$
196.     FOR r = 0 TO 3
197.         COLOR clr(r)
198.         FOR c = 0 TO 12
199.             IF player$ = "p" THEN
200.                 IF p$(c, r) = "" THEN
201.                     _PRINTSTRING (c * 40 + cardOffsetX, r * 16 + pCardsOffsetY), "   "
202.                 ELSE
203.                     _PRINTSTRING (c * 40 + cardOffsetX, r * 16 + pCardsOffsetY), p$(c, r)
204.                 END IF
205.  
206.             ELSE
207.                 IF c$(c, r) = "" THEN
208.                     _PRINTSTRING (c * 40 + cardOffsetX, r * 16 + cCardsOffsetY), "   "
209.                 ELSE
210.                     _PRINTSTRING (c * 40 + cardOffsetX, r * 16 + cCardsOffsetY), c$(c, r)
211.                 END IF
212.             END IF
213.         NEXT
214.     NEXT
215.     COLOR &HFFCCDD00 'dark brown sort a like deadwood?
216.     IF player$ = "p" THEN
217.         pDeadPts = deadwood(p$(), d$)
218.         yCP 80 + pCardsOffsetY, ts$(LEN(d$) \ 5) + " Deadwood Cards = " + ts$(pDeadPts) + " points"
219.     ELSE
220.         cDeadPts = deadwood(c$(), d$)
221.         yCP 80 + cCardsOffsetY, ts$(LEN(d$) \ 5) + " Deadwood Cards = " + ts$(cDeadPts) + " points"
222.     END IF
223.     COLOR white
224. END SUB
225.  
226. 'player reviews card rec'd and discards through mouse click
227. FUNCTION getDiscardClick$ 'this has to be reworked
228.     DIM oldMouse, mCol, mRow, mb
229.     yCP messageY, "Click Discard"
230.     oldMouse = -1
231.     DO
232.         WHILE _MOUSEINPUT: WEND 'convert mouse positions to array row and col
233.         mCol = INT((_MOUSEX - cardOffsetX) / (cardW + 8) + .25)
234.         mRow = INT((_MOUSEY - pCardsOffsetY) / (cardH))
235.         mb = _MOUSEBUTTON(1)
236.         'LOCATE 13, 2: PRINT mCol, mRow
237.         IF mb AND oldMouse = 0 THEN
238.             IF mRow >= 0 AND mRow <= 3 THEN
239.                 IF mCol >= 0 AND mCol <= 12 THEN
240.                     IF p$(mCol, mRow) <> "" THEN getDiscardClick$ = p$(mCol, mRow): EXIT FUNCTION
241.                 END IF
242.             END IF
243.         END IF
244.         oldMouse = mb
245.         _LIMIT 200
246.     LOOP
247. END FUNCTION
248.  
249. 'computer gets card and discards through this AI
250. SUB cardDiscard (card$) 'for AI
251.     DIM ci, r, c, low, d$, saveI, i
252.     DIM cds$(1 TO 11), dw(1 TO 11)
253.     ci = 1
254.     FOR r = 0 TO 3
255.         FOR c = 0 TO 12
256.             IF c$(c, r) <> "" THEN cds$(ci) = c$(c, r): ci = ci + 1
257.         NEXT
258.     NEXT
259.     cds$(11) = card$
260.     low = 200
261.     dw(11) = deadwood(c$(), d$)
262.     IF dw(11) < low THEN saveI = 11: low = dw(11)
263.     addCard c$(), card$
264.     FOR i = 1 TO 10
265.         removeCard c$(), cds$(i)
266.         dw(i) = deadwood(c$(), d$)
267.         IF dw(i) < low THEN saveI = i: low = dw(i)
268.         addCard c$(), cds$(i)
269.     NEXT
270.     ' 11 cards are in c$()
271.     IF card$ = discard$ THEN 'we dont want to take discard unless it makes significant difference
272.         IF dw(11) - low > 10 THEN 'take discard$ 'it's already in hand
273.             removeCard c$(), cds$(saveI)
274.             card$ = cds$(saveI) 'discard
275.         ELSE 'don't take discard$
276.             removeCard c$(), card$ 'reject the discard
277.         END IF
278.     ELSE 'have to remove something?
279.         removeCard c$(), cds$(saveI) ' remove from c$() to get it to 10
280.         card$ = cds$(saveI) ' pass it back in card variable
281.     END IF
282.     cDeadPts = deadwood(c$(), d$)
283. END SUB
284.  
285. ' This is key to Gin Rummy Game. This is a C for crosswords version of Deadwood.
286. ' Crosswords means a card can be used both in a group set and straight set in making meld.
287. ' Since Grim Rummy is based on Deadwood points there is no extra credit for using a card twice,
288. ' it just makes it easier to clear deadwood for players and calculate deadwood points for coder.
289. FUNCTION deadwood (a$(), dead$)
290.     REDIM sSets$(0), gSets$(0) 'although 0 based these sets have first element at 1 as they are added in by sAppend SUB
291.     DIM r, c, quit, cStart, cEnd, set$, ci, count 'finding meld sets
292.  
293.     ' checking for card intersets between gSet and sSet
294.     DIM si, gi '           index for each of these arrays of sets
295.     DIM nsCards, ngCards ' number of cards in the single set
296.     DIM place '            where in set a card is
297.  
298.     'sets with card intersects removed now time to count deadwood
299.     DIM nCards, cardI, n 'card Count, card index and another index
300.  
301.     FOR r = 0 TO 3 'look for straights
302.         c = 0: quit = 0
303.         DO WHILE quit = 0 AND c < 13
304.             WHILE a$(c, r) = ""
305.                 c = c + 1
306.                 IF c > 11 THEN quit = 1: EXIT WHILE
307.             WEND
308.             IF c < 11 THEN
309.                 cStart = c
310.                 WHILE a$(c, r) <> ""
311.                     c = c + 1
312.                     IF c = 13 THEN quit = 1: EXIT WHILE
313.                 WEND
314.                 IF c = 13 THEN cEnd = 12 ELSE cEnd = c - 1
315.                 IF cEnd - cStart + 1 > 2 THEN
316.                     set$ = ""
317.                     FOR ci = cStart TO cEnd
318.                         set$ = set$ + a$(ci, r)
319.                     NEXT
320.                     sAppend sSets$(), set$
321.                 END IF
322.                 IF c > 11 THEN quit = 1
323.             ELSE
324.                 EXIT DO
325.             END IF
326.         LOOP
327.     NEXT
328.     FOR c = 0 TO 12 ' now for the groups
329.         count = 0
330.         FOR ci = 0 TO 3
331.             IF a$(c, ci) <> "" THEN count = count + 1
332.         NEXT
333.         IF count > 2 THEN
334.             set$ = ""
335.             FOR ci = 0 TO 3
336.                 IF a$(c, ci) <> "" THEN set$ = set$ + a$(c, ci)
337.             NEXT
338.             sAppend gSets$(), set$
339.         END IF
340.     NEXT
341.     ' now it's time to calculate the deadwood number ======================================
342.     REDIM cards$(0) '<<< why is this at 11? hack fix for cardDiscard call
343.     FOR r = 0 TO 3
344.         FOR c = 0 TO 12
345.             IF a$(c, r) <> "" THEN sAppend cards$(), a$(c, r)
346.         NEXT
347.     NEXT
348.     nCards = UBOUND(cards$)
349.     FOR si = 1 TO UBOUND(sSets$)
350.         IF sSets$(si) <> "" THEN
351.             nsCards = LEN(sSets$(si)) / 4
352.             FOR cardI = 1 TO nsCards
353.                 FOR n = 1 TO nCards
354.                     IF cards$(n) = MID$(sSets$(si), cardI * 4 - 3, 4) THEN cards$(n) = ""
355.                 NEXT
356.             NEXT
357.         END IF
358.     NEXT
359.     FOR gi = 1 TO UBOUND(gSets$)
360.         IF gSets$(gi) <> "" THEN
361.             ngCards = LEN(gSets$(gi)) / 4
362.             FOR cardI = 1 TO ngCards
363.                 FOR n = 1 TO nCards
364.                     IF cards$(n) = MID$(gSets$(gi), cardI * 4 - 3, 4) THEN cards$(n) = ""
365.                 NEXT
366.             NEXT
367.         END IF
368.     NEXT
369.     'ok melded cards cleaned out
370.     dead$ = "": count = 0
371.     FOR n = 1 TO nCards
372.         IF cards$(n) <> "" THEN
373.             dead$ = dead$ + " " + cards$(n)
374.             place = INSTR("A 2 3 4 5 6 7 8 9 10J Q K ", MID$(cards$(n), 3, 2))
375.             IF (place + 1) / 2 < 10 THEN count = count + (place + 1) / 2 ELSE count = count + 10
376.         END IF
377.     NEXT
378.     deadwood = count
379. END FUNCTION
380.  
381. FUNCTION dealCard$
382.     dealCard$ = deck$(deckPointer): deckPointer = deckPointer + 1
383. END SUB
384.  
385. SUB addCard (a$(), card$)
386.     DIM r, c
387.     r = INSTR("CDHS", LEFT$(card$, 1)) - 1: c = (INSTR("A 2 3 4 5 6 7 8 9 10J Q K ", MID$(card$, 3, 2)) - 1) / 2
388.     a$(c, r) = card$
389. END SUB
390.  
391. SUB removeCard (a$(), card$)
392.     DIM r, c
393.     r = INSTR("CDHS", LEFT$(card$, 1)) - 1: c = (INSTR("A 2 3 4 5 6 7 8 9 10J Q K ", MID$(card$, 3, 2)) - 1) / 2
394.     a$(c, r) = ""
395. END SUB
396.  
397. 'modified for this app
398. SUB yCP (y, s$) 'for xmax pixel wide graphics screen Center Print at pixel y row
399.     _PRINTSTRING ((_WIDTH - 220 - LEN(s$) * 8) / 2, y), s$
400. END SUB
401.  
402. 'this sub uses drwBtn
403. FUNCTION getButtonNumberChoice% (choice$()) 'developed for this app but likely can use as is elsewhere
404.     DIM ub, b, oldmouse, mx, my, mb
405.  
406.     ub = UBOUND(choice$)
407.     FOR b = 0 TO ub
408.         drwBtn xmax - 210, b * 60 + 90, choice$(b)
409.     NEXT
410.     oldmouse = -1
411.     DO
412.         WHILE _MOUSEINPUT: WEND
413.         mx = _MOUSEX: my = _MOUSEY: mb = _MOUSEBUTTON(1)
414.         IF mb AND oldmouse = 0 THEN
415.             IF mx > xmax - 210 AND mx <= xmax - 10 THEN
416.                 FOR b = 0 TO ub
417.                     IF my >= b * 60 + 90 AND my <= b * 60 + 140 THEN
418.                         LINE (xmax - 210, 0)-(xmax, ymax), bColor, BF
419.                         getButtonNumberChoice% = b: EXIT FUNCTION
420.                     END IF
421.                 NEXT
422.                 BEEP
423.             ELSE
424.                 BEEP
425.             END IF
426.         END IF
427.         oldmouse = _MOUSEBUTTON(1)
428.         _LIMIT 200
429.     LOOP
430. END FUNCTION
431.  
432. SUB drwBtn (x, y, s$) '200 x 50
433.     DIM th, tw, gray~&
434.     th = 16: tw = 8 * LEN(s$): gray~& = _RGB32(190, 190, 190)
435.     LINE (x, y)-STEP(204, 54), _RGB32(0, 0, 0), BF
436.     LINE (x - 2, y - 2)-STEP(201, 51), _RGB32(255, 255, 255), BF
437.     LINE (x, y)-STEP(200, 50), gray~&, BF
438.     COLOR _RGB32(0, 0, 0), gray~&
439.     _PRINTSTRING (x + 100 - 4 * LEN(s$), y + 17), s$
440.     COLOR white, bColor
441. END SUB
442.  
443. SUB sAppend (arr() AS STRING, addItem$)
444.     REDIM _PRESERVE arr(LBOUND(arr) TO UBOUND(arr) + 1) AS STRING
445.     arr(UBOUND(arr)) = addItem$
446. END SUB
447.  
448. FUNCTION ts$ (number)
449.     ts$ = _TRIM$(STR$(number))
450. END FUNCTION
451.  

Until I can figure out how to code it otherwise, a card may be used both in a Straight set (3 or more sequence of same suit) and a Group set (3 or 4 of a kind).

It's quite a challenge to figure optimum Deadwood of 10 or 11 cards when, like in a regular game of Gin Rummy, a card may be used either in a Straight set or a Group set but not both. I've been at it for a few days now and haven't figured it out yet. Maybe one of you guys can get it?

The zip is just the source (above) and a helper txt file.

[bplus]

I have finally found the way to optimize a Gin Rummy hand and have revised Grim Rummy with the new code. It plays very well. Now you can use a card for a Straight set or a Group set but not both.

Grin Rummy variation coming next but might need even more AI.

[johnno56]

Another card game?... A glutton for punishment... lol

As I have never played this game before, I seriously doubt, that I can help you with the coding... If you ever get to the point of adding sound and graphics, as long as it's not too difficult, let me know...

[bplus]

Another card game?... A glutton for punishment... lol

As I have never played this game before, I seriously doubt, that I can help you with the coding... If you ever get to the point of adding sound and graphics, as long as it's not too difficult, let me know...

The idea behind all Gin Games is to match cards into sets, either a Group Set = all of a kind like 3 Jacks or 4 Nines or a Straight Set eg, Ace, 2, 3 of Spades or 5, 6, 7, 8, 9 of Harts... a sequence of of same suit. Minimum 3 cards to a set. So for group sets, the maximum can be 4 of a kind but theoretically a Gin hand can be one big Straight set! (Should maybe be extra points for that, hmm... )

Meld are all the cards matched to a set or the Points of those cards, Ace counts only as 1 and Face cards are 10 points the rest are their number value.

Now in my own invention, Grim Rummy Variation,  the only thing that matters is Deadwood. Deadwood are the cards or their point value of cards not matched into sets. When you have 10 or less points in Deadwood you "Knock" and player with least Deadwood Points wins the difference in Deadwood points PLUS 30 - number of cards remaining in deck (this almost guarantees at least 10 points won in a round).

The focus on Deadwood only seems kind of Grim hence the name of this variation.

Now the next Variation of my invention is Grin Rummy. The complete opposite of Grim it focuses entirely on Meld, Deadwood only matters for "Knocking" or calling Gin = 0 Deadwood cards or Points. I haven't worked out details for game scoring yet because I hadn't had a decent Gin hand Optimizer until Saturday.

Funny Saturday morning I woke up early and sketched out a new and different plan of attack for building the Optimizer code. It wasn't quite as easy as originally imagined but it turned out far more elegant than a rules or conditions based system that was so complex you get lost in handling all the possible cases that could happen but most aren't likely, like having to split a big Straight set without loosing more than 1 card for meld.

You know you can put together only 3 sets maximum for Gin Rummy yet the code it takes to establish the best 3 sets is quite involved! And cards that intersect both a Group set and a Straight set, they have to go in one or the other; trouble is all the combinations of which set the intersecting card should go. So finally Saturday I put together code that tests each combination and saves the first one that uses the most cards or has the highest points.

[Cobalt]

I've always wanted to recreate Intellivision's "Royal Dealer" version of Gin Rummy. Also has Hearts, Crazy 8s and one more thats not poppin in at the moment.

[bplus]

I've always wanted to recreate Intellivision's "Royal Dealer" version of Gin Rummy. Also has Hearts, Crazy 8s and one more thats not poppin in at the moment.

Rummy is #4, these days when it's not poppin try popping Google :) I had never even heard of Royal Dealer:
http://www.thevgatv.com/resources/Intellivision/Royal-Dealer-Intv.pdf

@johnno56  wanna try aliens for this?

 

[Cobalt]

I even have the graphics already sprite sheet-ed, from a bit of work I did some time ago on it. Yeah I forgot it had Rummy and Gin Rummy.

[bplus]

@Cobalt

I just watched this:

This guys says straights are limited to 3-4 cards in Gin Rummy, say it aint so, say this guy has his rules screwed up.

I am allowing Straights of any length including 10 cards!

[Cobalt]

I don't know... I think I have had full straight wins before. Its been a while since I've played so I might need to give it a go again, granted getting a full straight win is not easy to pull off any how.

[Cobalt]

Yeah you can get more than straights of 3 or 4, haven't gotten to 7 or more yet but here is a double 5 straight hand that won a round.

So yeah that dude is wack.

and I had the 9 of spades that discarded when I called gin, so I could have had 6 if I would have discarded a diamond instead.

[bplus]

Ah good! Glad to see Cobalt :) I've seen a few 7 Straights myself.

Here is Grin Rummy I had going months ago. Tonight I changed look and play of game a bit. It is allowing double use of a card both in a Straight set and a Group set. For Grin Rummy, this works out great for getting some really massive Melds built up if you can only beat the computer to GRIN :) In this game you have to meld all cards before computer melds it's hand to get your meld points scored, play is to 500 points.

Code: QB64: [Select]

1. OPTION _EXPLICIT
2. _TITLE "Grin Rummy" 'b+ started 2020-04-28  revised 2020-10-12
3. ' complete opposite of Grim Rummy
4.  
5. DEFINT A-Z
6. RANDOMIZE TIMER
7. CONST xmax = 800, ymax = 400 'screen to be expanded when start card images
8.  
9. 'y Constants for locating and displaying
10. CONST deckY = 128 ' deck status line
11. CONST messageY = 160 '2 lines down from deckY
12. CONST cardOffsetX = 20
13. CONST cCardsOffsetY = 16
14. CONST pCardsOffsetY = 288 ' now in pixels
15. ' for current and future card images
16. CONST cardW = 32 'pixels
17. CONST cardH = 16 'pixels
18. CONST black = &HFF000000, white = &HFFFFFFFF, bColor = &HFF5566FF
19. 'some colors
20.  
21. DIM SHARED clr(3) AS _UNSIGNED LONG
22. clr(0) = &HFF006644 'mid green  clubs
23. clr(1) = &HFF00FF44 'cyan       diamonds
24. clr(2) = &HFFCC3300 'red        hearts
25. clr(3) = &HFF880099 'mid blue   spades
26. ' card "##s" space or # for 10, # or Letter for digit/Face  card symbol
27.  
28. DIM SHARED deck$(0 TO 51), deckPointer AS INTEGER ' contains shuffled cards, deckpointer points to last card out
29. DIM SHARED discard$, turn$ 'discard$ is card always face up that both players see
30. DIM SHARED p$(12, 3), c$(12, 3)
31. DIM SHARED pMeldPts, cMeldPts, pND, cND, pScore, cScore, laydown, showComputerHand ' p = human or c = computer
32. DIM SHARED pick1$(2), pick2$(2) 'human player's choices at each play
33. pick1$(0) = "Quit": pick1$(1) = "Draw Discard": pick1$(2) = "Draw from Deck"
34. pick2$(0) = "Quit": pick2$(1) = "Grin - all cards melded": pick2$(2) = "Pass to Computer"
35.  
36. 'local variables for main loop of game round and laydown section
37. DIM clicked 'human's button choice
38. DIM card$ ' used often for passing back and forth with routines
39. DIM message$ ' used for reporting results of laydown
40. DIM meld ' used for reporting results of laydown
41. DIM oldMouse
42.  
43. SCREEN _NEWIMAGE(xmax, ymax, 32)
44. _SCREENMOVE 300, 150
45. setupGame 'create deck, human is first up
46. restart:
47. resetRound
48. DO
49.     IF turn$ = "p" THEN 'player's turn
50.         clicked = getButtonNumberChoice%(pick1$())
51.         IF clicked = 0 THEN ' human wants to quit
52.             SYSTEM
53.         ELSEIF clicked = 1 THEN '            Human draws discard
54.             addCard p$(), discard$ '   put the discard into the humans hand
55.             discard$ = "" '            show the discard missing because in human hand
56.         ELSEIF clicked = 2 THEN ' Human  Draws from deck if enough cards left
57.             IF 52 - deckPointer < 2 THEN laydown = 5: GOTO skip ELSE addCard p$(), dealCard$ ' place next deck card into humans hand
58.         END IF
59.         updateStatus '             display all this
60.         card$ = getDiscardClick$ ' get human's discard
61.         removeCard p$(), card$ '   take this card out of human hand
62.         discard$ = card$ '         put into discard catagory
63.         updateStatus '             show the changes
64.         IF pND = 0 THEN laydown = 1 ELSE turn$ = "c"
65.  
66.     ELSEIF turn$ = "c" THEN 'computer's turn
67.         card$ = discard$
68.         cardDiscard card$ '
69.         IF card$ = discard$ THEN 'computer passed on the discard by passing it back
70.             ' so draw from deck if not out of cards?
71.             IF 52 - deckPointer < 2 THEN laydown = 5: GOTO skip ELSE card$ = dealCard$
72.             cardDiscard card$
73.             discard$ = card$
74.             updateStatus
75.             yCP messageY, "Computer drew from Deck and discarded."
76.         ELSE 'computer kept discard
77.             discard$ = card$
78.             updateStatus
79.             yCP messageY, "Computer kept Discard and discarded another."
80.         END IF
81.         _DELAY 2
82.         IF cND = 0 THEN updateStatus: yCP messageY, "Grin": laydown = 3 ELSE turn$ = "p"
83.     END IF
84.     skip:
85. LOOP UNTIL laydown
86.  
87. 'show computer's hand when not in debug mode
88. 'remember the turn will go to loser of laydown
89. ' if players points exceed 100 after laydown results they win
90. showComputerHand = 1 'to show computer hand
91. SELECT CASE laydown
92.     IF pMeldPts > cMeldPts THEN meld = pMeldPts ELSE meld = cMeldPts
93.     CASE 1 ' human gin
94.         message$ = "Human: " + ts$(meld) + " has been added to your score."
95.         pScore = pScore + meld
96.         turn$ = "c"
97.     CASE 3 ' computer gin
98.         drwBtn xmax - 210, 200, "GRIN :)"
99.         message$ = "Computer: " + ts$(meld) + " has been added to your score."
100.         cScore = cScore + meld
101.         turn$ = "p"
102.     CASE 5
103.         message$ = "The deck has < 2 cards, this round is Null!" ' turn is same as was
104. END SELECT
105. updateStatus
106. IF pND = 0 THEN
107.     drwBtn xmax - 210, ymax - 100, "GRIN :)"
108. ELSEIF cND = 0 THEN
109.     drwBtn xmax - 210, 50, "GRIN :)"
110. END IF
111. IF cScore >= 500 OR pScore >= 500 THEN message$ = message$ + "  Winner!"
112. yCP messageY, message$ + "  click..."
113. oldMouse = -1
114. DO
115.     WHILE _MOUSEINPUT: WEND
116.     ' mb = _MOUSEBUTTON(1)
117.     IF _MOUSEBUTTON(1) AND oldMouse = 0 THEN
118.         LINE (xmax - 210, 0)-(xmax, ymax), bColor, BF
119.         IF INSTR(message$, "Winner!") THEN pScore = 0: cScore = 0
120.         EXIT DO
121.     END IF
122.     oldMouse = _MOUSEBUTTON(1)
123. LOOP
124. GOTO restart
125.  
126. SUB setupGame 'Intro to this version, create deck of cards, set turn to human
127.     DIM suit, value, i, bn
128.     DIM m$(2): m$(0) = "Quit": m$(1) = "Load .txt on Grin Rummy": m$(2) = "Let's play Grin Rummy"
129.     COLOR white, bColor 'once and for all on bColor
130.     CLS
131.     yCP 160, "'Load .txt of Grin Rummy' Button will call up"
132.     yCP 180, "'Grin Rummy Variation.txt' into your favorite editor"
133.     yCP 200, "for you to refer to now or during play of Grin Rummy."
134.  
135.     yCP 300, "Cool now the coder of this game can edit es notes"
136.     yCP 320, "as e develops the game!"
137.  
138.     bn = getButtonNumberChoice(m$())
139.     IF bn = 0 THEN SYSTEM
140.     IF bn = 1 THEN SHELL _DONTWAIT "Grin Rummy Variation.txt" 'oh nice! don't have to load and show!
141.     IF deck$(0) = "" THEN 'create deck
142.         FOR suit = 1 TO 4
143.             FOR value = 1 TO 13
144.                 deck$(i) = MID$(" A 2 3 4 5 6 7 8 910 J Q K", 2 * (value - 1) + 1, 2) + MID$(CHR$(3) + CHR$(4) + CHR$(5) + CHR$(6), suit, 1) 'Suit_Value
145.                 i = i + 1
146.             NEXT
147.         NEXT
148.     END IF
149.     turn$ = "p" 'player always starts game
150. END SUB
151.  
152. SUB resetRound
153.     DIM i, r 'locals, wow not many for all the code here
154.     ERASE p$, c$ 'clear hands  13 cols and 4 rows arrays  copy of ordered deck
155.     pMeldPts = 0: cMeldPts = 0: laydown = 0: showComputerHand = 0 '< 1 for debug or cheating
156.  
157.     'shuffle deck
158.     FOR i = 51 TO 1 STEP -1
159.         r = INT(RND * i)
160.         SWAP deck$(i), deck$(r)
161.     NEXT
162.     deckPointer = 0 'deal some cards out
163.     FOR i = 1 TO 10
164.         addCard p$(), dealCard$
165.         addCard c$(), dealCard$
166.     NEXT
167.     discard$ = deck$(deckPointer): deckPointer = deckPointer + 1 'set first discard$
168.     updateStatus
169. END SUB
170.  
171. SUB updateStatus
172.     COLOR white, bColor
173.     CLS
174.     show "p" '                    show updates pMeldPts  cardDiscard updates cMeldPts
175.     IF showComputerHand THEN show "c"
176.     COLOR clr(INSTR(CHR$(3) + CHR$(4) + CHR$(5) + CHR$(6), RIGHT$(discard$, 1)) - 1) 'display discard$ in it's suit color
177.     _PRINTSTRING (411, deckY), discard$
178.     COLOR white
179.     yCP deckY, "Cards remaining: " + ts$(52 - deckPointer) + "  Discard: "
180.     yCP deckY + 128, "Human: " + ts$(pScore) + "   Computer: " + ts$(cScore)
181. END SUB
182.  
183. SUB show (player$) 'players hand is displayed 5 lines above bottom of screen in 4 lines
184.     DIM r, c, nD
185.     FOR r = 0 TO 3
186.         COLOR clr(r)
187.         FOR c = 0 TO 12
188.             IF player$ = "p" THEN
189.                 IF p$(c, r) = "" THEN
190.                     _PRINTSTRING (c * 40 + cardOffsetX, r * 16 + pCardsOffsetY), "   "
191.                 ELSE
192.                     _PRINTSTRING (c * 40 + cardOffsetX, r * 16 + pCardsOffsetY), p$(c, r)
193.                 END IF
194.  
195.             ELSE
196.                 IF c$(c, r) = "" THEN
197.                     _PRINTSTRING (c * 40 + cardOffsetX, r * 16 + cCardsOffsetY), "   "
198.                 ELSE
199.                     _PRINTSTRING (c * 40 + cardOffsetX, r * 16 + cCardsOffsetY), c$(c, r)
200.                 END IF
201.             END IF
202.         NEXT
203.     NEXT
204.     COLOR &HFFFFFF00 'dark brown sort a like cMeldTotal?
205.     IF player$ = "p" THEN
206.         pMeldPts = cMeldTotal(p$(), nD): pND = nD
207.         yCP 80 + pCardsOffsetY, "  Player:  Meld = " + ts$(pMeldPts) + "    Deadwood Cards = " + ts$(pND)
208.     ELSE
209.         cMeldPts = cMeldTotal(c$(), nD): cND = nD
210.         yCP 80 + cCardsOffsetY, "Computer:  Meld = " + ts$(cMeldPts) + "    Deadwood Cards = " + ts$(cND)
211.     END IF
212.     COLOR white
213. END SUB
214.  
215. 'player reviews card rec'd and discards through mouse click
216. FUNCTION getDiscardClick$ 'this has to be reworked
217.     DIM oldMouse, mCol, mRow, mb
218.     yCP messageY, "Click Discard"
219.     oldMouse = -1
220.     DO
221.         WHILE _MOUSEINPUT: WEND 'convert mouse positions to array row and col
222.         mCol = INT((_MOUSEX - cardOffsetX) / (cardW + 8) + .25)
223.         mRow = INT((_MOUSEY - pCardsOffsetY) / (cardH))
224.         mb = _MOUSEBUTTON(1)
225.         'LOCATE 13, 2: PRINT mCol, mRow
226.         IF mb AND oldMouse = 0 THEN
227.             IF mRow >= 0 AND mRow <= 3 THEN
228.                 IF mCol >= 0 AND mCol <= 12 THEN
229.                     IF p$(mCol, mRow) <> "" THEN getDiscardClick$ = p$(mCol, mRow): EXIT FUNCTION
230.                 END IF
231.             END IF
232.         END IF
233.         oldMouse = mb
234.         _LIMIT 200
235.     LOOP
236. END FUNCTION
237.  
238. 'computer gets card and discards through this AI
239. SUB cardDiscard (card$) 'for AI
240.     DIM ci, r, c, dwStart, dwlow, nD, saveI, i
241.     DIM cds$(1 TO 11), meld(1 TO 11)
242.     ci = 1
243.     FOR r = 0 TO 3
244.         FOR c = 0 TO 12
245.             IF c$(c, r) <> "" THEN cds$(ci) = c$(c, r): ci = ci + 1
246.         NEXT
247.     NEXT
248.     cds$(11) = card$
249.     meld(11) = cMeldTotal(c$(), nD): dwlow = nD: saveI = 11: dwStart = nD 'the hand before considering the new card
250.     addCard c$(), card$
251.     FOR i = 1 TO 10 'remove each card in hand and check dwLow and meld
252.         removeCard c$(), cds$(i)
253.         meld(i) = cMeldTotal(c$(), nD)
254.         IF nD < dwlow THEN 'ah less dead wood it's a keeper
255.             saveI = i: dwlow = nD
256.         ELSEIF nD = dwlow THEN ' ah same amount of deadwood but more meld so keep this
257.             IF meld(i) > meld(saveI) THEN saveI = i
258.         END IF
259.         addCard c$(), cds$(i) 'restore card back to 11
260.     NEXT
261.  
262.     ' 11 cards are in c$()
263.     IF card$ = discard$ THEN 'we dont want to take discard unless it makes significant difference
264.         IF dwlow < dwStart THEN 'take discard$ 'it's already in hand
265.             removeCard c$(), cds$(saveI)
266.             card$ = cds$(saveI) 'discard
267.         ELSE 'don't take discard$
268.             removeCard c$(), card$ 'reject the discard
269.         END IF
270.     ELSE 'have to remove something?
271.         removeCard c$(), cds$(saveI) ' remove from c$() to get it to 10
272.         card$ = cds$(saveI) ' pass it back in card variable
273.     END IF
274.     cMeldPts = cMeldTotal(c$(), nD) 'update current cMeldPts
275.     cND = nD
276. END SUB
277.  
278. ' This is key to Grin Rummy Game. This is a C for crosswords version of cMeldTotal.
279. ' Crosswords means a card can be used both in a group set and straight set in making meld.
280. ' Since Grin Rummy is based on cMeldTotal points there is extra credit for using a card twice!
281. FUNCTION cMeldTotal% (a$(), nDeadCards) 'return Meld Point Total and nDeadCards
282.     REDIM sSets$(0), gSets$(0) 'although 0 based these sets have first element at 1 as they are added in by sAppend SUB
283.     DIM r, c, quit, cStart, cEnd, set$, ci, count 'finding meld sets
284.     REDIM cards$(0) 'make a list of cards while at it (in counting Group sets block)
285.     ' checking for card intersets between gSet and sSet
286.     DIM si, gi '           index for each of these arrays of sets
287.     DIM nsCards, ngCards ' number of cards in the single set
288.  
289.     'sets with card intersects removed now time to count cMeldTotal
290.     DIM nCards, cardI, n 'card Count, card index and another index
291.  
292.     FOR r = 0 TO 3 'look for straights
293.         c = 0: quit = 0
294.         DO WHILE quit = 0 AND c < 13
295.             WHILE a$(c, r) = ""
296.                 c = c + 1
297.                 IF c > 11 THEN quit = 1: EXIT WHILE
298.             WEND
299.             IF c < 11 THEN
300.                 cStart = c
301.                 WHILE a$(c, r) <> ""
302.                     c = c + 1
303.                     IF c = 13 THEN quit = 1: EXIT WHILE
304.                 WEND
305.                 IF c = 13 THEN cEnd = 12 ELSE cEnd = c - 1
306.                 IF cEnd - cStart + 1 > 2 THEN
307.                     set$ = ""
308.                     FOR ci = cStart TO cEnd
309.                         set$ = set$ + a$(ci, r)
310.                         cMeldTotal% = cMeldTotal% + points(a$(ci, r))
311.                     NEXT
312.                     sAppend sSets$(), set$
313.                 END IF
314.                 IF c > 11 THEN quit = 1
315.             ELSE
316.                 EXIT DO
317.             END IF
318.         LOOP
319.     NEXT
320.     FOR c = 0 TO 12 ' now for the groups and make a list of cards
321.         count = 0
322.         FOR ci = 0 TO 3
323.             IF a$(c, ci) <> "" THEN count = count + 1: sAppend cards$(), a$(c, ci) 'add to card list
324.         NEXT
325.         IF count > 2 THEN
326.             set$ = ""
327.             FOR ci = 0 TO 3
328.                 IF a$(c, ci) <> "" THEN set$ = set$ + a$(c, ci): cMeldTotal% = cMeldTotal% + points(a$(c, ci))
329.             NEXT
330.             sAppend gSets$(), set$
331.         END IF
332.     NEXT
333.     ' meld is counted but how many dead cards left?
334.     nCards = UBOUND(cards$)
335.     FOR si = 1 TO UBOUND(sSets$)
336.         IF sSets$(si) <> "" THEN
337.             nsCards = LEN(sSets$(si)) / 3
338.             FOR cardI = 1 TO nsCards
339.                 FOR n = 1 TO nCards
340.                     IF cards$(n) = MID$(sSets$(si), cardI * 3 - 2, 3) THEN cards$(n) = ""
341.                 NEXT
342.             NEXT
343.         END IF
344.     NEXT
345.     FOR gi = 1 TO UBOUND(gSets$)
346.         IF gSets$(gi) <> "" THEN
347.             ngCards = LEN(gSets$(gi)) / 3
348.             FOR cardI = 1 TO ngCards
349.                 FOR n = 1 TO nCards
350.                     IF cards$(n) = MID$(gSets$(gi), cardI * 3 - 2, 3) THEN cards$(n) = ""
351.                 NEXT
352.             NEXT
353.         END IF
354.     NEXT
355.     'ok melded cards cleaned out
356.     nDeadCards = 0
357.     FOR n = 1 TO nCards
358.         IF cards$(n) <> "" THEN
359.             nDeadCards = nDeadCards + 1
360.         END IF
361.     NEXT
362. END FUNCTION
363.  
364. FUNCTION dealCard$
365.     dealCard$ = deck$(deckPointer): deckPointer = deckPointer + 1
366. END SUB
367.  
368. FUNCTION points% (card$)
369.     DIM place
370.     place = INSTR(" A 2 3 4 5 6 7 8 910 J Q K", MID$(card$, 1, 2))
371.     IF (place + 1) / 2 < 10 THEN points% = (place + 1) / 2 ELSE points% = 10
372. END FUNCTION
373.  
374. SUB addCard (a$(), card$)
375.     PRINT card$
376.     DIM r, c
377.     r = INSTR(CHR$(3) + CHR$(4) + CHR$(5) + CHR$(6), RIGHT$(card$, 1)) - 1: c = (INSTR(" A 2 3 4 5 6 7 8 910 J Q K", MID$(card$, 1, 2)) - 1) / 2
378.     a$(c, r) = card$
379. END SUB
380.  
381. SUB removeCard (a$(), card$)
382.     DIM r, c
383.     r = INSTR(CHR$(3) + CHR$(4) + CHR$(5) + CHR$(6), RIGHT$(card$, 1)) - 1: c = (INSTR(" A 2 3 4 5 6 7 8 910 J Q K", MID$(card$, 1, 2)) - 1) / 2
384.     a$(c, r) = ""
385. END SUB
386.  
387. 'modified for this app
388. SUB yCP (y, s$) 'for xmax pixel wide graphics screen Center Print at pixel y row
389.     _PRINTSTRING ((_WIDTH - 220 - LEN(s$) * 8) / 2, y), s$
390. END SUB
391.  
392. 'this sub uses drwBtn
393. FUNCTION getButtonNumberChoice% (choice$()) 'developed for this app but likely can use as is elsewhere
394.     DIM ub, b, oldmouse, mx, my, mb
395.  
396.     ub = UBOUND(choice$)
397.     FOR b = 0 TO ub
398.         drwBtn xmax - 210, b * 60 + 90, choice$(b)
399.     NEXT
400.     oldmouse = -1
401.     DO
402.         WHILE _MOUSEINPUT: WEND
403.         mx = _MOUSEX: my = _MOUSEY: mb = _MOUSEBUTTON(1)
404.         IF mb AND oldmouse = 0 THEN
405.             IF mx > xmax - 210 AND mx <= xmax - 10 THEN
406.                 FOR b = 0 TO ub
407.                     IF my >= b * 60 + 90 AND my <= b * 60 + 140 THEN
408.                         LINE (xmax - 210, 0)-(xmax, ymax), bColor, BF
409.                         getButtonNumberChoice% = b: EXIT FUNCTION
410.                     END IF
411.                 NEXT
412.                 BEEP
413.             ELSE
414.                 BEEP
415.             END IF
416.         END IF
417.         oldmouse = _MOUSEBUTTON(1)
418.         _LIMIT 200
419.     LOOP
420. END FUNCTION
421.  
422. SUB drwBtn (x, y, s$) '200 x 50
423.     DIM th, tw, gray~&
424.     th = 16: tw = 8 * LEN(s$): gray~& = _RGB32(190, 190, 190)
425.     LINE (x, y)-STEP(204, 54), _RGB32(0, 0, 0), BF
426.     LINE (x - 2, y - 2)-STEP(201, 51), _RGB32(255, 255, 255), BF
427.     LINE (x, y)-STEP(200, 50), gray~&, BF
428.     COLOR _RGB32(0, 0, 0), gray~&
429.     _PRINTSTRING (x + 100 - 4 * LEN(s$), y + 17), s$
430.     COLOR white, bColor
431. END SUB
432.  
433. SUB sAppend (arr() AS STRING, addItem$)
434.     REDIM _PRESERVE arr(LBOUND(arr) TO UBOUND(arr) + 1) AS STRING
435.     arr(UBOUND(arr)) = addItem$
436. END SUB
437.  
438. FUNCTION ts$ (number)
439.     ts$ = _TRIM$(STR$(number))
440. END FUNCTION
441.  

In the zip there is a txt file included you can read out of the opening screen if shell to your txt editor works for your QB64. You don't really need it but it's there for an introduction.

Oh by the way, this is all mouse so after you see a GRIN :) button just click the screen for next round or game.

Time just flies by when I am playing this one.

[Cobalt]

not sure just how your game handles it exactly but reading the comments seems that you can use the same card twice?. In the INTV version you can't use the same card twice, so if you had 3D,3H,3C  and you had 2H4H5H  that 3H cant be used both as a 3-of-a-kind as well as the 4 card straight of hearts too. its one or the other. you would need the 3S as well to win that hand.

[bplus]

not sure just how your game handles it exactly but reading the comments seems that you can use the same card twice?. In the INTV version you can't use the same card twice, so if you had 3D,3H,3C  and you had 2H4H5H  that 3H cant be used both as a 3-of-a-kind as well as the 4 card straight of hearts too. its one or the other. you would need the 3S as well to win that hand.

Yes I know in regular Gin Rummy you aren't allowed to use the same card in a straight and a group set. And that is what I did with the latest code for Grim Rummy variation and that is what hung me up for months trying to get that to work out.

BUT
For the "Grin" Rummy variation there was no way I could make the game play as well as it does enforcing 1 card 1 set rule. So I stuck to my old version for that written back in May. It just plays better IMHO, what can I say?
I explained some of this in the little txt file that I included in the zip and probably in notes at top of code.

Anyway, doing these Gin Rummy variations I have more fun inventing games than sticking strictly to old ways.

I am not done, a regular version of the game probably with regular card images are still in my plans for future. I sure as heck am not going to waste that hard won optimizer code by saying I am done with Gin Rummy with that older Grin Rummy variation.

Thanks for checking it out Cobalt.

[Cobalt]

I DID IT!
I DID IT!

Finally a 10 straight! Quite possibly thee hardest way to win a hand!

[bplus]

Wow! That has to be more rare than Royal Flush, well I guess you can draw more cards but a sequence of 10 is something!

Cobalt is this from a game you are working on or from Intellivision's Royal Dealer?