Author Topic: QB64 vs same coded C/C++ program (Read 5605 times)

Ryster · « **Reply #15 on:** July 23, 2019, 10:10:23 am »

So out of curiosity, i compiled the code on my computer, result: 1847296 (1.76 MB)

Petr · « **Reply #16 on:** July 23, 2019, 12:05:55 pm »

Thank for reply, Pete, i think, with library is none problem if you add all to row 35 as .BI file and all from row 48 to end as .BM file.

I would just recommend using long specific names of variables and fields so that their names indicate that they belong to this library and do not interfere with variables that could be the same in other code while keeping the current names. I do that so, and it always help me, if write some library.

Pete · « **Reply #17 on:** July 23, 2019, 05:37:56 pm »

@Ashish: That's what Steve thought, it's the difference between your 32-bit and my 64 bit version. Thanks for getting back to us.

@Ryster: What version are you using, 32-bit or 64 bt, and what's the version number? Also, are you using Windows or another OS?

@Petr: Thanks for posting all those tests with various versions on your Windows 7. It's about a MB in range between all of those systems. Apparently, the newer versions and the 64-bit ones need to link more libraries, larger libraries, or some additional support information to the finished exe. Also, below is my beginnings into making what I initially posted int a usable library. Yes, I had that same thought about changing the variable names. I usually make programs with global variables, so this library, as currently written, would bite me in the ascii! Anyway, I may start another thread for this, as I'm curious if I could get away with fewer parameters to pass if I made my library variables into TYPES? Oh, and you can try this program, and turn on or off the variable displays. With the variable dispay off, you can see the cursor just fine.
------------------------------------------------------------

Here is the updated code, with some bug fixes and what I hope is the correct variable passing between subs. It compiled on my win 10 64-bit system running QB64 64-bit V1.3 @ 2,487 KB. Again, approx 2.5 MB.

Code: QB64: [Select]

main:
' The next two lines can be removed to use this library with other programs.
LINE INPUT "Input 1 for debug mode with variable display, any other to turn debug off. "; a$
IF a$ = "1" THEN DIM SHARED debug: debug = -1
 
' Place the routine that will use this library above and/or inside this loop...
WHILE (1)
    CALL UserInput
WEND
 
'=============================CONSOLE INPUT LIBRARY===========================
 
SUB UserInput
    STATIC UserInputSetup AS INTEGER
    STATIC MAX_SIZE AS INTEGER, prompt_column AS INTEGER, startpos AS INTEGER, vertpos AS INTEGER, endpos AS INTEGER, yyseparator AS INTEGER, ins AS INTEGER
    STATIC entry$(), xntry$(), prompt$(), entryrow() AS INTEGER
    STATIC xx AS INTEGER, yy AS INTEGER
 
    IF UserInputSetup = 0 THEN
 
        CONST prompt_length = 17 'Length of the longest prompt.
        CONST vmax = 4 'Number of prompts. Must not exceed rows of screen.
        CONST c1f = 0: CONST c1b = 7 'Default foreground and background text/screen colors.
        CONST c2f = 7: CONST c2b = 1 'Text highlighting color.
 
        DIM entry$(vmax) 'Text entry array.
        DIM prompt$(vmax) 'Prompt array.
        DIM entryrow(vmax) AS INTEGER 'Tracks row location of each prompt.
 
        MAX_SIZE = 36
        prompt_column = 10 'Number of columns to indent prompts.
        startpos = prompt_column + prompt_length - 1
        vertpos = 5
        endpos = startpos + MAX_SIZE
        yyseparator = 2 'Number of blank rows, less 1, between prompts. Do not set lower than 1.
        ins = 7 'Cursor vertical height for default insert text mode.
 
        CALL SetTitle
 
        CALL SetConsole(c1f, c1b)
 
        CALL GetPrompts(startpos, vertpos, vmax, yyseparator, xx, yy, prompt_column, entryrow(), prompt$())
 
        CALL SetCursor(ins)
 
        UserInputSetup = -1
    END IF
 
    CALL GetConsoleInput(startpos, endpos, vertpos, vmax, yyseparator, xx, yy, ins, MAX_SIZE, c1f, c1b, c2f, c2b, prompt_column, entryrow(), entry$())
 
END SUB
 
SUB SetTitle
    title$ = "Pete's Custom Keyboard Input App"
    _TITLE title$
END SUB
 
SUB SetConsole (c1f AS INTEGER, c1b AS INTEGER)
    PALETTE 7, 63
    COLOR c1f, c1b
    CLS
END SUB
 
SUB GetPrompts (startpos AS INTEGER, vertpos AS INTEGER, vmax AS INTEGER, yyseparator AS INTEGER, xx AS INTEGER, yy AS INTEGER, prompt_column AS INTEGER, entryrow() AS INTEGER, prompt$())
    DIM ii AS INTEGER
 
    xx = startpos
    yy = vertpos
 
    prompt$(0) = "Name..........: "
    prompt$(1) = "Address.......: "
    prompt$(2) = "City/State/Zip: "
    prompt$(3) = "Phone.........: "
 
    yy = vertpos
 
    FOR ii = 0 TO vmax - 1
        LOCATE yy, prompt_column
        PRINT prompt$(ii);
        entryrow(ii) = yy
        yy = yy + yyseparator
    NEXT
 
    LOCATE vertpos, startpos
    xx = startpos
    yy = vertpos
END SUB
 
SUB SetCursor (ins AS INTEGER)
    LOCATE , , 1, 7, ins
END SUB
 
SUB copy (startpos AS INTEGER, vertpos AS INTEGER, yyseparator AS INTEGER, xx AS INTEGER, yy AS INTEGER, hmrk AS INTEGER, entry$(), xntry$)
    DIM m1 AS INTEGER, m2 AS INTEGER
 
    IF xx - startpos + 1 < hmrk THEN
        m2 = hmrk
        m1 = xx - startpos + 1
    ELSE
        m1 = hmrk
        m2 = xx - startpos + 1
    END IF
    xntry$ = MID$(entry$((yy - vertpos) / yyseparator), m1, m2 - m1)
END SUB
 
SUB replace (startpos AS INTEGER, vertpos AS INTEGER, yyseparator AS INTEGER, xx AS INTEGER, yy AS INTEGER, entry$(), hmrk AS INTEGER, highlighton AS INTEGER, dir AS INTEGER, c1f AS INTEGER, c1b AS INTEGER)
    DIM j AS INTEGER, m1 AS INTEGER, m2 AS INTEGER
 
    j = LEN(entry$((yy - vertpos) / yyseparator))
    COLOR c1f, c1b
    IF xx - startpos + 1 < hmrk THEN
        m2 = hmrk
        m1 = xx - startpos
    ELSE
        m1 = hmrk - 1
        m2 = xx - startpos + 1
    END IF
    entry$((yy - vertpos) / yyseparator) = MID$(entry$((yy - vertpos) / yyseparator), 1, m1) + MID$(entry$((yy - vertpos) / yyseparator), m2)
    LOCATE yy, startpos
    PRINT entry$((yy - vertpos) / yyseparator);
    PRINT STRING$(j - LEN(entry$((yy - vertpos) / yyseparator)), 32);
    IF xx - startpos + 1 > hmrk THEN
        xx = hmrk - 1 + startpos
    END IF
    LOCATE yy, xx
    hmrk = 0
    highlighton = 0
    dir = 0
END SUB
 
SUB GetConsoleInput (startpos AS INTEGER, endpos AS INTEGER, vertpos AS INTEGER, vmax AS INTEGER, yyseparator AS INTEGER, xx AS INTEGER, yy AS INTEGER, ins AS INTEGER, MAX_SIZE AS INTEGER, c1f AS INTEGER, c1b AS INTEGER, c2f AS INTEGER, c2b AS INTEGER, prompt_column AS INTEGER, entryrow() AS INTEGER, entry$())
    STATIC drag AS INTEGER, dir AS INTEGER, highlighton AS INTEGER, hmrk AS INTEGER, xntry$, shift AS INTEGER
    DIM ii AS INTEGER, oldyy AS INTEGER
    DIM xntry$(MAX_SIZE) 'Cut/Copy array.
 
    IF ctrl THEN ctrl = 0
    IF shift < 0 THEN shift = 0
    DEF SEG = 0
    ii = PEEK(&H417) MOD 16
    SELECT CASE ii
        CASE 1, 2
            shift = -1
        CASE 4
            ctrl = -1
    END SELECT
    DEF SEG
 
    oldyy = yy
 
    IF drag = 0 THEN
        IF highlighton AND shift = 0 AND hmrk = 0 THEN
            highlighton = 0 ' Disable highlighton so character value isn't printed after a shift / release event without highlighting.
        END IF
    END IF
 
    CALL mouse(startpos, vmax, xx, yy, vertpos, yyseparator, hmrk, dir, highlighton, c1f, c1b, c2f, c2b, drag, prompt_column, MAX_SIZE, shift, ch$, entry$(), entryrow())
 
    IF drag = 0 THEN
        IF ch$ = "" THEN ch$ = INKEY$
        IF ch$ <> "" THEN
            IF ctrl THEN
                SELECT CASE LCASE$(ch$)
                    CASE CHR$(1) ' Select All
                        LOCATE yy, startpos
                        COLOR c2f, c2b
                        PRINT entry$((yy - vertpos) / yyseparator);
                        COLOR c1f, c1b
                        hmrk = 1
                        highlighton = -1
                        dir = LEN(entry$((yy - vertpos) / yyseparator))
                        xx = startpos + dir
                        LOCATE yy, xx
 
                    CASE CHR$(3) ' Copy
                        IF hmrk THEN
                            CALL copy(startpos, vertpos, yyseparator, xx, yy, hmrk, entry$(), xntry$)
                        END IF
 
                    CASE CHR$(24) ' Cut
                        IF hmrk THEN
                            CALL copy(startpos, vertpos, yyseparator, xx, yy, hmrk, entry$(), xntry$)
                            CALL replace(startpos, vertpos, yyseparator, xx, yy, entry$(), hmrk, highlighton, dir, c1f, c1b)
                        END IF
 
                    CASE CHR$(22) ' Paste
                        IF xntry$ <> "" THEN
                            IF hmrk THEN
                                CALL replace(startpos, vertpos, yyseparator, xx, yy, entry$(), hmrk, highlighton, dir, c1f, c1b)
                            END IF
                            m1 = xx - startpos
                            m2 = m1 + 1
                            IF LEN(xntry$) + LEN(entry$((yy - vertpos) / yyseparator)) - (m2 - m1) <= MAX_SIZE - 1 THEN
                                entry$((yy - vertpos) / yyseparator) = MID$(entry$((yy - vertpos) / yyseparator), 1, m1) + xntry$ + MID$(entry$((yy - vertpos) / yyseparator), m2)
                                LOCATE yy, startpos
                                COLOR c1f, c1b
                                PRINT entry$((yy - vertpos) / yyseparator);
                                xx = xx + LEN(xntry$)
                                LOCATE yy, xx
                            ELSE
                                BEEP ' Contents too large to paste.
                            END IF
                        END IF
                END SELECT
            ELSE
                SELECT CASE ch$
                    CASE CHR$(8) ' Backspace
                        ch$ = CHR$(0)
                        IF hmrk > 0 THEN
                            CALL replace(startpos, vertpos, yyseparator, xx, yy, entry$(), hmrk, highlighton, dir, c1f, c1b)
                        ELSE
                            IF xx > startpos THEN
                                xx = xx - 1
                                LOCATE yy, xx
                                PRINT MID$(entry$((yy - vertpos) / yyseparator), xx - startpos + 2); " ";
                                entry$((yy - vertpos) / yyseparator) = MID$(entry$((yy - vertpos) / yyseparator), 1, xx - startpos) + MID$(entry$((yy - vertpos) / yyseparator), xx - startpos + 2)
                                LOCATE yy, xx
                            END IF
                        END IF
                    CASE CHR$(0) + "S" ' Delete
                        IF shift THEN
                            IF hmrk THEN
                                CALL copy(startpos, vertpos, yyseparator, xx, yy, hmrk, entry$(), xntry$)
                                CALL replace(startpos, vertpos, yyseparator, xx, yy, entry$(), hmrk, highlighton, dir, c1f, c1b)
                            END IF
                        ELSE
                            ch$ = CHR$(0)
                            IF hmrk > 0 THEN
                                CALL replace(startpos, vertpos, yyseparator, xx, yy, entry$(), hmrk, highlighton, dir, c1f, c1b)
                            ELSE
                                IF LEN(entry$((yy - vertpos) / yyseparator)) > 0 AND xx - startpos <= LEN(entry$((yy - vertpos) / yyseparator)) THEN
                                    PRINT MID$(entry$((yy - vertpos) / yyseparator), xx - startpos + 2); " ";
                                    entry$((yy - vertpos) / yyseparator) = MID$(entry$((yy - vertpos) / yyseparator), 1, xx - startpos) + MID$(entry$((yy - vertpos) / yyseparator), xx - startpos + 2)
                                    LOCATE yy, xx
                                END IF
                            END IF
                        END IF
 
                    CASE CHR$(0) + "H" ' Arrow up
                        ch$ = CHR$(0)
                        IF yy > vertpos THEN
                            yy = yy - yyseparator
                            xx = startpos
                            LOCATE yy, xx
                        END IF
 
                    CASE CHR$(0) + "P", CHR$(13) ' Arrow down, Enter
                        ch$ = CHR$(0)
                        IF (yy - vertpos) / yyseparator + 1 < vmax THEN
                            yy = yy + yyseparator
                            xx = startpos
                            LOCATE yy, xx
                        END IF
 
                    CASE CHR$(0) + "K" ' Arrow left
                        ch$ = CHR$(0)
                        IF xx > startpos THEN
                            IF shift THEN
                                IF dir <= 0 THEN
                                    IF dir = 0 THEN
                                        hmrk = xx - startpos + 1
                                        highlighton = -1
                                    END IF
                                    xx = xx - 1
                                    LOCATE yy, xx
                                    COLOR c2f, c2b
                                    PRINT MID$(entry$((yy - vertpos) / yyseparator), xx - startpos + 1, 1)
                                    dir = dir - 1
                                    LOCATE yy, xx
                                ELSE
                                    xx = xx - 1
                                    LOCATE yy, xx
                                    COLOR c1f, c1b
                                    PRINT MID$(entry$((yy - vertpos) / yyseparator), xx - startpos + 1, 1)
                                    dir = dir - 1
                                    IF dir = 0 THEN
                                        hmrk = 0
                                    END IF
                                    LOCATE yy, xx
                                END IF
 
                            ELSE
                                xx = xx - 1
                                LOCATE yy, xx
                            END IF
                        END IF
 
                    CASE CHR$(0) + "M" ' Arrow right
                        ch$ = CHR$(0)
                        IF xx < endpos - 1 AND xx - startpos < LEN(entry$((yy - vertpos) / yyseparator)) THEN
                            IF shift THEN
                                IF dir >= 0 THEN
                                    IF dir = 0 THEN
                                        hmrk = xx - startpos + 1
                                        highlighton = -1
                                    END IF
                                    COLOR c2f, c2b
                                    PRINT MID$(entry$((yy - vertpos) / yyseparator), xx - startpos + 1, 1)
                                    xx = xx + 1
                                    LOCATE yy, xx
                                    dir = dir + 1
                                    LOCATE yy, xx
                                ELSE
                                    COLOR c1f, c1b
                                    PRINT MID$(entry$((yy - vertpos) / yyseparator), xx - startpos + 1, 1)
                                    xx = xx + 1
                                    dir = dir + 1
                                    IF dir = 0 THEN
                                        hmrk = 0
                                        highlighton = 0
                                    END IF
                                    LOCATE yy, xx
                                END IF
                            ELSE
                                xx = xx + 1
                                LOCATE yy, xx
                            END IF
                        END IF
 
                    CASE CHR$(0) + "G" ' Home
                        ch$ = CHR$(0)
                        IF xx > startpos THEN
                            IF shift THEN
                                WHILE xx > startpos
                                    IF dir <= 0 THEN
                                        IF dir = 0 THEN
                                            hmrk = xx - startpos + 1
                                            ' highlighton is already set.
                                        END IF
                                        xx = xx - 1
                                        LOCATE yy, xx
                                        COLOR c2f, c2b
                                        PRINT MID$(entry$((yy - vertpos) / yyseparator), xx - startpos + 1, 1);
                                        dir = dir - 1
                                        LOCATE yy, xx
                                    ELSE
                                        xx = xx - 1
                                        LOCATE yy, xx
                                        COLOR c1f, c1b
                                        PRINT MID$(entry$((yy - vertpos) / yyseparator), xx - startpos + 1, 1);
                                        dir = dir - 1
                                        IF dir = 0 THEN
                                            hmrk = 0
                                            highlighton = 0
                                        END IF
                                        LOCATE yy, xx
                                    END IF
                                WEND
                            ELSE
                                xx = startpos
                                LOCATE yy, xx
                            END IF
                        END IF
 
                    CASE CHR$(0) + "O" ' End
                        ch$ = CHR$(0)
                        IF xx < endpos - 1 THEN
                            IF shift THEN
                                WHILE xx - startpos < LEN(entry$((yy - vertpos) / yyseparator))
                                    IF dir >= 0 THEN
                                        IF dir = 0 THEN
                                            hmrk = xx - startpos + 1
                                            highlighton = -1
                                        END IF
                                        COLOR c2f, c2b
                                        PRINT MID$(entry$((yy - vertpos) / yyseparator), xx - startpos + 1, 1);
                                        xx = xx + 1
                                        LOCATE yy, xx
                                        dir = dir + 1
                                        LOCATE yy, xx
                                    ELSE
                                        COLOR c1f, c1b
                                        PRINT MID$(entry$((yy - vertpos) / yyseparator), xx - startpos + 1, 1);
                                        xx = xx + 1
                                        dir = dir + 1
                                        IF dir = 0 THEN
                                            hmrk = 0
                                        END IF
                                        LOCATE yy, xx
                                    END IF
                                WEND
                            ELSE
                                xx = startpos + LEN(entry$((yy - vertpos) / yyseparator))
                                LOCATE yy, xx
                            END IF
                        END IF
 
                    CASE CHR$(27)
                        ch$ = CHR$(0)
                        SYSTEM
 
                    CASE CHR$(0) + CHR$(82) ' Insert
                        ch$ = CHR$(0)
                        IF ins = 7 THEN ins = 30 ELSE ins = 7
                        SetCursor ins
 
                    CASE CHR$(32) TO CHR$(126)
                        IF hmrk > 0 THEN
                            CALL replace(startpos, vertpos, yyseparator, xx, yy, entry$(), hmrk, highlighton, dir, c1f, c1b)
                        END IF
                        IF ins = 30 THEN
                            IF xx - startpos < MAX_SIZE - 1 THEN
                                MID$(entry$((yy - vertpos) / yyseparator), xx - startpos + 1, 1) = ch$
                                LOCATE yy, xx
                                PRINT ch$;
                                xx = xx + 1
                                LOCATE yy, xx
                            END IF
                        ELSE
                            IF LEN(entry$((yy - vertpos) / yyseparator)) < MAX_SIZE - 1 THEN
                                PRINT ch$ + MID$(entry$((yy - vertpos) / yyseparator), xx - startpos + 1);
                                entry$((yy - vertpos) / yyseparator) = MID$(entry$((yy - vertpos) / yyseparator), 1, xx - startpos) + ch$ + MID$(entry$((yy - vertpos) / yyseparator), xx - startpos + 1)
                                xx = xx + 1
                                LOCATE yy, xx
                            END IF
                        END IF
                END SELECT
            END IF
        END IF
 
        IF shift THEN
            IF highlighton = 0 AND dir <> 0 THEN
                highlighton = -1 ' When dir <> 0 the first character has been highlighted.
            END IF
        ELSE
            IF ch$ <> "" THEN
                IF highlighton AND shift = 0 AND LCASE$(ch$) <> "x" AND ctrl = 0 AND ch$ <> CHR$(8) AND ch$ <> CHR$(0) + "S" THEN
                    ' ROutine to remove highlighting from text.
                    COLOR c1f, c1b
                    LOCATE oldyy, startpos
                    IF ch$ <> CHR$(0) THEN
                        PRINT ch$;
                    END IF
                    PRINT entry$((oldyy - vertpos) / yyseparator);
                    LOCATE yy, xx
                    hmrk = 0
                    highlighton = 0
                    dir = 0
                END IF
            END IF
        END IF
        ch$ = ""
    END IF
END SUB
 
SUB mouse (startpos AS INTEGER, vmax AS INTEGER, xx AS INTEGER, yy AS INTEGER, vertpos AS INTEGER, yyseparator AS INTEGER, hmrk AS INTEGER, dir AS INTEGER, highlighton AS INTEGER, c1f AS INTEGER, c1b AS INTEGER, c2f AS INTEGER, c2b AS INTEGER, drag AS INTEGER, prompt_column AS INTEGER, MAX_SIZE AS INTEGER, shift AS INTEGER, ch$, entry$(), entryrow() AS INTEGER)
    STATIC doubleclick AS INTEGER, lb AS INTEGER, lbdn AS INTEGER, z1, oldmx AS INTEGER, oldmy AS INTEGER, mhl AS INTEGER
    STATIC mx AS INTEGER, my AS INTEGER
    DIM ii AS INTEGER
 
    IF debug THEN
        LOCATE 20, 1
        COLOR c1f, c1b
        PRINT " oldmx"; oldmx; "  oldmy"; oldmy; "  mx"; mx; "  my"; my; "  xx"; xx; "  yy"; yy; "  lb"; lb; "  lbdn"; lbdn; "      "
        PRINT " shift"; shift; "  drag"; drag; "  mhl"; mhl; "  hmrk"; hmrk; "  dir"; dir; "  dblclk"; doubleclick; "  startpos"; startpos; "        "
        PRINT " mx"; mx - startpos + 1; "  my"; (my - vertpos) / yyseparator; "  xx"; xx - startpos + 1; "  yy"; (yy - vertpos) / yyseparator; "        "
        PRINT " highlighton"; highlighton; "     ";
        LOCATE yy, xx
    END IF
 
    WHILE _MOUSEINPUT: WEND
    mx = _MOUSEX
    my = _MOUSEY
    lb = _MOUSEBUTTON(1)
 
    IF lb AND highlighton AND shift = 0 AND drag = 0 AND mhl = 0 THEN ' Allows highlighting caused by mouse click to be removed in parent sub.
        ch$ = CHR$(0)
        EXIT SUB
    END IF
 
    IF shift AND lb AND drag = 0 OR mhl THEN
        IF mhl = 0 THEN ' Shift + click highlighting.
            IF my = yy AND mx <> xx AND mx >= startpos AND mx - startpos <= LEN(entry$((yy - vertpos) / yyseparator)) THEN
                mhl = mx - startpos + 1
            END IF
        ELSE ' Terminal point reached, end highlighting.
            IF mhl = xx - startpos + 1 THEN mhl = 0: drag = 0: EXIT SUB
        END IF
    END IF
 
    IF LEN(entry$((yy - vertpos) / yyseparator)) THEN
        IF lbdn AND xx <> mx AND shift = 0 OR mhl THEN ' Combined drag and shift + click highlighting.
            IF my = yy THEN ' Restrict to active text line.
                IF lb OR mhl THEN
                    IF xx > mx THEN
                        drag = -1
                    ELSE
                        drag = 1
                    END IF
                    GOSUB mousedrag
                    EXIT SUB
                ELSE
                    drag = 0
                END IF
            END IF
        END IF
    END IF
 
    IF lb THEN
        IF debug THEN COLOR c1f, c1b: LOCATE 2, 1: PRINT "left button down    "
        IF lbdn = 0 THEN lbdn = -1
        IF my = yy THEN
            IF mx >= startpos AND mx - startpos <= LEN(entry$((yy - vertpos) / yyseparator)) THEN
                IF drag = 0 AND shift = 0 THEN yy = my ' Prevents changing rows if a drag is in progress.
                xx = mx
                LOCATE yy, xx
                oldmx = mx: oldmy = my
            END IF
        ELSEIF shift = 0 THEN
            FOR ii = 0 TO vmax - 1
                IF my = entryrow(ii) THEN EXIT FOR
            NEXT
 
            IF my = entryrow(ii) AND drag = 0 THEN
                IF mx >= prompt_column AND mx - startpos <= MAX_SIZE THEN
                    IF mx - startpos > 0 AND mx - startpos <= LEN(entry$(ii)) THEN
                        yy = my: xx = mx
                    ELSE
                        yy = my: xx = startpos
                    END IF
                    LOCATE yy, xx
                END IF
            END IF
        END IF
    ELSE
        IF lbdn THEN
            z1 = TIMER
            IF debug THEN COLOR c1f, c1b: LOCATE 2, 1: PRINT "left button released"
            doubleclick = doubleclick + 1
            lbdn = 0
            drag = 0
        END IF
    END IF
 
    IF doubleclick = 1 THEN
        IF ABS(z1 - TIMER) > .33 THEN doubleclick = 0
    END IF
 
    IF doubleclick = 2 THEN
        ' Any double click events go here...
        IF debug THEN LOCATE 2, 1: PRINT "double click         ";
        doubleclick = 0
    END IF
    LOCATE yy, xx
 
    EXIT SUB
 
    mousedrag:
    SELECT CASE drag
        CASE IS < 0
            IF dir <= 0 THEN ' highlight to left
                IF dir = 0 THEN
                    hmrk = xx - startpos + 1
                    ' Do not emulate shift here. shift remains 0.
                    highlighton = -1
                END IF
                xx = xx - 1
                LOCATE yy, xx
                COLOR c2f, c2b
                PRINT MID$(entry$((yy - vertpos) / yyseparator), xx - startpos + 1, 1)
                dir = dir - 1
                LOCATE yy, xx
            ELSE ' unhighlight to left
                xx = xx - 1
                dir = dir - 1
                LOCATE yy, xx
                COLOR c1f, c1b
                PRINT MID$(entry$((yy - vertpos) / yyseparator), xx - startpos + 1, 1)
                IF dir = 0 THEN
                    hmrk = 0
                    highlighton = 0
                    shift = 0
                END IF
                LOCATE yy, xx
            END IF
        CASE IS > 0
            IF dir >= 0 THEN
                COLOR c2f, c2b
                PRINT MID$(entry$((yy - vertpos) / yyseparator), xx - startpos + 1, 1)
                IF dir = 0 THEN
                    hmrk = xx - startpos + 1
                    highlighton = -1
                    ' Do not emulate shift here. shift remains 0.
                END IF
                xx = xx + 1
                dir = dir + 1
                LOCATE yy, xx
            ELSE
                COLOR c1f, c1b
                PRINT MID$(entry$((yy - vertpos) / yyseparator), xx - startpos + 1, 1)
                xx = xx + 1
                dir = dir + 1
                IF dir = 0 THEN
                    hmrk = 0
                    highlighton = 0
                    shift = 0
                END IF
                LOCATE yy, xx
            END IF
    END SELECT
    RETURN
END SUB
 

Pete

Ryster · « **Reply #18 on:** July 24, 2019, 09:44:03 am »

The result of the compilation: 1847296 (1.76 MB)
Windows 10 - 1903, 64-bit. >>> QB64 1.2 - 32-bit.

Pete · « **Reply #19 on:** July 24, 2019, 12:04:49 pm »

Thank you. It seems there is a pattern emerging that 64-bit versions of QB64 compile to larger exe files than the 32-bit versions, and that the higher versions (more recent versions) likewise, compile larger exe files.

Pete

SMcNeill · « **Reply #20 on:** July 24, 2019, 03:12:23 pm »

Quote from: Pete on July 24, 2019, 12:04:49 pm

Thank you. It seems there is a pattern emerging that 64-bit versions of QB64 compile to larger exe files than the 32-bit versions, and that the higher versions (more recent versions) likewise, compile larger exe files.

Pete

Remember: V1.3 swapped out to the latest MinGW compiler. Prior versions used an old version of mingw which probably dated back to the Stone Age when LET was still in use by primitive programmers.

Ryster · « **Reply #21 on:** July 24, 2019, 03:43:15 pm »

SMcNeill.
It's nice to see that now you've come to the conclusion that previous versions were from the age of the splitting spit. As I wrote once, that the previous versions are unusable (at least in my case) that a lot of epithets rushed on my head, and that was what Clippy was leading. The only version that can meet my code is version 1.3 of December 2018 and I use it every day. Other non-useable ones.

News: