Nested triangles

[petoro]

This is an old vintage program to draw nested triangles and tetrahedra

Code: QB64: [Select]

1. 'cdg 1.03     (c) Jose Angel Gonzalez Rodriguez
2. 'Noviembre de 1997                      November 1997
3. 'Creado con QuickBasic 4.5              Created with QuickBasic 4.5
4. 'Compilado con PBasic 3.1               Compiled with PBasic 3.1
5.  
6.  
7. DEFINT A-Z
8. DECLARE SUB DibuFrameNegro ()
9. DECLARE SUB DibuNegro () : DECLARE SUB Mensajes ()
10. DECLARE SUB DibuFrame () : DECLARE SUB DibuCDG3 (col)
11. DECLARE SUB LineaEspanol () : DECLARE SUB LineaIngles ()
12. DECLARE SUB CDG3 (x1!, x2!, x3!, x4!, y1!, y2!, y3!, y4!, z1!, z2!, z3!, z4!, cont%, col)
13. DECLARE SUB CDG2 (x1!, x2!, x3!, y1!, y2!, y3!, z1!, z2!, z3!, cont%, col)
14. DECLARE SUB DibuCDG2 (col) : DECLARE SUB CogeTecla ()
15. DECLARE SUB Izquierda () : DECLARE SUB Arriba ()
16. DECLARE SUB Pitido1 () : DECLARE SUB SalidaOK ()
17. DECLARE SUB Resalta (a$, N%) : DECLARE SUB DibuCDG ()
18. DECLARE SUB cdg (x1!, x2!, x3!, x4!, y1!, y2!, y3!, y4!, z1!, z2!, z3!, z4!, cont)
19. DECLARE SUB Info () : DECLARE SUB BeepFallo ()
20. REM ON ERROR GOTO RutinaError
21.  
22. DIM b!(3 ^ 6, 10)
23. blanco = 15
24. negro = 0
25. pi! = 3.141592
26. paso! = pi! / 32
27. D3 = 0
28. D2 = 1
29. NIter = 3
30. py = 19
31. yy = py
32. ArMin! = 0
33. NVert = 4
34. DIM VertXY!(NVert, 3)
35. DIM f!(NVert, 3)
36. pot! = 3
37. dist! = 1
38.  
39. RANDOMIZE TIMER
40. SCREEN 12
41. r! = 640 / 480
42. WINDOW (-r!, -1)-(r!, 1)
43.  
44. PALETTE 0, 8
45. blue = 56: green = 63: red = 13
46. ColorNumber& = 65536 * blue + 256 * green + red
47. 'PALETTE 15, ColorNumber&
48.  
49. Empezar:
50.  
51. IF D3 = 1 THEN
52.   NVert = 4
53.   VertXY!(1, 1) = .4926414
54.   VertXY!(2, 1) = .54941
55.   VertXY!(3, 1) = -.1704186
56.   VertXY!(4, 1) = -.8716328
57.   VertXY!(1, 2) = -.5649168
58.   VertXY!(2, 2) = .804424
59.   VertXY!(3, 2) = -.5311065
60.   VertXY!(4, 2) = .2915995
61.   VertXY!(1, 3) = .6619467
62.   VertXY!(2, 3) = -.2259439
63.   VertXY!(3, 3) = -.82999
64.   VertXY!(4, 3) = .3939873
65. ELSE
66.   NVert = 3
67.   VertXY!(1, 1) = .5877291
68.   VertXY!(2, 1) = -.8816133
69.   VertXY!(3, 1) = .2938841
70.   VertXY!(1, 2) = -.4518031
71.   VertXY!(2, 2) = -.4036101
72.   VertXY!(3, 2) = .8554131
73.   VertXY!(1, 3) = .6711546
74.   VertXY!(2, 3) = -.2446566
75.   VertXY!(3, 3) = -.426498
76. END IF
77.  
78. Arriba
79. Izquierda
80.  
81. L1$ = CHR$(24)
82. L2$ = CHR$(27) + " " + CHR$(25) + " " + CHR$(26)
83.  
84. Redibuja:
85. REM dibujar poliedro
86. REM para saltar si es estable:
87.  
88. Mensajes
89. Dibujar:
90. REM CLS
91. CIRCLE (0, 0), 1
92.  
93. Redi:
94. DibuFrame
95. CogeTecla
96. IF NVert = 4 THEN
97.   DibuCDG3 blanco
98. ELSE
99.   DibuCDG2 blanco
100. END IF
101.  
102. 'Girando = 0
103. IntroduceCaracter:
104.  
105. K$ = INKEY$
106. IF K$ <> "" THEN
107.   kkk = ASC(RIGHT$(K$, 1))
108.   IF LEN(K$) = 2 THEN           '2 caracteres
109.     SELECT CASE kkk
110.       CASE 75                   'izquierda
111.                         REM h = 1
112.                         REM PRINT VertXY!(h, 1): PRINT VertXY!(h, 2): PRINT VertXY!(h, 3)
113.         DibuNegro
114.         FOR i = 1 TO NVert
115.           alfa! = ATN(VertXY!(i, 2) / SQR(VertXY!(i, 3) ^ 2 + VertXY!(i, 1) ^ 2))
116.           beta! = ATN(VertXY!(i, 1) / VertXY!(i, 3)) + paso!
117.           VertXY!(i, 2) = SIN(alfa!)
118.           VertXY!(i, 1) = SGN(VertXY!(i, 3)) * COS(alfa!) * SIN(beta!)
119.           VertXY!(i, 3) = SGN(VertXY!(i, 3)) * COS(alfa!) * COS(beta!)
120.         NEXT i
121.                         REM PRINT : PRINT VertXY!(h, 1): PRINT VertXY!(h, 2): PRINT VertXY!(h, 3)
122.                         REM END
123.       CASE 77                   'derecha
124.         DibuNegro
125.         FOR i = 1 TO NVert
126.           alfa! = ATN(VertXY!(i, 2) / SQR(VertXY!(i, 3) ^ 2 + VertXY!(i, 1) ^ 2))
127.           beta! = ATN(VertXY!(i, 1) / VertXY!(i, 3)) - paso!
128.           VertXY!(i, 2) = SIN(alfa!)
129.           VertXY!(i, 1) = SGN(VertXY!(i, 3)) * COS(alfa!) * SIN(beta!)
130.           VertXY!(i, 3) = SGN(VertXY!(i, 3)) * COS(alfa!) * COS(beta!)
131.         NEXT i
132.       CASE 72                   'arriba
133.         DibuNegro
134.         FOR i = 1 TO NVert
135.           alfa! = ATN(VertXY!(i, 1) / SQR(VertXY!(i, 2) ^ 2 + VertXY!(i, 3) ^ 2))
136.           beta! = ATN(VertXY!(i, 3) / VertXY!(i, 2)) + paso!
137.           VertXY!(i, 1) = SIN(alfa!)
138.           VertXY!(i, 3) = SGN(VertXY!(i, 2)) * COS(alfa!) * SIN(beta!)
139.           VertXY!(i, 2) = SGN(VertXY!(i, 2)) * COS(alfa!) * COS(beta!)
140.         NEXT i
141.       CASE 80                   'abajo
142.         DibuNegro
143.         FOR i = 1 TO NVert
144.           alfa! = ATN(VertXY!(i, 1) / SQR(VertXY!(i, 2) ^ 2 + VertXY!(i, 3) ^ 2))
145.           beta! = ATN(VertXY!(i, 3) / VertXY!(i, 2)) - paso!
146.           VertXY!(i, 1) = SIN(alfa!)
147.           VertXY!(i, 3) = SGN(VertXY!(i, 2)) * COS(alfa!) * SIN(beta!)
148.           VertXY!(i, 2) = SGN(VertXY!(i, 2)) * COS(alfa!) * COS(beta!)
149.         NEXT i
150.       CASE 59                 'pulsar F1
151.         CLS : Info
152.         keyy$ = "": DO WHILE keyy$ = "": keyy$ = INKEY$: LOOP
153.         CLS
154.         GOTO Redibuja:
155.     END SELECT
156.     Girando = 1
157.   ELSE                          '1 caracteres
158.     SELECT CASE kkk
159.       CASE 43, 62       '+ y >
160.         IF NIter = 6 THEN
161.           SOUND 240, 2
162.           GOTO IntroduceCaracter
163.         ELSE
164.           Pitido1
165.           NIter = NIter + 1
166.           GOTO Dibujar
167.         END IF
168.       CASE 45, 60       '- y <
169.         DibuNegro
170.         IF NIter = 0 THEN
171.           SOUND 240, 2
172.           GOTO Redi
173.         ELSE
174.           Pitido1
175.           NIter = NIter - 1
176.           GOTO Dibujar
177.         END IF
178.       CASE 50                   '2 --> 2-D
179.         DibuNegro
180.         D2 = 1: D3 = 0
181.         GOTO Empezar
182.       CASE 51                   '3 --> 3D
183.         DibuNegro
184.         D2 = 0: D3 = 1
185.         GOTO Empezar
186.       CASE 27
187.         SalidaOK
188.       CASE ELSE
189.     END SELECT
190.   END IF
191.   GOTO Dibujar
192. ELSE
193.   'GOTO ReDibuja
194.   GOTO IntroduceCaracter
195. END IF
196.  
197. SUB Arriba
198.  
199.   SHARED NVert, VertXY!(), pi!
200.  
201.   a! = RND * pi!
202.  
203.   FOR i = 1 TO NVert
204.     alfa! = ATN(VertXY!(i, 1) / SQR(VertXY!(i, 2) ^ 2 + VertXY!(i, 3) ^ 2))
205.     beta! = ATN(VertXY!(i, 3) / VertXY!(i, 2)) + a!
206.     VertXY!(i, 1) = SIN(alfa!)
207.     IF VertXY!(i, 2) > 0 THEN VertXY!(i, 3) = COS(alfa!) * SIN(beta!) ELSE VertXY!(i, 3) = -COS(alfa!) * SIN(beta!)
208.     IF VertXY!(i, 2) > 0 THEN VertXY!(i, 2) = COS(alfa!) * COS(beta!) ELSE VertXY!(i, 2) = -COS(alfa!) * COS(beta!)
209.   NEXT i
210.  
211. END SUB
212.  
213. SUB BeepFallo
214.   SOUND 100, .8
215. END SUB
216.  
217. SUB CDG2 (x1!, x2!, x3!, y1!, y2!, y3!, z1!, z2!, z3!, cont, col)
218. SHARED b!(), c
219. IF cont = 0 THEN EXIT SUB
220.  
221. xc! = (x1! + x2! + x3!) / 3
222. yc! = (y1! + y2! + y3!) / 3
223. zc! = (z1! + z2! + z3!) / 3
224. LINE (x1!, y1!)-(xc!, yc!), col
225. LINE (x2!, y2!)-(xc!, yc!), col
226. LINE (x3!, y3!)-(xc!, yc!), col
227.  
228. CDG2 x1!, x2!, xc!, y1!, y2!, yc!, z1!, z2!, zc!, cont - 1, col
229. CDG2 x1!, xc!, x3!, y1!, yc!, y3!, z1!, zc!, z3!, cont - 1, col
230. CDG2 xc!, x2!, x3!, yc!, y2!, y3!, zc!, z2!, z3!, cont - 1, col
231.  
232. END SUB
233.  
234. SUB CDG3 (x1!, x2!, x3!, x4!, y1!, y2!, y3!, y4!, z1!, z2!, z3!, z4!, cont, col)
235.  
236. IF cont = 0 THEN EXIT SUB
237.  
238. xc! = (x1! + x2! + x3! + x4!) / 4
239. yc! = (y1! + y2! + y3! + y4!) / 4
240. zc! = (z1! + z2! + z3! + z4!) / 4
241.  
242. LINE (x1!, y1!)-(xc!, yc!), col
243. LINE (x2!, y2!)-(xc!, yc!), col
244. LINE (x3!, y3!)-(xc!, yc!), col
245. LINE (x4!, y4!)-(xc!, yc!), col
246.  
247. CDG3 x1!, x2!, x3!, xc!, y1!, y2!, y3!, yc!, z1!, z2!, z3!, zc!, cont - 1, col
248. CDG3 x1!, x2!, xc!, x4!, y1!, y2!, yc!, y4!, z1!, z2!, zc!, z4!, cont - 1, col
249. CDG3 x1!, xc!, x3!, x4!, y1!, yc!, y3!, y4!, z1!, zc!, z3!, z4!, cont - 1, col
250. CDG3 xc!, x2!, x3!, x4!, yc!, y2!, y3!, y4!, zc!, z2!, z3!, z4!, cont - 1, col
251.  
252.  
253. END SUB
254.  
255. SUB CogeTecla
256.  
257. K$ = INKEY$
258. IF K$ <> "" THEN
259.   IF ASC(K$) = 27 THEN SalidaOK
260. END IF
261.  
262.  
263. END SUB
264.  
265. SUB DibuCDG2 (col)
266.  
267. SHARED VertXY!(), NIter
268.  
269. x1! = VertXY!(1, 1)
270. x2! = VertXY!(2, 1)
271. x3! = VertXY!(3, 1)
272.  
273. y1! = VertXY!(1, 2)
274. y2! = VertXY!(2, 2)
275. y3! = VertXY!(3, 2)
276.  
277. z1! = VertXY!(1, 3)
278. z2! = VertXY!(2, 3)
279. z3! = VertXY!(3, 3)
280.  
281. CDG2 x1!, x2!, x3!, y1!, y2!, y3!, z1!, z2!, z3!, NIter, col
282.  
283.  
284. END SUB
285.  
286. SUB DibuCDG3 (col)
287. SHARED VertXY!(), NIter
288.  
289. x1! = VertXY!(1, 1)
290. x2! = VertXY!(2, 1)
291. x3! = VertXY!(3, 1)
292. x4! = VertXY!(4, 1)
293.  
294. y1! = VertXY!(1, 2)
295. y2! = VertXY!(2, 2)
296. y3! = VertXY!(3, 2)
297. y4! = VertXY!(4, 2)
298.  
299. z1! = VertXY!(1, 3)
300. z2! = VertXY!(2, 3)
301. z3! = VertXY!(3, 3)
302. z4! = VertXY!(4, 3)
303.  
304. CDG3 x1!, x2!, x3!, x4!, y1!, y2!, y3!, y4!, z1!, z2!, z3!, z4!, NIter, col
305.  
306. END SUB
307.  
308. SUB DibuFrame
309. SHARED NVert, VertXY!(), f!()
310. negro = 0
311. FOR i = 1 TO NVert - 1
312.   FOR j = i + 1 TO NVert
313.     LINE (f!(i, 1), f!(i, 2))-(f!(j, 1), f!(j, 2)), negro
314.   NEXT j
315. NEXT i
316.  
317.  
318. FOR i = 1 TO NVert - 1
319.   FOR j = i + 1 TO NVert
320.     LINE (VertXY!(i, 1), VertXY!(i, 2))-(VertXY!(j, 1), VertXY!(j, 2))
321.   NEXT j
322. NEXT i
323.  
324. FOR i = 1 TO NVert - 1
325.   FOR j = i + 1 TO NVert
326.     f!(i, 1) = VertXY!(i, 1)
327.     f!(i, 2) = VertXY!(i, 2)
328.     f!(j, 1) = VertXY!(j, 1)
329.     f!(j, 2) = VertXY!(j, 2)
330.   NEXT j
331. NEXT i
332.  
333. END SUB
334.  
335. SUB DibuFrameNegro
336. SHARED NVert, VertXY!(), f!()
337. negro = 0
338. FOR i = 1 TO NVert - 1
339.   FOR j = i + 1 TO NVert
340.     LINE (f!(i, 1), f!(i, 2))-(f!(j, 1), f!(j, 2)), negro
341.   NEXT j
342. NEXT i
343.  
344. END SUB
345.  
346. SUB DibuNegro
347. SHARED NVert
348. DibuFrameNegro
349. negro = 0
350. IF NVert = 4 THEN
351.   DibuCDG3 negro
352. ELSE
353.   DibuCDG2 negro
354. END IF
355.  
356. END SUB
357.  
358. SUB EscapeParaSalir (Lin)
359.    LOCATE Lin, 62
360.      Resalta "Esc para salir", 3
361.  
362. END SUB
363.  
364. SUB Info
365. SHARED colorres
366. COLOR colorres
367. PRINT "-----------------------------------------------------------------------------";
368. LOCATE 2, 1
369. COLOR colorres: PRINT "                                Espa\A4ol:": PRINT
370. LineaEspanol
371. PRINT
372. COLOR 2
373. PRINT "Dibujemos un triangulo y su Centro De Gravedad."
374. PRINT "Tracemos lineas desde este C.D.G. hasta los vertices del"
375. PRINT "triangulo. Si hacemos lo mismo con los 3 nuevos triangulos"
376. PRINT "que se forman y obramos asi sucesivamente, conseguimos este fractal."
377. PRINT
378. PRINT "Si lo hacemos con tetraedros conseguimos la version tridimensional."
379. COLOR colorres
380. PRINT "-----------------------------------------------------------------------------";
381. PRINT "                                English:": PRINT
382. LineaIngles
383. PRINT : COLOR 2
384. PRINT "Let us draw a triangle and its Centre Of Gravity."
385. PRINT "Then we draw lines from this C.O.G to the vertex of the"
386. PRINT "triangle. If we do the same with the 3 new triangles and so on,"
387. PRINT "we get this fractal."
388. PRINT
389. PRINT "We can get it in 3-Dimensions if we do it with tetrahedrons."
390. COLOR colorres
391. PRINT "-----------------------------------------------------------------------------";
392. PRINT "Sugerencias: FidoNet 2:344/18.8 -- Correo: Jose Angel Gonzalez"
393. PRINT "                                           Capuchinos, 9 - 6 C "
394. PRINT "E-Mail: jgonzalezr@nexo.es                 31500 Tudela (Navarra) SPAIN";
395. COLOR 7: PRINT " ";
396. END SUB
397.  
398. SUB Izquierda
399.   SHARED NVert, VertXY!(), pi!
400.  
401.   a! = RND * pi!
402.  
403.   FOR i = 1 TO NVert
404.     alfa! = ATN(VertXY!(i, 2) / SQR(VertXY!(i, 3) ^ 2 + VertXY!(i, 1) ^ 2))
405.     beta! = ATN(VertXY!(i, 1) / VertXY!(i, 3)) + a!
406.     VertXY!(i, 2) = SIN(alfa!)
407.     IF VertXY!(i, 3) > 0 THEN VertXY!(i, 1) = COS(alfa!) * SIN(beta!) ELSE VertXY!(i, 1) = -COS(alfa!) * SIN(beta!)
408.     IF VertXY!(i, 3) > 0 THEN VertXY!(i, 3) = COS(alfa!) * COS(beta!) ELSE VertXY!(i, 3) = -COS(alfa!) * COS(beta!)
409.   NEXT i
410.  
411. END SUB
412.  
413. SUB LineaEspanol
414.   SHARED colorres, colornormal
415.   N = 3
416.   COLOR colornormal
417.   LOCATE N, 1: PRINT "Con + / - se cambia la densidad del fractal. Con las flechas puede girar.";
418.   COLOR colorres
419.   LOCATE N, 5: PRINT "+"
420.   LOCATE N, 9: PRINT "-"
421.  
422. END SUB
423.  
424. SUB LineaIngles
425.  
426.   SHARED colorres, colornormal
427.   N = 13
428.   COLOR colornormal
429.   LOCATE N, 1
430.   PRINT "With + / - you change the fractal's density. With arrows, you rotate it.";
431.   COLOR colorres
432.   LOCATE N, 6: PRINT "+"
433.   LOCATE N, 10: PRINT "-"
434.  
435. END SUB
436.  
437. SUB Mensajes
438. SHARED py, colorres, colornormal, NIter, L1$, L2$
439. py = 28: colorres = 14: colornormal = 7
440. COLOR 7: LOCATE py, 2: PRINT " -D   -D";
441. LOCATE 3, 65: Resalta "F1: Help", 2
442. LOCATE 3, 3: PRINT NIter; " Iteraciones";
443. COLOR colorres: LOCATE py, 2: PRINT "2"; : LOCATE py, 7: PRINT "3";
444. LOCATE py - 1, 72: PRINT L1$
445. LOCATE py, 70: PRINT L2$;
446. LOCATE py + 2, 3: PRINT "+   -";
447. LOCATE 30, 67: Resalta "Esc to exit", 3
448. LOCATE py + 2, 5: PRINT "/";
449. COLOR 15
450.  
451. END SUB
452.  
453. SUB Pitido1
454.   SOUND 740, .2
455. END SUB
456.  
457. SUB Resalta (a$, N)
458.  
459.   SHARED colorres, colornormal
460.   l = LEN(a$)
461.   b$ = LTRIM$(a$)
462.   L2 = LEN(b$)
463.   PRINT STRING$(l - L2, " ");
464.   COLOR colorres
465.   PRINT LEFT$(b$, N);
466.   COLOR colornormal
467.   PRINT RIGHT$(b$, L2 - N);
468.  
469. END SUB
470.  
471. SUB SalidaOK
472.   SHARED colornormal
473.   SCREEN 0
474.   Info
475.   END
476.  
477. END SUB
478.  

[bplus]

Nice fractal, I've not seen that before, thanks for sharing!

Oh, what would be nice would be to fill the triangles with transparent colors!
This will draw filled triangle, just need the 3 points (x, y) numbers:

Code: QB64: [Select]

1. ' found at [abandoned, outdated and now likely malicious qb64 dot net website - don’t go there]:    http://www.[abandoned, outdated and now likely malicious qb64 dot net website - don’t go there]/forum/index.php?topic=14425.0
2. SUB ftri (x1, y1, x2, y2, x3, y3, K AS _UNSIGNED LONG)
3.     DIM a&
4.     a& = _NEWIMAGE(1, 1, 32)
5.     _DEST a&
6.     PSET (0, 0), K
7.     _DEST 0
8.     _MAPTRIANGLE _SEAMLESS(0, 0)-(0, 0)-(0, 0), a& TO(x1, y1)-(x2, y2)-(x3, y3)
9.     _FREEIMAGE a& '<<< this is important!
10. END SUB
11.  

Do you know about transparent colors?

[petoro]

Glad you liked it.

I hadn't seen them anywhere until a couple of years ago or so.

[bplus]

Hi petoro,

I left code for drawing a filled triangle, don't worry about understanding how it works (yet), just feed it 3 points and an _RGBA color and it will draw a triangular colored glass panel if you use low alpha colors. Maybe you'd like to color the fractal or practice with the triangle code.

[petoro]

I can not make your code fragment run.

Could you show it with a particular example?

[bplus]

I can not make your code fragment run.

Could you show it with a particular example?

Love to! I forgot to mention you need to setup a graphics screen, you probably didn't have much luck with screen 12 if you use color numbers 0 - 15, I included brief comments about setting up a graphics screen.

Code: QB64: [Select]

1. _TITLE "Demo for triangle fill sub called ftri" 'b+ 2019-08-18
2.  
3. ' you will need to set up a graphics screen
4. SCREEN _NEWIMAGE(800, 600, 32) 'this sets the screen size to 800 pixels wide by 600 pixels high
5. '                               the 32 means _RGBA colors will work (allows transparencies)
6.  
7. _SCREENMOVE 300, 20 'this puts the screen towards center of display screen front and center
8.  
9. ' 3 points and one color
10. x1 = 0: y1 = 0 'top left screen corner
11.  
12. x2 = _WIDTH / 2 'middle screen x axis
13. y2 = 20 'move down a bit from 0 at top
14.  
15. x3 = _WIDTH / 4 ' 1/4 to right from left edge
16. y3 = _HEIGHT / 2 '1/2 down screen
17.  
18. 'for color solid dark red  _rgba(128, 0, 0, 255) 'the 4th argument is transparency 255 is solid no transparency
19. ftri x1, y1, x2, y2, x3, y3, _RGBA(128, 0, 0, 255)
20.  
21. 'make another yellow triangle using edge of last again a solid, non transparent color
22. ftri x2, y2, x3, y3, _WIDTH * .6, _HEIGHT * .8, _RGBA(255, 255, 0, 255)
23.  
24. 'now overlap these 2 triangles with a 128/255 = .5 transparent blue triangle
25. ftri 50, 75, _WIDTH * .8, 100, _WIDTH * .2, _HEIGHT * .5, _RGBA(0, 0, 255, 128)
26.  
27. LOCATE 35, 15: INPUT "For fun how about a morphing triangle screen saver, press enter ", wait$
28.  
29. WHILE _KEYDOWN(27) = 0 'while no escape key press
30.  
31.     'pick pick 3 random points on screen
32.     x1 = RND * _WIDTH: x2 = RND * _WIDTH: x3 = RND * _WIDTH
33.     y1 = RND * _HEIGHT: y2 = RND * _HEIGHT: y3 = RND * _HEIGHT
34.     r = RND * 255: g = RND * 255: b = RND * 255: a = 255
35.     dx1 = RND * 5 - 2.5: dx2 = RND * 5 - 2.5: dx3 = RND * 5 - 2.5
36.     dy1 = RND * 5 - 2.5: dy2 = RND * 5 - 2.5: dy3 = RND * 5 - 2.5
37.     dr = RND * 10 - 5: dg = RND * 10 - 5: db = RND * 10 - 5: da = -5: da = -3
38.     'morph triangle
39.     loopCnt = 0
40.     DO
41.         'draw it
42.         ftri x1, y1, x2, y2, x3, y3, _RGBA(r, g, b, a)
43.  
44.         'update morph
45.         x1 = x1 + dx1: IF x1 < 0 OR x1 > _WIDTH THEN dx1 = -dx1
46.         y1 = y1 + dy1: IF y1 < 0 OR y1 > _HEIGHT THEN dy1 = -dy1
47.  
48.         x2 = x2 + dx2: IF x2 < 0 OR x2 > _WIDTH THEN dx2 = -dx2
49.         y2 = y2 + dy2: IF y2 < 0 OR y2 > _HEIGHT THEN dy2 = -dy2
50.  
51.         x3 = x3 + dx3: IF x3 < 0 OR x3 > _WIDTH THEN dx3 = -dx3
52.         y3 = y3 + dy3: IF y3 < 0 OR y3 > _HEIGHT THEN dy3 = -dy3
53.  
54.         r = r + dr: IF r < 0 OR r > 255 THEN dr = -dr
55.         g = g + dg: IF g < 0 OR g > 255 THEN dg = -dg
56.         b = b + db: IF b < 0 OR b > 255 THEN db = -db
57.         a = a + 3: IF a < 10 OR a > 252 THEN da = -da
58.         loopCnt = loopCnt + 1
59.  
60.         _DISPLAY ' stops flickering specially when allot of CLS
61.         _LIMIT 60 ' << updates screen 60 times per secound
62.  
63.     LOOP UNTIL loopCnt = 1000
64.     CLS
65. WEND
66.  
67.  
68. ' found at [abandoned, outdated and now likely malicious qb64 dot net website - don’t go there]:    http://www.[abandoned, outdated and now likely malicious qb64 dot net website - don’t go there]/forum/index.php?topic=14425.0
69. SUB ftri (x1, y1, x2, y2, x3, y3, K AS _UNSIGNED LONG)
70.     DIM a&
71.     a& = _NEWIMAGE(1, 1, 32)
72.     _DEST a&
73.     PSET (0, 0), K
74.     _DEST 0
75.     _MAPTRIANGLE _SEAMLESS(0, 0)-(0, 0)-(0, 0), a& TO(x1, y1)-(x2, y2)-(x3, y3)
76.     _FREEIMAGE a& '<<< this is important!
77. END SUB
78.  
79.  

[petoro]

That is beautiful, there are several very interesting functions in your code, such as the Universal Resizer of the screen, the transparency fourth argument, the WAIT$ argument... and a lot more that I didn't knew. Thanks for sharing.

[bplus]

That is beautiful, there are several very interesting functions in your code, such as the Universal Resizer of the screen, the transparency fourth argument, the WAIT$ argument... and a lot more that I didn't knew. Thanks for sharing.

Yeah welcome to QB64! with SCREEN _NEWIMAGE(wide, heigh, 32)

The WAIT$ is just a dummy variable name describing what it was doing at the end of an INPUT statement, nothing special and not sure if I did all caps on purpose or not (it was not.) OK I just looked it up, there is a keyword WAIT, I guess I better stick to w$ abbreviated wait$, though it works OK.

[petoro]

Yeah welcome to QB64! with SCREEN _NEWIMAGE(wide, heigh, 32)

The WAIT$ is just a dummy variable name describing what it was doing at the end of an INPUT statement, nothing special and not sure if I did all caps on purpose or not (it was not.) OK I just looked it up, there is a keyword WAIT, I guess I better stick to w$ abbreviated wait$, though it works OK.

My fault, I misinterpreted its meaning...

[Ashish]

Amazing!!