Sometimes unexpected strong lags

[MrFreyer]

In this small program you can move around with w, a, s, d and while I do so, sometimes I got a massive lag.
Sometimes the lag lasts 0.5 till 1 second.

Is this because of my busy laptop, or something in the code?

EDIT:
And the movement isn't as fluent as it should be. It's like a permanent, slight stuttering.

Code: QB64: [Select]

1. DEFINT A-Z
2.  
3. CONST false = 0
4. CONST true = -1
5. CONST locked = 127
6.  
7. RANDOMIZE TIMER
8.  
9. desktopscreen.width = _DESKTOPWIDTH
10. desktopscreen.height = _DESKTOPHEIGHT
11.  
12. screenwindow.width = 1280
13. screenwindow.height = 720
14.  
15. SCREEN _NEWIMAGE(screenwindow.width, screenwindow.height, 32)
16. DO: LOOP UNTIL _SCREENEXISTS
17. _SCREENMOVE (desktopscreen.width * 0.5 - screenwindow.width * 0.5), 0
18. _PRINTMODE _KEEPBACKGROUND
19. _DISPLAY
20.  
21.  
22. cameraX = 640
23. cameraY = 640
24.  
25. DIM framesPerSecond AS SINGLE
26. DIM frametimeCurrent AS DOUBLE
27. DIM frametimeLast AS DOUBLE
28. DIM frametime AS SINGLE
29. DIM frames AS INTEGER
30. DIM frametimeStopped AS DOUBLE
31. DIM frametimeResumption AS DOUBLE
32. DIM framerate AS INTEGER
33.  
34.  
35.  
36. backgroundWidthTiles = 50
37. backgroundHeightTiles = 50
38.  
39. DIM drawlayer AS LONG
40. drawlayer = _NEWIMAGE(64 * backgroundWidthTiles, 64 * backgroundHeightTiles, 32)
41.  
42. _DEST drawlayer
43.  
44. 'draw backgound layer
45. drawpositionX = 0
46. drawpositionY = 0
47. FOR y = 1 TO backgroundHeightTiles
48.     FOR x = 1 TO backgroundWidthTiles
49.  
50.         'random tile colors
51.         randomNumber = (RND * 4) + 1
52.         SELECT CASE randomNumber
53.             CASE 1:
54.                 red = 124
55.                 green = 0
56.                 blue = 0
57.             CASE 2:
58.                 red = 0
59.                 green = 124
60.                 blue = 0
61.             CASE 3:
62.                 red = 0
63.                 green = 0
64.                 blue = 124
65.             CASE 4:
66.                 red = 124
67.                 green = 124
68.                 blue = 0
69.             CASE 5:
70.                 red = 124
71.                 green = 124
72.                 blue = 124
73.         END SELECT
74.  
75.         'draw tiles (64x64 pixel) on drawlayer
76.         LINE (drawpositionX, drawpositionY)-(drawpositionX + 63, drawpositionY + 63), _RGB(red, green, blue), BF
77.  
78.         drawpositionX = drawpositionX + 64
79.         IF drawpositionX > backgroundWidthTiles * 64 THEN drawpositionX = 0: drawpositionY = drawpositionY + 64
80.        
81.     NEXT x
82. NEXT y
83.  
84. _DEST 0
85.  
86.    
87. 'mainloop
88. DO
89.     _LIMIT 240
90.  
91.     DO
92.         frametimeCurrent = TIMER(.001)
93.         frametime = (frametimeCurrent - frametimeLast)
94.     LOOP UNTIL frametime >= 1 / 240 '240 is maximum frames per second
95.  
96.     frametimeLast = frametimeCurrent
97.  
98.     framesPerSecond = 1 / frametime
99.     IF framesPerSecond < 10 THEN framesPerSecond = 10 '10 is minimum frames per second
100.  
101.    
102.     'check keyinputs
103.     GOSUB keylistener
104.  
105.    
106.    
107.     'process keyinputs
108.     IF key27 = true THEN GOTO shutdown 'close program
109.  
110.     IF key119 = true THEN 'move up
111.         cameraY = cameraY - (320 / framesPerSecond)
112.         IF cameraY < 0 THEN cameraY = 0
113.     END IF
114.    
115.     IF key115 = true THEN 'move down
116.         cameraY = cameraY + (320 / framesPerSecond)
117.         IF cameraY > 50 * 64 - 1 THEN cameraY = 50 * 64 - 1
118.     END IF
119.    
120.     IF key97 = true THEN 'move left
121.         cameraX = cameraX - (320 / framesPerSecond)
122.         IF cameraX < 0 THEN cameraX = 0
123.     END IF
124.    
125.     IF key100 = true THEN 'move right
126.         cameraX = cameraX + (320 / framesPerSecond)
127.         IF cameraX > 50 * 64 - 1 THEN cameraX = 50 * 64 - 1
128.     END IF
129.  
130.  
131.    
132.  
133.     CLS
134.    
135.         'calculate drawposition of drawlayer
136.         drawpositionY = cameraY - (screenwindow.height * 0.5) + 1
137.         drawpositionX = cameraX - (screenwindow.width * 0.5) + 1
138.    
139.         _PUTIMAGE (0, 0), drawlayer, , (drawpositionX, drawpositionY)-(drawpositionX + screenwindow.width - 1, drawpositionY + screenwindow.height - 1)
140.  
141.  
142.     'print text
143.     COLOR _RGB(255, 255, 255)
144.     _PRINTSTRING (0, 16), "w/a/s/d = move"
145.     _PRINTSTRING (0, 32), "Escape = exit"
146.      
147.     _DISPLAY
148.  
149. LOOP
150.  
151. shutdown:
152. SYSTEM
153.  
154. END
155.  
156. keylistener:
157. 'Esc
158. IF _KEYDOWN(27) AND key27 = false THEN
159.     key27 = _KEYDOWN(27)
160. END IF
161. IF NOT _KEYDOWN(27) AND key27 <> false THEN
162.     key27 = false
163. END IF
164.  
165. 'w
166. IF _KEYDOWN(119) AND key119 = false THEN
167.     key119 = _KEYDOWN(119)
168. END IF
169. IF NOT _KEYDOWN(119) AND key119 <> false THEN
170.     key119 = false
171. END IF
172.  
173. 'a
174. IF _KEYDOWN(97) AND key97 = false THEN
175.     key97 = _KEYDOWN(97)
176. END IF
177. IF NOT _KEYDOWN(97) AND key97 <> false THEN
178.     key97 = false
179. END IF
180.  
181. 's
182. IF _KEYDOWN(115) AND key115 = false THEN
183.     key115 = _KEYDOWN(115)
184. END IF
185. IF NOT _KEYDOWN(115) AND key115 <> false THEN
186.     key115 = false
187. END IF
188.  
189. 'd
190. IF _KEYDOWN(100) AND key100 = false THEN
191.     key100 = _KEYDOWN(100)
192. END IF
193. IF NOT _KEYDOWN(100) AND key100 <> false THEN
194.     key100 = false
195. END IF
196. RETURN
197.  

Thanks

[Bert22306]

Seems to work beautifully for me, MrFreyer. Perhaps you could check your task manager, to see what else your PC is up to?

[bplus]

Seems to work beautifully for me, MrFreyer. Perhaps you could check your task manager, to see what else your PC is up to?

ditto!

Edit: oops no timers here :P

[MrFreyer]

The taskmanager looks relatively okay... but the program takes 50%-60% of my CPU and about 120MB RAM... guess because of the sortwareimages(?) :o

[SMcNeill]

Can’t you simplify the key handler quite a bit?  Less calls to KEYDOWN might improve performance.

From:

 
'a
IF _KEYDOWN(97) AND key97 = false THEN
    key97 = _KEYDOWN(97)
END IF
IF NOT _KEYDOWN(97) AND key97 <> false THEN
    key97 = false
END IF


To:

 
IF _KEYDOWN(97) THEN key97 = true ELSE key97 = false ‘a

One simple check to set if it’s down or not.

[MrFreyer]

Can’t you simplify the key handler quite a bit?  Less calls to KEYDOWN might improve performance.

From:

 
'a
IF _KEYDOWN(97) AND key97 = false THEN
    key97 = _KEYDOWN(97)
END IF
IF NOT _KEYDOWN(97) AND key97 <> false THEN
    key97 = false
END IF


To:

 
IF _KEYDOWN(97) THEN key97 = true ELSE key97 = false ‘a

One simple check to set if it’s down or not.

It's maybe slightly (but not much) better...

Normaly I use something like

IF _KEYDOWN(KEYCODE~%(keyA)) AND controlinput.key(keyA) = false THEN
    controlinput.key(keyA) = true
ELSEIF NOT _KEYDOWN(KEYCODE~%(keyA)) AND controlinput.key(keyA) THEN
    controlinput.key(keyA) = false
END IF

as the keyhandle, because sometimes I need to lock a key while pressing, to only do a specific action just one time.

Now I followed your sugestion but it doesn't change much.

[bplus]

This is what is getting the CPU all worked up!

Code: QB64: [Select]

1.     DO
2.         frametimeCurrent = TIMER(.001)
3.         frametime = (frametimeCurrent - frametimeLast)
4.     LOOP UNTIL frametime >= 1 / 240 '240 is maximum frames per second
5.  
6.  

[TempodiBasic]

Hi MrFreyer

it works well on my notebook  Toshiba celeron 1000 1.80Ghz  RAM 4.00giga, Windows10 64bit, QB64 1.3

but I see a not small different of size of ram used...  [ You are not allowed to view this attachment ]  
and the dimension of my exe is 2,041 kb.

[MrFreyer]

...but why is the CPU usage that high?

[TempodiBasic]

:-)
simple

because you set it high...

Code: QB64: [Select]

1. 'mainloop
2. DO
3. _LIMIT 240
4.  

remember that the syntax is

_LIMIT NumberOfAction/FramePerSecond

in fact pulling down the amount of actions to do in a second we get this result
  [ You are not allowed to view this attachment ]  

and this is the secret

Code: QB64: [Select]

1. 'mainloop
2. DO
3.     _LIMIT 40

Good Coding

[MrFreyer]

ahh, I forgot that I set the LIMIT to 240 :D

[acjacques]

Works fine for me too . Very good !