Ectoplasm

[SierraKen]

Pretty cool B+! I changed the F number to .05  and all the set loops to 2 so now it goes a bit faster and looks like blobs in a lava lamp. :D So I also changed the window shape to that more of like a lava lamp, a rectangle. Press the space bar a bunch of times and this is SOOO COOL! I just wish I knew the math in it. :)

Code: QB64: [Select]

1. 'Lava Lamp modified by Ken G. and from b+ and from SmallBASIC.
2. _TITLE "press spacebar" ' b+ 2020-01-20 translated and modified from SmallBASIC
3. 'Plasma Magnifico - updated 2015-11-26 for Android
4. 'This program creates a plasma surface, which looks oily or silky.
5.  
6. CONST xmax = 250, ymax = 600
7. TYPE xy
8.     x AS SINGLE
9.     y AS SINGLE
10.     dx AS SINGLE
11.     dy AS SINGLE
12. END TYPE
13. SCREEN _NEWIMAGE(xmax, ymax, 32)
14. _SCREENMOVE 300, 40
15.  
16. DIM c(360) AS _UNSIGNED LONG, p(6) AS xy, f(6)
17. restart:
18. r = RND: g = RND: b = RND: i = 0
19. FOR n = 1 TO 2
20.     r1 = r: g1 = g: b1 = b
21.     DO: r = RND: LOOP UNTIL ABS(r - r1) > .2
22.     DO: g = RND: LOOP UNTIL ABS(g - g1) > .2
23.     DO: b = RND: LOOP UNTIL ABS(g - g1) > .2
24.     FOR m = 0 TO 17: m1 = 17 - m
25.         f1 = (m * r) / 18: f2 = (m * g) / 18: f3 = (m * b) / 18: c(i) = rgbf(f1, f2, f3): i = i + 1
26.     NEXT
27.     FOR m = 0 TO 17: m1 = 17 - m
28.         f1 = (m + m1 * r) / 18: f2 = (m + m1 * g) / 18: f3 = (m + m1 * b) / 18: c(i) = rgbf(f1, f2, f3): i = i + 1
29.     NEXT
30.     FOR m = 0 TO 17: m1 = 17 - m
31.         f1 = (m1 + m * r) / 18: f2 = (m1 + m * g) / 18: f3 = (m1 + m * b) / 18: c(i) = rgbf(f1, f2, f3): i = i + 1
32.     NEXT
33.     FOR m = 0 TO 17: m1 = 17 - m
34.         f1 = (m1 * r) / 18: f2 = (m1 * g) / 18: f3 = (m1 * b) / 18: c(i) = rgbf(f1, f2, f3): i = i + 1
35.     NEXT
36. NEXT
37.  
38. FOR n = 0 TO 2
39.     p(n).x = RND * xmax: p(n).y = RND * ymax: p(n).dx = RND * 2 - 1: p(n).dy = RND * 2 - 1
40.     f(n) = RND * .05
41. NEXT
42.  
43. WHILE _KEYDOWN(27) = 0
44.     IF INKEY$ = " " THEN GOTO restart
45.     FOR i = 0 TO 2
46.         p(i).x = p(i).x + p(i).dx
47.         IF p(i).x > xmax OR p(i).x < 0 THEN p(i).dx = -p(i).dx
48.         p(i).y = p(i).y + p(i).dy
49.         IF p(i).y > ymax OR p(i).y < 0 THEN p(i).dy = -p(i).dy
50.     NEXT
51.     FOR y = 0 TO ymax - 1 STEP 2
52.         FOR x = 0 TO xmax - 1 STEP 2
53.             d = 0
54.             FOR n = 0 TO 2
55.                 dx = x - p(n).x: dy = y - p(n).y
56.                 k = SQR(dx * dx + dy * dy)
57.                 d = d + (SIN(k * f(n)) + 1) / 2
58.             NEXT n: d = d * 60
59.             LINE (x, y)-STEP(2, 2), c(d), BF
60.         NEXT
61.     NEXT
62.     _DISPLAY
63.     _LIMIT 100
64. WEND
65.  
66. FUNCTION rgbf~& (n1, n2, n3)
67.     rgbf~& = _RGB32(n1 * 255, n2 * 255, n3 * 255)
68. END FUNCTION
69.  

[bplus]

Here is my mod of your mod for Lava Lamp

Code: QB64: [Select]

1. 'Lava Lamp modified by Ken G. and from b+ and from SmallBASIC.   mod again B+
2. _TITLE "press spacebar" ' b+ 2020-01-20 translated and modified from SmallBASIC
3. 'Plasma Magnifico - updated 2015-11-26 for Android
4. 'This program creates a plasma surface, which looks oily or silky.
5.  
6. CONST xmax = 250, ymax = 600
7. TYPE xy
8.     x AS SINGLE
9.     y AS SINGLE
10.     dx AS SINGLE
11.     dy AS SINGLE
12. END TYPE
13. SCREEN _NEWIMAGE(xmax, ymax, 32)
14. _SCREENMOVE 300, 40
15.  
16. DIM c(360) AS _UNSIGNED LONG, p(6) AS xy, f(6)
17.  
18. restart:
19. r = RND: g = RND: b = RND: i = 0
20. FOR n = 1 TO 2
21.     r1 = r: g1 = g: b1 = b
22.     DO: r = RND: LOOP UNTIL ABS(r - r1) > .2
23.     DO: g = RND: LOOP UNTIL ABS(g - g1) > .2
24.     DO: b = RND: LOOP UNTIL ABS(g - g1) > .2
25.     FOR m = 0 TO 17: m1 = 17 - m
26.         f1 = (m * r) / 18: f2 = (m * g) / 18: f3 = (m * b) / 18: c(i) = rgbf(f1, f2, f3): i = i + 1
27.     NEXT
28.     FOR m = 0 TO 17: m1 = 17 - m
29.         f1 = (m + m1 * r) / 18: f2 = (m + m1 * g) / 18: f3 = (m + m1 * b) / 18: c(i) = rgbf(f1, f2, f3): i = i + 1
30.     NEXT
31.     FOR m = 0 TO 17: m1 = 17 - m
32.         f1 = (m1 + m * r) / 18: f2 = (m1 + m * g) / 18: f3 = (m1 + m * b) / 18: c(i) = rgbf(f1, f2, f3): i = i + 1
33.     NEXT
34.     FOR m = 0 TO 17: m1 = 17 - m
35.         f1 = (m1 * r) / 18: f2 = (m1 * g) / 18: f3 = (m1 * b) / 18: c(i) = rgbf(f1, f2, f3): i = i + 1
36.     NEXT
37. NEXT
38.  
39. FOR n = 0 TO 2
40.     p(n).x = RND * xmax: p(n).y = RND * ymax: p(n).dx = .25 * (RND * 2 - 1): p(n).dy = 2 * (RND * 2 - 1)
41.     f(n) = .015
42. NEXT
43.  
44. WHILE _KEYDOWN(27) = 0
45.     CLS
46.     IF INKEY$ = " " THEN GOTO restart
47.     FOR i = 0 TO 2
48.         p(i).x = p(i).x + p(i).dx
49.         IF p(i).x > xmax - 50 OR p(i).x < 50 THEN p(i).dx = -p(i).dx
50.         p(i).y = p(i).y + p(i).dy
51.         IF p(i).y > ymax + 100 OR p(i).y < -100 THEN p(i).dy = -p(i).dy
52.     NEXT
53.     FOR y = 0 TO ymax - 1 STEP 2
54.         FOR x = 0 TO xmax - 1 STEP 2
55.             d = 0
56.             FOR n = 0 TO 2
57.                 dx = x - p(n).x: dy = y - p(n).y
58.                 k = SQR(dx * dx + dy * dy)
59.                 d = d + (SIN(k * f(n)) + 1) / 2
60.             NEXT n: d = d * 60
61.             LINE (x, y)-STEP(2, 2), c(d), BF
62.         NEXT
63.     NEXT
64.     _DISPLAY
65.     _LIMIT 20
66. WEND
67.  
68. FUNCTION rgbf~& (n1, n2, n3)
69.     rgbf~& = _RGB32(n1 * 255, n2 * 255, n3 * 255)
70. END FUNCTION
71.  
72.  
73.  

[SierraKen]

Great job B+! Looks just like a lava lamp now pretty much.

[bplus]

OK I have studied the code for palette creation and can simplify the job immensely!

Code: QB64: [Select]

1. _TITLE "Color Mixing 4 Plasmatic" ' b+ 2020-01-23
2. ' continued study of what makes Plasmatic tick, here the color pallete created
3.  
4. CONST xmax = 800, ymax = 720
5. TYPE xy
6.     x AS SINGLE
7.     y AS SINGLE
8.     dx AS SINGLE
9.     dy AS SINGLE
10. END TYPE
11. SCREEN _NEWIMAGE(xmax, ymax, 32)
12. _SCREENMOVE 300, 10
13.  
14. DIM c(360) AS _UNSIGNED LONG, p(6) AS xy, f(6), i AS INTEGER, r AS INTEGER, g AS INTEGER, b AS INTEGER, m AS INTEGER
15. restart:
16. FOR i = 0 TO 360 'look at pallette
17.     IF i MOD 60 = 0 THEN r = RND * 255: g = RND * 255: b = RND * 255
18.     m = i MOD 60
19.     SELECT CASE m
20.         CASE IS < 15: c(i) = midInk(0, 0, 0, r, g, b, m / 15)
21.         CASE IS < 30: c(i) = midInk(r, g, b, 255, 255, 255, (m - 15) / 15)
22.         CASE IS < 45: c(i) = midInk(255, 255, 255, r, g, b, (m - 30) / 15)
23.         CASE IS < 60: c(i) = midInk(r, g, b, 0, 0, 0, (m - 45) / 15)
24.     END SELECT
25. NEXT
26.  
27. FOR n = 0 TO 5
28.     p(n).x = RND * xmax: p(n).y = RND * ymax: p(n).dx = RND * 2 - 1: p(n).dy = RND * 2 - 1
29.     f(n) = RND * .1
30. NEXT
31.  
32. WHILE _KEYDOWN(27) = 0
33.     IF INKEY$ = " " THEN GOTO restart
34.     FOR i = 0 TO 5
35.         p(i).x = p(i).x + p(i).dx
36.         IF p(i).x > xmax OR p(i).x < 0 THEN p(i).dx = -p(i).dx
37.         p(i).y = p(i).y + p(i).dy
38.         IF p(i).y > ymax OR p(i).y < 0 THEN p(i).dy = -p(i).dy
39.     NEXT
40.     FOR y = 0 TO ymax - 1 STEP 2
41.         FOR x = 0 TO xmax - 1 STEP 2
42.             d = 0
43.             FOR n = 0 TO 5
44.                 dx = x - p(n).x: dy = y - p(n).y
45.                 k = SQR(dx * dx + dy * dy)
46.                 d = d + (SIN(k * f(n)) + 1) / 2
47.             NEXT n: d = d * 60
48.             LINE (x, y)-STEP(2, 2), c(d), BF
49.         NEXT
50.     NEXT
51.     _DISPLAY
52.     _LIMIT 100
53. WEND
54.  
55. FUNCTION midInk~& (r1%, g1%, b1%, r2%, g2%, b2%, fr##)
56.     midInk~& = _RGB32(r1% + (r2% - r1%) * fr##, g1% + (g2% - g1%) * fr##, b1% + (b2% - b1%) * fr##)
57. END FUNCTION
58.  
59.  

This means I might be able to do a Plasmatic background for clock face or anything with far less code PLUS really mess with Plasma coloring that previously depends on a black border and white center like coloring a pipe in fake-3D.

[SierraKen]

Amazing job there. But I wonder if the slow speed will affect the speed of any more code you add?

[SMcNeill]

You were talking about getting rid of SQR...  Can’t you use _HYPOT?

                k = SQR(dx * dx + dy * dy)
k = _HYPOT(dx, dy)

[bplus]

You were talking about getting rid of SQR...  Can’t you use _HYPOT?

                k = SQR(dx * dx + dy * dy)
k = _HYPOT(dx, dy)

Thanks for suggestion, I tried it in following demo and it looks like SQR is a tiny bit faster, on my system the loop time is usually under .10 secs .09xxx with .10xxx showing more often with _HYPOT and .08xxx showing more with SQR. What is definitely slower is using ^.5 instead of SQR!


This is a demo of the new color Options available for Plasmatic effect, use t to toggle between Traditional Plasma that has high contrast Black between cells and White in cell centers, whereas the New Options available put any color between cells and any color as cell center:

again t to toggle between Traditional Plasma and New Options Plasma, use spacebar to change color sets:

Code: QB64: [Select]

1. _TITLE "Color Mixing 4 Plasmatic" ' b+ 2020-01-23
2. ' continued study of what makes Plasmatic tick, here the color pallete created
3.  
4. CONST xmax = 800, ymax = 600
5. TYPE xy
6.     x AS SINGLE
7.     y AS SINGLE
8.     dx AS SINGLE
9.     dy AS SINGLE
10. END TYPE
11. SCREEN _NEWIMAGE(xmax, ymax, 32)
12. _SCREENMOVE 300, 10
13. RANDOMIZE TIMER
14. DIM c(360) AS _UNSIGNED LONG, p(6) AS xy, f(6), i AS INTEGER, r AS INTEGER, g AS INTEGER, b AS INTEGER, m AS INTEGER
15. DIM r1 AS INTEGER, g1 AS INTEGER, b1 AS INTEGER
16. DIM r2 AS INTEGER, g2 AS INTEGER, b2 AS INTEGER
17. restart:
18. IF mode < .5 THEN '<< sorry I was using RND before mode but this line still works
19.     r1 = RND * 255: g1 = RND * 255: b1 = RND * 255
20.     r2 = RND * 255: g2 = RND * 255: b2 = RND * 255
21.     t$ = "t to toggle Current Mode New Plasma Option:  Between Cell Color" + STR$(r1) + STR$(g1) + STR$(b1) + "   Center Cell Color " + STR$(r2) + STR$(g2) + STR$(b2)
22. ELSE
23.     r2 = 255: g2 = 255: b2 = 255 'regular Plasma
24.     r1 = 0: g1 = 0: b1 = 0
25.     t$ = "t to toggle Current Mode Traditional Plasma:   Between Cell Color" + STR$(r1) + STR$(g1) + STR$(b1) + "   Center Cell Color" + STR$(r2) + STR$(g2) + STR$(b2)
26. END IF
27.  
28. FOR i = 0 TO 360
29.     IF i MOD 60 = 0 THEN r = RND * 255: g = RND * 255: b = RND * 255
30.     m = i MOD 60
31.     SELECT CASE m
32.         CASE IS < 15: c(i) = midInk(r1, g1, b1, r, g, b, m / 15)
33.         CASE IS < 30: c(i) = midInk(r, g, b, r2, g2, b2, (m - 15) / 15)
34.         CASE IS < 45: c(i) = midInk(r2, g2, b2, r, g, b, (m - 30) / 15)
35.         CASE IS < 60: c(i) = midInk(r, g, b, r1, g1, b1, (m - 45) / 15)
36.     END SELECT
37. NEXT
38.  
39. FOR n = 0 TO 5
40.     p(n).x = RND * xmax: p(n).y = RND * ymax: p(n).dx = RND * 2 - 1: p(n).dy = RND * 2 - 1
41.     f(n) = .1 * RND
42. NEXT
43.  
44. WHILE _KEYDOWN(27) = 0
45.     k$ = INKEY$
46.     IF k$ = " " THEN GOTO restart
47.     IF k$ = "t" THEN mode = 1 - mode: GOTO restart
48.     t = TIMER(.001)
49.     FOR i = 0 TO 5
50.         p(i).x = p(i).x + p(i).dx
51.         IF p(i).x > xmax OR p(i).x < 0 THEN p(i).dx = -p(i).dx
52.         p(i).y = p(i).y + p(i).dy
53.         IF p(i).y > ymax OR p(i).y < 0 THEN p(i).dy = -p(i).dy
54.     NEXT
55.     _TITLE t$
56.     FOR y = 0 TO ymax - 1 STEP 2
57.         FOR x = 0 TO xmax - 1 STEP 2
58.             d = 0
59.             FOR n = 0 TO 5
60.                 dx = x - p(n).x: dy = y - p(n).y
61.                 k = SQR(dx * dx + dy * dy)
62.                 'k = _HYPOT(dx, dy)
63.                 d = d + (SIN(k * f(n)) + 1) / 2
64.             NEXT n: d = d * 60
65.             LINE (x, y)-STEP(2, 2), c(d), BF
66.         NEXT
67.     NEXT
68.     LOCATE 1, 1: PRINT USING "#.####"; TIMER(.001) - t
69.     _DISPLAY
70.     '_LIMIT 100
71. WEND
72.  
73. FUNCTION midInk~& (r1%, g1%, b1%, r2%, g2%, b2%, fr##)
74.     midInk~& = _RGBA32(r1% + (r2% - r1%) * fr##, g1% + (g2% - g1%) * fr##, b1% + (b2% - b1%) * fr##, 255)
75. END FUNCTION
76.  
77.  

[johnno56]

Plasmas are great! Flashback to the late 60's and 70's... So cool... or should that be... "Heavy man" or "Far out"?

[SierraKen]

Regarding my Lava Lamp mod, and yours B+, I changed it a bit more today making it only red shades of color without the ability to use the Space Bar to change anything. I did this to make it more realistic for a lava lamp. I also increased some numbers inside the bottom main loop on 2 IF/THEN statements so it would keep moving longer before everything changes direction. Do you happen to know who made the original code in SmallBasic where you got this from? I ask because I want to add their name to a comment in the code thanking them for posting it on a forum.
Tell me what you think of this, thanks.

Code: QB64: [Select]

1. 'Lava Lamp modified by Ken G. and from b+ and from SmallBASIC.   mod again B+
2. _TITLE "Lava Lamp" '
3. 'Plasma Magnifico - updated 2015-11-26 for Android
4. 'This program creates a plasma surface, which looks oily or silky.
5. 'By SmallBasic and mods by B+ and SierraKen
6.  
7. CONST xmax = 250, ymax = 600
8. TYPE xy
9.     x AS SINGLE
10.     y AS SINGLE
11.     dx AS SINGLE
12.     dy AS SINGLE
13. END TYPE
14. SCREEN _NEWIMAGE(xmax, ymax, 32)
15. _SCREENMOVE 300, 40
16.  
17. DIM c(360) AS _UNSIGNED LONG, p(6) AS xy, f(6)
18.  
19. restart:
20. r = RND: g = .002: b = .002: i = 0
21. FOR n = 1 TO 2
22.     r1 = r: g1 = g: b1 = b
23.     DO: r = RND: LOOP UNTIL ABS(r - r1) > .55
24.  
25.     FOR m = 0 TO 17: m1 = 17 - m
26.         f1 = (m * r) / 18: f2 = (m * g) / 18: f3 = (m * b) / 18: c(i) = rgbf(f1, f2, f3): i = i + 1
27.     NEXT
28.     FOR m = 0 TO 17: m1 = 17 - m
29.         f1 = (m + m1 * r) / 18: f2 = (m + m1 * g) / 18: f3 = (m + m1 * b) / 18: c(i) = rgbf(f1, f2, f3): i = i + 1
30.     NEXT
31.     FOR m = 0 TO 17: m1 = 17 - m
32.         f1 = (m1 + m * r) / 18: f2 = (m1 + m * g) / 18: f3 = (m1 + m * b) / 18: c(i) = rgbf(f1, f2, f3): i = i + 1
33.     NEXT
34.     FOR m = 0 TO 17: m1 = 17 - m
35.         f1 = (m1 * r) / 18: f2 = (m1 * g) / 18: f3 = (m1 * b) / 18: c(i) = rgbf(f1, f2, f3): i = i + 1
36.     NEXT
37. NEXT
38.  
39. FOR n = 0 TO 2
40.     p(n).x = RND * xmax: p(n).y = RND * ymax: p(n).dx = .25 * (RND * 2 - 1): p(n).dy = 2 * (RND * 2 - 1)
41.     f(n) = .015
42. NEXT
43.  
44. DO
45.     CLS
46.     IF INKEY$ = CHR$(27) THEN END
47.     FOR i = 0 TO 6
48.         p(i).x = p(i).x + p(i).dx
49.         IF p(i).x > xmax - 500 OR p(i).x < 500 THEN p(i).dx = -p(i).dx
50.         p(i).y = p(i).y + p(i).dy
51.         IF p(i).y > ymax + 2000 OR p(i).y < -200 THEN p(i).dy = -p(i).dy
52.     NEXT
53.     FOR y = 0 TO ymax - 1 STEP 2
54.         FOR x = 0 TO xmax - 1 STEP 2
55.             d = 0
56.             FOR n = 0 TO 2
57.                 dx = x - p(n).x: dy = y - p(n).y
58.                 k = SQR(dx * dx + dy * dy)
59.                 d = d + (SIN(k * f(n)) + 1) / 2
60.             NEXT n: d = d * 60
61.             LINE (x, y)-STEP(2, 2), c(d), BF
62.         NEXT
63.     NEXT
64.     _DISPLAY
65.     _LIMIT 20
66. LOOP
67.  
68. FUNCTION rgbf~& (n1, n2, n3)
69.     rgbf~& = _RGB32(n1 * 255, n2 * 55, n3 * 55)
70. END FUNCTION
71.  
72.  

[bplus]

Do you happen to know who made the original code in SmallBasic where you got this from? I ask because I want to add their name to a comment in the code thanking them for posting it on a forum.

Hi Ken,
from reply #18 I left link to SmallBASIC Library and source code name

The program I (B+) translated and modified looked like this (plasmajvsh.bas from SmallBASIC code library,
http://smallbasic.github.io/pages/samples.html

That's all I know about it, that should be more than enough.

[SierraKen]

Thanks B+ :). So for the credit I have this now:

'Lava Lamp
_TITLE "Lava Lamp"
'This program creates a plasma surface, which looks oily or silky.
'By SmallBasic code plasmajvsh.bas from here: http://smallbasic.github.io/pages/samples.html
'and mods by B+ and SierraKen from the QB64.org forum.

[bplus]

Last night we played around with a Nautilus like Shell program from JB forum, yeah more eye candy but can you see the little gem in this code that may have great effect on the Plasmatic effect?

Code: QB64: [Select]

1. _TITLE "Shell of another color" 'b+2020-01-25
2. 'inspired by "shell-like thing" by tsh73 Jan 2020 at JB
3.  
4. SCREEN _NEWIMAGE(600, 600, 32)
5. DIM x(1600), y(1600), c AS _UNSIGNED LONG
6. cx = 300: cy = 300
7. FOR a = 0 TO _PI(8) STEP _PI(2 / 400) ' load x, y arrays
8.     x(i) = cx + ra * COS(a): y(i) = cy + ra * SIN(a)
9.     dr = dr + 1 / 4800: ra = ra + dr
10.     PSET (x(i), y(i)), &HFFFFFFFF
11.     i = i + 1
12. NEXT
13. WHILE 1
14.     r = RND: G = RND: B = RND: PN = 0
15.     FOR i = 0 TO 399 'this block is a cheat to fill half a hole!
16.         dx = x(i + 400) - x(i): dy = y(i + 400) - y(i)
17.         dist = SQR(dx * dx + dy * dy)
18.         dx = dx / dist: dy = dy / dist
19.         PN = PN + .5
20.         FOR j = 0 TO dist
21.             shade = 1 - ((dist / 2 - j + 1 / 2) / (dist / 2)) ^ 2
22.             c = _RGB32(shade * INT(127 + 127 * SIN(r * PN)), shade * INT(127 + 127 * SIN(G * PN)), shade * INT(127 + 127 * SIN(B * PN)))
23.             fcirc cx + j * dx, cy + j * dy, 1, c
24.         NEXT
25.     NEXT
26.     PN = PN - 200
27.     FOR i = 0 TO 1199
28.         dx = x(i + 400) - x(i): dy = y(i + 400) - y(i)
29.         dist = SQR(dx * dx + dy * dy)
30.         dx = dx / dist: dy = dy / dist
31.         PN = PN + .5
32.         FOR j = 0 TO dist
33.             shade = 1 - ((dist / 2 - j + 1 / 2) / (dist / 2)) ^ 2
34.             c = _RGB32(shade * INT(127 + 127 * SIN(r * PN)), shade * INT(127 + 127 * SIN(G * PN)), shade * INT(127 + 127 * SIN(B * PN)))
35.             fcirc x(i) + j * dx, y(i) + j * dy, 2, c
36.         NEXT
37.     NEXT
38.     _DISPLAY
39.     _DELAY 2
40. WEND
41.  
42. 'from Steve Gold standard
43. SUB fcirc (CX AS INTEGER, CY AS INTEGER, R AS INTEGER, C AS _UNSIGNED LONG)
44.     DIM Radius AS INTEGER, RadiusError AS INTEGER
45.     DIM X AS INTEGER, Y AS INTEGER
46.     Radius = ABS(R): RadiusError = -Radius: X = Radius: Y = 0
47.     IF Radius = 0 THEN PSET (CX, CY), C: EXIT SUB
48.     LINE (CX - X, CY)-(CX + X, CY), C, BF
49.     WHILE X > Y
50.         RadiusError = RadiusError + Y * 2 + 1
51.         IF RadiusError >= 0 THEN
52.             IF X <> Y + 1 THEN
53.                 LINE (CX - Y, CY - X)-(CX + Y, CY - X), C, BF
54.                 LINE (CX - Y, CY + X)-(CX + Y, CY + X), C, BF
55.             END IF
56.             X = X - 1
57.             RadiusError = RadiusError - X * 2
58.         END IF
59.         Y = Y + 1
60.         LINE (CX - X, CY - Y)-(CX + X, CY - Y), C, BF
61.         LINE (CX - X, CY + Y)-(CX + X, CY + Y), C, BF
62.     WEND
63. END SUB
64.  
65.  

I haven't tried to recode Plasmatic yet but I am pretty sure it will be a very nice modification.

[bplus]

Yes the new color options are no longer so flat looking, so here is best yet Plasmatic 5:

Code: QB64: [Select]

1. OPTION _EXPLICIT
2. _TITLE "Plasmatic 5 Color Shading" ' b+ 2020-01-26
3. ' Hopefully this will add shading to the new color options found in Pasmatic 4.
4.  
5. CONST xxmax = 800, yymax = 600, xmax = 900, ymax = 740, xoff = (xmax - xxmax) \ 2, yoff = (ymax - yymax) \ 2
6. TYPE xy
7.     x AS SINGLE
8.     y AS SINGLE
9.     dx AS SINGLE
10.     dy AS SINGLE
11. END TYPE
12. SCREEN _NEWIMAGE(xmax, ymax, 32)
13. _SCREENMOVE 250, 0
14. RANDOMIZE TIMER
15. DIM c(360) AS _UNSIGNED LONG, p(6) AS xy, f(6)
16. DIM i AS INTEGER, m AS INTEGER, n AS INTEGER, mode AS INTEGER, k$, t, x, y, d, dx, dy, dist, s
17. DIM r AS INTEGER, g AS INTEGER, b AS INTEGER, r1 AS INTEGER, g1 AS INTEGER, b1 AS INTEGER, r2 AS INTEGER, g2 AS INTEGER, b2 AS INTEGER
18.  
19. restart: 'select rgb1 and rgb2 based on mode of color mixing
20. IF mode = 0 THEN 'new plasma option ANY color for border and ANY color for middle
21.     r1 = RND * 255: g1 = RND * 255: b1 = RND * 255: r2 = RND * 255: g2 = RND * 255: b2 = RND * 255
22. ELSE ' traditional high contrast plasma black borders, white centers
23.     r1 = 0: g1 = 0: b1 = 0: r2 = 255: g2 = 255: b2 = 255 'regular Plasma
24. END IF
25.  
26. ' create 6 x 60 bands of color palette based on coloring mode (rgb1 set and rgb2 set)
27. FOR i = 0 TO 360
28.     IF i MOD 60 = 0 THEN r = RND * 255: g = RND * 255: b = RND * 255
29.     m = i MOD 60
30.     s = 1 - ((30 - m + .5) / 30) ^ 2
31.     SELECT CASE m
32.         CASE IS < 15: c(i) = midInk(s * r1, s * g1, s * b1, s * r, s * g, s * b, m / 15) '        1st stage increase rgb1 towards rgb color in 15 steps
33.         CASE IS < 30: c(i) = midInk(s * r, s * g, s * b, s * r2, s * g2, s * b2, (m - 15) / 15) ' 2nd stage increase rgb color towards rgb2 set in 15 steps
34.         CASE IS < 45: c(i) = midInk(s * r2, s * g2, s * b2, s * r, s * g, s * b, (m - 30) / 15) ' 3rd stage decrease rgb2 color back to rgb color in 15 steps
35.         CASE IS < 60: c(i) = midInk(s * r, s * g, s * b, s * r1, s * g1, s * b1, (m - 45) / 15) ' 4th and finally decrease rgb back to starting rgb1 set in 15 steps
36.     END SELECT
37. NEXT
38.  
39. ' behind the scenes variables for motion, weighting and shaping color mixing
40. FOR n = 0 TO 5
41.     p(n).x = RND * xmax: p(n).y = RND * yymax: p(n).dx = RND * 2 - 1: p(n).dy = RND * 2 - 1
42.     f(n) = .1 * RND
43. NEXT
44.  
45. 'screen labeling 3 lines for title above, 1 line instructions below
46. CLS
47. IF mode = 0 THEN
48.     yCP yoff - 60, "New Color Options for Plasma:"
49. ELSE
50.     yCP yoff - 60, "Traditional High Contrast Plasma: Black Borders and White Centers"
51. END IF
52. yCP yoff - 40, "Shaded Borders: RGB(" + TS$(r1 \ 1) + ", " + TS$(g1 \ 1) + ", " + TS$(b1 \ 1) + ")"
53. yCP yoff - 20, "Centers: RGB(" + TS$(r2 \ 1) + ", " + TS$(g2 \ 1) + ", " + TS$(b2 \ 1) + ")"
54. yCP yoff + yymax + 10, "Press t to toggle between Traditional and New Color Options Plasma"
55. yCP yoff + yymax + 30, "Press spacebar to get a new color set."
56.  
57. WHILE _KEYDOWN(27) = 0
58.     k$ = INKEY$
59.     IF k$ = " " THEN GOTO restart
60.     IF k$ = "t" THEN mode = 1 - mode: GOTO restart
61.     t = TIMER(.001)
62.     FOR i = 0 TO 5
63.         p(i).x = p(i).x + p(i).dx
64.         IF p(i).x > xxmax THEN p(i).dx = -p(i).dx: p(i).x = xxmax
65.         IF p(i).x < 0 THEN p(i).dx = -p(i).dx: p(i).x = 0
66.         p(i).y = p(i).y + p(i).dy
67.         IF p(i).y > xxmax THEN p(i).dy = -p(i).dy: p(i).y = yymax
68.         IF p(i).y < 0 THEN p(i).dy = -p(i).dy: p(i).y = 0
69.     NEXT
70.     FOR y = 0 TO yymax - 1 STEP 2
71.         FOR x = 0 TO xxmax - 1 STEP 2
72.             d = 0
73.             FOR n = 0 TO 5
74.                 dx = x - p(n).x: dy = y - p(n).y
75.                 dist = SQR(dx * dx + dy * dy)
76.                 'dist = _HYPOT(dx, dy)    'this may work faster on another system
77.                 d = d + (SIN(dist * f(n)) + 1) / 2
78.             NEXT n: d = d * 60
79.             LINE (x + xoff, y + yoff)-STEP(2, 2), c(d), BF
80.         NEXT
81.     NEXT
82.     yCP yoff + yymax + 50, SPACE$(50)
83.     yCP yoff + yymax + 50, TS$(INT(1000 * (TIMER(.001) - t))) + " ms per frame"
84.     _DISPLAY
85. WEND
86.  
87. FUNCTION midInk~& (r1%, g1%, b1%, r2%, g2%, b2%, fr##)
88.     midInk~& = _RGBA32(r1% + (r2% - r1%) * fr##, g1% + (g2% - g1%) * fr##, b1% + (b2% - b1%) * fr##, 255)
89. END FUNCTION
90.  
91. SUB yCP (y, s$) 'for xmax pixel wide graphics screen Center Print at pixel y row
92.     _PRINTSTRING ((_WIDTH - LEN(s$) * 8) / 2, y), s$
93. END SUB
94.  
95. FUNCTION TS$ (n AS INTEGER)
96.     TS$ = _TRIM$(STR$(n))
97. END FUNCTION
98.  
99.  

[STxAxTIC]

Heya bplus-

Pretty bang-up job, lots of results crammed into a relatively small amount of code.

Maybe it's my system, or maybe this is a familiar demon from the old plasma days, but it runs slow on my end. This immediately caused me to look at this part:

Code: QB64: [Select]

1.                 dx = x - p(n).x: dy = y - p(n).y
2.                 dist = SQR(dx * dx + dy * dy)
3.                 'dist = _HYPOT(dx, dy)    'this may work faster on another system
4.                 d = d + (SIN(dist * f(n)) + 1) / 2

Two things that probably don't need pointing out, but here they are:

1) You can speed things up by using a lookup table for the SIN() function. Even a crappy lookup table with an interpolation formula will certainly get you the precision you need, but probably be faster than the native SIN() function. They did this in the old days, I can only imagine it works now.

2) I see you fiddled with different ways to calculate the square root. Two-and-a-half thoughts on this: (1) Just leave it squared, you'll probably get the same kind of results anyway. (1a) Leave it squared but modify f(n) to compensate, if you can. (2) Use a lookup table for square roots. Linear interpolation for the in-between values will only be arithmetic and won't ever involve a square root in the loop.

I suppose you can also optimize in the direction of _MEM, but it becomes very nontransparent after that.

The third option is I upgrade my system........

[bplus]

Hi STxAxTIC,

How slow is it running for you?

More options for speed,
- decrease xxmax, yymax those are the inner screen dimensions
- decrease number n of points, really 2 or 3 are enough each point is another cycle over the whole drawing area.
- increase step size on x, y through xxmax and yymaxx
I had to employ all these for SmallBASIC which is only interpreted Basic.

I don't think tables would be practical (800 * 600)^2 x1, y1, x2, y2 the distance from any point to any other = 2.304*10^11 values.

I will try the suggestion of not squaring.