How can this be sped up?

[romichess]

This is just one of many rules (the simplest) in a "rule based transformation" engine that I wrote about 30 some years ago. I've always wanted to see the results on a higher resolution monitor. So I'm wondering if this example can be made faster.

It is a very interesting thing to watch. Some rule sets results in patterns that resemble a living system. Other rule sets produce something like Native American patterns such as they wove in their clothing. The possible rule sets are limitless. The name I gave it way back when was Evolve.

Code: QB64: [Select]

1. DIM ch AS STRING
2.  
3. screenw = _DESKTOPWIDTH
4. screenh = _DESKTOPHEIGHT
5. SCREEN _NEWIMAGE(screenw, screenh, 256)
6. _FULLSCREEN
7.  
8. FOR y = 0 TO screenh
9.     FOR x = 0 TO screenw
10.         clr = INT(RND * 16)
11.         PSET (x, y), clr
12.     NEXT
13.     _DISPLAY
14. NEXT
15.  
16. repeat = -1
17.  
18. WHILE repeat
19.  
20.     x = RND * screenw
21.     y = RND * screenh
22.     c = POINT(x, y)
23.     eat = c + 1
24.     IF eat > 15 THEN eat = 0
25.     FOR i = x - 1 TO x + 1
26.         FOR j = y - 1 TO y + 1
27.             c = POINT(i, j)
28.             IF c = eat THEN
29.                 PSET (x, y), c
30.                 EXIT FOR
31.             END IF
32.         NEXT
33.         IF c = eat THEN EXIT FOR
34.     NEXT
35.     ch = INKEY$
36.     IF ch = CHR$(27) THEN repeat = 0
37.     _DISPLAY
38. WEND
39.  
40. SYSTEM

[SMcNeill]

DO instead of FOR, _MEM instead of POINT and PSET.  Change to DEFLNG instead of default SINGLE precision.

[bplus]

More interesting though not that much faster:

Code: QB64: [Select]

1. DIM ch AS STRING
2.  
3. screenw = 100
4. screenh = 100
5. SCREEN _NEWIMAGE(screenw, screenh, 256)
6. '_FULLSCREEN
7.  
8. FOR y = 0 TO screenh
9.     FOR x = 0 TO screenw
10.         clr = INT(RND * 211)
11.         PSET (x, y), clr
12.     NEXT
13.     _DISPLAY
14. NEXT
15.  
16. repeat = -1
17.  
18. WHILE repeat
19.  
20.     x = RND * screenw
21.     y = RND * screenh
22.     c = POINT(x, y)
23.     eat = c + 1
24.     IF eat > 15 THEN eat = 0
25.     FOR i = x - 1 TO x + 1
26.         FOR j = y - 1 TO y + 1
27.             c = POINT(i, j)
28.             IF c = eat THEN
29.                 PSET (x, y), c
30.                 GOTO skip
31.             END IF
32.         NEXT
33.         'IF c = eat THEN EXIT FOR
34.     NEXT
35.     skip:
36.     'ch = INKEY$
37.     'IF ch = CHR$(27) THEN repeat = 0
38.     _DISPLAY
39. WEND
40.  
41. SYSTEM
42.  
43.  

[romichess]

DO instead of FOR, _MEM instead of POINT and PSET.  Change to DEFLNG instead of default SINGLE precision.

Thanks! I get started on it tomorrow. :)

[romichess]

Well looks like I'm up late again. My original Evolve engine started just about like the code that was posted. I'd like to describe where it was when it ended. It ended because all I had to work with was an 80386 50MHz machine and it just didn't have the computing power needed. It started off single pixel like the sample code. At the end I created 2x2 pixel entities. Just a few. After so many random pixels were plotted a scan would be made to look for new entities that had formed. They were stored in an array. They were immutable by random pixels. But the entities had rules of their own. They could bond, repel, move, destroy other entities. They formed chains. It was pseudo chemistry. However, with every random pixel having to be checked against the growing list of entities and checking for all the possibilities between entities quickly brought the simulation to a virtual standstill. So the idea was abandoned. One can imagine the possibilities! :)

[romichess]

Here is a better version that produces more consistent results. It is something that one does when they have other things to do and can check back every so often. It takes a while to evolve. I took a look at _mem and it was at first look boggling to my old brain. Maybe someone will champion the conversion? Oh, and post it, lol. :) Back to bed for another try at sleeping!

Code: QB64: [Select]

1. DIM ch AS STRING
2.  
3. screenw = _DESKTOPWIDTH
4. screenh = _DESKTOPHEIGHT
5. SCREEN _NEWIMAGE(screenw, screenh, 256)
6. _FULLSCREEN
7.  
8. FOR y = 0 TO screenh
9.     FOR x = 0 TO screenw
10.         clr = INT(RND * 16)
11.         PSET (x, y), clr
12.     NEXT
13.     _DISPLAY
14. NEXT
15.  
16. repeat = -1
17.  
18. WHILE repeat
19.  
20.     x = RND * screenw
21.     y = RND * screenh
22.     c = POINT(x, y)
23.     eat1 = c + 1
24.     eat2 = c + 2
25.     IF eat1 > 15 THEN
26.         eat1 = 0
27.         eat2 = 1
28.     ELSE
29.         IF eat2 > 16 THEN
30.             eat2 = 0
31.         END IF
32.     END IF
33.  
34.     FOR i = x - 1 TO x + 1
35.         FOR j = y - 1 TO y + 1
36.             c = POINT(i, j)
37.             IF c = eat1 OR c = eat2 THEN
38.                 PSET (x, y), c
39.                 EXIT FOR
40.             END IF
41.         NEXT
42.         IF c = eat1 OR c = eat2 THEN EXIT FOR
43.     NEXT
44.     ch = INKEY$
45.     IF ch = CHR$(27) THEN repeat = 0
46.     _DISPLAY
47. WEND
48.  
49. SYSTEM
50.  

[romichess]

I have become such a dunce in my old age, LOL. When I was getting into bed it hit me, "Why am I calling _DISPLAY AFTER EVERY SINGLE PIXEL, DUH! Run this simple one rule example and tell me your not amazed!!!?

Code: QB64: [Select]

1. DIM ch AS STRING
2.  
3. screenw = _DESKTOPWIDTH
4. screenh = _DESKTOPHEIGHT
5. SCREEN _NEWIMAGE(screenw, screenh, 256)
6. _FULLSCREEN
7.  
8. FOR y = 0 TO screenh
9.     FOR x = 0 TO screenw
10.         clr = INT(RND * 16)
11.         PSET (x, y), clr
12.     NEXT
13.     _DISPLAY
14. NEXT
15.  
16. repeat = -1
17.  
18. WHILE repeat
19.     FOR h = 1 TO 32000
20.         x = RND * screenw
21.         y = RND * screenh
22.         c = POINT(x, y)
23.         eat1 = c + 1
24.         eat2 = c + 2
25.         IF eat1 > 15 THEN
26.             eat1 = 0
27.             eat2 = 1
28.         ELSE
29.             IF eat2 > 16 THEN
30.                 eat2 = 0
31.             END IF
32.         END IF
33.  
34.         FOR i = x - 1 TO x + 1
35.             FOR j = y - 1 TO y + 1
36.                 c = POINT(i, j)
37.                 IF c = eat1 OR c = eat2 THEN
38.                     PSET (x, y), c
39.                     EXIT FOR
40.                 END IF
41.             NEXT
42.             IF c = eat1 OR c = eat2 THEN EXIT FOR
43.         NEXT
44.     NEXT
45.     _DISPLAY
46.     ch = INKEY$
47.     IF ch = CHR$(27) THEN repeat = 0
48. WEND
49.  
50. SYSTEM
51.  

[SMcNeill]

The original, with a FPS counter printed to the top left of it:

Code: QB64: [Select]

1. DIM ch AS STRING
2.  
3. screenw = _DESKTOPWIDTH
4. screenh = _DESKTOPHEIGHT
5. SCREEN _NEWIMAGE(screenw, screenh, 256)
6. _FULLSCREEN
7.  
8. FOR y = 0 TO screenh
9.     FOR x = 0 TO screenw
10.         clr = INT(RND * 16)
11.         PSET (x, y), clr
12.     NEXT
13.     _DISPLAY
14. NEXT
15.  
16. repeat = -1
17.  
18. t# = TIMER + 1
19. WHILE repeat
20.     fps = fps + 1
21.     x = RND * screenw
22.     y = RND * screenh
23.     c = POINT(x, y)
24.     eat = c + 1
25.     IF eat > 15 THEN eat = 0
26.     FOR i = x - 1 TO x + 1
27.         FOR j = y - 1 TO y + 1
28.             c = POINT(i, j)
29.             IF c = eat THEN
30.                 PSET (x, y), c
31.                 EXIT FOR
32.             END IF
33.         NEXT
34.         IF c = eat THEN EXIT FOR
35.     NEXT
36.     ch = INKEY$
37.     IF ch = CHR$(27) THEN repeat = 0
38.     IF TIMER > t# THEN fpsdisplay = fps: fps = 0: t# = TIMER + 1
39.     LOCATE 1, 1: PRINT "FPS:"; fpsdisplay
40.     _DISPLAY
41.  
42. WEND
43.  
44. SYSTEM
45.  

A _MEM version, with a FPS counter printed to the top left of it:

Code: QB64: [Select]

1. DIM ch AS STRING
2. DIM m AS _MEM, o AS _OFFSET
3. DEFLNG A-Z
4. $CHECKING:OFF
5.  
6. screenw = _DESKTOPWIDTH
7. screenh = _DESKTOPHEIGHT
8. SCREEN _NEWIMAGE(screenw, screenh, 256)
9. _FULLSCREEN
10. m = _MEMIMAGE(0) 'visible screen memory
11.  
12. o = 0
13. DO
14.     _MEMPUT m, m.OFFSET + o, INT(RND * 16) AS _UNSIGNED _BYTE
15.     o = o + 1
16. LOOP UNTIL o >= m.SIZE
17.  
18. repeat = -1
19.  
20. screenw = screenw - 3: screenh = screenh - 3
21. t# = TIMER + 1
22. WHILE repeat
23.     fps = fps + 1
24.     x = RND * screenw + 1
25.     y = RND * screenh + 1
26.     c = _MEMGET(m, m.OFFSET + y * screenw + x, _UNSIGNED _BYTE)
27.     eat = (c + 1) MOD 15
28.     i = x - 1
29.     DO
30.         j = y - 1
31.         DO
32.             c = _MEMGET(m, m.OFFSET + j * screenw + i, _UNSIGNED _BYTE)
33.             IF c = eat THEN
34.                 _MEMPUT m, m.OFFSET + y * screenw + x, c
35.                 GOTO skip
36.             END IF
37.             j = j + 1
38.         LOOP UNTIL j > y + 1
39.         i = i + 1
40.     LOOP UNTIL i > x + 1
41.     skip:
42.     IF _KEYDOWN(27) THEN repeat = 0
43.     IF TIMER > t# THEN fpsdisplay = fps: fps = 0: t# = TIMER + 1
44.     _PRINTSTRING (0, 0), STR$(fpsdisplay)
45. WEND
46.  
47. SYSTEM
48.  

There's just a slight difference between the two versions, with the original doing about 400 - 500 FPS on my PC, and the _MEM version only doing a little better at 800,000 - 1,000,000 FPS. :D

[romichess]

The original, with a FPS counter printed to the top left of it:

Code: QB64: [Select]

1. DIM ch AS STRING
2.  
3. screenw = _DESKTOPWIDTH
4. screenh = _DESKTOPHEIGHT
5. SCREEN _NEWIMAGE(screenw, screenh, 256)
6. _FULLSCREEN
7.  
8. FOR y = 0 TO screenh
9.     FOR x = 0 TO screenw
10.         clr = INT(RND * 16)
11.         PSET (x, y), clr
12.     NEXT
13.     _DISPLAY
14. NEXT
15.  
16. repeat = -1
17.  
18. t# = TIMER + 1
19. WHILE repeat
20.     fps = fps + 1
21.     x = RND * screenw
22.     y = RND * screenh
23.     c = POINT(x, y)
24.     eat = c + 1
25.     IF eat > 15 THEN eat = 0
26.     FOR i = x - 1 TO x + 1
27.         FOR j = y - 1 TO y + 1
28.             c = POINT(i, j)
29.             IF c = eat THEN
30.                 PSET (x, y), c
31.                 EXIT FOR
32.             END IF
33.         NEXT
34.         IF c = eat THEN EXIT FOR
35.     NEXT
36.     ch = INKEY$
37.     IF ch = CHR$(27) THEN repeat = 0
38.     IF TIMER > t# THEN fpsdisplay = fps: fps = 0: t# = TIMER + 1
39.     LOCATE 1, 1: PRINT "FPS:"; fpsdisplay
40.     _DISPLAY
41.  
42. WEND
43.  
44. SYSTEM
45.  

A _MEM version, with a FPS counter printed to the top left of it:

Code: QB64: [Select]

1. DIM ch AS STRING
2. DIM m AS _MEM, o AS _OFFSET
3. DEFLNG A-Z
4. $CHECKING:OFF
5.  
6. screenw = _DESKTOPWIDTH
7. screenh = _DESKTOPHEIGHT
8. SCREEN _NEWIMAGE(screenw, screenh, 256)
9. _FULLSCREEN
10. m = _MEMIMAGE(0) 'visible screen memory
11.  
12. o = 0
13. DO
14.     _MEMPUT m, m.OFFSET + o, INT(RND * 16) AS _UNSIGNED _BYTE
15.     o = o + 1
16. LOOP UNTIL o >= m.SIZE
17.  
18. repeat = -1
19.  
20. screenw = screenw - 3: screenh = screenh - 3
21. t# = TIMER + 1
22. WHILE repeat
23.     fps = fps + 1
24.     x = RND * screenw + 1
25.     y = RND * screenh + 1
26.     c = _MEMGET(m, m.OFFSET + y * screenw + x, _UNSIGNED _BYTE)
27.     eat = (c + 1) MOD 15
28.     i = x - 1
29.     DO
30.         j = y - 1
31.         DO
32.             c = _MEMGET(m, m.OFFSET + j * screenw + i, _UNSIGNED _BYTE)
33.             IF c = eat THEN
34.                 _MEMPUT m, m.OFFSET + y * screenw + x, c
35.                 GOTO skip
36.             END IF
37.             j = j + 1
38.         LOOP UNTIL j > y + 1
39.         i = i + 1
40.     LOOP UNTIL i > x + 1
41.     skip:
42.     IF _KEYDOWN(27) THEN repeat = 0
43.     IF TIMER > t# THEN fpsdisplay = fps: fps = 0: t# = TIMER + 1
44.     _PRINTSTRING (0, 0), STR$(fpsdisplay)
45. WEND
46.  
47. SYSTEM
48.  

There's just a slight difference between the two versions, with the original doing about 400 - 500 FPS on my PC, and the _MEM version only doing a little better at 800,000 - 1,000,000 FPS. :D

Wow, thanks! These are things I needed to learn.

[SMcNeill]

Let me point you over to some nice holiday movies to watch, and see if they don't take the mystery out of the commands for you: https://www.qb64.org/forum/index.php?topic=1731.0

[romichess]

Let me point you over to some nice holiday movies to watch, and see if they don't take the mystery out of the commands for you: https://www.qb64.org/forum/index.php?topic=1731.0

Ok cool. I'll watch them tomorrow. There is an error in the Do _mem version. I can't quite pinpoint what it is. And the timer does come with a big performance hit. Not a complaint. I appreciate the instruction! If you want to see what the original should look like then run this. It is really very appealing to watch. And it runs acceptably fast with _DISPLAY only called every 32k pixels.

Code: QB64: [Select]

1. DIM ch AS STRING
2.  
3. screenw = _DESKTOPWIDTH
4. screenh = _DESKTOPHEIGHT
5. SCREEN _NEWIMAGE(screenw, screenh, 256)
6. _FULLSCREEN
7.  
8. FOR y = 0 TO screenh
9.     FOR x = 0 TO screenw
10.         clr = INT(RND * 16)
11.         PSET (x, y), clr
12.     NEXT
13.     _DISPLAY
14. NEXT
15.  
16. repeat = -1
17.  
18. 't# = TIMER + 1
19. WHILE repeat
20.     FOR h = 1 TO 32000
21.         fps = fps + 1
22.         x = RND * screenw
23.         y = RND * screenh
24.         c = POINT(x, y)
25.         eat = c + 1
26.         IF eat > 15 THEN eat = 0
27.         FOR i = x - 1 TO x + 1
28.             FOR j = y - 1 TO y + 1
29.                 c = POINT(i, j)
30.                 IF c = eat THEN
31.                     PSET (x, y), c
32.                     EXIT FOR
33.                 END IF
34.             NEXT
35.             IF c = eat THEN EXIT FOR
36.         NEXT
37.         ch = INKEY$
38.         IF ch = CHR$(27) THEN repeat = 0
39.         '        IF TIMER > t# THEN fpsdisplay = fps: fps = 0: t# = TIMER + 1
40.         '        LOCATE 1, 1: PRINT "FPS:"; fpsdisplay
41.     NEXT
42.  
43.     _DISPLAY
44.  
45. WEND
46.  
47. SYSTEM
48.  
49.  

[romichess]

I'm starting a new thread in programs on this, "Evolve Engine".