Flashing text: how to do it?

[krovit]

I've never really understood how _LIMIT and _DISPLAY works but I think it's useful in case you want to create a flashing text.

For example: how to make the flashing text ?

Code: QB64: [Select]

1. do
2.  
3.     LOCATE 10,1: print "Text"
4.  
5. loop until inkey$=chr$(27)
6.  

[Real2Two]

What do you mean flashing text? Text constantly changing color/black and white?

[krovit]

Yes, or red and white etc.

Important information that I had forgotten to specify:
the screen is in SCREEN _NEWIMAGE(pixelx,pixely,32) and not usually SCREEN MODE (which is not specified anyway).

I think then the proposed code should simulate the flashing by entering the appropriate commands _LIMIT, _DISPALY, COLOR, etc.

[Real2Two]

Something like:

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(300, 500, 32)
2.  
3. colornum = 0
4.  
5. DO
6. CLS
7. IF colornum = 0 THEN
8. colornum = 1
9. COLOR &HFFffffff
10. ELSE
11. colornum = 0
12. COLOR &HFF000000
13. END IF
14. LOCATE 10, 1: PRINT "test"
15. _DISPLAY
16. _DELAY 10
17. LOOP UNTIL INKEY$ = CHR$(27)
18. SYSTEM ' Not required.

[krovit]

Thank you,

but nothing happens...
on your monitor instead?

[Real2Two]

Is the screen just black?

[krovit]

only white, stable text, and intercepts ESC late (but this is perhaps obvious given the statement _DELAY 10)

[Real2Two]

Try this:

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(300, 500, 32)
2.  
3. colornum = 0
4.  
5. DO
6. CLS
7. IF colornum = 0 THEN
8. colornum = 1
9. COLOR &HFFffffff
10. ELSE
11. colornum = 0
12. COLOR &HFF000000
13. END IF
14. LOCATE 10, 1: PRINT "test"
15. _DISPLAY
16. _LIMIT 10
17. LOOP UNTIL INKEY$ = CHR$(27)
18. SYSTEM ' Not required.

Also try adjusting _LIMIT

[krovit]

Great!
Every now and then I get lost in a glass of water

[Real2Two]

Worked? _LIMIT was always confusing to me.

SLEEP, _DELAY, _LIMIT... all so different

[krovit]

Me too!
Anyway now I'll see how to adapt it. I would like it to flash for a moment to warn me of something.

[FellippeHeitor]

If you're working with SCREEN 0 (text mode), then there's native blinking, as long as you use colors above index 15. To make it simple, use colors 1-15 as you would but add 16 when you want it to blink:

Code: QB64: [Select]

1. CONST BlinkFactor = 16
2. COLOR 15
3. PRINT "This is bright white;"
4. COLOR 15 + BlinkFactor
5. PRINT "This is bright white, but blinking."
6. COLOR 4
7. PRINT "This is red;"
8. COLOR 4 + BlinkFactor
9. PRINT "This is red, but blinking."

If you use _BLINK OFF, then blinking gets replaced with high-intensity background colors.

If you use _DISPLAY, blinking gets disabled.

Again, this is only for text mode (SCREEN 0).

[Pete]

Darn it, late to the party again! Yep, QBasic had built-in blinking for SCREEN 0... the only screen anyone needs.

Oh well, if we could just get QB64 to have a native blinking cursor in graphics mode, that would be nice. Who knows and maybe it has by now, but a long time ago, in QB, I had to make a cursor blinking routine for what few graphics programs I put together.

Pete

[bplus]

Here is a handy sub that allows allot more than just blinking text!
Demos _DISPLAY to prevent unwanted blinking and _LIMIT to control the maximum frames per second to show in loop.

Code: QB64: [Select]

1. _TITLE "Blinking and more with text string" 'b+ 2020-02-15
2.  
3. '===================================================================================
4. ' Lets blink between colors white and blue, expanding and shrinking text for 10 secs
5. '===================================================================================
6.  
7. s$ = "Blink colors white and blue, expanding and shrinking centered text for 10 secs"
8. SCREEN _NEWIMAGE(800, 600, 32)
9. th = 16 'Text Height - start normal
10. dh = 1  'change height
11. flashTimes = 100 'with limit 10 this will take 10 times a second and be done in 100/10 secs
12. start$ = TIME$
13. WHILE _KEYDOWN(27) = 0
14.     CLS
15.     PRINT start$; ", ";
16.     IF flashTimes THEN
17.         IF toggle = 1 THEN C~& = &HFFFFFFFF ELSE C~& = &HFF0000FF
18.         cText _WIDTH / 2, _HEIGHT / 2, th, C~&, s$
19.         toggle = 1 - toggle
20.         th = th + dh
21.         IF th > 64 THEN th = 64: dh = -dh
22.         IF th < 6 THEN th = 6: dh = -dh
23.         flashTimes = flashTimes - 1
24.         lastFlash$ = TIME$
25.     ELSE
26.         cText _WIDTH / 2, _HEIGHT / 2, 16, &HFFFFFF00, s$
27.     END IF
28.     PRINT lastFlash$; " <<<< notice these numbers are not flashing even though we CLS every frame"
29.     _DISPLAY '>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> eliminates blinking screens when use CLS
30.     _LIMIT 10 '>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>  allows maximum number of loops of 10 per sec
31. WEND
32.  
33. 'center the text at x, y with given height and color
34. SUB cText (x, y, textHeight, K AS _UNSIGNED LONG, txt$)
35.     DIM fg AS _UNSIGNED LONG, cur&, I&, mult, xlen
36.     fg = _DEFAULTCOLOR
37.     'screen snapshot
38.     cur& = _DEST
39.     I& = _NEWIMAGE(8 * LEN(txt$), 16, 32)
40.     _DEST I&
41.     COLOR K, _RGBA32(0, 0, 0, 0)
42.     _PRINTSTRING (0, 0), txt$
43.     mult = textHeight / 16
44.     xlen = LEN(txt$) * 8 * mult
45.     _PUTIMAGE (x - .5 * xlen, y - .5 * textHeight)-STEP(xlen, textHeight), I&, cur&
46.     COLOR fg
47.     _FREEIMAGE I&
48. END SUB
49.