Same Birthday Within A Group

[Qwerkey]

The likelihood of two people within a group in a room having the same birthday is higher than you first might think.  For example, in a group of just 23 people there is about a 50–50 chance that two of them will have the same birthday.

This apparently high likelihood has to do with all the possible combinations, rather than 1/365 times 23.  The mathematicians amongst us will understand this properly and will be aghast at my being unable to explain it clearly.  I'm only an engineer and can't be expected to understand this stuff!

So, I thought that I'd test this out, which is easily done in code.  Generate an array of "people" each with a random birthday (the code even takes into account February 29th) and then test all pairs for the same birthday.  Mathematicians have derived the probability from theory, and the program plots the results against this theory.

You will not be surprised that the output is very close to theory - isn't mathematics wonderful?  You will see the program results plotted along the same curve as the theory (you have to look closely) with some vertical error derived from sampling errors.

You will need the image file.

Code: QB64: [Select]

1. 'Who has the same birthday?
2. 'Image from edscave.com
3.  
4. CONST False = 0, True = NOT False, Qty% = 3000
5.  
6. RANDOMIZE (TIMER)
7. DIM Days%(1460)
8.  
9. 'Populate an array with equal probability of 1 to 365, with 366 having a quarter of this probability
10. 'This accounts for February 29th
11. FOR N% = 0 TO 3
12.     FOR M% = 0 TO 364
13.         Days%(N% * 365 + M%) = M% + 1
14.     NEXT M%
15. NEXT N%
16. Days%(1460) = 366
17.  
18. SCREEN _NEWIMAGE(600, 400, 32)
19. _DEST 0
20. COLOR _RGB32(255, 100, 0), _RGB32(255, 255, 255)
21. CLS
22. 'Image of probability from theory
23. _PUTIMAGE (0, 0)-(599, 399), _LOADIMAGE("P_SharedBirthday.png", 32)
24.  
25. 'LINE (80, 338)-(90, 338) Construction lines to find origin and top-right of graph
26. 'LINE (85, 333)-(85, 343) to get scale of plotting graph
27. 'LINE (567, 51)-(567, 61)
28. 'LINE (562, 56)-(572, 56)
29.  
30. LINE (0, 0)-(599, 399), _RGBA32(120, 120, 120, 150), BF
31.  
32. PrevX% = 85 + CINT(4.82)
33. PrevY% = 338
34. _DELAY 1.5
35.  
36. FOR NoFolks% = 2 TO 100
37.     REDIM Birthdays%(NoFolks% - 1)
38.     NoSame% = 0
39.     FOR N% = 1 TO Qty%
40.         'Randomise birthdays of participants
41.         FOR M% = 0 TO NoFolks% - 1
42.             Birthdays%(M%) = Days%(INT(RND * 1461))
43.         NEXT M%
44.         'Now find any pairs whose birthdays are the same
45.         TwoSame%% = False
46.         I% = 1
47.         J% = 2
48.         WHILE NOT TwoSame%% AND I% < NoFolks%
49.             IF Birthdays%(I% - 1) = Birthdays%(J% - 1) THEN
50.                 TwoSame%% = True
51.             ELSE
52.                 J% = J% + 1
53.                 IF J% > NoFolks% THEN
54.                     I% = I% + 1
55.                     J% = I% + 1
56.                 END IF
57.             END IF
58.         WEND
59.         IF TwoSame%% THEN NoSame% = NoSame% + 1
60.     NEXT N%
61.     RANDOMIZE (TIMER)
62.     'Print probabilities onto theoretical graph
63.     LINE (PrevX%, PrevY%)-(85 + CINT(4.82 * NoFolks%), CINT(338 - 2.82 * NoSame% * 100 / Qty%)) ', _RGB32(255, 255, 0)
64.     PrevX% = 85 + CINT(4.82 * NoFolks%)
65.     PrevY% = CINT(338 - 2.82 * NoSame% * 100 / Qty%)
66.     _DELAY 0.1
67. NEXT NoFolks%
68.  
69. WHILE INKEY$ = ""
70.     _LIMIT 30
71. WEND
72. SYSTEM
73.  

[STxAxTIC]

I like it. Search the attached for "birthday".

[bplus]

Yeah I like seeing math ideas demo'd in QB64.

For convenience when images are required, I recommend and request putting an image and source in zip or 7z so one gets everything one needs in single download.

Instead of using a line, this will show your data points that contrast better with theoretic graph.

Code: QB64: [Select]

1.     'Print prabilities onto theoretical graph
2.     CIRCLE (85 + CINT(4.82 * NoFolks%), CINT(338 - 2.82 * NoSame% * 100 / Qty%)), 2, &HFFFFFFFF
3.  

[bplus]

Here is an alternate approach: https://www.qb64.org/forum/index.php?topic=2507.msg117590#msg117590

using sort to stack duplicates in a sorted array.

[SMcNeill]

Explaining it really isn't that difficult.  Let's say we have 60 people in a room.  Random distribution says that our average is 5 birthdays each month.

In any given month, let's use 30 days for the day of the month.  Our first birthday can be on any day.  The second birthday has a 1 in 30 chance of being on that same day.  The 3rd birthday has a 1 in 30 chance of being on the same day.  The 4th birthday has a 1 in 30 chance of being on the same day.  The 5th birthday has a 1 in 30 chance of being on the same day.

There's a 4 in 30 chance that somebody has the same birthday as the first guy.

With 5 guys, there's still the chance that the other 4 have birthdays on the same day, even if they don't share them with the first guy.  I'm thinking the chance would be 4/30 + 3/30 + 2/30 + 1/30 for a total 10/30, or 1 in 3 chance of two people sharing the same birthday, in the first month...

With 12 months, you have 12 * 1 in 3 chances that out of a group of 60, some two people share birthdays -- and if that's not 100%, it's close enough to it to call it that!  ;)