Two beeps?

[STxAxTIC]

Why does this code beep twice when you click once:

Code: QB64: [Select]

1. DO
2.     mb = 0
3.  
4.     DO WHILE _MOUSEINPUT
5.         x = _MOUSEX
6.         y = _MOUSEY
7.         IF (x > 0) AND (x < _WIDTH) AND (y > 0) AND (y < _HEIGHT) THEN
8.             IF _MOUSEBUTTON(1) AND (mb = 0) THEN
9.                 BEEP
10.                 mb = 1
11.                 _DELAY .1
12.             ELSE
13.                 mb = 0
14.             END IF
15.         END IF
16.     LOOP
17.  
18.     _LIMIT 60
19. LOOP
20.  

whereas this code beeps once when you click once:

Code: QB64: [Select]

1. DO
2.     mb = 0
3.  
4.     DO WHILE _MOUSEINPUT
5.         x = _MOUSEX
6.         y = _MOUSEY
7.         IF (x > 0) AND (x < _WIDTH) AND (y > 0) AND (y < _HEIGHT) THEN
8.             IF _MOUSEBUTTON(1) THEN
9.                 IF (mb = 0) THEN
10.                     BEEP
11.                     mb = 1
12.                     _DELAY .1
13.                 END IF
14.             ELSE
15.                 mb = 0
16.             END IF
17.         END IF
18.     LOOP
19.  
20.     _LIMIT 60
21. LOOP
22.  

All I've done is fragment the IF statement into two lines, getting rid of an AND operator, and god knows what else under the hood. Can someone straighten me out?

[bplus]

Because (0 AND 0) might just be true!

No it's the ELSE clause

Code: QB64: [Select]

1. DO
2.     mb = 0
3.  
4.     DO WHILE _MOUSEINPUT
5.         x = _MOUSEX
6.         y = _MOUSEY
7.         IF (x > 0) AND (x < _WIDTH) AND (y > 0) AND (y < _HEIGHT) THEN
8.             IF _MOUSEBUTTON(1) AND (mb = 0) THEN
9.                 BEEP
10.                 mb = 1
11.                 _DELAY .1
12.             ELSE '<<<<<<<<<<<<<<<<<<<<<   take out
13.                 'mb = 0
14.             END IF
15.         END IF
16.     LOOP
17.  
18.     _LIMIT 60
19. LOOP
20.  

You don't need any ELSE.

[STxAxTIC]

Oh maybe, yeah that might be it. Yeah that's subtle. Nice catch.

Funny enough the part that you said "take out" just got nixed from my main code. I've been going too fast. Thanks for being a second set of eyes.

[Pete]

The beeping problem with beeps is they take up time. Make a beep, and the time it takes ruins any possibility of recording multiple clicks, like a classic double click, for example. We can get around that with a beeping timer delay, as follows...

Code: QB64: [Select]

1. DO
2.     WHILE _MOUSEINPUT: WEND
3.     IF mb THEN IF _MOUSEBUTTON(1) = 0 THEN mb = 1
4.     x = _MOUSEX
5.     y = _MOUSEY
6.     IF (x > 0) AND (x < _WIDTH) AND (y > 0) AND (y < _HEIGHT) THEN
7.         IF _MOUSEBUTTON(1) THEN
8.             z1 = TIMER
9.             IF mb >= 0 THEN click = click + 1
10.             mb = -1
11.         END IF
12.         IF z1 THEN
13.             IF ABS(z1 - TIMER) >= .2 THEN
14.                 PRINT "Number of clicks = "; click
15.                 FOR i = 1 TO click: BEEP: NEXT: click = 0
16.                 z1 = 0
17.             END IF
18.         END IF
19.     END IF
20.     _LIMIT 60
21. LOOP
22.  

Note: If you're fast enough, this will record triple clicks and maybe even a speed demon like BPlus can squeak out a bit more.

You're beeping welcome,

Pete

[EricE]

On my computer (Win10 Home, version 1903, 64-bit, 3.80 GHz) running QB64 x32 version 1.4, both code examples beep only once for each mouse click!
The double beep does not happen.
Here is the code that I used for testing (basically the same as what STxAxTIC provided).

Code: QB64: [Select]

1. ' uncomment one of the following
2. $LET TWOBEEPS = 1
3. '$LET ONEBEEP = 1
4.  
5.  
6. $IF TWOBEEPS THEN
7.     PRINT "TWO BEEPS"
8.     DO
9.         mb = 0
10.  
11.         DO WHILE _MOUSEINPUT
12.             x = _MOUSEX
13.             y = _MOUSEY
14.             IF (x > 0) AND (x < _WIDTH) AND (y > 0) AND (y < _HEIGHT) THEN
15.                 IF _MOUSEBUTTON(1) AND (mb = 0) THEN
16.                     BEEP
17.                     mb = 1
18.                     _DELAY .1
19.                 ELSE
20.                     mb = 0
21.                 END IF
22.             END IF
23.         LOOP
24.  
25.         _LIMIT 60
26.     LOOP
27. $END IF
28.  
29. $IF ONEBEEP THEN
30.     PRINT "ONE BEEP"
31.     DO
32.         mb = 0
33.  
34.         DO WHILE _MOUSEINPUT
35.             x = _MOUSEX
36.             y = _MOUSEY
37.             IF (x > 0) AND (x < _WIDTH) AND (y > 0) AND (y < _HEIGHT) THEN
38.                 IF _MOUSEBUTTON(1) THEN
39.                     IF (mb = 0) THEN
40.                         BEEP
41.                         mb = 1
42.                         _DELAY .1
43.                     END IF
44.                 ELSE
45.                     mb = 0
46.                 END IF
47.             END IF
48.         LOOP
49.  
50.         _LIMIT 60
51.     LOOP
52.  
53. $END IF
54.  
55.  

[Cobalt]

you might want to clear the mouse buffer too. Unless your the flash with those fingers!
Place this toward the bottom of your loop. It may not be the only issue but it wont hurt either.
DO:LOOP WHILE _MOUSEINPUT

that way there are no extra button clicks in there.

As the IF states mousebutton AND mb=0 the else doesn't really matter unless there is an extra button press to AND with it.  Nowif it was an OR then multiple beeps can ensue(though it would be more than 2)

what I am trying to say is  FALSE and TRUE don't pass go.  so if no mouse click and MB=0 you can't beep.
(and mousebutton returns 0 or -1)

Because (0 AND 0) might just be true!

You were joking right Bplus!??

STxAxTIC, I take it you mean you click on that area ONCE and get TWO beeps? or do you mean you click on the area multiple times and still get a beep??

[bplus]

The beeping problem with beeps is they take up time. Make a beep, and the time it takes ruins any possibility of recording multiple clicks, like a classic double click, for example. We can get around that with a beeping timer delay, as follows...

Code: QB64: [Select]

1. DO
2.     WHILE _MOUSEINPUT: WEND
3.     IF mb THEN IF _MOUSEBUTTON(1) = 0 THEN mb = 1
4.     x = _MOUSEX
5.     y = _MOUSEY
6.     IF (x > 0) AND (x < _WIDTH) AND (y > 0) AND (y < _HEIGHT) THEN
7.         IF _MOUSEBUTTON(1) THEN
8.             z1 = TIMER
9.             IF mb >= 0 THEN click = click + 1
10.             mb = -1
11.         END IF
12.         IF z1 THEN
13.             IF ABS(z1 - TIMER) >= .2 THEN
14.                 PRINT "Number of clicks = "; click
15.                 FOR i = 1 TO click: BEEP: NEXT: click = 0
16.                 z1 = 0
17.             END IF
18.         END IF
19.     END IF
20.     _LIMIT 60
21. LOOP
22.  

Note: If you're fast enough, this will record triple clicks and maybe even a speed demon like BPlus can squeak out a bit more.

You're beeping welcome,

Pete

Cool Game!

[bplus]

On my computer (Win10 Home, version 1903, 64-bit, 3.80 GHz) running QB64 x32 version 1.4, both code examples beep only once for each mouse click!
The double beep does not happen.
Here is the code that I used for testing (basically the same as what STxAxTIC provided).

Code: QB64: [Select]

1. ' uncomment one of the following
2. $LET TWOBEEPS = 1
3. '$LET ONEBEEP = 1
4.  
5.  
6. $IF TWOBEEPS THEN
7.     PRINT "TWO BEEPS"
8.     DO
9.         mb = 0
10.  
11.         DO WHILE _MOUSEINPUT
12.             x = _MOUSEX
13.             y = _MOUSEY
14.             IF (x > 0) AND (x < _WIDTH) AND (y > 0) AND (y < _HEIGHT) THEN
15.                 IF _MOUSEBUTTON(1) AND (mb = 0) THEN
16.                     BEEP
17.                     mb = 1
18.                     _DELAY .1
19.                 ELSE
20.                     mb = 0
21.                 END IF
22.             END IF
23.         LOOP
24.  
25.         _LIMIT 60
26.     LOOP
27. $END IF
28.  
29. $IF ONEBEEP THEN
30.     PRINT "ONE BEEP"
31.     DO
32.         mb = 0
33.  
34.         DO WHILE _MOUSEINPUT
35.             x = _MOUSEX
36.             y = _MOUSEY
37.             IF (x > 0) AND (x < _WIDTH) AND (y > 0) AND (y < _HEIGHT) THEN
38.                 IF _MOUSEBUTTON(1) THEN
39.                     IF (mb = 0) THEN
40.                         BEEP
41.                         mb = 1
42.                         _DELAY .1
43.                     END IF
44.                 ELSE
45.                     mb = 0
46.                 END IF
47.             END IF
48.         LOOP
49.  
50.         _LIMIT 60
51.     LOOP
52.  
53. $END IF
54.  
55.  

" ... (basically the same as what STxAxTIC provided)."

Except you are using metacommands???  and

Code: QB64: [Select]

1. $LET TWOBEEPS = 1

fuzzy math ;-))

[bplus]

Quote from: bplus on Yesterday at 12:03:11 PM
Because (0 AND 0) might just be true!
You were joking right Bplus!??

I was looking at

Code: QB64: [Select]

1. IF _MOUSEBUTTON(1) AND (mb = 0) THEN
2.  

and seeing when mb = 0 then (mb = 0) evaluates to true so if (_MOUSEBUTTON(1) = 0) also you have a true evaluation but we don't have IF (_MOUSEBUTTON(1) = 0) AND (mb = 0) THEN but it was sorta like having two things = 0 so getting a true evaluation from AND but I started typing before my brain caught up with my fingers, thought it kinda funny so kept it. So yeah, joking :)