A _MEM newbie with a question on moving large blocks of data

[OldMoses]

I've been finding Steve's youtube tutorial very enlightening, but I'm wondering about how versatile _MEM operations are.

Does one have to move discrete elements (integer, single, etc.) or can one define a block of data and move it a specified distance?

Below is the test code I've been playing with, the user variable is from my vector plotter, and what I'm seeking to do is to move everything from .ap thru .status (37 bytes), exactly 37 bytes down to reside at .op thru .Ostat.

Can I move one 'get' of 37 bytes to one 'put' 37 bytes downward, or do I have to grab each individual element?

I saw a reference to LEN, but nothing showing as an example of syntax. Would treating it as a string of 37 bytes be the way to go?

Code: QB64: [Select]

1. TYPE unitpoint '                                                relative unit placement
2.     pX AS _INTEGER64 '                                          X coordinate / mem 0-7
3.     pY AS _INTEGER64 '                                          Y coordinate / mem 8-15
4.     pZ AS _INTEGER64 '                                          Z coordinate / mem 16-23
5. END TYPE
6.  
7. TYPE ship '                                                     unit info variable
8.     id AS _BYTE '                                               unit ID / mem 0
9.     Nam AS STRING * 10 '                                        unit name / mem 1 - 10
10.     MaxG AS _BYTE '                                             Maximum thrust ship can use / mem 11
11.     op AS unitpoint '                                           previous turn x,y,z position op=old position / mem 12-19,20-27,28-35
12.     OSp AS SINGLE '                                             previous turn velocity / mem 36-39
13.     OHd AS SINGLE '                                             previous turn heading / mem 40-43
14.     OIn AS SINGLE '                                             previous turn inclination / mem 44-47
15.     Ostat AS _BYTE '                                            previous turn status / mem 48
16.     ap AS unitpoint '                                           Absolute x,y,z position ap=absolute position / mem 49-56,57-64,65-72
17.     Sp AS SINGLE '                                              coasting velocity / mem 73-76
18.     Hd AS SINGLE '                                              coasting heading / mem 77-80
19.     In AS SINGLE '                                              coasting inclination / mem 81-84
20.     status AS _BYTE '                                           0=destroyed 1=in flight 2=landed / mem 85
21.     bstat AS _BYTE '                                            type of solution 0=none 1=evade 2=intercept 3=Planetfall / mem 86
22.     bogey AS _BYTE '                                            target of intercept/evade solution / mem 87
23. END TYPE
24.  
25. DIM sh AS ship
26.  
27. sh.ap.pX = 78: sh.ap.pY = 7800: sh.ap.pZ = 78000
28. PRINT sh.ap.pX, sh.ap.pY, sh.ap.pZ
29. PRINT sh.op.pX, sh.op.pY, sh.op.pZ
30. DIM m AS _MEM
31. 'DIM x AS _INTEGER64
32. m = _MEM(sh)
33. PRINT m.ELEMENTSIZE
34. _MEMGET m, m.OFFSET + 49, x 'remember to use m.ELEMENTSIZE & DO-LOOP for array shifts
35. _MEMPUT m, m.OFFSET + 12, x
36. _MEMGET m, m.OFFSET + 57, x
37. _MEMPUT m, m.OFFSET + 20, x
38. _MEMGET m, m.OFFSET + 65, x
39. _MEMPUT m, m.OFFSET + 28, x
40. _MEMFREE m
41. PRINT sh.ap.pX, sh.ap.pY, sh.ap.pZ
42. PRINT sh.op.pX, sh.op.pY, sh.op.pZ
43.  

[SMcNeill]

_MEMCOPY is what you’re looking for.  https://www.qb64.org/wiki/MEMCOPY

Copy from the old spot, to the new spot, and then use _MEMFILL if you need to blank out the original area.

[OldMoses]

UPDATE:

Ah yes! defining a 37 byte string and moving it worked perfectly!

Done in one move.

Code: QB64: [Select]

1. TYPE unitpoint '                                                relative unit placement
2.     pX AS _INTEGER64 '                                          X coordinate / mem 0-7
3.     pY AS _INTEGER64 '                                          Y coordinate / mem 8-15
4.     pZ AS _INTEGER64 '                                          Z coordinate / mem 16-23
5. END TYPE
6.  
7. TYPE ship '                                                     unit info variable
8.     id AS _BYTE '                                               unit ID / mem 0
9.     Nam AS STRING * 10 '                                        unit name / mem 1 - 10
10.     MaxG AS _BYTE '                                             Maximum thrust ship can use / mem 11
11.     op AS unitpoint '                                           previous turn x,y,z position op=old position / mem 12-19,20-27,28-35
12.     OSp AS SINGLE '                                             previous turn velocity / mem 36-39
13.     OHd AS SINGLE '                                             previous turn heading / mem 40-43
14.     OIn AS SINGLE '                                             previous turn inclination / mem 44-47
15.     Ostat AS _BYTE '                                            previous turn status / mem 48
16.     ap AS unitpoint '                                           Absolute x,y,z position ap=absolute position / mem 49-56,57-64,65-72
17.     Sp AS SINGLE '                                              coasting velocity / mem 73-76
18.     Hd AS SINGLE '                                              coasting heading / mem 77-80
19.     In AS SINGLE '                                              coasting inclination / mem 81-84
20.     status AS _BYTE '                                           0=destroyed 1=in flight 2=landed / mem 85
21.     bstat AS _BYTE '                                            type of solution 0=none 1=evade 2=intercept 3=Planetfall / mem 86
22.     bogey AS _BYTE '                                            target of intercept/evade solution / mem 87
23. END TYPE
24.  
25. DIM sh AS ship
26.  
27. sh.ap.pX = 78: sh.ap.pY = 7800: sh.ap.pZ = 78000: sh.Sp = 48.5: sh.Hd = 357: sh.In = 15: sh.status = 1
28. PRINT sh.ap.pX, sh.ap.pY, sh.ap.pZ, sh.Sp, sh.Hd, sh.In, sh.status
29. PRINT sh.op.pX, sh.op.pY, sh.op.pZ, sh.OSp, sh.OHd, sh.OIn, sh.Ostat
30. DIM m AS _MEM
31. DIM x AS STRING * 37
32. m = _MEM(sh)
33. PRINT m.ELEMENTSIZE
34. _MEMGET m, m.OFFSET + 49, x 'remember to use m.ELEMENTSIZE & DO-LOOP for array shifts
35. _MEMPUT m, m.OFFSET + 12, x
36. _MEMFREE m
37. PRINT sh.ap.pX, sh.ap.pY, sh.ap.pZ, sh.Sp, sh.Hd, sh.In, sh.status
38. PRINT sh.op.pX, sh.op.pY, sh.op.pZ, sh.OSp, sh.OHd, sh.OIn, sh.Ostat
39.  
40.  

[OldMoses]

Thanks Steve, so many tools available that I can't find them all.

[SMcNeill]

You can combine these 2 commands into one:

Code: [Select]

_MEMGET m, m.OFFSET + 49, x 'remember to use m.ELEMENTSIZE & DO-LOOP for array shifts
_MEMPUT m, m.OFFSET + 12, x
TO:

Code: [Select]

_MEMCOPY m, m.OFFSET +49, 37 TO m, m.OFFSET + 12
I haven’t got around to a tutorial on the extra mem commands yet, for the holidays, but I’ll try and remedy that after the New Years.  ;)

[Qwerkey]

I haven’t got around to a tutorial on the extra mem commands yet, for the holidays, but I’ll try and remedy that after the New Years.  ;)

Can't wait!

[OldMoses]

I'm looking forward to it too. The ones you've done so far have helped take a lot of the mystique out of the commands, and have got the wheels turning in my head as to just what I can accomplish with it.