Author Topic: _KEYDOWN with alphanumeric keys (Read 5183 times)

johannhowitzer · « **on:** July 19, 2019, 10:38:12 pm »

When I use _KEYDOWN with a value such as 100304 for left shift, it works fine, but everything I try for alphanumeric keys doesn't work - such as _KEYDOWN(90) or _KEYDOWN(100090) for the z key. Is this impossible, or is the wiki / help documentation incorrect?

bplus · « **Reply #1 on:** July 19, 2019, 10:50:19 pm »

Looks OK to me:

Code: QB64: [Select]

WHILE _KEYDOWN(27) = 0
    FOR i = 65 TO 90
        IF _KEYDOWN(i) THEN PRINT CHR$(i),
    NEXT
    FOR i = 97 TO 122
        IF _KEYDOWN(i) THEN PRINT CHR$(i),
    NEXT
    _LIMIT 100
WEND
 
 

johannhowitzer · « **Reply #2 on:** July 19, 2019, 11:12:13 pm »

Code: QB64: [Select]

screen _newimage(640, 480, 12)
 
const true = -1
const false = 0
 
const up& = 18432
const right& = 19712
const down& = 20480
const left& = 19200
 
const lshift& = 100304
const lctrl& = 100306
 
do
   _limit 60: _display
   cls
   if _keydown(up&) = true then print "UP"
   if _keydown(right&) = true then print "RIGHT"
   if _keydown(down&) = true then print "DOWN"
   if _keydown(left&) = true then print "LEFT"
 
   if _keydown(lshift&) = true then print "LSHIFT"
   if _keydown(lctrl&) = true then print "LCTRL"
   if _keydown(90) = true then print "Z"
   if _keydown(88) = true then print "X"
loop
 

Your code is working, but mine isn't. It prints everything but the Z and X.

SMcNeill · « **Reply #3 on:** July 19, 2019, 11:23:38 pm »

Also try _KEYDOWN(122). There’s a different return code for lowercase and uppercase versions of letters.

Pete · « **Reply #4 on:** July 19, 2019, 11:27:58 pm »

You could use INKEY$ with a PEEK routine...

Code: QB64: [Select]

DO
    _LIMIT 30
 
    DEF SEG = 0
    ii = PEEK(&H417) MOD 16
    SELECT CASE ii
        CASE 0
            IF shift THEN PRINT "shift key up": shift = 0
            IF ctrl THEN PRINT "ctrl key up": ctrl = 0
        CASE 1, 2
            shift = -1
            PRINT "shift key down"
        CASE 4
            ctrl = -1
            PRINT "ctrl key down"
    END SELECT
    DEF SEG
 
    key$ = INKEY$
    SELECT CASE key$
        CASE CHR$(27)
            END
        CASE CHR$(32) TO CHR$(126)
            PRINT key$
    END SELECT
LOOP

Pete

FellippeHeitor · « **Reply #5 on:** July 19, 2019, 11:38:15 pm »

Let peek and poke rest. If _KEYHIT/_KEYDOWN can’t get it, find the bug in the code, as per McNeil’s suggestion.

johannhowitzer · « **Reply #6 on:** July 19, 2019, 11:52:42 pm »

Huh, the uppercase version works. I wonder why bplus' code worked and mine didn't. Still, that solves my problem.

SMcNeill · « **Reply #7 on:** July 19, 2019, 11:58:39 pm »

Quote from: johannhowitzer on July 19, 2019, 11:52:42 pm

Huh, the uppercase version works. I wonder why bplus' code worked and mine didn't. Still, that solves my problem.

Bplus trapped for both uppercase and lowercase; you need to do the same.

IF _KEYDOWN(90) = true OR _KEYDOWN(122) = true THEN....

Depending on CapsLock state, you’ll generate different key codes.

“Z” is not the same keypress as “z”.

Pete · « **Reply #8 on:** July 20, 2019, 12:32:41 am »

Quote from: FellippeHeitor on July 19, 2019, 11:38:15 pm

Let peek and poke rest. If _KEYHIT/_KEYDOWN can’t get it, find the bug in the code, as per McNeil’s suggestion.

What? Them's fightin' words varmint!

OK, fine, use Windows API, instead...

Code: QB64: [Select]

CONST VK_SHIFT = &H10
CONST VK_CONTROL = &H11
 
DECLARE DYNAMIC LIBRARY "user32"
    FUNCTION GetAsyncKeyState% (BYVAL nul%)
END DECLARE
 
DO
    shift% = GetAsyncKeyState%(VK_SHIFT): IF shift% THEN shiftdown% = -1: PRINT "shift key down"
    ctrl% = GetAsyncKeyState(VK_CONTROL): IF ctrl% THEN ctrldown% = -1: PRINT "ctrl key down"
 
    IF shiftdown% AND shift% = 0 THEN PRINT "shift key up": shiftdown% = 0
    IF ctrldown% AND ctrl% = 0 THEN PRINT "ctrl key up": ctrldown% = 0
 
    key$ = INKEY$
    SELECT CASE key$
        CASE CHR$(27)
            END
        CASE CHR$(32) TO CHR$(126)
            PRINT key$
    END SELECT
LOOP
END
 

- Sam

bplus · « **Reply #9 on:** July 20, 2019, 12:39:00 am »

Hi johannhowitzer,

When I hold down the shift key and hold down the z key, your code will print "Z" for me, using vers 1.3 on Windows 10 Laptop.

Remember _KEYDOWN detects keys that are being held down, no recorded buffer.

bplus · « **Reply #10 on:** July 20, 2019, 12:41:29 am »

Quote from: Pete on July 20, 2019, 12:32:41 am

What? Them's fightin' words varmint!

OK, fine, use Windows API, instead...

Code: QB64: [Select]
CONST VK_SHIFT = &H10
CONST VK_CONTROL = &H11

DECLARE DYNAMIC LIBRARY "user32"
FUNCTION GetAsyncKeyState% (BYVAL nul%)
END DECLARE

DO
shift% = GetAsyncKeyState%(VK_SHIFT): IF shift% THEN shiftdown% = -1: PRINT "shift key down"
ctrl% = GetAsyncKeyState(VK_CONTROL): IF ctrl% THEN ctrldown% = -1: PRINT "ctrl key down"

IF shiftdown% AND shift% = 0 THEN PRINT "shift key up": shiftdown% = 0
IF ctrldown% AND ctrl% = 0 THEN PRINT "ctrl key up": ctrldown% = 0

key$ = INKEY$
SELECT CASE key$
CASE CHR$(27)
END
CASE CHR$(32) TO CHR$(126)
PRINT key$
END SELECT
LOOP
END

- Sam

LOL! Can't kill a fly so call in the SWAT team! :D

Pete · « **Reply #11 on:** July 20, 2019, 01:42:44 am »

SWAT the hell are ya talking about now? Oh, ya wants ta know hows ta do it with INP? Well, why didn't ya say so, varmint?

Code: QB64: [Select]

DO
    scancode% = INP(&H60)
    SELECT CASE scancode%
        CASE 29
            IF ctrl% = 0 THEN PRINT "ctrl key down": ctrl% = -1
        CASE 29 + 128
            IF ctrl% THEN PRINT "ctrl key up": ctrl% = 0
        CASE 42
            IF lshift% = 0 THEN PRINT "left shift key down": lshift% = -1
        CASE 42 + 128
            IF lshift% THEN PRINT "left shift key up": lshift% = 0
        CASE 54
            IF rshift% = 0 THEN PRINT "right shift key down": rshift% = -1
        CASE 54 + 128
            IF rshift% THEN PRINT "right shift key up": rshift% = 0
    END SELECT
 
    key$ = INKEY$
    SELECT CASE key$
        CASE CHR$(27)
            END
        CASE CHR$(32) TO CHR$(126)
            PRINT key$
    END SELECT
LOOP
END
 

TempodiBasic · « **Reply #12 on:** July 20, 2019, 12:02:44 pm »

Hi Pete
fine INP use!

Using on my Toshiba with external USB Keyboard it doesn't detect right Alt key and detects as Ctrl Key the left Alt key...

Pete · « **Reply #13 on:** July 20, 2019, 12:14:16 pm »

Well you know what they say, Toshiba, Japanese for "I'm sorry!"

Those are the correct scan codes for those keys. For fun, I just plugged in my USB Insignia keyboard to my HP laptop, and the keys work correctly. I have no idea why you are getting different results. Maybe someone who knows more about the hardware can answer that question.

Could you also run the PEEK and Windows API code, and see if you get the same results?

Pete

TempodiBasic · « **Reply #14 on:** July 20, 2019, 12:42:40 pm »

Hi Pete

Yes I have enlarged my experience with your codes...
I get the same results both using INP code both using Windows API code!
And more I tried both using USB Sigma Keyboard both using internal notebook keyboard!

That's all

PS using internal Keyboard I have no limit of _KEYDOWN detected holding more than one key

News: