[FIXED] Help please an example taken from wiki is bugged! (Paint tiling)

[TempodiBasic]

Hi guys
try to run this example (n°3 in the wiki on PAINT I get nothing ....
who can say me why?
Thans for attention and answers

Code: QB64: [Select]

1. DIM Row$(1 TO 8)
2. SCREEN 12
3.  
4.    'make red-brick wall
5.     Row$(1) = CHR$(&H0) + CHR$(&H0) + CHR$(&HFE) + CHR$(&HFE)
6.     Row$(2) = Row$(1)
7.     Row$(3) = Row$(1)
8.     Row$(4) = CHR$(&H0) + CHR$(&H0) + CHR$(&H0) + CHR$(&H0)
9.     Row$(5) = CHR$(&H0) + CHR$(&H0) + CHR$(&HEF) + CHR$(&HEF)
10.     Row$(6) = Row$(5)
11.     Row$(7) = Row$(5)
12.     Row$(8) = Row$(4)
13.     Tile$ = Row$(1) + Row$(2) + Row$(3) + Row$(4) + Row$(5) + Row$(6) + Row$(7) + Row$(8)
14.  
15.     LINE (59, 124)-(581, 336), 14, B 'yellow box border to paint inside
16.     PAINT (320, 240), Tile$, 14 'paints brick tiles within yellow border

[Petr]

Hi. Bad News. in help for PAINT is:
fillColor could be a string made up of a sequence of CHR$ values, each representing a tiling pattern to fill the shape.
While this is not implemented in QB64, a string value is still accepted, though it won't produce any results.

I am afraid that this statement is still valid. BUT I can try to write my own tool on this. What exactly does it do? It fill this field with a text string? I have an idea how to do it if it is so.

[Petr]

I just made a quick suggestion and now I realize my mistake: What you want is not filling the image with text, but filling the image with a bit mask. I'm on it!

bad code for text fill:

Code: QB64: [Select]

1. DIM Row$(1 TO 8)
2. SCREEN 12
3.  
4. 'make red-brick wall
5. Row$(1) = CHR$(&H0) + CHR$(&H0) + CHR$(&HFE) + CHR$(&HFE)
6. Row$(2) = Row$(1)
7. Row$(3) = Row$(1)
8. Row$(4) = CHR$(&H0) + CHR$(&H0) + CHR$(&H0) + CHR$(&H0)
9. Row$(5) = CHR$(&H0) + CHR$(&H0) + CHR$(&HEF) + CHR$(&HEF)
10. Row$(6) = Row$(5)
11. Row$(7) = Row$(5)
12. Row$(8) = Row$(4)
13. Tile$ = Row$(1) + Row$(2) + Row$(3) + Row$(4) + Row$(5) + Row$(6) + Row$(7) + Row$(8)
14. LINE (59, 124)-(581, 336), 14, B 'yellow box border to paint inside
15.  
16. PPAINT 320, 240, 15, 14, Tile$ 'paints brick tiles within yellow border
17.  
18. SUB PPAINT (X AS INTEGER, Y AS INTEGER, c1 AS _UNSIGNED LONG, c2 AS _UNSIGNED LONG, s AS STRING)
19.     D = _DEST
20.     PAINT (X, Y), c1, c2
21.     SELECT CASE _PIXELSIZE(D)
22.         CASE 0: LOCATE Y, X: PRINT s$: EXIT SUB
23.         CASE 1: bh = 256
24.         CASE 4: bh = 32
25.     END SELECT
26.     virtualTXT = _NEWIMAGE(_WIDTH, _HEIGHT, bh)
27.  
28.     REM  _PRINTMODE _KEEPBACKGROUND
29.     COLOR c1
30.     FOR Y = 1 TO _HEIGHT STEP _FONTHEIGHT
31.         FOR X = 1 TO _WIDTH STEP _PRINTWIDTH(s)
32.             _PRINTSTRING (X, Y), s$, virtualTXT
33.     NEXT X, Y
34.  
35.     virtual = _NEWIMAGE(_WIDTH(D), _HEIGHT(D), bh)
36.     _PUTIMAGE , D, virtual
37.     _CLEARCOLOR c1, virtual
38.     _PUTIMAGE , virtual, virtualTXT
39.  
40.     _PUTIMAGE , virtualTXT, _DISPLAY
41.  
42.     _FREEIMAGE virtual
43.     _FREEIMAGE virtualTXT
44. END SUB
45.  

[Petr]

How does it work correctly according to the original definition of QB4.5 for the PAINT command? Is the string a maximum of 32 bits (4 bytes) per line, or long as the format string line (* 8)? I'll try it for a maximum length of 4 bytes (although I don't know if it should be so.)

[bplus]

OK maybe it doesn't say on Wiki but in the IDE help I get this message below example #3 (also not in Wiki)

It says Tiling (like with Tile$) doesn't work in QB64.

[bplus]

Here's some bricks :)

Code: QB64: [Select]

1. CONST white = &HFFFFFFFF
2. CONST black = &HFF000000
3. CONST red = &HFFFF0000
4. CONST grey = &HFF7C7C7C
5. CONST darkgrey = &HFF323232
6.  
7. DIM SHARED scrn&, background&, brick&, halfBrick&
8.  
9. scrn& = _NEWIMAGE(800, 600, 32)
10. SCREEN scrn&
11. makeBrick
12. makeHalfBrick
13. MakeBackground
14. _DEST display& '<<< or just plain 0
15. gameover$ = "false"
16. DO
17.     CLS
18.     _PUTIMAGE (0, 0), background&
19.     _PRINTMODE _KEEPBACKGROUND
20.     _DISPLAY
21.     _LIMIT 60
22. LOOP UNTIL gameover$ = "true"
23. DO
24.     _DISPLAY
25. LOOP UNTIL INKEY$ = CHR$(27)
26. SYSTEM
27.  
28. 'for ease of brick laying I made 1 brick 49 wide and 24 high so next brick starts 50 before or after or 25 above or below
29. SUB makeBrick ()
30.     brick& = _NEWIMAGE(50, 25, 32)
31.     _DEST brick&
32.     LINE (0, 0)-STEP(49, 24), darkgrey, BF
33.     LINE (1, 1)-STEP(46, 20), red, BF
34.     LINE (1, 0)-STEP(46, 0), white
35.     LINE (47, 0)-STEP(0, 21), white
36.     LINE (0, 0)-STEP(0, 22), black
37.     LINE (0, 0 + 22)-STEP(47, 0), black
38. END SUB
39.  
40. SUB makeHalfBrick ()
41.     halfBrick& = _NEWIMAGE(25, 25, 32)
42.     _DEST halfBrick&
43.     '_SOURCE brick&   '<<< not needed
44.  
45.     'oh the left side of the half bricks on right edge are off, need more space
46.     _PUTIMAGE (0, 0)-(25, 25), brick&, halfBrick&, (25, 0)-(50, 25)
47.     'need to add black line on left side
48.     LINE (0, 0)-STEP(0, 22), black 'EDIT add a black line to left side of half brick
49.  
50. END SUB
51.  
52. SUB MakeBackground
53.     background& = _NEWIMAGE(800, 600)
54.     _DEST background&
55.     'make sky
56.     LINE (0, 0)-(800, 460), &HFF00AAFF, BF
57.     i = 0
58.     FOR y = 450 TO 600 STEP 25 'all bricks start 25 pixels after last
59.         i = (i + 1) MOD 2
60.         IF i MOD 2 THEN adj = 25 ELSE adj = 0
61.         FOR x = 0 + adj TO 800 - 2 * adj STEP 50 'all bricks start 50 pxels after last
62.             _PUTIMAGE (x, y), brick&, background&
63.         NEXT
64.         IF i THEN _PUTIMAGE (0, y), halfBrick&, background&
65.         IF i THEN _PUTIMAGE (775, y), halfBrick&, background&
66.     NEXT
67. END SUB
68.  
69.  

[Petr]

So I have a result. I converted the strings into individual bits and used them to render the mask. Then, using transparency, I put an image with the original screen without a fill over the mask image. The result is a filling image. I did this by slow methods because I am still not quite sure about use AND for convert to bits. I do not know if it should be, or should be fill across the entire rectangle frame next to the frame, I would need to see the result under QB4.5 to tune the program (and a new brain, 3 coffee, and mainly peace and quiet...)

Tested just for 8 bit screens!

Code: QB64: [Select]

1. DIM Row$(1 TO 8)
2. SCREEN 12
3.  
4. 'make red-brick wall
5. Row$(1) = CHR$(&H0) + CHR$(&H0) + CHR$(&HFE) + CHR$(&HFE)
6. Row$(2) = Row$(1)
7. Row$(3) = Row$(1)
8. Row$(4) = CHR$(&H0) + CHR$(&H0) + CHR$(&H0) + CHR$(&H0)
9. Row$(5) = CHR$(&H0) + CHR$(&H0) + CHR$(&HEF) + CHR$(&HEF)
10. Row$(6) = Row$(5)
11. Row$(7) = Row$(5)
12. Row$(8) = Row$(4)
13. Tile$ = Row$(1) + Row$(2) + Row$(3) + Row$(4) + Row$(5) + Row$(6) + Row$(7) + Row$(8)
14. LINE (59, 124)-(581, 336), 14, B 'yellow box border to paint inside
15.  
16.  
17.  
18.  
19.  
20.  
21. PPAINT 320, 240, 15, 14, Tile$ 'paints brick tiles within yellow border
22.  
23. SUB PPAINT (X AS INTEGER, Y AS INTEGER, c1 AS _UNSIGNED LONG, c2 AS _UNSIGNED LONG, s AS STRING)
24.  
25.     PAINT (X, Y), c1, c2
26.     D = _DEST
27.  
28.     'create mask:
29.  
30.     ROWS = LEN(s$) \ 4
31.     DIM R(ROWS) AS STRING '* 32
32.  
33.     FOR M = 1 TO LEN(s) - 4 STEP 4
34.         FOR row = M TO M + 4
35.             st$ = st$ + DECtoBIN$(ASC(s, row))
36.         NEXT row
37.         R(i) = st$
38.         st$ = ""
39.         i = i + 1
40.     NEXT M
41.  
42.     SELECT CASE _PIXELSIZE(D)
43.         CASE 0: LOCATE Y, X: PRINT s$: EXIT SUB
44.         CASE 1: bh = 256
45.         CASE 4: bh = 32
46.     END SELECT
47.     virtualTXT = _NEWIMAGE(_WIDTH, _HEIGHT, bh)
48.     _DEST virtualTXT
49.     Lin = 0
50.     Colum = 0
51.  
52.     FOR Y = 1 TO _HEIGHT
53.         FOR X = 1 TO _WIDTH
54.             Colum = Colum + 1
55.             IF Colum > 32 THEN Colum = 1
56.             IF MID$(R(Lin), Colum, 1) = "1" THEN
57.                 PSET (X, Y), c1
58.             ELSE
59.                 '                PSET (X, Y), c2
60.             END IF
61.         NEXT X
62.         Lin = Lin + 1
63.         IF Lin > UBOUND(r) THEN Lin = LBOUND(r)
64.     NEXT Y
65.  
66.  
67.     virtual = _NEWIMAGE(_WIDTH(D), _HEIGHT(D), bh)
68.     _DEST virtual
69.     _PUTIMAGE , D, virtual
70.     _CLEARCOLOR c1, virtual
71.     _PUTIMAGE , virtual, virtualTXT
72.  
73.     _PUTIMAGE , virtualTXT, _DISPLAY
74.  
75.  
76.     _FREEIMAGE virtual
77.     _FREEIMAGE virtualTXT
78. END SUB
79.  
80. FUNCTION DECtoBIN$ (vstup)
81.     FOR rj = 7 TO 0 STEP -1
82.         IF vstup AND 2 ^ rj THEN DECtoBIN$ = DECtoBIN$ + "1" ELSE DECtoBIN$ = DECtoBIN$ + "0"
83.     NEXT rj
84. END FUNCTION
85.  

  [ You are not allowed to view this attachment ]  

[FellippeHeitor]

Some bits in there set colors too. This is rendered red in QBasic.

[FellippeHeitor]

And without the gaps.

[Petr]

Hi Fellippe, Could you add a picture? I'll try to find it.

You say without spaces. This means that some bytes control color. Well, I'm going to look.

[FellippeHeitor]

There.

 [ You are not allowed to view this attachment ]  

[Petr]

Thank you.


Well, I can't figure it out. I looked at the Qbasic book and it says that the colors are coded into individual bytes (so, since SCREEN 12 is 4 bit, one byte should carry a 2 pixel color), but the correct color numbers do not match. I do not understand where it takes information about red, when the first two bytes are always zero...  it also seems that the bits in the first two bytes may control the bit mask laying method, which seems to be in the last two bytes. But they're all my assumptions, unsubstantiated. I'll try later, I'm hungry. I try later to add AND for background color cooperations, if it help...

[TempodiBasic]

Hi
thanks for your time!

1.
tiling is not supported in QB64. I know this also for LINE command!
I have been surprised that there is an example in Wiki of PAINT.

2. about tiling how Qbasic does it....
I can confirm that it is a red wall of bricks also in my Qbasic under Dosbox.

  [ You are not allowed to view this attachment ]  

observing the CHR$ of Tile$ it uses &Hvalue,  3 same value and a forth zero for the 4 values (Row$) while it uses another 3 &H value for the first 3 value of second 4 Row$ and a final zero (the eightth Row$).

I have got strange results using just Row$(1) and/or Row$(5) as Tile$ of PAINT, while Row$(4) or Ror$(8) gives a black square.
So we can assume that using the pattern a decoder mask choose color and what pixel to color!

[TempodiBasic]

Hi Bplus
your bricks are very beautyful!
Thanks also for blu sky!

[bplus]

Hi TempodiBasic,

You know, it is an interesting problem to "paint" a tile pattern, you've got me thinking (and Petr looks to be making good progress). I know Steve and I did "paint" balls of assorted sizes and colors in a defined rectangular area but "PAINTing" with a colored tile pattern in every nook and cranny not bounded by enclosed areas is a thinker... :)