Triangle Dissection

[bplus]

Here is why I needed to know Tangent Circle to a Line, what I really needed was point on line closest (and perpendicular) to a point outside the line.

Code: QB64: [Select]

1. OPTION _EXPLICIT
2. _DEFINE A-Z AS _FLOAT
3. _TITLE "Triangle Dissection 2 user click" 'B+ 2020-01-29
4. ' Turn a triangle into a square (and back)
5. ' 2020-01-30 now for any triangle, oh and swap points around until back to original dissection! nice  :)
6. ' 2020-01-30 Oh now let user click his own triangle for dissection
7.  
8. CONST xmax = 800, ymax = 740, blu = &H880000FF, red = &H88FF0000
9. SCREEN _NEWIMAGE(xmax, ymax, 32)
10. _SCREENMOVE 300, 0
11.  
12. DIM Ax, Ay, Fx, Fy, Jx, Jy '3 corners A is apex, F and J form iso triangle
13. DIM Bx, By, Cx, Cy 'midpoint AF and AJ
14. DIM Gx, Gy, Hx, Hy '1/4 lengths of base
15. DIM distFJ, aJ ' to calc points G and H
16. DIM Dx, Dy, Ex, Ey 'two crital points for forming 90 degree angles
17. DIM D2x, D2y, E2x, E2y, G2x, G2y 'copy points to move as independent blocks
18. DIM a, cnt, cc 'a = angle in degrees loop counter, cycle counter
19. DIM tx, ty ' for temp holders to swap points  3 way swap not 2 way
20. DIM mx(3), my(3), pi, oldMouse 'for mouse user input
21.  
22.  
23. getUserTri:
24. cc = 0
25. CLS: CIRCLE (400, 370), 200
26. WHILE pi < 3 'get 3 mouse clicks
27.     _PRINTSTRING (5, 5), SPACE$(20)
28.     _PRINTSTRING (5, 5), "Need 3 clicks inside circle, have" + STR$(pi)
29.     WHILE _MOUSEINPUT: WEND
30.     mx(0) = _MOUSEX: my(0) = _MOUSEY
31.     IF _MOUSEBUTTON(1) AND oldMouse = 0 THEN 'new mouse down
32.         IF SQR((mx(0) - 400) ^ 2 + (my(0) - 370) ^ 2) < 200 THEN
33.             pi = pi + 1
34.             mx(pi) = mx(0): my(pi) = my(0)
35.             CIRCLE (mx(pi), my(pi)), 2
36.         END IF
37.     END IF
38.     oldMouse = _MOUSEBUTTON(1)
39.     _DISPLAY
40.     _LIMIT 60
41. WEND
42. Ax = mx(1): Ay = my(1)
43. Jx = mx(2): Jy = my(2)
44. Fx = mx(3): Fy = my(3)
45.  
46. 'initial triangle
47. 'Ax = 400: Ay = 200: Fx = 200: Fy = 500: Jx = 600: Jy = 500 'jx = 600, jy = 500
48.  
49. restart:
50. cc = cc + 1
51. IF cc = 4 THEN pi = 0: GOTO getUserTri
52.  
53. Bx = (Ax + Fx) / 2: By = (Ay + Fy) / 2: Cx = (Ax + Jx) / 2: Cy = (Ay + Jy) / 2
54. distFJ = _HYPOT(Fx - Jx, Fy - Jy)
55. aJ = _ATAN2(Jy - Fy, Jx - Fx)
56. Gx = Fx + .25 * distFJ * COS(aJ)
57. Gy = Fy + .25 * distFJ * SIN(aJ)
58. Hx = Fx + .75 * distFJ * COS(aJ)
59. Hy = Fy + .75 * distFJ * SIN(aJ)
60. circleTangentXY Gx, Gy, Cx, Cy, Bx, By, Dx, Dy
61. circleTangentXY Gx, Gy, Cx, Cy, Hx, Hy, Ex, Ey
62. D2x = Dx: D2y = Dy
63. E2x = Ex: E2y = Ey
64. G2x = Gx: G2y = Gy
65.  
66. 'draw traingle for check
67. 'ln Ax, Ay, Fx, Fy
68. 'ln Ax, Ay, Jx, Jy
69. 'ln Fx, Fy, Jx, Jy
70. 'ln Gx, Gy, Cx, Cy
71. 'ln Dx, Dy, Bx, By
72. 'ln Ex, Ey, Hx, Hy
73. '_DISPLAY
74. '_DELAY 1
75.  
76. 'draw our starter triangle
77. CLS
78. fquad Ax, Ay, Cx, Cy, Dx, Dy, Bx, By, blu
79. fquad Bx, By, D2x, D2y, Gx, Gy, Fx, Fy, blu
80. fquad Cx, Cy, Jx, Jy, Hx, Hy, Ex, Ey, blu
81. ftri Hx, Hy, G2x, G2y, E2x, E2y, blu
82. _DISPLAY
83. _DELAY 1
84.  
85. 'start dissection with all points needed
86. a = 1: cnt = 0
87. WHILE cnt < 180
88.     CLS
89.  
90.     fquad Ax, Ay, Cx, Cy, Dx, Dy, Bx, By, blu
91.  
92.     rotate D2x, D2y, Bx, By, a
93.     rotate Gx, Gy, Bx, By, a
94.     rotate Fx, Fy, Bx, By, a
95.     fquad Bx, By, D2x, D2y, Gx, Gy, Fx, Fy, blu
96.  
97.     rotate Jx, Jy, Cx, Cy, -a
98.     rotate Hx, Hy, Cx, Cy, -a
99.     rotate Ex, Ey, Cx, Cy, -a
100.     fquad Cx, Cy, Jx, Jy, Hx, Hy, Ex, Ey, blu
101.  
102.     rotate G2x, G2y, Cx, Cy, -a
103.     rotate E2x, E2y, Cx, Cy, -a
104.     ftri Hx, Hy, G2x, G2y, E2x, E2y, blu
105.     _DISPLAY
106.     _LIMIT 60
107.     cnt = cnt + 1
108. WEND
109. cnt = 0
110. WHILE cnt < 180
111.     CLS
112.     fquad Ax, Ay, Cx, Cy, Dx, Dy, Bx, By, blu
113.     fquad Bx, By, D2x, D2y, Gx, Gy, Fx, Fy, blu
114.     fquad Cx, Cy, Jx, Jy, Hx, Hy, Ex, Ey, blu
115.  
116.     rotate G2x, G2y, Hx, Hy, -a
117.     rotate E2x, E2y, Hx, Hy, -a
118.     ftri Hx, Hy, G2x, G2y, E2x, E2y, blu
119.  
120.     cnt = cnt + 1
121.     _DISPLAY
122.     _LIMIT 60
123. WEND
124. _DELAY 1
125. cnt = 0
126. WHILE cnt < 180
127.     CLS
128.     fquad Ax, Ay, Cx, Cy, Dx, Dy, Bx, By, blu
129.     fquad Bx, By, D2x, D2y, Gx, Gy, Fx, Fy, blu
130.     fquad Cx, Cy, Jx, Jy, Hx, Hy, Ex, Ey, blu
131.  
132.     rotate G2x, G2y, Hx, Hy, a
133.     rotate E2x, E2y, Hx, Hy, a
134.     ftri Hx, Hy, G2x, G2y, E2x, E2y, blu
135.  
136.     cnt = cnt + 1
137.     _DISPLAY
138.     _LIMIT 60
139. WEND
140. cnt = 0
141. WHILE cnt < 180
142.     CLS
143.  
144.     fquad Ax, Ay, Cx, Cy, Dx, Dy, Bx, By, blu
145.  
146.     rotate D2x, D2y, Bx, By, -a
147.     rotate Gx, Gy, Bx, By, -a
148.     rotate Fx, Fy, Bx, By, -a
149.     fquad Bx, By, D2x, D2y, Gx, Gy, Fx, Fy, blu
150.  
151.     rotate Jx, Jy, Cx, Cy, a
152.     rotate Hx, Hy, Cx, Cy, a
153.     rotate Ex, Ey, Cx, Cy, a
154.     fquad Cx, Cy, Jx, Jy, Hx, Hy, Ex, Ey, blu
155.  
156.     rotate G2x, G2y, Cx, Cy, a
157.     rotate E2x, E2y, Cx, Cy, a
158.     ftri Hx, Hy, G2x, G2y, E2x, E2y, blu
159.  
160.     cnt = cnt + 1
161.     _DISPLAY
162.     _LIMIT 60
163. WEND
164. _DELAY 1
165. 'swap points for different dissection
166. tx = Ax: ty = Ay
167. Ax = Jx: Ay = Jy
168. Jx = Fx: Jy = Fy
169. Fx = tx: Fy = ty
170. GOTO restart
171.  
172.  
173. SUB rotate (x, y, cx, cy, rAngle) 'replace x, y with new position
174.     DIM angle, distance
175.     angle = _ATAN2(y - cy, x - cx)
176.     distance = ((x - cx) ^ 2 + (y - cy) ^ 2) ^ .5
177.     x = cx + distance * COS(angle + _D2R(rAngle))
178.     y = cy + distance * SIN(angle + _D2R(rAngle))
179. END SUB
180.  
181. SUB circleTangentXY (X1, Y1, X2, Y2, xC, yC, findXperp, findYperp)
182.     'p1 and p2 form a line, with slop and y intersect y0
183.     'xC, yC is a circle origin
184.     'we find X, Y such that line x, y to xC, yC is perpendicular to p1, p2 line that is radius of tangent circle
185.     DIM slope, y0, A, B
186.     IF X2 <> X1 THEN
187.         slope = (Y2 - Y1) / (X2 - X1)
188.         y0 = slope * (0 - X1) + Y1
189.         A = slope ^ 2 + 1
190.         B = 2 * (slope * y0 - slope * yC - xC)
191.         findXperp = -B / (2 * A)
192.         findYperp = slope * findXperp + y0
193.     ELSE
194.         findXperp = X1
195.         findYperp = yC
196.     END IF
197. END SUB
198.  
199. 'SUB drawLine (x1, y1, x2, y2, K AS _UNSIGNED LONG)
200. '    slope = (y2 - y1) / (x2 - x1)
201. '    y0 = slope * (0 - x1) + y1
202. '    LINE (0, y0)-(_WIDTH, slope * _WIDTH + y0), &HFF0000FF
203. 'END SUB
204.  
205. SUB ln (x1, y1, x2, y2)
206.     LINE (x1, y1)-(x2, y2)
207. END SUB
208.  
209. '2019-12-16 fix by Steve saves some time with STATIC and saves and restores last dest
210. SUB ftri (x1, y1, x2, y2, x3, y3, K AS _UNSIGNED LONG)
211.     DIM D AS LONG
212.     STATIC a&
213.     D = _DEST
214.     IF a& = 0 THEN a& = _NEWIMAGE(1, 1, 32)
215.     _DEST a&
216.     _DONTBLEND a& '  '<<<< new 2019-12-16 fix
217.     PSET (0, 0), K
218.     _BLEND a& '<<<< new 2019-12-16 fix
219.     _DEST D
220.     _MAPTRIANGLE _SEAMLESS(0, 0)-(0, 0)-(0, 0), a& TO(x1, y1)-(x2, y2)-(x3, y3)
221. END SUB
222.  
223. 'update 2019-12-16 needs updated fTri 2019-12-16
224. 'need 4 non linear points (not all on 1 line) list them clockwise so x2, y2 is opposite of x4, y4
225. SUB fquad (x1, y1, x2, y2, x3, y3, x4, y4, K AS _UNSIGNED LONG)
226.     ftri x1, y1, x2, y2, x3, y3, K
227.     ftri x3, y3, x4, y4, x1, y1, K
228. END SUB
229.  
230.  

[OldMoses]

That was simply awesome.
You are the Maestro.

[bplus]

Thanks, That one has been on my bucket list for awhile!

[STxAxTIC]

Satisfying to watch.

I get this kind of question *ALL* the damn time, so it feels weird to be the one to ask it, but here goes:

"Why have you done such math?"

(i.e., whats this used for beyond its own sake?)

[bplus]

Satisfying to watch.

I get this kind of question *ALL* the damn time, so it feels weird to be the one to ask it, but here goes:

"Why have you done such math?"

(i.e., whats this used for beyond its own sake?)

https://books.google.com/books?id=LoFNDQAAQBAJ&pg=PA204&lpg=PA204&dq=beyond+its+own+sake?&source=bl&ots=QdDoeKmMXk&sig=ACfU3U1ibaVnT0X0SruzymYEMDl1k29Zpg&hl=en&sa=X&ved=2ahUKEwjQj9ic8qznAhUJWs0KHQAmC3AQ6AEwBXoECAkQAQ#v=onepage&q=beyond%20its%20own%20sake%3F&f=false

[dajan]

bplus, i suspect that is a very cool looking proof of some geometric rule, I don't have a clue about.

[dajan]

Sorry for doble post.

[STxAxTIC]

Quote from: STxAxTIC on Yesterday at 08:39:29 PM
Satisfying to watch.

I get this kind of question *ALL* the damn time, so it feels weird to be the one to ask it, but here goes:

"Why have you done such math?"

(i.e., whats this used for beyond its own sake?)

https://books.google.com/books?id=LoFNDQAAQBAJ&pg=PA204&lpg=PA204&dq=beyond+its+own+sake?&source=bl&ots=QdDoeKmMXk&sig=ACfU3U1ibaVnT0X0SruzymYEMDl1k29Zpg&hl=en&sa=X&ved=2ahUKEwjQj9ic8qznAhUJWs0KHQAmC3AQ6AEwBXoECAkQAQ#v=onepage&q=beyond%20its%20own%20sake%3F&f=false

WHAT?

[luke]

Based on reading a part of that book, I can only fathom that bplus is suggesting we talk about Markov chain text generation - because I'm pretty sure that book doesn't actually have any meaning.

[bplus]

Based on reading a part of that book, I can only fathom that bplus is suggesting we talk about Markov chain text generation - because I'm pretty sure that book doesn't actually have any meaning.

LOL that's a pretty good place to begin if you go in search of meaning.

WHAT?

Sorry I didn't have a short answer at the time so I found some dazzling bull shit to keep you busy. It's from Google search of "beyond it's own sake", you got to admit such a question invites religion or psychology and philosophy or moral answering. Like Danilin, that book is always on the verge of making sense ;-))

Back to question,

Satisfying to watch.

I get this kind of question *ALL* the damn time, so it feels weird to be the one to ask it, but here goes:

"Why have you done such math?"

(i.e., whats this used for beyond its own sake?)

Let me rephrase it to what do people get out of math that you can't get from anywhere else?

Unlike any other material thing, math offers certainty and perfection forever and with computers you can picture it quite beautifully, how else might a mere mortal join with the gods?

bplus, i suspect that is a very cool looking proof of some geometric rule, I don't have a clue about.

Not a proof, more a geometric construction and then animated, just so cool looking (that's all I need to be inspired) that when I first saw this at another forum I wanted to replicate the effect without copying the code, so I at least had to understand each step and put them in order. The idea to swap point labels for drawing constructions occurred to me after I checked to see if any triangle will work and going clockwise or counterclockwise with point clicking (check that out if you haven't, along with obtuse vrs acute triangles).

Turns out the construction does not work for any triangle, I found out last night. ;((
I think you need acute triangles; with obtuse, the angle's are ambiguous  2 possible instead of one and you get extra triangles appearing seemly out of nowhere. ???

[STxAxTIC]

Turns out the construction does not work for any triangle, I found out last night. ;((
I think you need acute triangles; with obtuse, the angle's are ambiguous  2 possible instead of one and you get extra triangles appearing seemly out of nowhere. ???

Hm, I didn't find it... But could whatever you saw be caused by a discontinuity across pi/2, 2pi, etc - in your trig functions? If so, there's always a vector equivalent to trig that won't suffer the same problem, supposing it arose there. I love watching this thing go though. Make that into a screensaver - the person won't want to wake the computer up!

[bplus]

Hm, I didn't find it... But could whatever you saw be caused by a discontinuity across pi/2, 2pi, etc - in your trig functions? If so, there's always a vector equivalent to trig that won't suffer the same problem, supposing it arose there. I love watching this thing go though. Make that into a screensaver - the person won't want to wake the computer up!

I am thinking the extra triangles are coming from the geometric problem of solving for missing sides (S) or angles (A) that occurs with obtuse angles. Remember SAS, SSS, AAA... ASA? one of them runs into a problem when the angle opposite the hypotenuse is obtuse and has 2 possible solutions for A and thus for 3rd side. The construction just doesn't work for obtuse. OK, I was happily surprised that points can be done counterclockwise as well as clockwise though you get rotations inward instead of the ideal outward but thanks to alpha coloring we can show that too! Heck I was happy A, F, J didn't have to be in particular order eg A had to be top middle point with F to lower left and J lower right, it was at least that flexible (what I like about geometry, works on any scale and often any set of points).

As far as screen savers go, I think this is too simple to hold one's attention for long. Richard Frost's kitchen sink graphics sampler, sorry I can't remember name, Qwerkey's Pie-In-The Sky, to almost name a couple are nice screen saver material IMO. :) 

[STxAxTIC]

Ah, I see whatcha mean for obtuse triangles. Seems like that's nobody's fault really. Still such a mesmerizing thing to watch happen.

[Dimster]

Just ran this for the family and the response was "Can bplus also develop the math that will put a square peg into a round hole?" Another member quibbed "Only if math lies". From there the discussion disintegrated into realms and dimensions and outlandish theories. With regret bplus, I can never show them one of your creations again, it could trigger the next world war. 

[bplus]

LOL

Code: QB64: [Select]

1. SCREEN 12
2.  
3. CIRCLE (320, 240), 100
4. r = 100 / SQR(2) - 2 ' <<< math  ;-))
5. LINE (320 - r, 240 - r)-(320 + r, 240 + r), , BF
6.  
7.