Archery!

[Cobalt]

Blast from the past! Archery is a remake of the game from 1985! Nearing completion, a preview\beta release.
Totally self contained, needing no extra files!(which is uncommon for me)

Do some practice shooting by yourself, play with a friend, or go head to head with the computer!

Code: QB64: [Select]

1. 'Archery 1985 by Brain Blankenship
2. '2019 Archery By Cobalt
3. '8/13/2019|
4. 'V0.4
5. '-Sprites\Title\Options screens done
6. 'V0.6
7. '-Scoreboard done
8. '-target movement done
9. '-arrow movement done
10. 'V0.7
11. '-collision detection
12. '8/14/2019
13. 'V0.8
14. 'player 2 frames
15. 'Random site creation
16. '8/15/2019
17. 'v0.9
18. 'Computer AI for player 2
19. 'Computer vs computer possible
20. '8/16/2019
21. 'V1.0b
22. 'Highscore file\list added
23. 'Bug-Computer goes first in 1 player game fixed(Thanks Bplus!)
24. 'Computer only play option added
25. 'V1.0c
26. 'Bug-Player 2 goes first in 2 player game fixed(Thanks TempodiBasic)
27. 'Error- corrected ORIGNALLY to ORIGINALLY in title screen(Thanks TempodiBasic)
28.  
29. TYPE Position
30.  X AS INTEGER
31.  Y AS INTEGER
32.  Speed AS _BYTE
33.  OrigX AS INTEGER
34.  OrigY AS INTEGER
35. END TYPE
36.  
37. SCREEN _NEWIMAGE(640, 400, 32)
38. _DELAY .125
39. _SCREENMOVE 20, 20
40. _TITLE "Archery 1985   v1.0c"
41.  
42. '-------------CONSTANTS----------------
43. CONST TRUE = -1, FALSE = NOT TRUE
44. CONST Black = &HFF000101~&, Cyan = &HFF01A0A0~&, Magenta = &HFF941090~&, OffWhite = &HFFC7C0C0~&, Green = &HFF1B9010~&, CtrWhite = &HFFCAC0C0~&
45. '--------------------------------------
46. '-------ARRAYS & SHARED VARIABLES------
47. DIM SHARED Layer(10) AS LONG, Shots(1, 5, 2) AS _BYTE, HitSound$, QuitGame%%, ComputerOnly%%
48. DIM SHARED Computer.Class, Player$(2), Flag AS _BYTE, Turn%%, Noise%%, Winner%%
49. DIM SHARED Arrow AS Position, Target AS Position
50. '--------------------------------------
51. '---------------LAYERS-----------------
52. Layer(0) = _DISPLAY
53. Layer(1) = _NEWIMAGE(640, 400, 32) 'mix layer
54. Layer(2) = _NEWIMAGE(320, 200, 32) 'Title Screen Layer
55. Layer(3) = _NEWIMAGE(320, 200, 32) 'Sprite sheet layer
56. Layer(4) = _NEWIMAGE(320, 200, 32) 'Collision layer
57. Layer(5) = _NEWIMAGE(320, 200, 32) 'Extra/Scoreboard layer
58. Layer(6) = _NEWIMAGE(320, 200, 32) 'Input layer/Prebuild layer
59. Layer(7) = _NEWIMAGE(320, 200, 32) 'high score layer
60. '--------------------------------------
61. '-----------ARROW HIT SOUND------------
62. PLAY "t230l64" 'setup sound play rate
63. HitSound$ = "o1bagfedc"
64. '--------------------------------------
65. Draw_Sprites
66. Draw_Title_Screen
67. Title_Animation
68. '-------Inital Values------------------
69. RANDOMIZE TIMER
70. Target.Speed = 1
71. Target.Y = 0: Target.OrigY = 0
72. Target.X = 309: Target.OrigX = 309
73. Arrow.Speed = 0
74. Arrow.OrigY = 135: Arrow.Y = Arrow.OrigY
75. Arrow.OrigX = 69: Arrow.X = Arrow.OrigX
76. ExitFlag%% = FALSE
77. Turn%% = TRUE
78. Computer.Class = 3 'skill level of computer(experimental)
79. Noise%% = Computer_AI 'adds little randomness to computer shots
80. '-------------MAIN LOOP----------------
81. DO
82.  ClearLayer Layer(5)
83.  Game_Option_Screen
84.  Scoreboard_Setup
85.  MainGame
86.  IF Calc_Score(0) >= Calc_Score(1) THEN Winner%% = 0 ELSE Winner%% = 1
87.  HighScore_Screen
88.  IF QuitGame%% THEN ExitFlag%% = TRUE
89. LOOP UNTIL ExitFlag%%
90. CLS
91. _DEST Layer(0)
92. PRINT "Thank you for playing Archery 2019!"
93. PRINT "leave any comments, suggestions, or bugs at:"
94. PRINT "www.QB64.org/Forum/index.php?topic=1627.0"
95. _KEYCLEAR
96. SLEEP
97. SYSTEM
98. '--------------------------------------
99.  
100. FUNCTION Calc_Score~%% (Who%%)
101.  Result~%% = 0
102.  FOR F%% = 0 TO 4
103.   FOR S%% = 0 TO 2
104.    Result~%% = Result~%% + Shots(Who%%, F%%, S%%)
105.   NEXT S%%
106.  NEXT F%%
107.  Calc_Score = Result~%%
108. END FUNCTION
109.  
110. SUB ClearLayer (L&)
111.  _DEST L&
112.  CLS
113.  _DEST _DISPLAY
114. END SUB
115.  
116. FUNCTION Collision_Check~%% (X%, Y%)
117.  IF _SOURCE <> Layer(4) THEN _SOURCE Layer(4)
118.  Result~%% = 0
119.  FOR I%% = 0 TO 1
120.   Test~& = POINT(25 + X% + I%%, Y% + 3)
121.   R~%% = _RED32(Test~&)
122.   IF R~%% = 255 THEN R~%% = 1
123.   IF R~%% > 0 THEN Result~%% = R~%%: I%% = 5
124.  NEXT I%%
125.  Collision_Check = Result~%%
126. END FUNCTION
127.  
128. FUNCTION Computer_AI%% ()
129.  Result%% = 0
130.  SELECT CASE Computer.Class
131.   CASE 1 'basic
132.    Result%% = INT(RND * 28) - 10
133.   CASE 2 'decent
134.    Result%% = INT(RND * 24) - 8
135.   CASE 3 'good
136.    Result%% = INT(RND * 20) - 6
137.   CASE 4 'hard
138.    Result%% = INT(RND * 16) - 4
139.   CASE 5 'Robin Hood unbeatable 150!
140.    IF Arrow.OrigX MOD 2 THEN Result%% = 5 ELSE Result%% = 6
141.  END SELECT
142.  Computer_AI%% = Result%%
143. END FUNCTION
144.  
145. SUB Display_Scoreboard
146.  _PUTIMAGE , Layer(5), Layer(6)
147.  _DEST Layer(6)
148.  _FONT 8
149.  COLOR OffWhite
150.  FOR P%% = 0 TO 1
151.   FOR Flight%% = 0 TO 4
152.    FOR Shot%% = 0 TO 2
153.     LOCATE 4 + Shot%% + (P%% * 4), 12 + Flight%% * 4
154.     PRINT Shots(P%%, Flight%%, Shot%%)
155.    NEXT Shot%%
156.   NEXT Flight%%
157.  NEXT P%%
158.  LOCATE 4, 32: PRINT Calc_Score(0)
159.  LOCATE 8, 32: PRINT Calc_Score(1)
160.  
161.  _FONT 16
162.  _DEST Layer(0)
163. END SUB
164.  
165. SUB Draw_Sprites
166.  ClearLayer Layer(3)
167.  _DEST Layer(1)
168.  'Original target draw /w color fix
169.  DRAW "bm318,140c" + STR$(Cyan) + "d30l1u30l1d30u6l1c" + STR$(Magenta) + "u18l1d18l1u18d6l1c" + STR$(OffWhite) + "d6l1u6"
170.  'original arrow draw /w color fix
171.  DRAW "bm10,155c" + STR$(Cyan) + "r20l20c" + STR$(Magenta) + "h3f3g3e3c" + STR$(OffWhite) + "bm+2,+0h3f3g3e3c" + STR$(Magenta) + "bm+2,+0h3f3g3e3bm+15,-2c" + STR$(OffWhite) + "d4u1r1u2d1r1"
172.  LINE (311, 155)-STEP(1, 0), CtrWhite
173.  _DEST Layer(0)
174.  _PUTIMAGE (0, 0), Layer(1), Layer(3), (310, 140)-STEP(8, 30) 'move target to sprite sheet
175.  _PUTIMAGE (0, 32), Layer(1), Layer(3), (7, 152)-STEP(24, 6) 'move arrow to sprite sheet
176.  _CLEARCOLOR _RGB32(0, 0, 0), Layer(3)
177.  ClearLayer Layer(1)
178. END SUB
179.  
180. SUB Draw_Title_Screen
181.  _DEST Layer(1)
182.  _FONT 8
183.  COLOR OffWhite
184.  PSET (0, 0), OffWhite
185.  DRAW "bm41,70e30r10d30l8u12l8g12l11bm+34,-24d6l7e7bm+11,-5d30r8u15m+15,+15r10h18u12l14bm+4,+5d5r4u5l4"
186.  DRAW "BM+20,-5r30d12l8u4l17f15r3u5r7d12l15h20u10r4bm+37,-0r8d10r8u10r8d30l8u10l8d10l8u30bm+30,-0r20d6l15d8r8d5l8d6r15d5l20u30"
187.  DRAW "bm+26,-0d30r8u15m+15,+15r10h18u12l14bm+4,+5d5r4u5l4bm+17,-5d10f16d4r8u30l8d17h7u10l8"
188.  DATA 46,90,129,150,180,206,243
189.  FOR i%% = 1 TO 7
190.   READ t%
191.   PAINT (t%, 68), Magenta, OffWhite
192.  NEXT i%%
193.  LOCATE 17, 11: PRINT "Originally by:"
194.  LOCATE 20, 16: PRINT "Brain Blankenship"
195.  _FONT 16
196.  _DEST Layer(0)
197.  _PUTIMAGE (1, 0), Layer(1), Layer(2), (1, 0)-(319, 199)
198.  _PUTIMAGE (310, 140), Layer(3), Layer(2), (0, 0)-STEP(7, 30) 'target
199.  _CLEARCOLOR _RGB32(0, 0, 0), Layer(2)
200.  ClearLayer Layer(1)
201. END SUB
202.  
203. SUB Game_Option_Screen
204.  _DEST Layer(5)
205.  _FONT 8
206.  COLOR OffWhite
207.  PRINT "Instructions": PRINT
208.  PRINT " Score as many  points as  possible by"
209.  PRINT "  hitting  the   target  close  to  the"
210.  PRINT "  center. Press the space bar to shoot."
211.  PRINT "  You get three trys from each of  five"
212.  PRINT "  sites, highest score wins. 3 to watch"
213.  PRINT "  the computer battle it out."
214.  PRINT
215.  PushScreen 5
216.  _DELAY 3
217.  PRINT: PRINT: PRINT
218.  PRINT "Number of Players(1/2[3])?"
219.  PushScreen 5
220.  DO: kbd$ = INKEY$: LOOP UNTIL kbd$ = "1" OR kbd$ = "2" OR kbd$ = "3"
221.  IF kbd$ <> "3" THEN
222.   Flag = Flag + 2 ^ (VAL(kbd$) - 1) 'set bit 0 if 1 player, bit 1 for 2 player
223.   PRINT: PRINT "Enter player one's name :?"
224.   Turn%% = TRUE
225.   PushScreen 5
226.   Player$(0) = Get_Player_Name(0)
227.   _PRINTSTRING (212, 112), Player$(0)
228.  
229.   IF Flag AND 2 THEN
230.    PRINT: PRINT "Enter player two's name :?"
231.    PushScreen 5
232.    Player$(1) = Get_Player_Name(1)
233.    _PRINTSTRING (212, 128), Player$(1)
234.   ELSE
235.    PRINT: PRINT "           Play Computer ?"
236.    PushScreen 5
237.    DO: kbd$ = LCASE$(INKEY$): LOOP UNTIL kbd$ = "y" OR kbd$ = "n"
238.    IF kbd$ = "y" THEN Flag = 4: Player$(1) = "Computer"
239.   END IF
240.  ELSE
241.   Player$(0) = "Computr1"
242.   Player$(1) = "Computr2"
243.   ComputerOnly%% = TRUE: Turn%% = FALSE 'watch the computer play itself!
244.   Flag = 4 'set player 2 to computer(needed for computer only play)
245.  END IF
246.  _FONT 16
247.  _DEST Layer(0)
248.  ClearLayer Layer(1)
249. END SUB
250.  
251. FUNCTION Get_Player_Name$ (Who%%)
252.  DO
253.   kbd$ = INKEY$
254.   IF LEN(Result$) < 8 AND kbd$ >= CHR$(32) THEN Result$ = Result$ + kbd$
255.   IF kbd$ = CHR$(8) THEN Result$ = LEFT$(Result$, LEN(Result$) - 1)
256.   IF Who%% THEN _PRINTSTRING (212, 120), Result$ ELSE _PRINTSTRING (212, 104), Result$
257.   PushScreen 5
258.   _DELAY .025
259.   IF Who%% THEN LINE (212, 128)-STEP(72, 8), Black, BF ELSE LINE (212, 112)-STEP(72, 8), Black, BF
260.  LOOP UNTIL kbd$ = CHR$(13)
261.  Get_Player_Name = Result$
262. END FUNCTION
263.  
264. SUB HighScore_Screen
265.  _DEST Layer(7): CLS: _FONT 8
266.  COLOR OffWhite
267.  DIM C(5) AS _UNSIGNED LONG, Score.Name(11) AS STRING * 8, Score.Val(11) AS _UNSIGNED _BYTE
268.  C(1) = Magenta: C(2) = Magenta: C(3) = Magenta: C(4) = OffWhite: C(5) = Cyan
269.  CI%% = 1
270.  '-----load previous scores(if any)------
271.  IF _FILEEXISTS("Archery.dat") THEN
272.   OPEN "Archery.dat" FOR INPUT AS #1
273.   INPUT #1, Count%% 'how many scores recored
274.   FOR i%% = 1 TO Count%%
275.    INPUT #1, Score.Name(i%%)
276.    INPUT #1, Score.Val(i%%)
277.   NEXT i%%
278.   CLOSE #1
279.   OPEN "Archery.dat" FOR OUTPUT AS #1
280.  ELSE
281.   OPEN "Archery.dat" FOR OUTPUT AS #1
282.   Count%% = 0
283.  END IF
284.  '-----------------------------------------
285.  '-------tack new score on bottom-------
286.  Count%% = Count%% + 1
287.  Score.Name(Count%%) = Player$(Winner%%)
288.  Score.Val(Count%%) = Calc_Score(Winner%%)
289.  '--------------------------------------
290.  '------------Ultra basic sort----------
291.  IF Count%% > 1 THEN
292.   FOR i%% = 1 TO Count%%
293.    FOR j%% = i%% TO Count%%
294.     IF Score.Val(j%%) > Score.Val(i%%) THEN SWAP Score.Val(j%%), Score.Val(i%%): SWAP Score.Name(j%%), Score.Name(i%%)
295.    NEXT j%%
296.   NEXT i%%
297.  END IF
298.  '---------------------------------------
299.  '--------------save scores--------------
300.  IF Count%% = 11 THEN Count%% = 10 'drop lowest score
301.  PRINT #1, Count%%
302.  FOR i%% = 1 TO Count%%
303.   PRINT #1, Score.Name(i%%)
304.   PRINT #1, Score.Val(i%%)
305.  NEXT i%%
306.  CLOSE
307.  '---------------------------------------
308.  i%% = 0
309.  DO
310.   KBD$ = INKEY$
311.   IF KBD$ = CHR$(27) THEN ExitFlag%% = TRUE: QuitGame%% = TRUE
312.   IF UCASE$(KBD$) = "Y" THEN ExitFlag%% = TRUE
313.   IF UCASE$(KBD$) = "N" THEN ExitFlag%% = TRUE: QuitGame%% = TRUE
314.   'erase highscore list
315.   IF UCASE$(KBD$) = "S" AND _FILEEXISTS("Archery.dat") THEN KILL "Archery.dat"
316.   '---------box area----------
317.   LINE (9 + i%%, 9 + i%%)-STEP(263 - i%% * 2, 138 - i%% * 2), C(CI%%), B
318.   '---------------------------
319.   i%% = i%% + 1
320.   IF i%% = 9 THEN i%% = 0
321.   CI%% = CI%% + 1
322.   IF CI%% = 6 THEN CI%% = 1
323.   FOR j%% = 1 TO Count%%
324.    LOCATE 4 + j%%, 10: PRINT Score.Name(j%%); TAB(23 + 3 - LEN(LTRIM$(RTRIM$(STR$(Score.Val(j%%)))))); Score.Val(j%%)
325.   NEXT j%%
326.   LOCATE 22, 14: PRINT "Play Again?"
327.   _PUTIMAGE , Layer(7), Layer(1), (0, 0)-STEP(319, 199)
328.   _PUTIMAGE , Layer(1), Layer(0)
329.   _DELAY .005
330.  LOOP UNTIL ExitFlag%%
331.  Reset_Game
332.  _FONT 16
333.  _DEST Layer(0)
334. END SUB
335.  
336. SUB Move_Target
337.  Target.Y = Target.Y + Target.Speed
338.  _PUTIMAGE (Target.X, Target.Y), Layer(3), Layer(6), (0, 0)-STEP(8, 30) 'target
339.  'collision layer
340.  ClearLayer Layer(4)
341.  _PUTIMAGE (Target.X, Target.Y), Layer(3), Layer(4), (0, 0)-STEP(8, 30) 'target
342.  _PUTIMAGE (318, 0)-STEP(1, 199), Layer(5), Layer(4), (319, 0)-(319, 199) 'target
343. END SUB
344.  
345. SUB Move_Arrow
346.  Arrow.X = Arrow.X + Arrow.Speed
347.  _PUTIMAGE (Arrow.X, Arrow.Y), Layer(3), Layer(6), (0, 32)-STEP(24, 6) 'arrow
348. END SUB
349.  
350. SUB PushScreen (id%%)
351.  _PUTIMAGE (0, 0)-STEP(639, 399), Layer(id%%), Layer(1), (0, 0)-STEP(319, 199)
352.  _PUTIMAGE , Layer(1), Layer(0)
353. END SUB
354.  
355. SUB New_Site
356.  Arrow.OrigX = INT(RND * 240) + 10
357.  Arrow.OrigY = INT(RND * 50) + 120
358. END SUB
359.  
360. SUB Reset_Game
361.  Reset_Shot 99, 99, 0 'reset frame and flight
362.  FOR x%% = 0 TO 1 'reset score
363.   FOR y%% = 0 TO 4
364.    FOR z%% = 0 TO 2
365.     Shots(x%%, y%%, z%%) = 0
366.  NEXT z%%, y%%, x%%
367. END SUB
368.  
369. SUB Reset_Shot (Shot%%, Shoot%%, Hit~%%)
370.  STATIC Flight%%, Frame%%, Player%%
371.  '-------assign score-------
372.  Shots(Player%%, Frame%%, Flight%%) = Hit~%% MOD 16
373.  '--------------------------
374.  '-----increment flight-----
375.  Flight%% = Flight%% + 1
376.  IF Flight%% = 3 THEN '3 flights per frame
377.   IF Flag AND 1 THEN
378.    Frame%% = Frame%% + 1: Flight%% = 0: New_Site
379.   END IF
380.   IF Flag AND 2 OR Flag AND 4 THEN 'is there a second player or computer?
381.    IF Player%% THEN 'player 2 just loosed, next frame for player 1
382.     Player%% = 0: Frame%% = Frame%% + 1: Flight%% = 0: New_Site
383.     IF NOT ComputerOnly%% THEN Turn%% = TRUE
384.    ELSE 'let player 2 loose his first frame
385.     IF Flag AND 4 THEN Turn%% = FALSE
386.     Player%% = 1: Flight%% = 0
387.    END IF
388.   END IF
389.  END IF
390.  '--------------------------
391.  Target.Y = Target.OrigY
392.  Target.Speed = 1
393.  Arrow.Y = Arrow.OrigY
394.  Arrow.X = Arrow.OrigX
395.  IF Shot%% = 99 AND Shoot%% = 99 THEN Flight%% = 0: Frame%% = 0
396.  Shot%% = FALSE
397.  Shoot%% = FALSE
398.  IF Frame%% = 5 THEN Hit~%% = 99 ELSE Hit~%% = 0 'end game trigger
399.  Noise%% = Computer_AI 'adds little randomness to computer shots
400. END SUB
401.  
402. SUB Scoreboard_Setup
403.  ClearLayer Layer(5)
404.  _DEST Layer(5)
405.  _FONT 8
406.  COLOR OffWhite
407.  LINE (1, 1)-STEP(300, 84), Cyan, B
408.  LINE (2, 2)-STEP(298, 82), Magenta, B
409.  LINE (3, 3)-STEP(296, 80), OffWhite, B
410.  LINE (4, 4)-STEP(294, 78), Black, BF
411.  LOCATE 2, 2: PRINT "Player    #1  #2  #3  #4  #5  Total"
412.  LOCATE 4, 3: PRINT Player$(0)
413.  LOCATE 8, 3: PRINT Player$(1)
414.  LINE (319, 0)-(319, 199), Green, BF
415.  _FONT 16
416.  _DEST Layer(0)
417. END SUB
418.  
419. SUB Title_Animation
420.  _DEST Layer(5)
421.  COLOR OffWhite
422.  _DEST Layer(0)
423.  _PRINTSTRING (4, 0), "UniKorn", Layer(5)
424.  _PRINTSTRING (36, 16), "ProDucKions", Layer(5)
425.  _PUTIMAGE (0, 0)-STEP(639, 400), Layer(5), Layer(1), (0, 0)-STEP(125, 39)
426.  _PUTIMAGE (0, 0)-STEP(639, 399), Layer(1), Layer(0)
427.  _PRINTSTRING (290, 350), "Presents", Layer(0)
428.  _DELAY 2.5
429.  ClearLayer Layer(5)
430.  CLS
431.  _PUTIMAGE (7 + i%, 152), Layer(3), Layer(5), (0, 32)-STEP(24, 6) 'arrow
432.  _PUTIMAGE , Layer(2), Layer(5)
433.  _PUTIMAGE (0, 0)-STEP(639, 399), Layer(5), Layer(1)
434.  _PUTIMAGE , Layer(1), Layer(0)
435.  _DELAY 1.5
436.  FOR i% = 0 TO 279 STEP 2
437.   _DELAY .02
438.   _PUTIMAGE (8 + i%, 152), Layer(3), Layer(5), (0, 32)-STEP(24, 6) 'arrow
439.   _PUTIMAGE , Layer(2), Layer(5) 'title layer
440.   _PUTIMAGE (0, 0)-STEP(639, 399), Layer(5), Layer(1)
441.   _PUTIMAGE , Layer(1), Layer(0)
442.   ClearLayer Layer(5)
443.  NEXT i%
444.  PLAY HitSound$
445.  _DELAY 1.5
446.  _DEST Layer(0)
447.  CLS
448. END SUB
449.  
450. SUB MainGame
451.  DO
452.   '-----controls-----
453.   KBD$ = INKEY$
454.   IF KBD$ = CHR$(27) THEN ExitFlag%% = TRUE
455.   IF Flag AND 1 OR Flag AND 2 THEN
456.    IF KBD$ = CHR$(32) AND (NOT Shot%%) THEN Shoot%% = TRUE: Shot%% = TRUE
457.   ELSE
458.    IF NOT Turn%% THEN
459.     IF Fire%% AND (NOT Shot%%) THEN Shoot%% = TRUE: Shot%% = TRUE: Fire%% = FALSE ': ExitFlag%% = TRUE
460.    ELSE
461.     IF KBD$ = CHR$(32) AND (NOT Shot%%) THEN Shoot%% = TRUE: Shot%% = TRUE
462.    END IF
463.   END IF
464.   '-----------------
465.  
466.   '------Logic------
467.   IF Shoot%% THEN Hit~%% = Collision_Check(Arrow.X, Arrow.Y)
468.   IF Hit~%% AND Shoot%% THEN Shoot%% = FALSE: PLAY HitSound$
469.   IF Shoot%% THEN Arrow.Speed = 3 ELSE Arrow.Speed = 0
470.   IF Target.Y = 201 THEN Target.Speed = 0
471.   IF Target.Y = 201 AND (NOT Shot%%) THEN Shot%% = TRUE 'if player doesn't shoot then they forefit
472.   IF Target.Speed = 0 AND Shot%% AND (NOT Shoot%%) THEN Reset_Shot Shot%%, Shoot%%, Hit~%%: Fire%% = FALSE
473.   SELECT CASE Hit~%% MOD 16
474.    CASE 0 'in travel
475.    CASE 11 'back stop
476.     Hit~%% = 0
477.    CASE ELSE 'hit target
478.     Arrow.Y = Arrow.Y + 1
479.   END SELECT
480.   '-computer player-
481.   Dist% = 309 - Arrow.OrigX '~how far to end of feild
482.   Tim%% = Dist% \ 3 + Noise%% 'time from loose to hit+random factor
483.   IF Target.Y + Tim%% >= Arrow.OrigY AND (NOT Shot%%) THEN Fire%% = TRUE
484.   '-----------------
485.  
486.   '-Display update--
487.   ClearLayer Layer(6)
488.   Display_Scoreboard
489.   Move_Target
490.   Move_Arrow
491.   PushScreen 6
492.   '-----------------
493.   IF Hit~%% = 99 THEN ExitFlag%% = TRUE 'game over
494.   _DELAY .03
495.  LOOP UNTIL ExitFlag%%
496.  
497. END SUB

not an exact copy of the original, having added small things like randomized shooting locations and potentially adjustable computer difficulty. and maybe should I get adventurous network play and score keeping!

This took way longer than it should typing 90% left handed only, I just couldn't sit on my arse doing nothing and while playing some old DOS games that made me want to write some code I bit the bullet and pecked a large potion single handedly, literally! Believe it or not the original game was written in basic and the source code is out there on github by the author. when I tried to pull it up it would only show in some encoded format but the strings where still readable so that saved me a huge amount of time trying to DRAW out the sprites and title(all done with DRAW command and PAINT!) It was supposedly written in something similar to GWBASIC not QB45 so why it has some kind of encoding I don't know, unless its some GitHub thing?(here is the original: https://github.com/inverted1/Archery) But I managed and here is the result so far.
 Give it a go. Let me know if it all works on newer QB64 builds.

for computer VS computer play you need to goto line 283 and comment out 'Turn%% = TRUE' as well as uncomment the line 70 and 71
adjusting Computer.Class varies how good the computer is, found a slight issue with level 5,which should always get 10s, as every so often it won't hit center. I can get it up to 4 out of 5 frames solid 10s but for some reason there are locations that the math doesn't work on.

Update 8-17-2019: fixed the computer player jump start Bplus found. Forgot to set player 1's turn flag.

Update II 8-17-2019: Fixed Player 2 line jumping(shooting first), and spelling error found by TempodiBasic.

[bplus]

Hi Cobalt,

I gave it a shot playing against the computer and it is hard to tell who is shooting, or specifically when I am up.

Also there seems to be a delay from time I press spacebar and when the arrow starts moving.

That name, Brain Blankenship, sounds familiar?

[STxAxTIC]

By the way, hi Cobolt!

[Cobalt]

Also there seems to be a delay from time I press spacebar and when the arrow starts moving.

I haven't noticed it.

And I never gave any thought to identifying whos up, the original game doesn't but I might do something about it, maybe changing the color, back in those days with SCREEN 1 that would have been harder to pull off.

Hey Stxaxtic long time. Try the game?

[STxAxTIC]

I tried the game and kicked nuts. It was easy to discern whose turn it is - just look at the scoreboard and whoever's triplet isn't complete, it's still their turn.

Funny enough we have a guy named Lefty here now, so now I have to think of some other nickname... Cobalternative Hand?

[johnno56]

Cool game. At times it was a bit tricky to figure the timing to shoot, but once I got the hang of it, mongrel game changed the distance to shoot.... lol

Simple but addictive. Nicely done.

Quick question: I am familiar with "step" in a for-next loop but how does it work in putimage?

[bplus]

OK when I tested playing, I answered 1 to players, yes to play against computer and I swear the code is shooting and filling out board under my name at least on first round which caused me to wonder and provide the feedback that I did. I tested this 5 times now and it shoots for me each time on first round.

If I go 1 player not against computer it works fine.

BTW cool start screen!

[bplus]

OK I took another copy of the code from forum, just to triple check:

Code: QB64: [Select]

1. 'Archery 1985 by Brain Blankenship
2. '2019 Archery By Cobalt
3. '8/13/2019|
4. 'V0.4
5. '-Sprites\Title\Options screens done
6. 'V0.6
7. '-Scoreboard done
8. '-target movement done
9. '-arrow movement done
10. 'V0.7
11. '-collision detection
12. '8/14/2019
13. 'V0.8
14. 'player 2 frames
15. 'Random site creation
16. '8/15/2019
17. 'v0.9
18. 'Computer AI for player 2
19. 'Computer vs computer possible
20.  
21. TYPE Position
22.     X AS INTEGER
23.     Y AS INTEGER
24.     Speed AS _BYTE
25.     OrigX AS INTEGER
26.     OrigY AS INTEGER
27. END TYPE
28.  
29. SCREEN _NEWIMAGE(640, 400, 32)
30. _DELAY .125
31. _SCREENMOVE 20, 20
32. _TITLE "Archery 1985   v0.9"
33.  
34. '-------------CONSTANTS----------------
35. CONST TRUE = -1, FALSE = NOT TRUE
36. CONST Black = &HFF000101~&, Cyan = &HFF01A0A0~&, Magenta = &HFF941090~&, OffWhite = &HFFC7C0C0~&, Green = &HFF1B9010~&, CtrWhite = &HFFCAC0C0~&
37. '--------------------------------------
38. '-------ARRAYS & SHARED VARIABLES------
39. DIM SHARED Layer(10) AS LONG, Shots(1, 4, 2) AS _BYTE, HitSound$
40. DIM SHARED Computer.Class, Player$(2), Flag AS _BYTE, Turn%%, Noise%%
41. DIM SHARED Arrow AS Position, Target AS Position
42. '--------------------------------------
43. '---------------LAYERS-----------------
44. Layer(0) = _DISPLAY
45. Layer(1) = _NEWIMAGE(640, 400, 32) 'mix layer
46. Layer(2) = _NEWIMAGE(320, 200, 32) 'Title Screen Layer
47. Layer(3) = _NEWIMAGE(320, 200, 32) 'Sprite sheet layer
48. Layer(4) = _NEWIMAGE(320, 200, 32) 'Collision layer
49. Layer(5) = _NEWIMAGE(320, 200, 32) 'Extra/Scoreboard layer
50. Layer(6) = _NEWIMAGE(320, 200, 32) 'Input layer/Prebuild layer
51. '--------------------------------------
52. '-----------ARROW HIT SOUND------------
53. PLAY "t230l64" 'setup sound play rate
54. HitSound$ = "o1bagfedc"
55. '--------------------------------------
56. Draw_Sprites
57. Draw_Title_Screen
58. Title_Animation
59. Game_Option_Screen
60. Scoreboard_Setup
61. '-------Inital Values------------------
62. RANDOMIZE TIMER
63. Target.Speed = 1
64. Target.Y = 0: Target.OrigY = 0
65. Target.X = 309: Target.OrigX = 309
66. Arrow.Speed = 0
67. Arrow.OrigY = 135: Arrow.Y = Arrow.OrigY
68. Arrow.OrigX = 69: Arrow.X = Arrow.OrigX
69. ExitFlag%% = FALSE
70. 'Turn%% = FALSE 'watch the computer play itself!
71. 'Flag = 4'set player 2 to computer(needed for computer only play)
72. Computer.Class = 3 'skill level of computer(experimental)
73. Noise%% = Computer_AI 'adds little randomness to computer shots
74. '-------------MAIN LOOP----------------
75.  
76. DO
77.     '-----controls-----
78.     KBD$ = INKEY$
79.     IF KBD$ = CHR$(27) THEN ExitFlag%% = TRUE
80.     IF Flag AND 1 OR Flag AND 2 THEN
81.         IF KBD$ = CHR$(32) AND (NOT Shot%%) THEN Shoot%% = TRUE: Shot%% = TRUE
82.     ELSE
83.         IF NOT Turn%% THEN
84.             IF Fire%% AND (NOT Shot%%) THEN Shoot%% = TRUE: Shot%% = TRUE: Fire%% = FALSE ': ExitFlag%% = TRUE
85.         ELSE
86.             IF KBD$ = CHR$(32) AND (NOT Shot%%) THEN Shoot%% = TRUE: Shot%% = TRUE
87.         END IF
88.     END IF
89.     '-----------------
90.  
91.     '------Logic------
92.     IF Shoot%% THEN Hit~%% = Collision_Check(Arrow.X, Arrow.Y)
93.     IF Hit~%% AND Shoot%% THEN Shoot%% = FALSE: PLAY HitSound$
94.     IF Shoot%% THEN Arrow.Speed = 3 ELSE Arrow.Speed = 0
95.     IF Target.Y = 201 THEN Target.Speed = 0
96.     IF Target.Y = 201 AND (NOT Shot%%) THEN Shot%% = TRUE 'if player doesn't shoot then they forefit
97.     IF Target.Speed = 0 AND Shot%% AND (NOT Shoot%%) THEN Reset_Shot Shot%%, Shoot%%, Hit~%%: Fire%% = FALSE
98.     SELECT CASE Hit~%% MOD 16
99.         CASE 0 'in travel
100.         CASE 11 'back stop
101.             Hit~%% = 0
102.         CASE ELSE 'hit target
103.             Arrow.Y = Arrow.Y + 1
104.     END SELECT
105.     '-computer player-
106.     Dist% = 309 - Arrow.OrigX '~how far to end of feild
107.     Tim%% = Dist% \ 3 + Noise%% 'time from loose to hit+random factor
108.     IF Target.Y + Tim%% >= Arrow.OrigY AND (NOT Shot%%) THEN Fire%% = TRUE
109.     '-----------------
110.  
111.     '-Display update--
112.     ClearLayer Layer(6)
113.     Display_Scoreboard
114.     Move_Target
115.     Move_Arrow
116.     PushScreen 6
117.     '-----------------
118.     ' LOCATE 1, 1: PRINT Arrow.OrigX; Arrow.OrigY; Target.Y + Tim%%; Dist%; Tim%%;
119.     IF Hit~%% = 99 THEN ExitFlag%% = TRUE 'game over
120.     _DELAY .03
121. LOOP UNTIL ExitFlag%%
122. '--------------------------------------
123.  
124. FUNCTION Calc_Score~%% (Who%%)
125.     Result~%% = 0
126.     FOR F%% = 0 TO 4
127.         FOR S%% = 0 TO 2
128.             Result~%% = Result~%% + Shots(Who%%, F%%, S%%)
129.         NEXT S%%
130.     NEXT F%%
131.     Calc_Score = Result~%%
132. END FUNCTION
133.  
134. SUB ClearLayer (L&)
135.     _DEST L&
136.     CLS
137.     _DEST _DISPLAY
138. END SUB
139.  
140. SUB Display_Scoreboard
141.     _PUTIMAGE , Layer(5), Layer(6)
142.     _DEST Layer(6)
143.     _FONT 8
144.     COLOR OffWhite
145.     FOR P%% = 0 TO 1
146.         FOR Flight%% = 0 TO 4
147.             FOR Shot%% = 0 TO 2
148.                 LOCATE 4 + Shot%% + (P%% * 4), 12 + Flight%% * 4
149.                 PRINT Shots(P%%, Flight%%, Shot%%)
150.             NEXT Shot%%
151.         NEXT Flight%%
152.     NEXT P%%
153.     LOCATE 4, 32: PRINT Calc_Score(0)
154.     LOCATE 8, 32: PRINT Calc_Score(1)
155.  
156.     _FONT 16
157.     _DEST Layer(0)
158. END SUB
159.  
160. SUB Draw_Sprites
161.     ClearLayer Layer(3)
162.     _DEST Layer(1)
163.     'Original target draw /w color fix
164.     DRAW "bm318,140c" + STR$(Cyan) + "d30l1u30l1d30u6l1c" + STR$(Magenta) + "u18l1d18l1u18d6l1c" + STR$(OffWhite) + "d6l1u6"
165.     'original arrow draw /w color fix
166.     DRAW "bm10,155c" + STR$(Cyan) + "r20l20c" + STR$(Magenta) + "h3f3g3e3c" + STR$(OffWhite) + "bm+2,+0h3f3g3e3c" + STR$(Magenta) + "bm+2,+0h3f3g3e3bm+15,-2c" + STR$(OffWhite) + "d4u1r1u2d1r1"
167.     LINE (311, 155)-STEP(1, 0), CtrWhite
168.     _DEST Layer(0)
169.     _PUTIMAGE (0, 0), Layer(1), Layer(3), (310, 140)-STEP(8, 30) 'move target to sprite sheet
170.     _PUTIMAGE (0, 32), Layer(1), Layer(3), (7, 152)-STEP(24, 6) 'move arrow to sprite sheet
171.     _CLEARCOLOR _RGB32(0, 0, 0), Layer(3)
172.     ClearLayer Layer(1)
173. END SUB
174.  
175. SUB Draw_Title_Screen
176.     _DEST Layer(1)
177.     _FONT 8
178.     COLOR OffWhite
179.     PSET (0, 0), OffWhite
180.     DRAW "bm41,70e30r10d30l8u12l8g12l11bm+34,-24d6l7e7bm+11,-5d30r8u15m+15,+15r10h18u12l14bm+4,+5d5r4u5l4"
181.     DRAW "BM+20,-5r30d12l8u4l17f15r3u5r7d12l15h20u10r4bm+37,-0r8d10r8u10r8d30l8u10l8d10l8u30bm+30,-0r20d6l15d8r8d5l8d6r15d5l20u30"
182.     DRAW "bm+26,-0d30r8u15m+15,+15r10h18u12l14bm+4,+5d5r4u5l4bm+17,-5d10f16d4r8u30l8d17h7u10l8"
183.     DATA 46,90,129,150,180,206,243
184.     FOR i%% = 1 TO 7
185.         READ t%
186.         PAINT (t%, 68), Magenta, OffWhite
187.     NEXT i%%
188.     LOCATE 17, 11: PRINT "Orignally by:"
189.     LOCATE 20, 16: PRINT "Brain Blankenship"
190.     _FONT 16
191.     _DEST Layer(0)
192.     _PUTIMAGE (1, 0), Layer(1), Layer(2), (1, 0)-(319, 199)
193.     _PUTIMAGE (310, 140), Layer(3), Layer(2), (0, 0)-STEP(7, 30) 'target
194.     _CLEARCOLOR _RGB32(0, 0, 0), Layer(2)
195.     ClearLayer Layer(1)
196. END SUB
197.  
198. SUB Game_Option_Screen
199.     _DEST Layer(5)
200.     _FONT 8
201.     COLOR OffWhite
202.     PRINT "Instructions": PRINT
203.     PRINT " Score as many  points as  possible by"
204.     PRINT "  hitting  the   target  close  to  the"
205.     PRINT "  center. Press the space bar to shoot."
206.     PRINT "  You get three trys from each of  five"
207.     PRINT "  sites, highest score wins."
208.     PRINT
209.     PushScreen 5
210.     _DELAY 3
211.     PRINT: PRINT: PRINT
212.     PRINT "Number of Players(1/2)?"
213.     PushScreen 5
214.     DO: kbd$ = INKEY$: LOOP UNTIL kbd$ = "1" OR kbd$ = "2"
215.     Flag = Flag + 2 ^ (VAL(kbd$) - 1) 'set bit 0 if 1 player, bit 1 for 2 player
216.  
217.     PRINT: PRINT "Enter player one's name :?"
218.     PushScreen 5
219.     Player$(0) = Get_Player_Name(0)
220.     _PRINTSTRING (212, 104), Player$(0)
221.  
222.     IF Flag AND 2 THEN
223.         PRINT: PRINT "Enter player two's name :?"
224.         PushScreen 5
225.         Player$(1) = Get_Player_Name(1)
226.         _PRINTSTRING (212, 120), Player$(1)
227.     ELSE
228.         PRINT: PRINT "           Play Computer ?"
229.         PushScreen 5
230.         DO: kbd$ = LCASE$(INKEY$): LOOP UNTIL kbd$ = "y" OR kbd$ = "n"
231.         IF kbd$ = "y" THEN Flag = 4: Player$(1) = "Computer"
232.     END IF
233.     _FONT 16
234.     _DEST Layer(0)
235.     ClearLayer Layer(1)
236. END SUB
237.  
238. FUNCTION Get_Player_Name$ (Who%%)
239.     DO
240.         kbd$ = INKEY$
241.         IF LEN(Result$) < 8 AND kbd$ >= CHR$(32) THEN Result$ = Result$ + kbd$
242.         IF kbd$ = CHR$(8) THEN Result$ = LEFT$(Result$, LEN(Result$) - 1)
243.         IF Who%% THEN _PRINTSTRING (212, 120), Result$ ELSE _PRINTSTRING (212, 104), Result$
244.         PushScreen 5
245.         _DELAY .025
246.         IF Who%% THEN LINE (212, 120)-STEP(72, 8), Black, BF ELSE LINE (212, 104)-STEP(72, 8), Black, BF
247.     LOOP UNTIL kbd$ = CHR$(13)
248.     Get_Player_Name = Result$
249. END FUNCTION
250.  
251. SUB Move_Target
252.     Target.Y = Target.Y + Target.Speed
253.     _PUTIMAGE (Target.X, Target.Y), Layer(3), Layer(6), (0, 0)-STEP(8, 30) 'target
254.     'collision layer
255.     ClearLayer Layer(4)
256.     _PUTIMAGE (Target.X, Target.Y), Layer(3), Layer(4), (0, 0)-STEP(8, 30) 'target
257.     _PUTIMAGE (318, 0)-STEP(1, 199), Layer(5), Layer(4), (319, 0)-(319, 199) 'target
258. END SUB
259.  
260. SUB Move_Arrow
261.     Arrow.X = Arrow.X + Arrow.Speed
262.     _PUTIMAGE (Arrow.X, Arrow.Y), Layer(3), Layer(6), (0, 32)-STEP(24, 6) 'arrow
263. END SUB
264.  
265. SUB PushScreen (id%%)
266.     _PUTIMAGE (0, 0)-STEP(639, 399), Layer(id%%), Layer(1), (0, 0)-STEP(319, 199)
267.     _PUTIMAGE , Layer(1), Layer(0)
268. END SUB
269.  
270. SUB Reset_Shot (Shot%%, Shoot%%, Hit~%%)
271.     STATIC Flight%%, Frame%%, Player%%
272.     '-------assign score-------
273.     Shots(Player%%, Frame%%, Flight%%) = Hit~%% MOD 16
274.     '--------------------------
275.     '-----increment flight-----
276.     Flight%% = Flight%% + 1
277.     IF Flight%% = 3 THEN '3 flights per frame
278.         IF Flag AND 1 THEN
279.             Frame%% = Frame%% + 1: Flight%% = 0: New_Site
280.         END IF
281.         IF Flag AND 2 OR Flag AND 4 THEN 'is there a second player or computer?
282.             IF Player%% THEN 'player 2 just loosed, next frame for player 1
283.                 Player%% = 0: Frame%% = Frame%% + 1: Flight%% = 0: New_Site: Turn%% = TRUE
284.             ELSE 'let player 2 loose his first frame
285.                 IF Flag AND 4 THEN Turn%% = FALSE
286.                 Player%% = 1: Flight%% = 0
287.             END IF
288.         END IF
289.     END IF
290.     '--------------------------
291.     Target.Y = Target.OrigY
292.     Target.Speed = 1
293.     Arrow.Y = Arrow.OrigY
294.     Arrow.X = Arrow.OrigX
295.     Shot%% = FALSE
296.     Shoot%% = FALSE
297.     IF Frame%% = 5 THEN Hit~%% = 99 ELSE Hit~%% = 0 'end game trigger
298.     Noise%% = Computer_AI 'adds little randomness to computer shots
299. END SUB
300.  
301. FUNCTION Computer_AI%% ()
302.     Result%% = 0
303.     SELECT CASE Computer.Class
304.         CASE 1 'basic
305.             Result%% = INT(RND * 28) - 10
306.         CASE 2 'decent
307.             Result%% = INT(RND * 24) - 8
308.         CASE 3 'good
309.             Result%% = INT(RND * 20) - 6
310.         CASE 4 'hard
311.             Result%% = INT(RND * 16) - 4
312.         CASE 5 'Robin Hood unbeatable 150!
313.             IF Arrow.OrigX MOD 2 THEN Result%% = 5 ELSE Result%% = 6
314.     END SELECT
315.     Computer_AI%% = Result%%
316. END FUNCTION
317.  
318. SUB Scoreboard_Setup
319.     ClearLayer Layer(5)
320.     _DEST Layer(5)
321.     _FONT 8
322.     COLOR OffWhite
323.     LINE (1, 1)-STEP(300, 84), Cyan, B
324.     LINE (2, 2)-STEP(298, 82), Magenta, B
325.     LINE (3, 3)-STEP(296, 80), OffWhite, B
326.     LINE (4, 4)-STEP(294, 78), Black, BF
327.     LOCATE 2, 2: PRINT "Player    #1  #2  #3  #4  #5  Total"
328.     LOCATE 4, 3: PRINT Player$(0)
329.     LOCATE 8, 3: PRINT Player$(1)
330.     LINE (319, 0)-(319, 199), Green, BF
331.     _FONT 16
332.     _DEST Layer(0)
333. END SUB
334.  
335. SUB Title_Animation
336.     _DEST Layer(5)
337.     COLOR OffWhite
338.     _DEST Layer(0)
339.     _PRINTSTRING (4, 0), "UniKorn", Layer(5)
340.     _PRINTSTRING (36, 16), "ProDucKions", Layer(5)
341.     _PUTIMAGE (0, 0)-STEP(639, 400), Layer(5), Layer(1), (0, 0)-STEP(125, 39)
342.     _PUTIMAGE (0, 0)-STEP(639, 399), Layer(1), Layer(0)
343.     _PRINTSTRING (290, 350), "Presents", Layer(0)
344.     _DELAY 2.5
345.     ClearLayer Layer(5)
346.     CLS
347.     _PUTIMAGE (7 + i%, 152), Layer(3), Layer(5), (0, 32)-STEP(24, 6) 'arrow
348.     _PUTIMAGE , Layer(2), Layer(5)
349.     _PUTIMAGE (0, 0)-STEP(639, 399), Layer(5), Layer(1)
350.     _PUTIMAGE , Layer(1), Layer(0)
351.     _DELAY 1.5
352.     FOR i% = 0 TO 279 STEP 2
353.         _DELAY .02
354.         _PUTIMAGE (8 + i%, 152), Layer(3), Layer(5), (0, 32)-STEP(24, 6) 'arrow
355.         _PUTIMAGE , Layer(2), Layer(5) 'title layer
356.         _PUTIMAGE (0, 0)-STEP(639, 399), Layer(5), Layer(1)
357.         _PUTIMAGE , Layer(1), Layer(0)
358.         ClearLayer Layer(5)
359.     NEXT i%
360.     PLAY HitSound$
361.     _DELAY 1.5
362.     _DEST Layer(0)
363.     CLS
364. END SUB
365.  
366. FUNCTION Collision_Check~%% (X%, Y%)
367.     IF _SOURCE <> Layer(4) THEN _SOURCE Layer(4)
368.     Result~%% = 0
369.     FOR I%% = 0 TO 1
370.         Test~& = POINT(25 + X% + I%%, Y% + 3)
371.         R~%% = _RED32(Test~&)
372.         IF R~%% = 255 THEN R~%% = 1
373.         IF R~%% > 0 THEN Result~%% = R~%%: I%% = 5
374.     NEXT I%%
375.     Collision_Check = Result~%%
376. END FUNCTION
377.  
378. SUB New_Site
379.     Arrow.OrigX = INT(RND * 240) + 10
380.     Arrow.OrigY = INT(RND * 50) + 120
381. END SUB
382.  
383.  

Again if I choose 1 player and play against the copmuter, the game shoots for me on the first round.

If I press the spacebar early on first round, no response until the code decides to shoot the arrow, causing me at first to think there was a delay.

Do y'all think you are shooting on the first round against the computer?  ;-))

[TempodiBasic]

Hi Cobalt
fine remake!
Thanks to share code

@Bplus

Again if I choose 1 player and play against the copmuter, the game shoots for me on the first round.

If I press the spacebar early on first round, no response until the code decides to shoot the arrow, causing me at first to think there was a delay.

yes I have the same experience.... but You're right
 in main DO...LOOP there is a _delay

Code: QB64: [Select]

1.   _DELAY .03

;)

[Petr]

Nice game!

[Cobalt]

Again if I choose 1 player and play against the copmuter, the game shoots for me on the first round.

If I press the spacebar early on first round, no response until the code decides to shoot the arrow, causing me at first to think there was a delay.

Do y'all think you are shooting on the first round against the computer?  ;-))

Haha, your right, I forgot one(1!) line of code, Turn%% = TRUE needs to be placed between line 69 and 70(or there abouts) to set player 1's turn when the game starts. Opps.

Quick question: I am familiar with "step" in a for-next loop but how does it work in putimage?

its just a different way to set coordinates, instead of having to state the exact pixel location you are simply telling it to STEP this far in X and this far in Y from the start point. it is also used in LINE. the only thing to remember is that the area includes the start point so if you needed, a LINE for example, to make a box that is 125x100 starting at point 10,10 you would 'LINE (10,10)-STEP(124,99),color~&,B'  kind of like thinking in base 0 terms. comes in handy if you have a lot of sprites and you know where they start and their size and dont want to have to do the math over and over to find the X2,Y2 pixel for each one. I don't believe there is any other advantage or anything.

[bplus]

Haha, your right, I forgot one(1!) line of code, Turn%% = TRUE needs to be placed between line 69 and 70(or there abouts) to set player 1's turn when the game starts. Opps.

Thanks for confirmation. If grammar police show up just remember you're right to remain silent.

[TempodiBasic]

Yep you have already solved!
I find it!
Remming Turn%%= FALSE is the same that leaving it there because QB64 inizialite Turn%% to 0 so FALSE.

Great!

[TempodiBasic]

Sorry Cobalt

little mod

1. I have activated line 70

Code: QB64: [Select]

1. 70 Turn%% = TRUE ' FALSE gives turn to play to Computer

2. I added i to "Orignally " on

Code: QB64: [Select]

1. 188 LOCATE 17, 11: PRINT "Originally by:"

3. sorry but I like to make simpler (to simplify)
215  Flag = Flag + 2 ^ (VAL(kbd$) - 1) 'set bit 0 if 1 player, bit 1 for 2 player
but kbd$ can be 1 or 2 so VAL(kbd$)-1 can be 0 or 1 so  2^0= 1 2^1 = 2
and so if kbd$ = 1 then 2^(VAL(kbd$)-1)= 1 while if kbd$= 2 then 2^(VAL(kbd$)-1)= 2
so at the end

Code: QB64: [Select]

1. 215 Flag = Flag +VAL(kbd$)

4. I think that this is clearer...
228 play computer against you?

5. scoreboard adjournment...inDisplay_Scoreboard
I cancel line 144 COLOR OffWhite  and I add an IF shots() THEN color ELSE color into the inner FOR NEXT to show score gained
while just after outer FOR NEXT I add istructions Color to show total scores

6.
about name of player
I find no funny to play with a void name so I give a default data if no name has been got with
IF Result$ = "" THEN Result$ = "Anonim" ' fine to be Anonimous for self_privacy

7.
about to show better what player must play
I saw that
a) Turn%% switches between TRUE and FALSE
b) name of player is written one time at startup
c) Human vs Computer let's play Human only as first play with these instructions
    LOCATE 4, 3: PRINT Player$(0)
    LOCATE 8, 3: PRINT Player$(1)
so for player 1 we must set Turn%% true and for player 2 we must set Turn%% false
where? In the SUB that adjourn the scoreboard!

Code: QB64: [Select]

1. 'Archery 1985 by Brain Blankenship
2. '2019 Archery By Cobalt
3. '8/13/2019|
4. 'V0.4
5. '-Sprites\Title\Options screens done
6. 'V0.6
7. '-Scoreboard done
8. '-target movement done
9. '-arrow movement done
10. 'V0.7
11. '-collision detection
12. '8/14/2019
13. 'V0.8
14. 'player 2 frames
15. 'Random site creation
16. '8/15/2019
17. 'v0.9
18. 'Computer AI for player 2
19. 'Computer vs computer possible
20.  
21. TYPE Position
22.     X AS INTEGER
23.     Y AS INTEGER
24.     Speed AS _BYTE
25.     OrigX AS INTEGER
26.     OrigY AS INTEGER
27. END TYPE
28.  
29. SCREEN _NEWIMAGE(640, 400, 32)
30. _DELAY .125
31. _SCREENMOVE 20, 20
32. _TITLE "Archery 1985   v0.9"
33.  
34. '-------------CONSTANTS----------------
35. CONST TRUE = -1, FALSE = NOT TRUE
36. CONST Black = &HFF000101~&, Cyan = &HFF01A0A0~&, Magenta = &HFF941090~&, OffWhite = &HFFC7C0C0~&, Green = &HFF1B9010~&, CtrWhite = &HFFCAC0C0~&
37. '--------------------------------------
38. '-------ARRAYS & SHARED VARIABLES------
39. DIM SHARED Layer(10) AS LONG, Shots(1, 4, 2) AS _BYTE, HitSound$
40. DIM SHARED Computer.Class, Player$(2), Flag AS _BYTE, Turn%%, Noise%%
41. DIM SHARED Arrow AS Position, Target AS Position
42. '--------------------------------------
43. '---------------LAYERS-----------------
44. Layer(0) = _DISPLAY
45. Layer(1) = _NEWIMAGE(640, 400, 32) 'mix layer
46. Layer(2) = _NEWIMAGE(320, 200, 32) 'Title Screen Layer
47. Layer(3) = _NEWIMAGE(320, 200, 32) 'Sprite sheet layer
48. Layer(4) = _NEWIMAGE(320, 200, 32) 'Collision layer
49. Layer(5) = _NEWIMAGE(320, 200, 32) 'Extra/Scoreboard layer
50. Layer(6) = _NEWIMAGE(320, 200, 32) 'Input layer/Prebuild layer
51. '--------------------------------------
52. '-----------ARROW HIT SOUND------------
53. PLAY "t230l64" 'setup sound play rate
54. HitSound$ = "o1bagfedc"
55. '--------------------------------------
56. Draw_Sprites
57. Draw_Title_Screen
58. Title_Animation
59. Game_Option_Screen
60. Scoreboard_Setup
61. '-------Inital Values------------------
62. RANDOMIZE TIMER
63. Target.Speed = 1
64. Target.Y = 0: Target.OrigY = 0
65. Target.X = 309: Target.OrigX = 309
66. Arrow.Speed = 0
67. Arrow.OrigY = 135: Arrow.Y = Arrow.OrigY
68. Arrow.OrigX = 69: Arrow.X = Arrow.OrigX
69. ExitFlag%% = FALSE
70. Turn%% = TRUE ' FALSE 'watch the computer play itself!
71. 'Flag = 4'set player 2 to computer(needed for computer only play)
72. Computer.Class = 3 'skill level of computer(experimental)
73. Noise%% = Computer_AI 'adds little randomness to computer shots
74. '-------------MAIN LOOP----------------
75.  
76. DO
77.     '-----controls-----
78.     KBD$ = INKEY$
79.     IF KBD$ = CHR$(27) THEN ExitFlag%% = TRUE
80.     IF Flag AND 1 OR Flag AND 2 THEN ' if player 1 or 2 is human
81.         IF KBD$ = CHR$(32) AND (NOT Shot%%) THEN Shoot%% = TRUE: Shot%% = TRUE
82.     ELSE ' when player 2 is computer and Flag is 4
83.         IF NOT Turn%% THEN
84.             IF Fire%% AND (NOT Shot%%) THEN Shoot%% = TRUE: Shot%% = TRUE: Fire%% = FALSE ': ExitFlag%% = TRUE
85.         ELSE
86.             IF KBD$ = CHR$(32) AND (NOT Shot%%) THEN Shoot%% = TRUE: Shot%% = TRUE
87.         END IF
88.     END IF
89.     '-----------------
90.  
91.     '------Logic------
92.     IF Shoot%% THEN Hit~%% = Collision_Check(Arrow.X, Arrow.Y)
93.     IF Hit~%% AND Shoot%% THEN Shoot%% = FALSE: PLAY HitSound$
94.     IF Shoot%% THEN Arrow.Speed = 3 ELSE Arrow.Speed = 0
95.     IF Target.Y = 201 THEN Target.Speed = 0
96.     IF Target.Y = 201 AND (NOT Shot%%) THEN Shot%% = TRUE 'if player doesn't shoot then they forefit
97.     IF Target.Speed = 0 AND Shot%% AND (NOT Shoot%%) THEN Reset_Shot Shot%%, Shoot%%, Hit~%%: Fire%% = FALSE
98.     SELECT CASE Hit~%% MOD 16
99.         CASE 0 'in travel
100.         CASE 11 'back stop
101.             Hit~%% = 0
102.         CASE ELSE 'hit target
103.             Arrow.Y = Arrow.Y + 1
104.     END SELECT
105.     '-computer player-
106.     Dist% = 309 - Arrow.OrigX '~how far to end of feild
107.     Tim%% = Dist% \ 3 + Noise%% 'time from loose to hit+random factor
108.     IF Target.Y + Tim%% >= Arrow.OrigY AND (NOT Shot%%) THEN Fire%% = TRUE
109.     '-----------------
110.  
111.     '-Display update--
112.     ClearLayer Layer(6)
113.     Display_Scoreboard
114.     Move_Target
115.     Move_Arrow
116.     PushScreen 6
117.     '-----------------
118.     ' LOCATE 1, 1: PRINT Arrow.OrigX; Arrow.OrigY; Target.Y + Tim%%; Dist%; Tim%%;
119.     IF Hit~%% = 99 THEN ExitFlag%% = TRUE 'game over
120.     _DELAY .03
121. LOOP UNTIL ExitFlag%%
122. '--------------------------------------
123.  
124. FUNCTION Calc_Score~%% (Who%%)
125.     Result~%% = 0
126.     FOR F%% = 0 TO 4
127.         FOR S%% = 0 TO 2
128.             Result~%% = Result~%% + Shots(Who%%, F%%, S%%)
129.         NEXT S%%
130.     NEXT F%%
131.     Calc_Score = Result~%%
132. END FUNCTION
133.  
134. SUB ClearLayer (L&)
135.     _DEST L&
136.     CLS
137.     _DEST _DISPLAY
138. END SUB
139.  
140. SUB Display_Scoreboard
141.     _PUTIMAGE , Layer(5), Layer(6)
142.     _DEST Layer(6)
143.     _FONT 8
144.     FOR P%% = 0 TO 1
145.         FOR Flight%% = 0 TO 4
146.             FOR Shot%% = 0 TO 2
147.                 IF Shots(P%%, Flight%%, Shot%%) = 0 THEN COLOR OffWhite ELSE COLOR Magenta
148.                 LOCATE 4 + Shot%% + (P%% * 4), 12 + Flight%% * 4
149.                 PRINT Shots(P%%, Flight%%, Shot%%)
150.             NEXT Shot%%
151.         NEXT Flight%%
152.     NEXT P%%
153.     COLOR Green
154.     IF Flag = 4 OR Flag = 1 THEN ' one player alone or versus computer
155.         IF Turn%% THEN
156.             LOCATE 4, 3: PRINT Player$(0)
157.         ELSE
158.             LOCATE 8, 3: PRINT Player$(1)
159.         END IF
160.     ELSEIF Flag = 2 THEN 'human vs human
161.  
162.     END IF
163.    
164.     LOCATE 4, 32: PRINT Calc_Score(0)
165.     LOCATE 8, 32: PRINT Calc_Score(1)
166.     COLOR OffWhite
167.     _FONT 16
168.     _DEST Layer(0)
169. END SUB
170.  
171. SUB Draw_Sprites
172.     ClearLayer Layer(3)
173.     _DEST Layer(1)
174.     'Original target draw /w color fix
175.     DRAW "bm318,140c" + STR$(Cyan) + "d30l1u30l1d30u6l1c" + STR$(Magenta) + "u18l1d18l1u18d6l1c" + STR$(OffWhite) + "d6l1u6"
176.     'original arrow draw /w color fix
177.     DRAW "bm10,155c" + STR$(Cyan) + "r20l20c" + STR$(Magenta) + "h3f3g3e3c" + STR$(OffWhite) + "bm+2,+0h3f3g3e3c" + STR$(Magenta) + "bm+2,+0h3f3g3e3bm+15,-2c" + STR$(OffWhite) + "d4u1r1u2d1r1"
178.     LINE (311, 155)-STEP(1, 0), CtrWhite
179.     _DEST Layer(0)
180.     _PUTIMAGE (0, 0), Layer(1), Layer(3), (310, 140)-STEP(8, 30) 'move target to sprite sheet
181.     _PUTIMAGE (0, 32), Layer(1), Layer(3), (7, 152)-STEP(24, 6) 'move arrow to sprite sheet
182.     _CLEARCOLOR _RGB32(0, 0, 0), Layer(3)
183.     ClearLayer Layer(1)
184. END SUB
185.  
186. SUB Draw_Title_Screen
187.     _DEST Layer(1)
188.     _FONT 8
189.     COLOR OffWhite
190.     PSET (0, 0), OffWhite
191.     DRAW "bm41,70e30r10d30l8u12l8g12l11bm+34,-24d6l7e7bm+11,-5d30r8u15m+15,+15r10h18u12l14bm+4,+5d5r4u5l4"
192.     DRAW "BM+20,-5r30d12l8u4l17f15r3u5r7d12l15h20u10r4bm+37,-0r8d10r8u10r8d30l8u10l8d10l8u30bm+30,-0r20d6l15d8r8d5l8d6r15d5l20u30"
193.     DRAW "bm+26,-0d30r8u15m+15,+15r10h18u12l14bm+4,+5d5r4u5l4bm+17,-5d10f16d4r8u30l8d17h7u10l8"
194.     DATA 46,90,129,150,180,206,243
195.     FOR i%% = 1 TO 7
196.         READ t%
197.         PAINT (t%, 68), Magenta, OffWhite
198.     NEXT i%%
199.     LOCATE 17, 11: PRINT "Originally by:"
200.     LOCATE 20, 16: PRINT "Brain Blankenship"
201.     _FONT 16
202.     _DEST Layer(0)
203.     _PUTIMAGE (1, 0), Layer(1), Layer(2), (1, 0)-(319, 199)
204.     _PUTIMAGE (310, 140), Layer(3), Layer(2), (0, 0)-STEP(7, 30) 'target
205.     _CLEARCOLOR _RGB32(0, 0, 0), Layer(2)
206.     ClearLayer Layer(1)
207. END SUB
208.  
209. SUB Game_Option_Screen
210.     _DEST Layer(5)
211.     _FONT 8
212.     COLOR OffWhite
213.     PRINT "Instructions": PRINT
214.     PRINT " Score as many  points as  possible by"
215.     PRINT "  hitting  the   target  close  to  the"
216.     PRINT "  center. Press the space bar to shoot."
217.     PRINT "  You get three trys from each of  five"
218.     PRINT "  sites, highest score wins."
219.     PRINT
220.     PushScreen 5
221.     _DELAY 3
222.     PRINT: PRINT: PRINT
223.     PRINT "Number of Players(1/2)?"
224.     PushScreen 5
225.     DO: kbd$ = INKEY$: LOOP UNTIL kbd$ = "1" OR kbd$ = "2"
226.     Flag = Flag + VAL(kbd$) 'Flag = Flag + 2 ^ (VAL(kbd$) - 1) 'set bit 0 if 1 player, bit 1 for 2 player
227.  
228.     PRINT: PRINT "Enter player one's name :?"
229.     PushScreen 5
230.     Player$(0) = Get_Player_Name(0)
231.     _PRINTSTRING (212, 104), Player$(0)
232.  
233.     IF Flag AND 2 THEN
234.         PRINT: PRINT "Enter player two's name :?"
235.         PushScreen 5
236.         Player$(1) = Get_Player_Name(1)
237.         _PRINTSTRING (212, 120), Player$(1)
238.     ELSE
239.         PRINT: PRINT " Do you play against computer?"
240.         PushScreen 5
241.         DO: kbd$ = LCASE$(INKEY$): LOOP UNTIL kbd$ = "y" OR kbd$ = "n"
242.         IF kbd$ = "y" THEN
243.             Flag = 4: Player$(1) = "Computer"
244.         ELSE
245.             Player$(1) = "Nobody"
246.         END IF
247.     END IF
248.     _FONT 16
249.     _DEST Layer(0)
250.     ClearLayer Layer(1)
251. END SUB
252.  
253. FUNCTION Get_Player_Name$ (Who%%)
254.     DO
255.         kbd$ = INKEY$
256.         IF LEN(Result$) < 8 AND kbd$ >= CHR$(32) THEN Result$ = Result$ + kbd$
257.         IF kbd$ = CHR$(8) THEN Result$ = LEFT$(Result$, LEN(Result$) - 1)
258.         IF Who%% THEN _PRINTSTRING (212, 120), Result$ ELSE _PRINTSTRING (212, 104), Result$
259.         PushScreen 5
260.         _DELAY .025
261.         IF Who%% THEN LINE (212, 120)-STEP(72, 8), Black, BF ELSE LINE (212, 104)-STEP(72, 8), Black, BF
262.     LOOP UNTIL kbd$ = CHR$(13)
263.     IF Result$ = "" THEN Result$ = "Anonim" ' fine to be Anonimous for self_privacy
264.     Get_Player_Name = Result$
265. END FUNCTION
266.  
267. SUB Move_Target
268.     Target.Y = Target.Y + Target.Speed
269.     _PUTIMAGE (Target.X, Target.Y), Layer(3), Layer(6), (0, 0)-STEP(8, 30) 'target
270.     'collision layer
271.     ClearLayer Layer(4)
272.     _PUTIMAGE (Target.X, Target.Y), Layer(3), Layer(4), (0, 0)-STEP(8, 30) 'target
273.     _PUTIMAGE (318, 0)-STEP(1, 199), Layer(5), Layer(4), (319, 0)-(319, 199) 'target
274. END SUB
275.  
276. SUB Move_Arrow
277.     Arrow.X = Arrow.X + Arrow.Speed
278.     _PUTIMAGE (Arrow.X, Arrow.Y), Layer(3), Layer(6), (0, 32)-STEP(24, 6) 'arrow
279. END SUB
280.  
281. SUB PushScreen (id%%)
282.     _PUTIMAGE (0, 0)-STEP(639, 399), Layer(id%%), Layer(1), (0, 0)-STEP(319, 199)
283.     _PUTIMAGE , Layer(1), Layer(0)
284. END SUB
285.  
286. SUB Reset_Shot (Shot%%, Shoot%%, Hit~%%)
287.     STATIC Flight%%, Frame%%, Player%%
288.     '-------assign score-------
289.     Shots(Player%%, Frame%%, Flight%%) = Hit~%% MOD 16
290.     '--------------------------
291.     '-----increment flight-----
292.     Flight%% = Flight%% + 1
293.     IF Flight%% = 3 THEN '3 flights per frame
294.         IF Flag AND 1 THEN
295.             Frame%% = Frame%% + 1: Flight%% = 0: New_Site
296.         END IF
297.         IF Flag AND 2 OR Flag AND 4 THEN 'is there a second player or computer?
298.             IF Player%% THEN 'player 2 just loosed, next frame for player 1
299.                 Player%% = 0: Frame%% = Frame%% + 1: Flight%% = 0: New_Site: Turn%% = TRUE
300.             ELSE 'let player 2 loose his first frame
301.                 IF Flag AND 4 THEN Turn%% = FALSE
302.                 Player%% = 1: Flight%% = 0
303.             END IF
304.         END IF
305.     END IF
306.     '--------------------------
307.     Target.Y = Target.OrigY
308.     Target.Speed = 1
309.     Arrow.Y = Arrow.OrigY
310.     Arrow.X = Arrow.OrigX
311.     Shot%% = FALSE
312.     Shoot%% = FALSE
313.     IF Frame%% = 5 THEN Hit~%% = 99 ELSE Hit~%% = 0 'end game trigger
314.     Noise%% = Computer_AI 'adds little randomness to computer shots
315. END SUB
316.  
317. FUNCTION Computer_AI%% ()
318.     Result%% = 0
319.     SELECT CASE Computer.Class
320.         CASE 1 'basic
321.             Result%% = INT(RND * 28) - 10
322.         CASE 2 'decent
323.             Result%% = INT(RND * 24) - 8
324.         CASE 3 'good
325.             Result%% = INT(RND * 20) - 6
326.         CASE 4 'hard
327.             Result%% = INT(RND * 16) - 4
328.         CASE 5 'Robin Hood unbeatable 150!
329.             IF Arrow.OrigX MOD 2 THEN Result%% = 5 ELSE Result%% = 6
330.     END SELECT
331.     Computer_AI%% = Result%%
332. END FUNCTION
333.  
334. SUB Scoreboard_Setup
335.     ClearLayer Layer(5)
336.     _DEST Layer(5)
337.     _FONT 8
338.     COLOR OffWhite
339.     LINE (1, 1)-STEP(300, 84), Cyan, B
340.     LINE (2, 2)-STEP(298, 82), Magenta, B
341.     LINE (3, 3)-STEP(296, 80), OffWhite, B
342.     LINE (4, 4)-STEP(294, 78), Black, BF
343.     LOCATE 2, 2: PRINT "Player    #1  #2  #3  #4  #5  Total"
344.     LOCATE 4, 3: PRINT Player$(0)
345.     LOCATE 8, 3: PRINT Player$(1)
346.     LINE (319, 0)-(319, 199), Green, BF
347.     _FONT 16
348.     _DEST Layer(0)
349. END SUB
350.  
351. SUB Title_Animation
352.     _DEST Layer(5)
353.     COLOR OffWhite
354.     _DEST Layer(0)
355.     _PRINTSTRING (4, 0), "UniKorn", Layer(5)
356.     _PRINTSTRING (36, 16), "ProDucKions", Layer(5)
357.     _PUTIMAGE (0, 0)-STEP(639, 400), Layer(5), Layer(1), (0, 0)-STEP(125, 39)
358.     _PUTIMAGE (0, 0)-STEP(639, 399), Layer(1), Layer(0)
359.     _PRINTSTRING (290, 350), "Presents", Layer(0)
360.     _DELAY 2.5
361.     ClearLayer Layer(5)
362.     CLS
363.     _PUTIMAGE (7 + i%, 152), Layer(3), Layer(5), (0, 32)-STEP(24, 6) 'arrow
364.     _PUTIMAGE , Layer(2), Layer(5)
365.     _PUTIMAGE (0, 0)-STEP(639, 399), Layer(5), Layer(1)
366.     _PUTIMAGE , Layer(1), Layer(0)
367.     _DELAY 1.5
368.     FOR i% = 0 TO 279 STEP 2
369.         _DELAY .02
370.         _PUTIMAGE (8 + i%, 152), Layer(3), Layer(5), (0, 32)-STEP(24, 6) 'arrow
371.         _PUTIMAGE , Layer(2), Layer(5) 'title layer
372.         _PUTIMAGE (0, 0)-STEP(639, 399), Layer(5), Layer(1)
373.         _PUTIMAGE , Layer(1), Layer(0)
374.         ClearLayer Layer(5)
375.     NEXT i%
376.     PLAY HitSound$
377.     _DELAY 1.5
378.     _DEST Layer(0)
379.     CLS
380. END SUB
381.  
382. FUNCTION Collision_Check~%% (X%, Y%)
383.     IF _SOURCE <> Layer(4) THEN _SOURCE Layer(4)
384.     Result~%% = 0
385.     FOR I%% = 0 TO 1
386.         Test~& = POINT(25 + X% + I%%, Y% + 3)
387.         R~%% = _RED32(Test~&)
388.         IF R~%% = 255 THEN R~%% = 1
389.         IF R~%% > 0 THEN Result~%% = R~%%: I%% = 5
390.     NEXT I%%
391.     Collision_Check = Result~%%
392. END FUNCTION
393.  
394. SUB New_Site
395.     Arrow.OrigX = INT(RND * 240) + 10
396.     Arrow.OrigY = INT(RND * 50) + 120
397. END SUB
398.  

Be patient with my imagination

Thanks to share

[TempodiBasic]

But this doesn't work when there are two humans! Turn%% is always true and Flag is always 2!
I must find where is the information of the current player....

Yep it is here.... in Reset_Shot SUB that has into a STATIC Player%%....

now I append at the end of global variables this

Code: QB64: [Select]

1. DIM SHARED Playing AS INTEGER

and at initialization before main DO...LOOP this

Code: QB64: [Select]

1. Playing = 0

and into SUB  Reset_Shot as last line of code before END SUB this

Code: QB64: [Select]

1.  Playing = Player%%  

and in SUB Dysplay_Scoreboard

this

Code: QB64: [Select]

1.     IF Playing = 0 THEN
2.         LOCATE 4, 3: PRINT Player$(0)
3.     ELSE
4.         LOCATE 8, 3: PRINT Player$(1)
5.     END IF

and deleting this

Code: QB64: [Select]

1.    IF Flag = 4 OR Flag = 1 THEN ' one player alone or versus computer
2.         IF Turn%% THEN
3.             LOCATE 4, 3: PRINT Player$(0)
4.         ELSE
5.             LOCATE 8, 3: PRINT Player$(1)
6.         END IF
7.     ELSEIF Flag = 2 THEN 'human vs human
8.  
9.     END IF

Now we wait Cobalt for news about autoplay Computer vs Computer and Infinite play following his initial declarations.

Thanks to share

PS
here the new mod code

Code: QB64: [Select]

1. 'Archery 1985 by Brain Blankenship
2. '2019 Archery By Cobalt
3. '8/13/2019|
4. 'V0.4
5. '-Sprites\Title\Options screens done
6. 'V0.6
7. '-Scoreboard done
8. '-target movement done
9. '-arrow movement done
10. 'V0.7
11. '-collision detection
12. '8/14/2019
13. 'V0.8
14. 'player 2 frames
15. 'Random site creation
16. '8/15/2019
17. 'v0.9
18. 'Computer AI for player 2
19. 'Computer vs computer possible
20.  
21. TYPE Position
22.     X AS INTEGER
23.     Y AS INTEGER
24.     Speed AS _BYTE
25.     OrigX AS INTEGER
26.     OrigY AS INTEGER
27. END TYPE
28.  
29. SCREEN _NEWIMAGE(640, 400, 32)
30. _DELAY .125
31. _SCREENMOVE 20, 20
32. _TITLE "Archery 1985   v0.9"
33.  
34. '-------------CONSTANTS----------------
35. CONST TRUE = -1, FALSE = NOT TRUE
36. CONST Black = &HFF000101~&, Cyan = &HFF01A0A0~&, Magenta = &HFF941090~&, OffWhite = &HFFC7C0C0~&, Green = &HFF1B9010~&, CtrWhite = &HFFCAC0C0~&
37. '--------------------------------------
38. '-------ARRAYS & SHARED VARIABLES------
39. DIM SHARED Layer(10) AS LONG, Shots(1, 4, 2) AS _BYTE, HitSound$
40. DIM SHARED Computer.Class, Player$(2), Flag AS _BYTE, Turn%%, Noise%%
41. DIM SHARED Arrow AS Position, Target AS Position
42. DIM SHARED Playing AS INTEGER ' who is playing? Only the variable
43. '--------------------------------------
44. '---------------LAYERS-----------------
45. Layer(0) = _DISPLAY
46. Layer(1) = _NEWIMAGE(640, 400, 32) 'mix layer
47. Layer(2) = _NEWIMAGE(320, 200, 32) 'Title Screen Layer
48. Layer(3) = _NEWIMAGE(320, 200, 32) 'Sprite sheet layer
49. Layer(4) = _NEWIMAGE(320, 200, 32) 'Collision layer
50. Layer(5) = _NEWIMAGE(320, 200, 32) 'Extra/Scoreboard layer
51. Layer(6) = _NEWIMAGE(320, 200, 32) 'Input layer/Prebuild layer
52. '--------------------------------------
53. '-----------ARROW HIT SOUND------------
54. PLAY "t230l64" 'setup sound play rate
55. HitSound$ = "o1bagfedc"
56. '--------------------------------------
57. Draw_Sprites
58. Draw_Title_Screen
59. Title_Animation
60. Game_Option_Screen
61. Scoreboard_Setup
62. '-------Inital Values------------------
63. RANDOMIZE TIMER
64. Target.Speed = 1
65. Target.Y = 0: Target.OrigY = 0
66. Target.X = 309: Target.OrigX = 309
67. Arrow.Speed = 0
68. Arrow.OrigY = 135: Arrow.Y = Arrow.OrigY
69. Arrow.OrigX = 69: Arrow.X = Arrow.OrigX
70. ExitFlag%% = FALSE
71. Turn%% = TRUE ' FALSE 'watch the computer play itself!
72. 'Flag = 4'set player 2 to computer(needed for computer only play)
73. Computer.Class = 3 'skill level of computer(experimental)
74. Noise%% = Computer_AI 'adds little randomness to computer shots
75. Playing = 0
76. '-------------MAIN LOOP----------------
77.  
78. DO
79.     '-----controls-----
80.     KBD$ = INKEY$
81.     IF KBD$ = CHR$(27) THEN ExitFlag%% = TRUE
82.     IF Flag AND 1 OR Flag AND 2 THEN ' if player 1 or 2 is human
83.         IF KBD$ = CHR$(32) AND (NOT Shot%%) THEN Shoot%% = TRUE: Shot%% = TRUE
84.     ELSE ' when player 2 is computer and Flag is 4
85.         IF NOT Turn%% THEN
86.             IF Fire%% AND (NOT Shot%%) THEN Shoot%% = TRUE: Shot%% = TRUE: Fire%% = FALSE ': ExitFlag%% = TRUE
87.         ELSE
88.             IF KBD$ = CHR$(32) AND (NOT Shot%%) THEN Shoot%% = TRUE: Shot%% = TRUE
89.         END IF
90.     END IF
91.     '-----------------
92.  
93.     '------Logic------
94.     IF Shoot%% THEN Hit~%% = Collision_Check(Arrow.X, Arrow.Y)
95.     IF Hit~%% AND Shoot%% THEN Shoot%% = FALSE: PLAY HitSound$
96.     IF Shoot%% THEN Arrow.Speed = 3 ELSE Arrow.Speed = 0
97.     IF Target.Y = 201 THEN Target.Speed = 0
98.     IF Target.Y = 201 AND (NOT Shot%%) THEN Shot%% = TRUE 'if player doesn't shoot then they forefit
99.     IF Target.Speed = 0 AND Shot%% AND (NOT Shoot%%) THEN Reset_Shot Shot%%, Shoot%%, Hit~%%: Fire%% = FALSE
100.     SELECT CASE Hit~%% MOD 16
101.         CASE 0 'in travel
102.         CASE 11 'back stop
103.             Hit~%% = 0
104.         CASE ELSE 'hit target
105.             Arrow.Y = Arrow.Y + 1
106.     END SELECT
107.     '-computer player-
108.     Dist% = 309 - Arrow.OrigX '~how far to end of feild
109.     Tim%% = Dist% \ 3 + Noise%% 'time from loose to hit+random factor
110.     IF Target.Y + Tim%% >= Arrow.OrigY AND (NOT Shot%%) THEN Fire%% = TRUE
111.     '-----------------
112.  
113.     '-Display update--
114.     ClearLayer Layer(6)
115.     Display_Scoreboard
116.     Move_Target
117.     Move_Arrow
118.     PushScreen 6
119.     '-----------------
120.     ' LOCATE 1, 1: PRINT Arrow.OrigX; Arrow.OrigY; Target.Y + Tim%%; Dist%; Tim%%;
121.     IF Hit~%% = 99 THEN ExitFlag%% = TRUE 'game over
122.     _DELAY .03
123. LOOP UNTIL ExitFlag%%
124. '--------------------------------------
125.  
126. FUNCTION Calc_Score~%% (Who%%)
127.     Result~%% = 0
128.     FOR F%% = 0 TO 4
129.         FOR S%% = 0 TO 2
130.             Result~%% = Result~%% + Shots(Who%%, F%%, S%%)
131.         NEXT S%%
132.     NEXT F%%
133.     Calc_Score = Result~%%
134. END FUNCTION
135.  
136. SUB ClearLayer (L&)
137.     _DEST L&
138.     CLS
139.     _DEST _DISPLAY
140. END SUB
141.  
142. SUB Display_Scoreboard
143.     _PUTIMAGE , Layer(5), Layer(6)
144.     _DEST Layer(6)
145.     _FONT 8
146.     FOR P%% = 0 TO 1
147.         FOR Flight%% = 0 TO 4
148.             FOR Shot%% = 0 TO 2
149.                 IF Shots(P%%, Flight%%, Shot%%) = 0 THEN COLOR OffWhite ELSE COLOR Magenta
150.                 LOCATE 4 + Shot%% + (P%% * 4), 12 + Flight%% * 4
151.                 PRINT Shots(P%%, Flight%%, Shot%%)
152.             NEXT Shot%%
153.         NEXT Flight%%
154.     NEXT P%%
155.     COLOR Green
156.     IF Playing = 0 THEN
157.         LOCATE 4, 3: PRINT Player$(0)
158.     ELSE
159.         LOCATE 8, 3: PRINT Player$(1)
160.     END IF
161.  
162.     LOCATE 4, 32: PRINT Calc_Score(0)
163.     LOCATE 8, 32: PRINT Calc_Score(1)
164.     COLOR OffWhite
165.     _FONT 16
166.     _DEST Layer(0)
167. END SUB
168.  
169. SUB Draw_Sprites
170.     ClearLayer Layer(3)
171.     _DEST Layer(1)
172.     'Original target draw /w color fix
173.     DRAW "bm318,140c" + STR$(Cyan) + "d30l1u30l1d30u6l1c" + STR$(Magenta) + "u18l1d18l1u18d6l1c" + STR$(OffWhite) + "d6l1u6"
174.     'original arrow draw /w color fix
175.     DRAW "bm10,155c" + STR$(Cyan) + "r20l20c" + STR$(Magenta) + "h3f3g3e3c" + STR$(OffWhite) + "bm+2,+0h3f3g3e3c" + STR$(Magenta) + "bm+2,+0h3f3g3e3bm+15,-2c" + STR$(OffWhite) + "d4u1r1u2d1r1"
176.     LINE (311, 155)-STEP(1, 0), CtrWhite
177.     _DEST Layer(0)
178.     _PUTIMAGE (0, 0), Layer(1), Layer(3), (310, 140)-STEP(8, 30) 'move target to sprite sheet
179.     _PUTIMAGE (0, 32), Layer(1), Layer(3), (7, 152)-STEP(24, 6) 'move arrow to sprite sheet
180.     _CLEARCOLOR _RGB32(0, 0, 0), Layer(3)
181.     ClearLayer Layer(1)
182. END SUB
183.  
184. SUB Draw_Title_Screen
185.     _DEST Layer(1)
186.     _FONT 8
187.     COLOR OffWhite
188.     PSET (0, 0), OffWhite
189.     DRAW "bm41,70e30r10d30l8u12l8g12l11bm+34,-24d6l7e7bm+11,-5d30r8u15m+15,+15r10h18u12l14bm+4,+5d5r4u5l4"
190.     DRAW "BM+20,-5r30d12l8u4l17f15r3u5r7d12l15h20u10r4bm+37,-0r8d10r8u10r8d30l8u10l8d10l8u30bm+30,-0r20d6l15d8r8d5l8d6r15d5l20u30"
191.     DRAW "bm+26,-0d30r8u15m+15,+15r10h18u12l14bm+4,+5d5r4u5l4bm+17,-5d10f16d4r8u30l8d17h7u10l8"
192.     DATA 46,90,129,150,180,206,243
193.     FOR i%% = 1 TO 7
194.         READ t%
195.         PAINT (t%, 68), Magenta, OffWhite
196.     NEXT i%%
197.     LOCATE 17, 11: PRINT "Originally by:"
198.     LOCATE 20, 16: PRINT "Brain Blankenship"
199.     _FONT 16
200.     _DEST Layer(0)
201.     _PUTIMAGE (1, 0), Layer(1), Layer(2), (1, 0)-(319, 199)
202.     _PUTIMAGE (310, 140), Layer(3), Layer(2), (0, 0)-STEP(7, 30) 'target
203.     _CLEARCOLOR _RGB32(0, 0, 0), Layer(2)
204.     ClearLayer Layer(1)
205. END SUB
206.  
207. SUB Game_Option_Screen
208.     _DEST Layer(5)
209.     _FONT 8
210.     COLOR OffWhite
211.     PRINT "Instructions": PRINT
212.     PRINT " Score as many  points as  possible by"
213.     PRINT "  hitting  the   target  close  to  the"
214.     PRINT "  center. Press the space bar to shoot."
215.     PRINT "  You get three trys from each of  five"
216.     PRINT "  sites, highest score wins."
217.     PRINT
218.     PushScreen 5
219.     _DELAY 3
220.     PRINT: PRINT: PRINT
221.     PRINT "Number of Players(1/2)?"
222.     PushScreen 5
223.     DO: kbd$ = INKEY$: LOOP UNTIL kbd$ = "1" OR kbd$ = "2"
224.     Flag = Flag + VAL(kbd$) 'Flag = Flag + 2 ^ (VAL(kbd$) - 1) 'set bit 0 if 1 player, bit 1 for 2 player
225.  
226.     PRINT: PRINT "Enter player one's name :?"
227.     PushScreen 5
228.     Player$(0) = Get_Player_Name(0)
229.     _PRINTSTRING (212, 104), Player$(0)
230.  
231.     IF Flag AND 2 THEN
232.         PRINT: PRINT "Enter player two's name :?"
233.         PushScreen 5
234.         Player$(1) = Get_Player_Name(1)
235.         _PRINTSTRING (212, 120), Player$(1)
236.     ELSE
237.         PRINT: PRINT " Do you play against computer?"
238.         PushScreen 5
239.         DO: kbd$ = LCASE$(INKEY$): LOOP UNTIL kbd$ = "y" OR kbd$ = "n"
240.         IF kbd$ = "y" THEN
241.             Flag = 4: Player$(1) = "Computer"
242.         ELSE
243.             Player$(1) = "Nobody"
244.         END IF
245.     END IF
246.     _FONT 16
247.     _DEST Layer(0)
248.     ClearLayer Layer(1)
249. END SUB
250.  
251. FUNCTION Get_Player_Name$ (Who%%)
252.     DO
253.         kbd$ = INKEY$
254.         IF LEN(Result$) < 8 AND kbd$ >= CHR$(32) THEN Result$ = Result$ + kbd$
255.         IF kbd$ = CHR$(8) THEN Result$ = LEFT$(Result$, LEN(Result$) - 1)
256.         IF Who%% THEN _PRINTSTRING (212, 120), Result$ ELSE _PRINTSTRING (212, 104), Result$
257.         PushScreen 5
258.         _DELAY .025
259.         IF Who%% THEN LINE (212, 120)-STEP(72, 8), Black, BF ELSE LINE (212, 104)-STEP(72, 8), Black, BF
260.     LOOP UNTIL kbd$ = CHR$(13)
261.     IF Result$ = "" THEN Result$ = "Anonim" ' fine to be Anonimous for self_privacy
262.     Get_Player_Name = Result$
263. END FUNCTION
264.  
265. SUB Move_Target
266.     Target.Y = Target.Y + Target.Speed
267.     _PUTIMAGE (Target.X, Target.Y), Layer(3), Layer(6), (0, 0)-STEP(8, 30) 'target
268.     'collision layer
269.     ClearLayer Layer(4)
270.     _PUTIMAGE (Target.X, Target.Y), Layer(3), Layer(4), (0, 0)-STEP(8, 30) 'target
271.     _PUTIMAGE (318, 0)-STEP(1, 199), Layer(5), Layer(4), (319, 0)-(319, 199) 'target
272. END SUB
273.  
274. SUB Move_Arrow
275.     Arrow.X = Arrow.X + Arrow.Speed
276.     _PUTIMAGE (Arrow.X, Arrow.Y), Layer(3), Layer(6), (0, 32)-STEP(24, 6) 'arrow
277. END SUB
278.  
279. SUB PushScreen (id%%)
280.     _PUTIMAGE (0, 0)-STEP(639, 399), Layer(id%%), Layer(1), (0, 0)-STEP(319, 199)
281.     _PUTIMAGE , Layer(1), Layer(0)
282. END SUB
283.  
284. SUB Reset_Shot (Shot%%, Shoot%%, Hit~%%)
285.     STATIC Flight%%, Frame%%, Player%%
286.     '-------assign score-------
287.     Shots(Player%%, Frame%%, Flight%%) = Hit~%% MOD 16
288.     '--------------------------
289.     '-----increment flight-----
290.     Flight%% = Flight%% + 1
291.     IF Flight%% = 3 THEN '3 flights per frame
292.         IF Flag AND 1 THEN
293.             Frame%% = Frame%% + 1: Flight%% = 0: New_Site
294.         END IF
295.         IF Flag AND 2 OR Flag AND 4 THEN 'is there a second player or computer?
296.             IF Player%% THEN 'player 2 just loosed, next frame for player 1
297.                 Player%% = 0: Frame%% = Frame%% + 1: Flight%% = 0: New_Site: Turn%% = TRUE
298.             ELSE 'let player 2 loose his first frame
299.                 IF Flag AND 4 THEN Turn%% = FALSE
300.                 Player%% = 1: Flight%% = 0
301.             END IF
302.         END IF
303.     END IF
304.     '--------------------------
305.     Target.Y = Target.OrigY
306.     Target.Speed = 1
307.     Arrow.Y = Arrow.OrigY
308.     Arrow.X = Arrow.OrigX
309.     Shot%% = FALSE
310.     Shoot%% = FALSE
311.     IF Frame%% = 5 THEN Hit~%% = 99 ELSE Hit~%% = 0 'end game trigger
312.     Noise%% = Computer_AI 'adds little randomness to computer shots
313.     Playing = Player%%
314. END SUB
315.  
316. FUNCTION Computer_AI%% ()
317.     Result%% = 0
318.     SELECT CASE Computer.Class
319.         CASE 1 'basic
320.             Result%% = INT(RND * 28) - 10
321.         CASE 2 'decent
322.             Result%% = INT(RND * 24) - 8
323.         CASE 3 'good
324.             Result%% = INT(RND * 20) - 6
325.         CASE 4 'hard
326.             Result%% = INT(RND * 16) - 4
327.         CASE 5 'Robin Hood unbeatable 150!
328.             IF Arrow.OrigX MOD 2 THEN Result%% = 5 ELSE Result%% = 6
329.     END SELECT
330.     Computer_AI%% = Result%%
331. END FUNCTION
332.  
333. SUB Scoreboard_Setup
334.     ClearLayer Layer(5)
335.     _DEST Layer(5)
336.     _FONT 8
337.     COLOR OffWhite
338.     LINE (1, 1)-STEP(300, 84), Cyan, B
339.     LINE (2, 2)-STEP(298, 82), Magenta, B
340.     LINE (3, 3)-STEP(296, 80), OffWhite, B
341.     LINE (4, 4)-STEP(294, 78), Black, BF
342.     LOCATE 2, 2: PRINT "Player    #1  #2  #3  #4  #5  Total"
343.     LOCATE 4, 3: PRINT Player$(0)
344.     LOCATE 8, 3: PRINT Player$(1)
345.     LINE (319, 0)-(319, 199), Green, BF
346.     _FONT 16
347.     _DEST Layer(0)
348. END SUB
349.  
350. SUB Title_Animation
351.     _DEST Layer(5)
352.     COLOR OffWhite
353.     _DEST Layer(0)
354.     _PRINTSTRING (4, 0), "UniKorn", Layer(5)
355.     _PRINTSTRING (36, 16), "ProDucKions", Layer(5)
356.     _PUTIMAGE (0, 0)-STEP(639, 400), Layer(5), Layer(1), (0, 0)-STEP(125, 39)
357.     _PUTIMAGE (0, 0)-STEP(639, 399), Layer(1), Layer(0)
358.     _PRINTSTRING (290, 350), "Presents", Layer(0)
359.     _DELAY 2.5
360.     ClearLayer Layer(5)
361.     CLS
362.     _PUTIMAGE (7 + i%, 152), Layer(3), Layer(5), (0, 32)-STEP(24, 6) 'arrow
363.     _PUTIMAGE , Layer(2), Layer(5)
364.     _PUTIMAGE (0, 0)-STEP(639, 399), Layer(5), Layer(1)
365.     _PUTIMAGE , Layer(1), Layer(0)
366.     _DELAY 1.5
367.     FOR i% = 0 TO 279 STEP 2
368.         _DELAY .02
369.         _PUTIMAGE (8 + i%, 152), Layer(3), Layer(5), (0, 32)-STEP(24, 6) 'arrow
370.         _PUTIMAGE , Layer(2), Layer(5) 'title layer
371.         _PUTIMAGE (0, 0)-STEP(639, 399), Layer(5), Layer(1)
372.         _PUTIMAGE , Layer(1), Layer(0)
373.         ClearLayer Layer(5)
374.     NEXT i%
375.     PLAY HitSound$
376.     _DELAY 1.5
377.     _DEST Layer(0)
378.     CLS
379. END SUB
380.  
381. FUNCTION Collision_Check~%% (X%, Y%)
382.     IF _SOURCE <> Layer(4) THEN _SOURCE Layer(4)
383.     Result~%% = 0
384.     FOR I%% = 0 TO 1
385.         Test~& = POINT(25 + X% + I%%, Y% + 3)
386.         R~%% = _RED32(Test~&)
387.         IF R~%% = 255 THEN R~%% = 1
388.         IF R~%% > 0 THEN Result~%% = R~%%: I%% = 5
389.     NEXT I%%
390.     Collision_Check = Result~%%
391. END FUNCTION
392.  
393. SUB New_Site
394.     Arrow.OrigX = INT(RND * 240) + 10
395.     Arrow.OrigY = INT(RND * 50) + 120
396. END SUB
397.