Mini Messenger

[SMcNeill]

A lot of folks are curious about how we can get our programs to talk to each other, and curious about how we'd use QB64 to communicate via TCP/IP over a network.  The wiki has a few examples, but they tend to be outdated and simply don't work for me.  (Such as the mini-messenger  example here: http://www.qb64.org/wiki/OPENHOST.) I figured people might like a working example of how to get all the proper parts working together, so I tried various wiki samples and eventually decided to rework one until I got it to working for me...

The finished code here is working as intended on Windows. (I dunno if it'll work for Linux or Mac users, but I'd love to hear if it does or doesn't.)  Instead of a single set of code which tries to toggle between client and host, I worked this up as two separate sets of code -- one for each.   Copy one set of code into QB64, and then run it.  Then, while that program is still running in the background, copy the second set of code and run it..  Type in either program and watch as they happily communicate with each other without any issues.

THE HOST:

Code: QB64: [Select]

1. DIM SHARED Users(1 TO 1000) ' array to hold other client info
2. DIM SHARED NumClients
3. DIM SHARED out$
4.  
5.  
6. PRINT "[Steve's Mini Messenger]"
7. host = _OPENHOST("TCP/IP:7319") ' no host found, so begin new host
8. IF host THEN
9.     PRINT "[Beginning new host chat session!]"
10.     NumClients = 0
11.     client = _OPENCLIENT("TCP/IP:7319:localhost")
12.     IF client = 0 THEN PRINT "ERROR: could not attach host's personal client to host!"
13.     INPUT "Enter your name:", myname$
14.     'PRINT #client, myname$ + " connected!"
15.     PRINT "[Chat session active!]"
16. ELSE
17.     PRINT "ERROR: Could not begin new host!"
18. END IF ' host
19.  
20.  
21. DO ' host main loop
22.     newclient = _OPENCONNECTION(host) ' receive any new connection
23.     IF newclient THEN
24.         NumClients = NumClients + 1
25.         Users(NumClients) = newclient
26.         PRINT "Welcome to Steve's Mini Messenger!"
27.     END IF
28.     FOR i = 1 TO NumClients
29.         GetMessage Users(i) 'check all clients for a message
30.         IF out$ <> "" THEN
31.             l = LEN(out$)
32.             FOR j = 1 TO NumClients ' distribute incoming messages to all clients
33.                 PUT #Users(j), , l
34.                 PUT #Users(j), , out$
35.             NEXT
36.         END IF
37.     NEXT i
38.  
39.     SendMessage myname$, mymessage$, client
40.     _LIMIT 30
41. LOOP
42.  
43.  
44. SUB GetMessage (client) ' get & display any new message
45.     GET #client, , l
46.     IF l > 0 THEN
47.         out$ = SPACE$(l)
48.         GET #client, , out$
49.         VIEW PRINT 1 TO 20
50.         LOCATE 20, 1
51.         PRINT out$
52.         VIEW PRINT 1 TO 24
53.     ELSE
54.         out$ = ""
55.     END IF
56. END SUB
57.  
58. SUB SendMessage (myname$, mymessage$, client) ' simple input handler
59.     k$ = INKEY$
60.     IF LEN(k$) THEN
61.         IF k$ = CHR$(8) AND LEN(mymessage$) <> 0 THEN
62.             mymessage$ = LEFT$(mymessage$, LEN(mymessage$) - 1)
63.         ELSE
64.             IF LEN(k$) = 1 AND ASC(k$) >= 32 THEN mymessage$ = mymessage$ + k$
65.         END IF
66.     END IF
67.     VIEW PRINT 1 TO 24
68.     LOCATE 22, 1: PRINT SPACE$(80); ' erase previous message displayed
69.     LOCATE 22, 1: PRINT myname$ + ": "; mymessage$;
70.     IF k$ = CHR$(13) THEN ' [Enter] sends the message
71.         IF mymessage$ = "" THEN SYSTEM ' [Enter] with no message ends program
72.         mymessage$ = myname$ + ":" + mymessage$
73.         l = LEN(mymessage$)
74.         PUT #client, , l
75.         PUT #client, , mymessage$
76.         mymessage$ = ""
77.     END IF
78.     IF k$ = CHR$(27) THEN SYSTEM ' [Esc] key ends program
79. END SUB

THE CLIENT:

Code: QB64: [Select]

1. DIM SHARED out$
2.  
3.  
4. PRINT "[Steve's Mini Messenger]"
5. client = _OPENCLIENT("TCP/IP:7319:localhost") ' Attempt to connect to local host as a client
6. PRINT "[connected to " + _CONNECTIONADDRESS(client) + "]"
7.  
8. INPUT "Enter your name: ", myname$
9. out$ = myname$ + " connected!"
10. l = LEN(out$)
11. PUT #client, , l
12. PUT #client, , out$
13. DO
14.     GetMessage client
15.     SendMessage myname$, mymessage$, client ' display current input on screen
16.     _LIMIT 30
17. LOOP
18.  
19. '.................... END OF MAIN PROGRAM ................
20.  
21.  
22. SUB GetMessage (client) ' get & display any new message
23.     GET #client, , l
24.     IF l > 0 THEN
25.         out$ = SPACE$(l)
26.         GET #client, , out$
27.         VIEW PRINT 1 TO 20
28.         LOCATE 20, 1
29.         PRINT out$
30.         VIEW PRINT 1 TO 24
31.     ELSE
32.         out$ = ""
33.     END IF
34. END SUB
35.  
36. SUB SendMessage (myname$, mymessage$, client) ' simple input handler
37.     k$ = INKEY$
38.     IF LEN(k$) THEN
39.         IF k$ = CHR$(8) AND LEN(mymessage$) <> 0 THEN
40.             mymessage$ = LEFT$(mymessage$, LEN(mymessage$) - 1)
41.         ELSE
42.             IF LEN(k$) = 1 AND ASC(k$) >= 32 THEN mymessage$ = mymessage$ + k$
43.         END IF
44.     END IF
45.     VIEW PRINT 1 TO 24
46.     LOCATE 22, 1: PRINT SPACE$(80); ' erase previous message displayed
47.     LOCATE 22, 1: PRINT myname$ + ": "; mymessage$;
48.     IF k$ = CHR$(13) THEN ' [Enter] sends the message
49.         IF mymessage$ = "" THEN SYSTEM ' [Enter] with no message ends program
50.         mymessage$ = myname$ + ":" + mymessage$
51.         l = LEN(mymessage$)
52.         PUT #client, , l
53.         PUT #client, , mymessage$
54.         mymessage$ = ""
55.     END IF
56.     IF k$ = CHR$(27) THEN SYSTEM ' [Esc] key ends program
57. END SUB
58.  

Have fun playing around with this as a local system messenger program.  Try it out, kick it around, and let me know if there's anything you don't understand about what it's doing.  This isn’t exactly how I'd normally write one of these; but that's because I started with what the wiki had and then gutted it and rebuilt it up until it was actually working  for me as it should.  Honestly, I think I would've been better off to have just wrote the whole program from scratch!  :P

[Zeppelin]

SMcNeill,
First off just wanna say thanks for actually getting TCP/IP to work. I've tried many times with the examples on the wiki.

Code: QB64: [Select]

1. DIM SHARED Users(1 TO 1000) ' array to hold other client info
2. DIM SHARED NumClients
3. DIM SHARED OUT$
4.  
5.  
6. PRINT "[Steve's Mini Messenger]"
7. host = _OPENHOST("TCP/IP:7319") ' no host found, so begin new host
8. IF host THEN
9.     PRINT "[Beginning new host chat session!]"
10.     NumClients = 0
11.     client = _OPENCLIENT("TCP/IP:7319:localhost")
12.     IF client = 0 THEN PRINT "ERROR: could not attach host's personal client to host!"
13.     INPUT "Enter your name:", myname$
14.     'PRINT #client, myname$ + " connected!"
15.     PRINT "[Chat session active!]"
16. ELSE
17.     PRINT "ERROR: Could not begin new host!"
18.     PRINT "JOINING as CLIENT"
19.  
20.     'Join as client
21.     client = _OPENCLIENT("TCP/IP:7319:localhost") ' Attempt to connect to local host as a client
22. END IF ' host
23.  
24. IF host THEN
25.     _TITLE "HOST"
26.     DO ' host main loop
27.         newclient = _OPENCONNECTION(host) ' receive any new connection
28.         IF newclient THEN
29.             NumClients = NumClients + 1
30.             Users(NumClients) = newclient
31.             PRINT "Welcome to Steve's Mini Messenger!"
32.         END IF
33.         FOR i = 1 TO NumClients
34.             GetMessage Users(i) 'check all clients for a message
35.             IF OUT$ <> "" THEN
36.                 l = LEN(OUT$)
37.                 FOR j = 1 TO NumClients ' distribute incoming messages to all clients
38.                     PUT #Users(j), , l
39.                     PUT #Users(j), , OUT$
40.                 NEXT
41.             END IF
42.         NEXT i
43.  
44.         SendMessage myname$, mymessage$, client
45.         _LIMIT 30
46.     LOOP
47. END IF
48.  
49. IF client THEN
50.     INPUT "Enter your name: ", myname$
51.     OUT$ = myname$ + " connected!"
52.     l = LEN(OUT$)
53.     PUT #client, , l
54.     PUT #client, , OUT$
55.  
56.     _TITLE "CLIENT"
57.     DO
58.         GetMessage client
59.         SendMessage myname$, mymessage$, client ' display current input on screen
60.         _LIMIT 30
61.     LOOP
62. END IF
63.  
64.  
65. SUB GetMessage (client) ' get & display any new message
66.     GET #client, , l
67.     IF l > 0 THEN
68.         OUT$ = SPACE$(l)
69.         GET #client, , OUT$
70.         VIEW PRINT 1 TO 20
71.         LOCATE 20, 1
72.         PRINT OUT$
73.         VIEW PRINT 1 TO 24
74.     ELSE
75.         OUT$ = ""
76.     END IF
77. END SUB
78.  
79. SUB SendMessage (myname$, mymessage$, client) ' simple input handler
80.     k$ = INKEY$
81.     IF LEN(k$) THEN
82.         IF k$ = CHR$(8) AND LEN(mymessage$) <> 0 THEN
83.             mymessage$ = LEFT$(mymessage$, LEN(mymessage$) - 1)
84.         ELSE
85.             IF LEN(k$) = 1 AND ASC(k$) >= 32 THEN mymessage$ = mymessage$ + k$
86.         END IF
87.     END IF
88.     VIEW PRINT 1 TO 24
89.     LOCATE 22, 1: PRINT SPACE$(80); ' erase previous message displayed
90.     LOCATE 22, 1: PRINT myname$ + ": "; mymessage$;
91.     IF k$ = CHR$(13) THEN ' [Enter] sends the message
92.         IF mymessage$ = "" THEN SYSTEM ' [Enter] with no message ends program
93.         mymessage$ = myname$ + ":" + mymessage$
94.         l = LEN(mymessage$)
95.         PUT #client, , l
96.         PUT #client, , mymessage$
97.         mymessage$ = ""
98.     END IF
99.     IF k$ = CHR$(27) THEN SYSTEM ' [Esc] key ends program
100. END SUB
101.  

Here's a version of your program that can run both client and/or host. Checks if a host is already open, then connects as client. Its just easier than having two separate programs.

Zep

[SMcNeill]

Here's a version of your program that can run both client and/or host. Checks if a host is already open, then connects as client. Its just easier than having two separate programs.

Zep

I agree, in many ways, I think it is too.  The only reason I placed them separate is in case someone only wanted to include the client side code for some reason.  (Perhaps to only allow a set of users to only join a game server and not have the code to actually host one themselves, or to keep compiled EXE size as small as possible...)

Thanks for taking the time and effort to assemble the pieces together for everyone else.  As you say, it's generally just a lot more convenient when everything is packaged all together for usage.  ;)

[Cobalt]

Or If you want an example of how to use it for Network game play you can check out my Battleship 64! game.

https://www.qb64.org/forum/index.php?topic=826

the LAN network game play is\was(at that time) fully working. The basic guts of the network code is based off the Mini Messenger example from the wiki.

If anything I would Love to know how to get it running over the NET instead of just a LAN.

[SMcNeill]

Or If you want an example of how to use it for Network game play you can check out my Battleship 64! game.

https://www.qb64.org/forum/index.php?topic=826

the LAN network game play is\was(at that time) fully working. The basic guts of the network code is based off the Mini Messenger example from the wiki.

If anything I would Love to know how to get it running over the NET instead of just a LAN.

Don’t you need to set up your router for port forwarding for that?  Or am I overthinking things?

[Cobalt]

Don’t you need to set up your router for port forwarding for that?  Or am I overthinking things?

I have no idea, wonder how browsers do it? Its not like I setup anything for them to work over the web. but like I said, just something I would love to figure that out someday.

[SMcNeill]

If anyone is around, kindly test the following code if you can...  I'm thinking this should work as a means for folks to use the mini-messenger and connect to my home PC right now from across the interwebs...

Code: QB64: [Select]

1. DIM SHARED OUT$
2. DIM SHARED l AS LONG
3.  
4. PRINT "[Steve's Mini Messenger]"
5. client = _OPENCLIENT("TCP/IP:80:172.93.60.23") ' Attempt to connect to local host as a client
6. PRINT "[connected to " + _CONNECTIONADDRESS(client) + "]"
7.  
8. INPUT "Enter your name: ", myname$
9. OUT$ = myname$ + " connected!"
10. l = LEN(OUT$)
11. PUT #client, , l
12. PUT #client, , OUT$
13. DO
14.     GetMessage client
15.     SendMessage myname$, mymessage$, client ' display current input on screen
16.     _LIMIT 30
17. LOOP
18.  
19. '.................... END OF MAIN PROGRAM ................
20.  
21.  
22. SUB GetMessage (client) ' get & display any new message
23.     l = 0
24.     GET #client, , l
25.     IF l > 0 THEN
26.         _DELAY .1 'some delay so the other 'puter can send the info to us across spiderman's excretions!
27.         OUT$ = SPACE$(l)
28.         GET #client, , OUT$
29.         VIEW PRINT 1 TO 20
30.         LOCATE 20, 1
31.         IF _TRIM$(OUT$) <> "" THEN PRINT OUT$
32.         VIEW PRINT 1 TO 24
33.     ELSE
34.         OUT$ = ""
35.     END IF
36. END SUB
37.  
38. SUB SendMessage (myname$, mymessage$, client) ' simple input handler
39.     k$ = INKEY$
40.     IF LEN(k$) THEN
41.         IF k$ = CHR$(8) AND LEN(mymessage$) <> 0 THEN
42.             mymessage$ = LEFT$(mymessage$, LEN(mymessage$) - 1)
43.         ELSE
44.             IF LEN(k$) = 1 AND ASC(k$) >= 32 THEN mymessage$ = mymessage$ + k$
45.         END IF
46.     END IF
47.     VIEW PRINT 1 TO 24
48.     LOCATE 22, 1: PRINT SPACE$(80); ' erase previous message displayed
49.     LOCATE 22, 1: PRINT myname$ + ": "; mymessage$;
50.     IF k$ = CHR$(13) THEN ' [Enter] sends the message
51.         IF mymessage$ = "" THEN SYSTEM ' [Enter] with no message ends program
52.         mymessage$ = myname$ + ":" + mymessage$
53.         l = LEN(mymessage$)
54.         PUT #client, , l
55.         PUT #client, , mymessage$
56.         mymessage$ = ""
57.     END IF
58.     IF k$ = CHR$(27) THEN SYSTEM ' [Esc] key ends program
59. END SUB

Note: This offer is limited in time and I don't know how long you'll be able to test this out.  Currently I'm experimenting with Firewalls down and ports being forwarded, and all that good stuff, and I'm not going to leave my PC open to the world like this forevermore...  If you test this sample and nothing happens either:

A) The code simply doesn't work...

OR

B) It works, but my PC is either off, the chat host is down, or all my firewalls are back up and denying access..    No hard feelings for anyone who misses out on the chance to playtest this little snippet with me.  ;)

[SMcNeill]

Chat server is currently down...  Initial tests between me and Cobalt showed that I was getting and sending information back and forth between the programs, but the simple _DELAY system I was using to wait and send responses is too inefficient to work as it currently exists.  The code above is a nice proof-of-concept test, and shows that port forwarding does work to allow our programs to talk to each other across the interwebs, but the way it's written doesn't account for lost packets, transmission times, or any other problems which may arise from when it's sent from point A to point B...

At the very least, there should probably be a checksum of some sort tossed into things to help verify the information sent...

I'm going to redo the program and see if I can get a better demo up and going for us, and share it later today/tomorrow so folks can test it out and connect to my computer here at home.  :)

[Petr]

Hi. I tried it now, with Bad Filename or number error message on line 6. Probably because the server is down. In a real network, when passing data through multiple routers (namely one computer was connected via wifi, the other by cable over two routers) while I was writing battleship, I found that the client and server should watch the time from sending the packet until receive is not confirmed, or after time limit must be  the packet again send. Then the counterparty should wait and send an acknowledgment upon receipt, perhaps as a LONG type with the size of the incoming packet. Perhaps a byte structure such as a PNG header would be useful, - I heard it was well written for work in network. (PNG begin and PNG end blocks)

[SMcNeill]

Hi. I tried it now, with Bad Filename or number error message on line 6. Probably because the server is down. In a real network, when passing data through multiple routers (namely one computer was connected via wifi, the other by cable over two routers) while I was writing battleship, I found that the client and server should watch the time from sending the packet until receive is not confirmed, or after time limit must be  the packet again send. Then the counterparty should wait and send an acknowledgment upon receipt, perhaps as a LONG type with the size of the incoming packet. Perhaps a byte structure such as a PNG header would be useful, - I heard it was well written for work in network. (PNG begin and PNG end blocks)

Aye.  It's down for now.  It's lunch time here now, but I'm going to see about reworking it and fixing it for better communication between systems, and then I'll post another version up for testing after that....

ETA... I dunno!  Hopefully soon.  ;)

[SierraKen]

Is this like a DCC Chat that's directly computer to computer over the Internet, or just a local LAN chat, or an Internet chat that needs a host server? I ask because first you talk about it being used locally, then later guys are talking to each other with it. I haven't tried it, just wondering, thanks.

[SMcNeill]

Is this like a DCC Chat that's directly computer to computer over the Internet, or just a local LAN chat, or an Internet chat that needs a host server? I ask because first you talk about it being used locally, then later guys are talking to each other with it. I haven't tried it, just wondering, thanks.

The first code is a simple little demo which works with your local computer, to allow your programs to communicate to each other, as indicated here: TCP/IP:7319:localhost

Down at Reply #6, I changed the code and the sample there is one which will allow you to communicate and trade info with the host program which is running on my PC here: TCP/IP:80:172.93.60.23

Both were working, but the code in #6 needs a little tweaking before it's fit for mass testing and lots of folks try it out, so I pulled the plug on it for now.  I'll do a rewrite, and we'll see how things look/go after that.  ;)

[SMcNeill]

Internet Mini-Messenger is up and going once again.  Test it out and see what happens for you.

Code: QB64: [Select]

1. DIM SHARED OUT$
2. DIM SHARED l AS LONG
3.  
4. PRINT "[Steve's Mini Messenger]"
5. client = _OPENCLIENT("TCP/IP:7993:172.93.60.23") ' Attempt to connect to local host as a client
6. PRINT "[connected to " + _CONNECTIONADDRESS(client) + "]"
7.  
8. INPUT "Enter your name: ", myname$
9. OUT$ = myname$ + " connected!" + CHR$(10)
10. PUT #client, , OUT$
11. DO
12.     GetMessage client
13.     OUT$ = ""
14.     SendMessage myname$, mymessage$, client ' display current input on screen
15.     _LIMIT 30
16. LOOP
17.  
18. '.................... END OF MAIN PROGRAM ................
19.  
20.  
21. SUB GetMessage (client) ' get & display any new message
22.  
23.     DO
24.         GET #client, , a$
25.         done = -1
26.         IF LEN(a$) > 0 THEN
27.             OUT$ = LTRIM$(OUT$ + a$)
28.             done = 0
29.             l = INSTR(a$, CHR$(10))
30.             IF l THEN done = -1:: OUT$ = LEFT$(OUT$, l - 1)
31.         END IF
32.         _LIMIT 30
33.     LOOP UNTIL done
34.  
35.     VIEW PRINT 1 TO 20
36.     LOCATE 20, 1
37.     IF _TRIM$(OUT$) <> "" THEN PRINT OUT$
38.     VIEW PRINT 1 TO 24
39. END SUB
40.  
41. SUB SendMessage (myname$, mymessage$, client) ' simple input handler
42.     k$ = INKEY$
43.     IF LEN(k$) THEN
44.         IF k$ = CHR$(8) AND LEN(mymessage$) <> 0 THEN
45.             mymessage$ = LEFT$(mymessage$, LEN(mymessage$) - 1)
46.         ELSE
47.             IF LEN(k$) = 1 AND ASC(k$) >= 32 THEN mymessage$ = mymessage$ + k$
48.         END IF
49.     END IF
50.     VIEW PRINT 1 TO 24
51.     LOCATE 22, 1: PRINT SPACE$(80); ' erase previous message displayed
52.     LOCATE 22, 1: PRINT myname$ + ": "; mymessage$;
53.     IF k$ = CHR$(13) THEN ' [Enter] sends the message
54.         IF mymessage$ = "" THEN SYSTEM ' [Enter] with no message ends program
55.         mymessage$ = myname$ + ":" + mymessage$ + CHR$(10)
56.         PUT #client, , mymessage$
57.         mymessage$ = ""
58.     END IF
59.     IF k$ = CHR$(27) THEN SYSTEM ' [Esc] key ends program
60. END SUB

[Petr]

Steve, i see your sentences. And you mine?

[SMcNeill]

Steve, i see your sentences. And you mine?

You need to close and restart.  My internet rebooted...  My apologies, but you guys got disconnected.