Fire Effect!

[Ashish]

Hi everyone! :)
Just after coding water ripple effect, I started studing about simulating fire and this page helps me lot - http://lodev.org/cgtutor/fire.html
This simulation looks kinda real effect!
Just check the code below. :)

Code: QB64: [Select]

1. 'Simple Fire Effect coded By Ashish. Just for Practice :D
2. 'http://lodev.org/cgtutor/fire.html
3. RANDOMIZE TIMER
4. _TITLE "Fire Effect"
5. SCREEN _NEWIMAGE(300, 300, 32)
6.  
7. DIM fireBuffer(_WIDTH + 2, _HEIGHT), colorPal(256) AS _UNSIGNED LONG
8.  
9. 'creating our palette for fire
10. FOR i = 255 TO 0 STEP -1
11.     IF i <= 255 AND i >= 200 THEN 'white to yellow
12.         colorPal(i) = _RGB(map(i, 255, 200, 255, 255), map(i, 255, 200, 255, 242), map(i, 255, 200, 255, 0))
13.     ELSEIF i <= 201 AND i >= 90 THEN 'yellow to orange
14.         colorPal(i) = _RGB(map(i, 201, 90, 255, 221), map(i, 201, 90, 242, 140), map(i, 201, 90, 0, 0))
15.     ELSEIF i <= 89 AND i >= 79 THEN 'orange to dark orange red
16.         colorPal(i) = _RGB(map(i, 89, 79, 221, 183), map(i, 89, 79, 140, 45), map(i, 89, 79, 0, 0))
17.     ELSEIF i <= 78 AND i >= 48 THEN 'dark orange red to dark grey
18.         colorPal(i) = _RGB(map(i, 78, 48, 183, 10), map(i, 78, 48, 45, 10), map(i, 78, 48, 0, 10))
19.     ELSEIF i <= 47 AND i >= 27 THEN 'dark grey to light grey
20.         colorPal(i) = _RGBA(map(i, 47, 27, 10, 40), map(i, 47, 27, 10, 40), map(i, 47, 27, 10, 40), map(i, 47, 27, 255, 100))
21.     ELSEIF i <= 26 AND i >= 0 THEN 'light grey to black
22.         colorPal(i) = _RGBA(map(i, 26, 0, 40, 0), map(i, 26, 0, 40, 0), map(i, 26, 0, 40, 0), map(i, 26, 0, 100, 0))
23.     END IF
24. NEXT
25. 'creating an image,  placing  a text, and storing the white pixel in an array
26. tmp& = _NEWIMAGE(94, 20, 32)
27. _DEST tmp&
28. _PRINTSTRING (5, 0), "QB64 Rocks!"
29. _DEST 0
30. _PUTIMAGE (0, 100)-(282, 160), tmp&
31. FOR i = 100 TO 160
32.     FOR j = 0 TO 282
33.         IF POINT(j, i) = _RGB(255, 255, 255) THEN n = n + 1
34. NEXT j, i
35. DIM textPixelPosX(n), textPixelPosY(n)
36. n = 1
37. FOR i = 100 TO 160
38.     FOR j = 0 TO 282
39.         IF POINT(j, i) = _RGB(255, 255, 255) THEN textPixelPosX(n) = j: textPixelPosY(n) = i: n = n + 1
40. NEXT j, i
41.  
42. t# = TIMER
43. DO
44.     IF TIMER - t# > 1.8 THEN
45.         xOff = p5random(-100, 100)
46.         yOff = p5random(-70, 70)
47.         'using stored pixel array to display fire text
48.         FOR i = 0 TO n - 1
49.             xx = textPixelPosX(i) + xOff
50.             yy = textPixelPosY(i) + yOff
51.             IF xx > 1 AND xx < _WIDTH - 1 AND yy > 1 AND yy < _HEIGHT - 1 THEN fireBuffer(xx, yy) = p5random(100, 255)
52.         NEXT
53.         t# = TIMER
54.     END IF
55.     CLS
56.     FOR x = 0 TO _WIDTH
57.         fireBuffer(x, _HEIGHT - 1) = p5random(10, 255)
58.     NEXT
59.     FOR y = 0 TO _HEIGHT - 2
60.         FOR x = 1 TO _WIDTH - 1
61.             fireBuffer(x, y) = (fireBuffer(x - 1, y + 1) + fireBuffer(x, y + 1) + fireBuffer(x + 1, y + 1) + fireBuffer(x, y + 2)) * .2441
62.     NEXT x, y
63.  
64.     FOR x = 0 TO _WIDTH - 1
65.         FOR y = 0 TO _HEIGHT - 1
66.             PSET (x, y), colorPal(INT(fireBuffer(x, y)))
67.     NEXT y, x
68.     _DISPLAY
69.     _LIMIT 60
70. LOOP
71.  
72. 'taken from p5js.bas
73. 'https://bit.ly/p5jsbas
74. FUNCTION map! (value!, minRange!, maxRange!, newMinRange!, newMaxRange!)
75.     map! = ((value! - minRange!) / (maxRange! - minRange!)) * (newMaxRange! - newMinRange!) + newMinRange!
76. END FUNCTION
77.  
78. FUNCTION p5random! (mn!, mx!)
79.     IF mn! > mx! THEN
80.         SWAP mn!, mx!
81.     END IF
82.     p5random! = RND * (mx! - mn!) + mn!
83. END FUNCTION
84.  
85.  

[FellippeHeitor]

Looks awesome, Ashish, great job

Coding Train for the win! :-)

[Ashish]

Looks awesome, Ashish, great job

Coding Train for the win! :-)

Thanks! :D

[bplus]

Yeah another discoverer of fire!