Extended Input

[SMcNeill]

Several times over the years, I've seen people posting and asking questions like, "Why can't I paste text into INPUT?", or, "Why doesn't INPUT accept ALT-number input?" 

The answer has always been the same:  "It doesn't.  You'll just have to write your own input handler to do that!"

So, after ages of telling people they had to write their own, I finally needed to write my own input handler, so I thought I'd share:

Code: [Select]

_CONTROLCHR OFF
PRINT ExtendedInput$



FUNCTION ExtendedInput$
    PCOPY 0, 1
    A = _AUTODISPLAY: X = POS(0): Y = CSRLIN
    _KEYCLEAR
    DO
        PCOPY 1, 0
        IF _KEYDOWN(100307) OR _KEYDOWN(100308) THEN AltDown = -1 ELSE AltDown = 0
        k = _KEYHIT
        IF AltDown THEN
            SELECT CASE k 'ignore all keypresses except ALT-number presses
                CASE 48 TO 57: AltWasDown = -1: alt$ = alt$ + CHR$(k)
            END SELECT
        ELSE
            SELECT CASE k 'without alt, add any keypresses to our input
                CASE 8: oldin$ = in$: in$ = LEFT$(in$, LEN(in$) - 1) 'backspace to erase input
                CASE 9: oldin$ = in$: in$ = in$ + SPACE$(4) 'four spaces for any TAB entered
                CASE 32 TO 128
                    IF _KEYDOWN(100305) OR _KEYDOWN(100306) THEN
                        IF k = 118 OR k = 86 THEN oldin$ = in$: in$ = in$ + _CLIPBOARD$ 'ctrl-v paste
                        IF k = 122 OR k = 90 THEN SWAP in$, oldin$ 'ctrl-z undo
                    ELSE
                        oldin$ = in$: in$ = in$ + CHR$(k) 'add input to our string
                    END IF
            END SELECT
        END IF
        alt$ = RIGHT$(alt$, 3)
        IF AltWasDown = -1 AND AltDown = 0 THEN
            v = VAL(alt$)
            IF v >= 0 AND v <= 255 THEN in$ = in$ + CHR$(v)
            alt$ = "": AltWasDown = 0
        END IF
        blink = (blink + 1) MOD 30
        LOCATE Y, X: IF blink \ 15 THEN PRINT in$ ELSE PRINT in$ + "_"
        _DISPLAY
        _LIMIT 30
    LOOP UNTIL k = 13

    PCOPY 1, 0
    LOCATE Y, X: PRINT in$
    ExtendedInput$ = in$
    IF A THEN _AUTODISPLAY
END FUNCTION
This is used as basically a replacement for INPUT$, and handles quite a few special cases for us.

• We handle regular input, as normal.
• CTRL-V works as a paste command, so we can paste clipboard text into the input.
• CTRL-Z works as an undo, to undo the last change to our text.
• ALT-number keys can be used to enter an ASCII character into the input.
• TAB inserts four spaces into our input automatically for ease of formatting.

Like INPUT, this pauses program execution until we finish our input, and it plays nicely with background processes. 


Try it out and play around with it.  See if it performs as you'd expect/want it to.  Type some junk in it.  Then hold down ALT and type in a few numeric codes. (ALT-65 is "A", ALT-1 is the little smiley face, for example.)  Try CTRL-V to paste something, and CTRL-Z to undo your last input (which can be quite useful if you paste the wrong junk into your text with CTRL-V). 

I think this should be easily expandable so people could customize it to suit their own specific needs, if they have any which is different from what it's currently doing.  At the moment, it's doing all that I'd expect it to do, for me, and I hope others might find it useful as well. 

At least now, when somebody asks about "Why can't INPUT do XXXX" again in the future, I can at least say, "Take a look at this, see if it suits your needs, and if not, maybe it'll be a nice starting point to help you write your own input handler."  :D

[bplus]

Very nice Steve, thanks!

[SMcNeill]

Slight tweak made to make certain the display didn't leave a stray blinker behind when we hit enter.  :)

[bplus]

Hey Steve is it possible to do multiple lines, CHR$(10) Line Feed? That would be really cool!

[SMcNeill]

Hey Steve is it possible to do multiple lines, CHR$(10) Line Feed? That would be really cool!

Wouldn't you just take out the first line so that _CONTROLCHR was ON instead of OFF, and then type in input with ALT-10.   

Say an INPUT of "As" + ALT-10 + "the world turns"... 

The above should display as :

"As"
"the world turns"

(And that CHR$(10) is preserved in there for formatting.)

[Pete]

What??? No INKEY$ model available??? BOOOOOOOOOOOOO!!!

Pete :D

You know you can't please everyone, so you have to please myself...

[Cobalt]

What no SHIFT+INSERT support!?! what a rip!   WAAAAHHHHHhhhhh....  XD

As usual, nice work Steve.

[SMcNeill]

Extended Extended Input:

Code: QB64: [Select]

1. _CONTROLCHR OFF
2. PRINT ExtendedInput$
3.  
4.  
5.  
6. FUNCTION ExtendedInput$
7.     PCOPY 0, 1
8.     A = _AUTODISPLAY: X = POS(0): Y = CSRLIN
9.     CP = 0: OldCP = 0 'Cursor Position
10.     _KEYCLEAR
11.     DO
12.         PCOPY 1, 0
13.         IF _KEYDOWN(100307) OR _KEYDOWN(100308) THEN AltDown = -1 ELSE AltDown = 0
14.         k = _KEYHIT
15.         IF AltDown THEN
16.             SELECT CASE k 'ignore all keypresses except ALT-number presses
17.                 CASE 48 TO 57: AltWasDown = -1: alt$ = alt$ + CHR$(k)
18.             END SELECT
19.         ELSE
20.             SELECT CASE k 'without alt, add any keypresses to our input
21.                 CASE 8
22.                     oldin$ = in$
23.                     IF CP > 0 THEN OldCP = CP: CP = CP - 1
24.                     in$ = LEFT$(in$, CP) + MID$(in$, CP + 2) 'backspace to erase input
25.                 CASE 9
26.                     oldin$ = in$
27.                     in$ = LEFT$(in$, CP) + SPACE$(4) + MID$(in$, CP + 1) 'four spaces for any TAB entered
28.                     OldCP = CP
29.                     CP = CP + 4
30.                 CASE 32 TO 128
31.                     IF _KEYDOWN(100305) OR _KEYDOWN(100306) THEN
32.                         IF k = 118 OR k = 86 THEN
33.                             oldin$ = in$
34.                             in$ = LEFT$(in$, CP) + _CLIPBOARD$ + MID$(in$, CP + 1) 'ctrl-v paste
35.                             'CTRL-V leaves cursor in position before the paste, without moving it after.
36.                             'Feel free to modify that behavior here, if you want it to move to after the paste.
37.                         END IF
38.                         IF k = 122 OR k = 90 THEN SWAP in$, oldin$: SWAP OldCP, CP 'ctrl-z undo
39.                     ELSE
40.                         oldin$ = in$
41.                         in$ = LEFT$(in$, CP) + CHR$(k) + MID$(in$, CP + 1) 'add input to our string
42.                         OldCP = CP
43.                         CP = CP + 1
44.                     END IF
45.                 CASE 18176 'Home
46.                     CP = 0
47.                 CASE 20224 'End
48.                     CP = LEN(in$)
49.                 CASE 21248 'Delete
50.                     oldin$ = in$
51.                     in$ = LEFT$(in$, CP) + MID$(in$, CP + 2)
52.                 CASE 19200 'Left
53.                     CP = CP - 1
54.                     IF CP < 0 THEN CP = 0
55.                 CASE 19712 'Right
56.                     CP = CP + 1
57.                     IF CP > LEN(in$) THEN CP = LEN(in$)
58.             END SELECT
59.         END IF
60.         alt$ = RIGHT$(alt$, 3)
61.         IF AltWasDown = -1 AND AltDown = 0 THEN
62.             v = VAL(alt$)
63.             IF v >= 0 AND v <= 255 THEN in$ = in$ + CHR$(v)
64.             alt$ = "": AltWasDown = 0
65.         END IF
66.         blink = (blink + 1) MOD 30
67.         LOCATE Y, X
68.         PRINT LEFT$(in$, CP);
69.         IF blink \ 15 THEN PRINT " "; ELSE PRINT "_";
70.         PRINT MID$(in$, CP + 1)
71.  
72.         _DISPLAY
73.         _LIMIT 30
74.     LOOP UNTIL k = 13
75.  
76.     PCOPY 1, 0
77.     LOCATE Y, X: PRINT in$
78.     ExtendedInput$ = in$
79.     IF A THEN _AUTODISPLAY
80. END FUNCTION
81.  

Added on to the basic functionality presented in the original post so that now:

• arrow keys move the cursor position inside the text.
• Home moves the cursor to the beginning of the text.
• End moves the cursor to the end of the text.
• Delete now deletes a text character to the right of the cursor.

These basic capabilities make going back and editing our text much simpler and efficient than just hitting backspace until we find our glitch and then retype everything over from that point forward.


And the reason I didn't just replace the original post with this one is simply in case someone wants to write their own extended input handler.  Often, it's best to keep the base process as simple as possible, if others are going to build upon it later, rather than overly complicate things which makes it harder for them to sort out what's going on and alter/add to the original.  So, I figure in this case, simply posting both versions is the simplest way to go -- a basic routine which folks can enhance themselves to suit their personal needs, and a more robust version which offers a few more bells and whistles for plug-n-play usability.

[STxAxTIC]

Heya Steve,

So I was thinking (over the years but) recently (due to this post) that a different (and in some cases, better) extended input would not hang up the whole program with a DO... LOOP right in the function, but instead run on a timer to capture input and keep track of a cursor in exactly the way you make it appear, but let other things run while this is happening.

Case in point: my "universal" Sprezzo program, in client mode, can also log into chat rooms. Problem is, in order to watch the chat happen, an INPUT-like statement can't be open. Having something that passively log the keystrokes is a lot better. The old Sprezzo in fact did this, but the function wasn't just a plug-n'-play black box like you're going for.

Short story long, do you find it worth making a passive extended input function? Cause I might, but don't wanna steal your thunder. BUT... since you're kindof setting a standard with this one, there's no reason not to have a second one look and feel the same.

[SMcNeill]

Heya Steve,

So I was thinking (over the years but) recently (due to this post) that a different (and in some cases, better) extended input would not hang up the whole program with a DO... LOOP right in the function, but instead run on a timer to capture input and keep track of a cursor in exactly the way you make it appear, but let other things run while this is happening.

Case in point: my "universal" Sprezzo program, in client mode, can also log into chat rooms. Problem is, in order to watch the chat happen, an INPUT-like statement can't be open. Having something that passively log the keystrokes is a lot better. The old Sprezzo in fact did this, but the function wasn't just a plug-n'-play black box like you're going for.

Short story long, do you find it worth making a passive extended input function? Cause I might, but don't wanna steal your thunder. BUT... since you're kindof setting a standard with this one, there's no reason not to have a second one look and feel the same.

Terry Ritchie’s GLInput Library is passive as you’re describing it.  Your program can run in the background, with it capturing input for you.  I’ve used it several times in the past, and it’s extremely powerful and flexible once you sort out how to use it.  What I’ve got here is mainly just a simple substitute for INPUT, and it’s intended to pause program execution until ENTER is hit (just as INPUT does).

If you need passive input, check out Terry’s library before you go about building your own.  Even if it’s not what you needed, it’s well commented and documented, and might help you on the path of crafting your own easier.  ;)

[STxAxTIC]

Terry Ritchie’s GLInput Library is passive as you’re describing it.  Your program can run in the background, with it capturing input for you.  I’ve used it several times in the past, and it’s extremely powerful and flexible once you sort out how to use it.  What I’ve got here is mainly just a simple substitute for INPUT, and it’s intended to pause program execution until ENTER is hit (just as INPUT does).

If you need passive input, check out Terry’s library before you go about building your own.  Even if it’s not what you needed, it’s well commented and documented, and might help you on the path of crafting your own easier.  ;)

Say, good to know. My ego pretty much doesn't allow me to use someone else's code, but I *may* give it a look. Tee hee hee.

[bplus]

Doesn't _LIMIT allow background processing if there is any extra time in the loop?

[STxAxTIC]

This could be true I suppose if the other things run on timers - otherwise I figure you'd be trying to violate sequence.

[SMcNeill]

And an upgrade to this that no one was asking for -- OEInput!

Code: QB64: [Select]

1. OEInput "{P}Enter a password =>", a$
2. PRINT a$
3.  
4. OEInput "{UI}Enter an unsigned integer =>", a$
5. PRINT a$
6.  
7. OEInput "{I}Enter an integer=>", a$
8. PRINT a$
9.  
10. OEInput "{F}Enter a float=>", a$
11. PRINT a$
12.  
13. OEInput "{IL10}Enter an integer of less than 10 digits =>", a$
14. PRINT a$
15.  
16. OEInput "{X15,Y15}Enter whatever at loc 15,15 =>", a$
17. PRINT a$
18.  
19. OEInput "{D}Check to make certain paste is disabled here =>", a$
20. PRINT a$
21.  
22.  
23.  
24.  
25. SUB OEInput (prompt$, result$) 'Over Engineered Input
26.     PCOPY 0, 1
27.     A = _AUTODISPLAY: X = POS(0): Y = CSRLIN
28.     CP = 0: OldCP = 0 'Cursor Position
29.     _KEYCLEAR
30.  
31.     IF LEFT$(prompt$, 1) = "{" THEN 'possible limiter
32.         i = INSTR(prompt$, "}")
33.         IF i THEN 'yep, we have something!
34.             limiter$ = UCASE$(MID$(prompt$, 2, i - 2))
35.             IF INSTR(limiter$, "U") THEN limit = limit OR 1 'Unsigned
36.             IF INSTR(limiter$, "I") THEN 'can't limit to BOTH an integer AND a float
37.                 limit = limit OR 2 'Integer
38.             ELSEIF INSTR(limiter$, "F") THEN
39.                 limit = limit OR 4 'Float
40.             END IF
41.             IF INSTR(limiter$, "P") THEN password_protected = -1: limit = limit OR 8 'don't show passwords.
42.             IF INSTR(limiter$, "L") THEN 'Length Limitation
43.                 limit = limit OR 16
44.                 jstart = INSTR(limiter$, "L")
45.                 DO
46.                     j = j + 1
47.                     m$ = MID$(limiter$, jstart + j, 1)
48.                 LOOP UNTIL m$ < "0" OR m$ > "9"
49.                 length_limit = VAL(MID$(limiter$, jstart + 1, j - 1))
50.             END IF
51.             IF INSTR(limiter$, "X") THEN 'X position on screen
52.                 limit = limit OR 32
53.                 jstart = INSTR(limiter$, "X")
54.                 DO
55.                     j = j + 1
56.                     m$ = MID$(limiter$, jstart + j, 1)
57.                 LOOP UNTIL m$ < "0" OR m$ > "9"
58.                 X = VAL(MID$(limiter$, jstart + 1, j - 1))
59.             END IF
60.             IF INSTR(limiter$, "Y") THEN 'Y position on scren
61.                 limit = limit OR 64
62.                 jstart = INSTR(limiter$, "Y")
63.                 DO
64.                     j = j + 1
65.                     m$ = MID$(limiter$, jstart + j, 1)
66.                 LOOP UNTIL m$ < "0" OR m$ > "9"
67.                 Y = VAL(MID$(limiter$, jstart + 1, j - 1))
68.             END IF
69.             IF INSTR(limiter$, "D") THEN disable_paste = -1: limit = limit OR 128 'disable paste
70.         END IF
71.         IF limit <> 0 THEN prompt$ = MID$(prompt$, i + 1)
72.     END IF
73.  
74.     DO
75.         PCOPY 1, 0
76.         IF _KEYDOWN(100307) OR _KEYDOWN(100308) THEN AltDown = -1 ELSE AltDown = 0
77.         k = _KEYHIT
78.         IF AltDown THEN
79.             SELECT CASE k 'ignore all keypresses except ALT-number presses
80.                 CASE -57 TO -48: AltWasDown = -1: alt$ = alt$ + CHR$(-k)
81.             END SELECT
82.         ELSE
83.             SELECT CASE k 'without alt, add any keypresses to our input
84.                 CASE 8
85.                     oldin$ = in$
86.                     IF CP > 0 THEN OldCP = CP: CP = CP - 1
87.                     in$ = LEFT$(in$, CP) + MID$(in$, CP + 2) 'backspace to erase input
88.                 CASE 9
89.                     oldin$ = in$
90.                     in$ = LEFT$(in$, CP) + SPACE$(4) + MID$(in$, CP + 1) 'four spaces for any TAB entered
91.                     OldCP = CP
92.                     CP = CP + 4
93.                 CASE 32 TO 128
94.                     IF _KEYDOWN(100305) OR _KEYDOWN(100306) THEN
95.                         IF k = 118 OR k = 86 THEN
96.                             IF disable_paste = 0 THEN
97.                                 oldin$ = in$
98.                                 in$ = LEFT$(in$, CP) + _CLIPBOARD$ + MID$(in$, CP + 1) 'ctrl-v paste
99.                                 'CTRL-V leaves cursor in position before the paste, without moving it after.
100.                                 'Feel free to modify that behavior here, if you want it to move to after the paste.
101.                             END IF
102.                         END IF
103.                         IF k = 122 OR k = 90 THEN SWAP in$, oldin$: SWAP OldCP, CP 'ctrl-z undo
104.                     ELSE
105.                         check_input:
106.                         oldin$ = in$
107.                         IF limit AND 1 THEN 'unsigned
108.                             IF k = 43 OR k = 45 THEN _CONTINUE 'remove signs +/-
109.                         END IF
110.                         IF limit AND 2 THEN 'integer
111.                             IF k = 45 AND CP = 0 THEN GOTO good_input 'only allow a - sign for the first digit
112.                             IF k < 48 OR k > 57 THEN _CONTINUE 'remove anything non-numeric
113.                         END IF
114.                         IF limit AND 4 THEN 'float
115.                             IF k = 45 AND CP = 0 THEN GOTO good_input 'only allow a - sign for the first digit
116.                             IF k = 46 AND period = 0 THEN period = -1: GOTO good_input 'only one decimal point
117.                             IF k < 48 OR k > 57 THEN _CONTINUE 'remove anything non-numeric
118.                         END IF
119.                         good_input:
120.                         IF CP < length_limit OR length_limit = 0 THEN
121.                             in$ = LEFT$(in$, CP) + CHR$(k) + MID$(in$, CP + 1) 'add input to our string
122.  
123.                             OldCP = CP
124.                             CP = CP + 1
125.                         END IF
126.                     END IF
127.                 CASE 18176 'Home
128.                     CP = 0
129.                 CASE 20224 'End
130.                     CP = LEN(in$)
131.                 CASE 21248 'Delete
132.                     oldin$ = in$
133.                     in$ = LEFT$(in$, CP) + MID$(in$, CP + 2)
134.                 CASE 19200 'Left
135.                     CP = CP - 1
136.                     IF CP < 0 THEN CP = 0
137.                 CASE 19712 'Right
138.                     CP = CP + 1
139.                     IF CP > LEN(in$) THEN CP = LEN(in$)
140.             END SELECT
141.         END IF
142.         alt$ = RIGHT$(alt$, 3)
143.         IF AltWasDown = -1 AND AltDown = 0 THEN
144.             v = VAL(alt$)
145.             IF v >= 0 AND v <= 255 THEN
146.                 k = v
147.                 alt$ = "": AltWasDown = 0
148.                 GOTO check_input
149.             END IF
150.         END IF
151.         blink = (blink + 1) MOD 30
152.         LOCATE Y, X
153.         PRINT prompt$;
154.         IF password_protected THEN
155.             PRINT STRING$(LEN(LEFT$(in$, CP)), "*");
156.             IF blink \ 15 THEN PRINT " "; ELSE PRINT "_";
157.             PRINT STRING$(LEN(MID$(in$, CP + 1)), "*")
158.         ELSE
159.             PRINT LEFT$(in$, CP);
160.             IF blink \ 15 THEN PRINT " "; ELSE PRINT "_";
161.             PRINT MID$(in$, CP + 1)
162.         END IF
163.  
164.         _DISPLAY
165.         _LIMIT 30
166.     LOOP UNTIL k = 13
167.  
168.     PCOPY 1, 0
169.     LOCATE Y, X:
170.     IF password_protected THEN
171.         PRINT prompt$; STRING$(LEN(in$), "*")
172.     ELSE
173.         PRINT prompt$; in$
174.     END IF
175.     result$ = in$
176.     IF A THEN _AUTODISPLAY
177. END FUNCTION
178.  

It does all it did before, but now you can send it a prompt to print to the screen, much like INPUT "Enter a number => "; n$

And, since I'm adding a prompt, I'm adding it's own little control system of limiters which we play around with for our text.

Control starts as the first digits of your prompt and begin with an "{" and end with an "}", and we add our control codes inside those braces.

We can limit by number (integer, unsigned, or float).  We can limit by length.  We can position our prompt without using locate. We can hide user input for passwords.  We can disable paste capabilities (which probably don't make sense to have, if we're going to limit input with other things...) Alt-### can be used to enter ASCII characters via the num pad now.

We can do one of these things, or all of these things, or none of these things!

And, if folks need something else added to this, feel free to speak up while I'm still at home and have a few days where I don't have to take care of mom.  (Which gives you the next 3 days, or so, to make requests for additions/alterations.)

My philosophy is, "If you're going to over engineer something, then by God, do it right!" 

[STxAxTIC]

My philosophy is, "If you're going to over engineer something, then by God, do it right!"

Ahem, where's OPTION _EXPLICIT?