double click

[krovit]

Hi all,

I have to give up... can you help me understand, please, where is the error in this example?
Can you enter the missing code?

Code: QB64: [Select]

1.  DO
2.         j$ = INKEY$          'other controls
3.         xxw& = _KEYHIT   'other controls
4.  
5.         num_click=0    
6.         the_end=0            'other controls
7.  
8.  
9.  
10. ' here one o double click control missing code
11. '--------------------------------------------------
12.  
13.  
14.  
15.  
16.  
17. LOOP UNTIL j$ <> "" OR the_end > 0
18.  
19.  
20. ? num_click
21.  
22.  

I can't insert the wiki example.
I had solved the single click but now I need to monotorate the second click.

[krovit]

Code: QB64: [Select]

1.  DO
2.         j$ = INKEY$
3.         xxw& = _KEYHIT
4.  
5.         num_click=0    
6.         the_end=0  
7.  
8.    
9.         DO WHILE _MOUSEINPUT                'check mouse status
10.                 mb% = _MOUSEBUTTON(1)
11.         LOOP
12.         DO WHILE mb%                 'check for button release
13.                 i = _MOUSEINPUT
14.                 mb% = _MOUSEBUTTON(1)
15.                 num_click=1
16.         LOOP
17.  
18.         IF num_click = 1 THEN                   'if button was pressed and released
19.                 t = TIMER + .3
20.                 DO WHILE TIMER < t      'check for a second press within .3 seconds
21.                         i = _MOUSEINPUT
22.                         IF _MOUSEBUTTON(1) THEN num_click = 2': EXIT DO
23.                 LOOP
24.                 'IF num_click>0 then exit do
25.         END IF
26.  
27.  
28. LOOP UNTIL j$ <> "" OR the_end > 0 or num_click>0
29.  
30.  
31. ? num_click
32.  
33.  

So it works but then, inserting it into the real program, no. Maybe it's some variable that disturbs...

In any case is this the cleanest code to monitor the double click or do you think and be another more efficient?

Thank you

[bplus]

OK same menu demo I gave you last time now with modification for Double Click detection:

Code: QB64: [Select]

1. _TITLE "press menu number key or Double Click Menu Item" 'b+ 2020-02-16
2. WHILE 1
3.     CLS
4.     PRINT "Press menu # key or double click menu item:"
5.     FOR m = 1 TO 8
6.         ms$ = _TRIM$(STR$(m))
7.         PRINT ms$; ") Menu item "; ms$
8.     NEXT
9.     PRINT "9) Quit this demo"
10.  
11.  
12.     k$ = INKEY$ '<<<<<<<<<<<<<<<<<<< update k$
13.     WHILE _MOUSEINPUT: WEND ' <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< update mouse status
14.  
15.     ' ++++++++++++++++++++++++++++++++++++ Report Stuff +++++++++++++++++++++++++++++++++++++++++++++++
16.     mb = _MOUSEBUTTON(1) OR _MOUSEBUTTON(2) OR _MOUSEBUTTON(3) ' >>>>>>>>>>>>> report mouse status
17.     mx = _MOUSEX: my = _MOUSEY
18.     PRINT
19.     PRINT "INKEY$:"; k$; "   _MOUSEBUTTON(X) pressed "; mb; "  Current _MOUSEX"; mx; "  Current _MOUSEY"; my
20.     PRINT
21.     '-------------------------------------------------------------------------------------------------------
22.  
23.     IF mb AND oldMouse = 0 OR LEN(k$) THEN '>>>>> wait for oldMouse to clear to 0  so you know mb is new one!
24.         IF TIMER(.001) - lastTime < 0 THEN curTime = TIMER(.001) + 24 * 60 * 60 ELSE curTime = TIMER(.001)
25.         IF curTime - lastTime < .3 THEN 'double = two clicks in less than .3 sec
26.             mb2 = 1
27.         ELSE
28.             lastTime = curTime 'save last click time
29.             mb2 = 0 'clear last double click report
30.         END IF
31.         FOR m = 1 TO 9
32.             IF mb2 AND my = m + 1 OR k$ = _TRIM$(STR$(m)) THEN 'for screen 0 or default my = line number
33.                 PRINT "You selected menu"; m: _DELAY 2
34.                 IF m = 9 THEN SYSTEM
35.             END IF
36.         NEXT
37.     END IF
38.  
39.     'save last mouse status
40.     oldMouse = mb ' <<<  comment on and off to see difference when hold mouse button down and go up and down menu
41.     '          oldMouse will wait until you release mousebutton before accepting another menu selection
42.  
43.  
44.     _LIMIT 60
45. WEND
46.  
47.  
48.  
49.  

EDIT add comments

EDIT 2: before Steve reminds us of Midnight problem here is the fix.

[krovit]

Thank you, it actually seems like the best, clean and efficient routine.

I can't import it into my program but maybe it depends on the complexity of the function in which I want to insert it.
And the flow of execution is probably not as efficient.
It's going to take me some time...

[bplus]

Does not port?

Aha! I see a problem trying to get INKEY$ when mouse polling is done outside main loop where INKEY$ polling is.

So do INKEY$ (and/or _KEYHIT) with mouse polling in a portable FUNCTION:

Code: QB64: [Select]

1. _TITLE "press menu number key or Double Click Menu Item" 'b+ 2020-02-18
2. DIM SHARED k$
3. WHILE 1
4.     CLS
5.     PRINT "Press menu # key or double click menu item:"
6.     FOR m = 1 TO 8
7.         ms$ = _TRIM$(STR$(m))
8.         PRINT ms$; ") Menu item "; ms$
9.     NEXT
10.     PRINT "9) Quit this demo"
11.  
12.     '====================================  evaluate for double click ======================================
13.     IF singleClick%(mx, my, k$) THEN
14.         IF TIMER(.001) - lastTime < 0 THEN curTime = TIMER(.001) + 24 * 60 * 60 ELSE curTime = TIMER(.001)
15.         IF curTime - lastTime < .3 THEN 'double = two clicks in less than .3 sec
16.             mb2 = 1
17.         ELSE
18.             lastTime = curTime 'save last click time
19.             mb2 = 0 'clear last double click report
20.         END IF
21.     END IF
22.     ' ================================== use mb2, mx, my for double click existence and location ==========
23.  
24.     ' mF = 0 ' Demo using keypress or double click info
25.     FOR m = 1 TO 9
26.         IF mb2 AND my = m + 1 OR k$ = _TRIM$(STR$(m)) THEN 'for screen 0 or default my = line number
27.             PRINT "You selected menu"; m: _DELAY 2
28.             IF m = 9 THEN SYSTEM
29.             'mF = 1
30.         END IF
31.     NEXT
32.  
33.     ' Demo use single click info when doesn't interfere with dbl click evaluation, ie doesn't delay 2nd click detection
34.     IF my > 10 THEN PRINT " You clicked outside then menu area: col"; mx; ", row"; my: _DELAY 2
35.     IF LEN(k$) THEN PRINT "You pressed "; k$: _DELAY 2
36. WEND
37.  
38. FUNCTION singleClick% (atX, atY, K$) 'this function waits until mousebutton is pressed and released or a key is pressed
39.     _KEYCLEAR: atX = -1: atY = -1
40.     DO
41.         K$ = INKEY$ '<<<<<<<<<<<<<<<<<<< update k$
42.         WHILE _MOUSEINPUT: WEND ' <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< update mouse status
43.         mb = _MOUSEBUTTON(1) OR _MOUSEBUTTON(2) OR _MOUSEBUTTON(3) ' >>>>>>>>>>>>> report mouse status
44.         mx = _MOUSEX: my = _MOUSEY
45.  
46.         '___________________________________ Comment this block out in app _______________________________________________
47.         LOCATE 15
48.         PRINT
49.         PRINT "INKEY$:"; K$; "   _MOUSEBUTTON(X) pressed "; mb; "  Current _MOUSEX"; mx; "  Current _MOUSEY"; my
50.         PRINT
51.  
52.  
53.         IF mb AND oldMouse = 0 THEN '>>>>> wait for oldMouse to clear to 0  so you know mb is new one!
54.             singleClick% = -1: atX = mx: atY = my
55.         END IF
56.         oldMouse = mb
57.         _LIMIT 200 '<<<<<<<<<<<<<<<<<<<<<<<<<< reduce if you want to see a keypress flash
58.     LOOP UNTIL singleClick% AND oldMouse = 0 OR LEN(K$) 'hang until mouse button is released
59. END FUNCTION
60.  
61.  
62.  

Edit again: I keep finding improvements

[krovit]

Maybe it's like you say.

I'm going crazy trying to understand why when it enters the routine at the first click it already thinks it has double clicked and then exits...

The version you posted is improved and even more effective than the previous one. But I'm going crazy trying...




My programs has tens of thousands of lines ... posting it is impossible. If I say it again to explain the problem, it simplifies too much.

The application are all parametric and modular.
A series of fields can be selected with the keyboard and with the mouse.
With a first click jump to the position of the field.
With the second click ... nothing happens. And that's okay!
In fact the second click, only in certain fields, activates a drop-down menu. Alternatively, on that field, I press CTRL+Enter and I get the same result.

Everything worked fine until I realized how useful it is to activate the drop-down menu with a double click.
I can't insert double click! when I'm on the field (because I pressed a click or because I got there by scrolling through the fields with the keyboard) I can't manage the double click: it doesn't notice and during the attempts I get to the maximum that the first click is already mistaken for the second and activate - or try to activate even where it doesn't exist - the drop-down menu.

I understand that it is difficult to understand in words... but in fact I seem to move your routines to the right position of mine but it no longer works! It's really frustrating.

I am one who does not give up but I know that I could spend months looking for the solution.
And I'm not that young anymore.


I will try your second version again.
In the meantime if something else comes to mind... write it! Thank you!

[bplus]

Oh man, drop down menus!

I don't know if we could detect both a single click AND a double click for the same spot (in the same screen state), the single click would always win I would think, though I think Windows does it.

We could mouse down on a spot and release mouse at another spot far enough away to call that a double click or  otherwise mouse release at very near the same spot and call that a single click as would be expected. That way we don't have to count clicks we just distinguish how far away the mouse is when released.

Another consideration, use a right click instead of a double left click?

Ah trying to distinguish double click AND single from same spot might be possible, I have an experiment in mind... ;-)

[SMcNeill]

Oh man, drop down menus!

I don't know if we could detect both a single click AND a double click for the same spot (in the same screen state), the single click would always win I would think, though I think Windows does it.

We could mouse down on a spot and release mouse at another spot far enough away to call that a double click or  otherwise mouse release at very near the same spot and call that a single click as would be expected. That way we don't have to count clicks we just distinguish how far away the mouse is when released.

Another consideration, use a right click instead of a double left click?

Ah trying to distinguish double click AND single from same spot might be possible, I have an experiment in mind... ;-)

I’ve got a few mouse demos which cover single/double clicks, hover events, drag events, and all, on one of these various forums.  If I can find some free time here later, I’ll try and drag one up for you guys.

The trick is in using a timer and counter with the mouse.  Basically:

FUNCTION mouseclick
    STATIC lastclicktime AS _FLOAT, oldmouse AS INTEGER
    WHILE _MOUSEINPUT: WEND
     IF lastclicktime = 0 THEN ‘there was no previous click event to deal with
         IF oldmouse = UP AND _MOUSEINPUT(1) = DOWN THEN lastclicktime = TIMER ‘start the timer
     ELSE ‘we had a previous click event
          IF lastclicktime + 0.2 > TIMER THEN
               lastclicktime = 0 ‘reset timer
               mouseclick = 1 ‘single click if there’s no double click in 0.2 seconds
         ELSE
              IF oldmouse = UP AND _MOUSEINPUT(1) = DOWN THEN
                  mouseclick = 2 ‘doubleclick
                  lastclicktimer = 0
         END IF
     END IF

    oldmouse = _MOUSEINPUT(1)
EXIT FUNCTION

[SMcNeill]

If you’re worried about the mouse moving, just store the old x/y positions and compare them before you decide what the result is.

STATIC mx, my

If ABS(_MOUSEX - mx) > 5 OR ABS(_MOUSEY - my) THEN mousemoved = TRUE


^ With something like the above, you store the mouse x/y position when the first click event starts and then compare to see if the mouse has moved before the time is up to determine your double click vs click resolution.  I like the idea of ABS(firstposition - currentposition) < 5 instead of firstposition = currentposition type comparison as I’ve had some old mice over the years which “jiggle” +/- a few pixels almost constantly.  Give it an acceptable threshold for minor variance, before you just declare it “moved” from a single pixel’s change.   ;)

[TerryRitchie]

Here is how I usually detect single and double mouse clicks within a looping structure. Perhaps this can help you.

Code: QB64: [Select]

1. TYPE MOUSE
2.     x AS INTEGER '           actual Y location of mouse cursor
3.     y AS INTEGER '           actual X location of mouse cursor
4.     Click AS INTEGER '       TRUE if single click occurred
5.     DoubleClick AS INTEGER ' TRUE if double click occurred
6.     DCTimer AS INTEGER '     double click timer
7.     LeftDown AS INTEGER '    TRUE if left button is down
8.     ClickX AS INTEGER
9.     ClickY AS INTEGER
10. END TYPE
11.  
12. CONST FALSE = 0, TRUE = NOT FALSE
13. CONST FPS = 60
14.  
15. DIM Mouse AS MOUSE
16.  
17. SCREEN _NEWIMAGE(640, 480, 32)
18. CLS
19.  
20. DO
21.     _LIMIT FPS
22.     CLS
23.     UpdateMouse
24.     IF Mouse.DoubleClick THEN SOUND 880, 1
25.     IF Mouse.Click THEN SOUND 440, 1
26.     _DISPLAY
27. LOOP
28.  
29.  
30. SUB UpdateMouse ()
31.  
32.     SHARED Mouse AS MOUSE
33.  
34.     WHILE _MOUSEINPUT: WEND
35.     Mouse.x = _MOUSEX '                     actual X coordinate
36.     Mouse.y = _MOUSEY '                     actual Y coordinate
37.     Mouse.DoubleClick = FALSE
38.     Mouse.Click = FALSE
39.     SELECT CASE _MOUSEBUTTON(1) '                   current state of left button?
40.         CASE TRUE '                                 button is down
41.             IF NOT Mouse.LeftDown THEN '            already held down?
42.                 Mouse.LeftDown = TRUE '             no, remember that it is now
43.                 IF Mouse.DCTimer THEN '             was last click less than double click timer value?
44.                     IF ABS(Mouse.ClickX - Mouse.x) < 3 AND ABS(Mouse.ClickY - Mouse.y) < 3 THEN
45.                         Mouse.DoubleClick = TRUE '  yes, report a double click happened
46.                     END IF
47.                     Mouse.DCTimer = 0 '             reset the double click timer
48.                 ELSE '                              no, double click timer has run out
49.                     Mouse.DCTimer = FPS \ 3 '       reset double click timer to 1/3 second
50.                     Mouse.ClickX = Mouse.x '        remember X location of click
51.                     Mouse.ClickY = Mouse.y '        remember Y location of click
52.                     Mouse.Click = TRUE '            report that a single click occurred
53.                 END IF
54.             END IF
55.         CASE FALSE '                                button is up
56.             IF Mouse.LeftDown THEN '                was the left button previously down?
57.                 Mouse.LeftDown = FALSE '            yes, report that it's now up
58.             END IF
59.             IF Mouse.DCTimer THEN '                 time left in double click timer?
60.                 Mouse.DCTimer = Mouse.DCTimer - 1 ' yes, decrement value
61.             END IF
62.     END SELECT
63. END SUB
64.  

[bplus]

You all are missing a point, we need to get keypress also and  krovit is looking for both INKEY$ and _KEYHIT.

Test and prove in working app / demo.

[SMcNeill]

You all are missing a point, we need to get keypress also and  krovit is looking for both INKEY$ and _KEYHIT.

Test and prove in working app / demo.

Mouse in one function, keyhit in a second one, and check desired resolution results in your main loop.

[TerryRitchie]

You all are missing a point, we need to get keypress also and  krovit is looking for both INKEY$ and _KEYHIT.

Test and prove in working app / demo.

I'm not seeing the issue here. Here is the previous code I wrote modified a bit to detect _KEYHIT and INKEY$.

Code: QB64: [Select]

1. TYPE MOUSE
2.     x AS INTEGER '           actual Y location of mouse cursor
3.     y AS INTEGER '           actual X location of mouse cursor
4.     Click AS INTEGER '       TRUE if single click occurred
5.     DoubleClick AS INTEGER ' TRUE if double click occurred
6.     DCTimer AS INTEGER '     double click timer
7.     LeftDown AS INTEGER '    TRUE if left button is down
8.     ClickX AS INTEGER
9.     ClickY AS INTEGER
10. END TYPE
11.  
12. CONST FALSE = 0, TRUE = NOT FALSE
13. CONST FPS = 60
14.  
15. DIM Mouse AS MOUSE
16.  
17. SCREEN _NEWIMAGE(640, 480, 32)
18. CLS
19.  
20. DO
21.     _LIMIT FPS
22.     CLS
23.     UpdateMouse
24.     IF Mouse.DoubleClick THEN SOUND 880, 1
25.     IF Mouse.Click THEN SOUND 440, 1
26.     PRINT "Mouse X     : "; Mouse.x
27.     PRINT "Mouse Y     : "; Mouse.y
28.     PRINT "Last click X: "; Mouse.ClickX
29.     PRINT "Last click Y: "; Mouse.ClickY
30.     PRINT "Left button is ";
31.     IF Mouse.LeftDown THEN PRINT "DOWN" ELSE PRINT "UP"
32.     keyhit = _KEYHIT
33.     IF keyhit > 0 THEN oldkeyhit = keyhit
34.     ink$ = INKEY$
35.     IF ink$ <> "" THEN oldink$ = ink$
36.     PRINT "Last KeyHit = "; oldkeyhit
37.     PRINT "Last Inkey$ = "; oldink$
38.     _DISPLAY
39. LOOP
40.  
41.  
42. SUB UpdateMouse ()
43.  
44.     SHARED Mouse AS MOUSE
45.  
46.     WHILE _MOUSEINPUT: WEND
47.     Mouse.x = _MOUSEX '                     actual X coordinate
48.     Mouse.y = _MOUSEY '                     actual Y coordinate
49.     Mouse.DoubleClick = FALSE
50.     Mouse.Click = FALSE
51.     SELECT CASE _MOUSEBUTTON(1) '                   current state of left button?
52.         CASE TRUE '                                 button is down
53.             IF NOT Mouse.LeftDown THEN '            already held down?
54.                 Mouse.LeftDown = TRUE '             no, remember that it is now
55.                 IF Mouse.DCTimer THEN '             was last click less than double click timer value?
56.                     IF ABS(Mouse.ClickX - Mouse.x) < 3 AND ABS(Mouse.ClickY - Mouse.y) < 3 THEN
57.                         Mouse.DoubleClick = TRUE '  yes, report a double click happened
58.                     END IF
59.                     Mouse.DCTimer = 0 '             reset the double click timer
60.                 ELSE '                              no, double click timer has run out
61.                     Mouse.DCTimer = FPS \ 3 '       reset double click timer to 1/3 second
62.                     Mouse.ClickX = Mouse.x '        remember X location of click
63.                     Mouse.ClickY = Mouse.y '        remember Y location of click
64.                     Mouse.Click = TRUE '            report that a single click occurred
65.                 END IF
66.             END IF
67.         CASE FALSE '                                button is up
68.             IF Mouse.LeftDown THEN '                was the left button previously down?
69.                 Mouse.LeftDown = FALSE '            yes, report that it's now up
70.             END IF
71.             IF Mouse.DCTimer THEN '                 time left in double click timer?
72.                 Mouse.DCTimer = Mouse.DCTimer - 1 ' yes, decrement value
73.             END IF
74.     END SELECT
75. END SUB
76.  
77.  

[TerryRitchie]

Here it is modified a bit more. Now you can drag a selection box around while holding down the left mouse button. It still detects keystrokes as well while dragging the box.

Code: QB64: [Select]

1. TYPE MOUSE
2.     x AS INTEGER '           actual Y location of mouse cursor
3.     y AS INTEGER '           actual X location of mouse cursor
4.     Click AS INTEGER '       TRUE if single click occurred
5.     DoubleClick AS INTEGER ' TRUE if double click occurred
6.     DCTimer AS INTEGER '     double click timer
7.     LeftDown AS INTEGER '    TRUE if left button is down
8.     ClickX AS INTEGER
9.     ClickY AS INTEGER
10. END TYPE
11.  
12. CONST FALSE = 0, TRUE = NOT FALSE
13. CONST FPS = 60
14.  
15. DIM Mouse AS MOUSE
16.  
17. SCREEN _NEWIMAGE(640, 480, 32)
18. CLS
19.  
20. DO
21.     _LIMIT FPS
22.     CLS
23.     UpdateMouse
24.     IF Mouse.DoubleClick THEN SOUND 880, 1
25.     IF Mouse.Click THEN SOUND 440, 1
26.     PRINT "Mouse X     : "; Mouse.x
27.     PRINT "Mouse Y     : "; Mouse.y
28.     PRINT "Last click X: "; Mouse.ClickX
29.     PRINT "Last click Y: "; Mouse.ClickY
30.     PRINT "Left button is ";
31.     IF Mouse.LeftDown THEN PRINT "DOWN" ELSE PRINT "UP"
32.     keyhit = _KEYHIT
33.     IF keyhit > 0 THEN oldkeyhit = keyhit
34.     ink$ = INKEY$
35.     IF ink$ <> "" THEN oldink$ = ink$
36.     PRINT "Last KeyHit = "; oldkeyhit
37.     PRINT "Last Inkey$ = "; oldink$
38.     IF Mouse.LeftDown THEN
39.         LINE (Mouse.ClickX, Mouse.ClickY)-(Mouse.x, Mouse.y), _RGB32(0, 0, 255), BF
40.     END IF
41.     _DISPLAY
42. LOOP
43.  
44.  
45. SUB UpdateMouse ()
46.  
47.     SHARED Mouse AS MOUSE
48.  
49.     WHILE _MOUSEINPUT: WEND
50.     Mouse.x = _MOUSEX '                     actual X coordinate
51.     Mouse.y = _MOUSEY '                     actual Y coordinate
52.     Mouse.DoubleClick = FALSE
53.     Mouse.Click = FALSE
54.     SELECT CASE _MOUSEBUTTON(1) '                   current state of left button?
55.         CASE TRUE '                                 button is down
56.             IF NOT Mouse.LeftDown THEN '            already held down?
57.                 Mouse.LeftDown = TRUE '             no, remember that it is now
58.                 IF Mouse.DCTimer THEN '             was last click less than double click timer value?
59.                     IF ABS(Mouse.ClickX - Mouse.x) < 3 AND ABS(Mouse.ClickY - Mouse.y) < 3 THEN
60.                         Mouse.DoubleClick = TRUE '  yes, report a double click happened
61.                     END IF
62.                     Mouse.DCTimer = 0 '             reset the double click timer
63.                 ELSE '                              no, double click timer has run out
64.                     Mouse.DCTimer = FPS \ 3 '       reset double click timer to 1/3 second
65.                     Mouse.ClickX = Mouse.x '        remember X location of click
66.                     Mouse.ClickY = Mouse.y '        remember Y location of click
67.                     Mouse.Click = TRUE '            report that a single click occurred
68.                 END IF
69.             END IF
70.         CASE FALSE '                                button is up
71.             IF Mouse.LeftDown THEN '                was the left button previously down?
72.                 Mouse.LeftDown = FALSE '            yes, report that it's now up
73.             END IF
74.             IF Mouse.DCTimer THEN '                 time left in double click timer?
75.                 Mouse.DCTimer = Mouse.DCTimer - 1 ' yes, decrement value
76.             END IF
77.     END SELECT
78. END SUB
79.  
80.  

[krovit]

Wow, thank you for your interest!

In fact, the issue is crucial. it's also crucial because an application can't ignore the intensive use of the mouse.


Checking the timer behavior in the various examples entered in my code I see some oddities.
This is the differential within which to count the number of clicks.

Well, it seems that whatever the frequency and speed of clicks the time between one and the other is always the same (and it happens always out of the imposed range - in the examples usually 0.3 seconds). Change, when there is, you see after the ninth, tenth and over digit after the comma.

Another question:
the results are very different when treated in double precision or in a single.

In single precision the results seem completely unreliable (even have the appearance of a random value and the differential between one measurement and the other is absolutely far from the 0.3-second limit).
It seems to be for this reason - or at least that this is one of the reasons why the second click is not intercepted.

That there is a problem in the TIMER command that in some particular case may arise?
Or maybe the command is used incorrectly or improperly?

Anyway I'll try your contributions in my code to continue to check their behavior.

I need to monitor that second click! And I can't give up after so much effort and to the point where I've come.