Chrome's dinosaur game prototype

[FellippeHeitor]

This guy writes a prototype of the dino game you find in Chrome's offline page:

The original is written in javascript, code at https://github.com/TylerPottsDev/chrome-dino-replica/blob/master/main.js, and here's the translation of that code to QB64:

Jump with the spacebar or up arrow, crouch/duck with left shift key or down arrow.

Code: QB64 $NOPREFIX: [Select]

1. $NOPREFIX
2. OPTION EXPLICIT
3.  
4. CONST true = -1, false = NOT true
5.  
6. TYPE Actor
7.     index AS LONG
8.  
9.     x AS SINGLE
10.     y AS SINGLE
11.     w AS SINGLE
12.     h AS SINGLE
13.     c AS UNSIGNED LONG
14.  
15.     dy AS SINGLE
16.     dx AS SINGLE
17.     jumpForce AS SINGLE
18.     originalHeight AS SINGLE
19.     grounded AS BYTE
20.     jumpTimer AS SINGLE
21.  
22.     state AS BYTE
23. END TYPE
24.  
25. DIM SHARED score AS UNSIGNED INTEGER64
26. DIM SHARED highScore AS UNSIGNED INTEGER64
27.  
28. DIM canvas AS LONG
29. canvas = NEWIMAGE(800, 300, 32)
30. SCREEN canvas
31.  
32. DIM SHARED gravity AS SINGLE, gameSpeed AS SINGLE
33. DIM SHARED initialSpawnTimer AS SINGLE, spawnTimer AS SINGLE
34. DIM SHARED gameOver AS BYTE
35. initialSpawnTimer = 200
36.  
37. DO
38.     gravity = 1
39.     gameSpeed = 3
40.     spawnTimer = initialSpawnTimer
41.     score = 0
42.     gameOver = false
43.  
44.     DIM SHARED player AS Actor
45.     player.x = 100
46.     player.y = 0
47.     player.w = 50
48.     player.h = 50
49.     player.originalHeight = player.h
50.     player.c = RGB32(255, 0, 0)
51.     player.jumpForce = 10
52.     player.grounded = false
53.  
54.     REDIM SHARED obstacles(100) AS Actor
55.  
56.     DO
57.         update
58.         DISPLAY
59.         LIMIT 60
60.     LOOP UNTIL gameOver
61. LOOP
62.  
63. SUB update
64.     DIM i AS LONG
65.     LINE (0, 0)-(WIDTH, HEIGHT), RGB32(255, 200), BF
66.  
67.     spawnTimer = spawnTimer - 1
68.     IF spawnTimer <= 0 THEN
69.         spawnObstacle
70.         spawnTimer = initialSpawnTimer - gameSpeed * 8
71.  
72.         IF spawnTimer < 60 THEN
73.             spawnTimer = 60
74.         END IF
75.     END IF
76.  
77.     FOR i = 1 TO UBOUND(obstacles)
78.         IF obstacles(i).state = true THEN
79.             IF obstacles(i).x + obstacles(i).w < 0 THEN
80.                 obstacles(i).state = false
81.                 CONTINUE
82.             END IF
83.  
84.             IF player.x < obstacles(i).x + obstacles(i).w AND _
85.                player.x + player.w > obstacles(i).x AND _
86.                player.y < obstacles(i).y + obstacles(i).h AND _
87.                player.y + player.h > obstacles(i).y THEN
88.                 gameOver = true
89.                 EXIT SUB
90.             END IF
91.         END IF
92.         updateObstacle i
93.     NEXT
94.  
95.     animate player
96.     score = score + 1
97.  
98.     DIM t AS STRING
99.     t = "Score:" + STR$(score)
100.     PRINTSTRING (25, 0), t
101.  
102.     IF score > highScore THEN
103.         highScore = score
104.     END IF
105.  
106.     t = "Highscore:" + STR$(highScore)
107.     PRINTSTRING (WIDTH - 25 - PRINTWIDTH(t), 0), t
108.  
109.     gameSpeed = gameSpeed + .003
110. END SUB
111.  
112. SUB updateObstacle (i AS LONG)
113.     obstacles(i).x = obstacles(i).x + obstacles(i).dx
114.     drawit obstacles(i)
115.     obstacles(i).dx = -gameSpeed
116. END SUB
117.  
118. SUB spawnObstacle
119.     DIM i AS LONG, kind AS LONG, size AS LONG
120.     FOR i = 1 TO UBOUND(obstacles)
121.         IF obstacles(i).state = false THEN
122.             obstacles(i).index = i
123.             obstacles(i).state = true
124.             size = rand(20, 70)
125.             kind = rand(0, 1)
126.  
127.             obstacles(i).x = WIDTH + size
128.             obstacles(i).y = HEIGHT - size
129.             obstacles(i).w = size
130.             obstacles(i).h = size
131.             obstacles(i).c = RGB32(83, 50, 194)
132.  
133.             IF kind = 0 THEN
134.                 obstacles(i).y = obstacles(i).y - player.originalHeight + 10
135.             END IF
136.             EXIT SUB
137.         END IF
138.     NEXT
139. END SUB
140.  
141. FUNCTION rand& (min AS LONG, max AS LONG)
142.     rand& = ROUND(RND * (max - min) + min)
143. END FUNCTION
144.  
145. SUB animate (this AS Actor)
146.     IF KEYDOWN(32) OR KEYDOWN(18432) THEN 'space or up arrow to jump
147.         jump this
148.     ELSE
149.         this.jumpTimer = 0
150.     END IF
151.  
152.     IF KEYDOWN(100304) OR KEYDOWN(20480) THEN 'left-shift or down arrow to duck
153.         this.h = this.originalHeight / 2
154.     ELSE
155.         this.h = this.originalHeight
156.     END IF
157.  
158.     this.y = this.y + this.dy
159.  
160.     'gravity
161.     IF this.y + this.h < HEIGHT THEN
162.         this.dy = this.dy + gravity
163.         this.grounded = false
164.     ELSE
165.         this.dy = 0
166.         this.grounded = true
167.         this.y = HEIGHT - this.h
168.     END IF
169.  
170.     drawit this
171. END SUB
172.  
173. SUB jump (this AS Actor)
174.     IF this.grounded AND this.jumpTimer = 0 THEN
175.         this.jumpTimer = 1
176.         this.dy = -this.jumpForce
177.     ELSEIF this.jumpTimer > 0 AND this.jumpTimer < 15 THEN
178.         this.jumpTimer = this.jumpTimer + 1
179.         this.dy = -this.jumpForce - (this.jumpTimer / 50)
180.     END IF
181. END SUB
182.  
183. SUB drawit (this AS Actor)
184.     LINE (this.x, this.y)-STEP(this.w, this.h), this.c, BF
185. END SUB

I tried to remain as faithful to the original as possible with QB64. Here's a screenshot:

[bplus]

Cute little game.

I was thinking of Dodge ball after codevsb12 collision inquiry.

[Petr]

Nice game!

 

[TempodiBasic]

fine !
But I like more you game platform....because it has background and more graphic output.

[Ashish]

Good one.... I use to play it my school computer lab when teacher is not there...

[johnno56]

Very nice. Simple but annoyingly addictive... Well done!