Question on VIEW & WINDOW in 32 bit display

[OldMoses]

I've been working on a graphic vector movement display with full code at:
https://www.qb64.org/forum/index.php?topic=1429.0

I set up a display window thus

A& = _NEWIMAGE(1200, 700, 32)

In a later SUB I do this:

    _DEST A&
    CLS
    c = 3 'color variable (local)

    '0=black,1=blue,2=green,3=aqua,4=red,5=purple,6=brown,7=white
    '8=gray, +8=bright color, except 14=yellow,

    COLOR clr&(c) '                                                    color array set up in main module

    VIEW (560, 18)-(1180, 638), , clr&(c) '                     set graphics port on right side w/box
    WINDOW (-1000, 1000)-(1000, -1000) '                        set relative cartesian coords

Now any graphics commands go in the box, just as I wanted, but now I would like to set up another window next to it to contain mouse click targets without affecting the existing graphic port. This code was originally from SCREEN 12

I've tried invoking VIEW with new position parameters, and by itself. The former does funny things to the existing port, while the later has no effect and graphic commands still go in the existing port. Obviously, I'm either missing something or what I'm trying to do cannot be done in this mode. I'm not very experienced with graphics work of this magnitude.

Should I rather be just doing a series of _PUTIMAGEs for mouse buttons instead?

Any solutions or insights are appreciated.

[TempodiBasic]

Hi OldMoses

here my little contribution to your issue...
I have never used intensively this tecnique but I know it in theory so here a little code example to let you see how you can combine viewport , resetting of cohordinates and graphic instructions

Code: QB64: [Select]

1. SCREEN 12
2. ' Graphic viewport with absolute cohordinate
3. VIEW SCREEN(1, 1)-(200, 50), 2, 7 ' viewport1
4. MakeG ' this draws in absolute cohordinates
5. VIEW SCREEN(1, 51)-(200, 100), 12, 14 ' viewport2
6. MakeG ' also this draws at absolute cohordinates  --> graphic is made on previous port
7. VIEW (1, 101)-(200, 150), 1, 4 ' viewport3
8. MakeG ' this draws at relative cohordinate of the viewport
9. VIEW (201, 1)-(400, 50), 3, 5 ' viewport4
10. WINDOW SCREEN(1, 1)-(200, 50) ' this set a different cohordinates that mimic those of viewport1
11. MakeG ' this draws in relative cohordinates
12.  
13. END
14.  
15. SUB MakeG
16.     LINE (10, 2)-(60, 18), 15, BF
17.     CIRCLE (50, 30), 10, 7
18. END SUB

God Coding

[bplus]

Hi OldMoses,

With a handle for the image, you could work on image updates independently while screen is showing using _SOURCE and _DEST then use _PUTIMAGE to show contents of image anywhere, anytime on current screen such that your image works like a view window.

EDIT: well not like a view window that is stuck and that code works around, more like a floating view port window over the top of current screen. With _PUTIMAGE you have much more flexibility of where to put it and how big to blow it up or shrink or cover whole screen. Use _PRINTSTRING  (like a graphics PRINT) to control where you want to put text to stay away from where you plan to show the image.

[OldMoses]

Hi OldMoses

here my little contribution to your issue...
I have never used intensively this tecnique but I know it in theory so here a little code example to let you see how you can combine viewport , resetting of cohordinates and graphic instructions

I tried putting this in a 32 bit screen and it came up black, so apparently there's a problem with my approach to displaying my old SCREEN 12 work in the new 32 bit screen.

With a handle for the image, you could work on image updates independently while screen is showing using _SOURCE and _DEST then use _PUTIMAGE to show contents of image anywhere, anytime on current screen such that your image works like a view window.

EDIT: well not like a view window that is stuck and that code works around, more like a floating view port window over the top of current screen.

This sounds like the solution, and shouldn't take much code if I understand it right. I must unlearn what I have learned, lo these many years past.

Thanks, this helps refocus my thinking.

[bplus]

Graphics with 32 in the _NEWIMAGE command needs RGB32 colors, so all those numbers 0 - 15 in screen 12 look like Black in graphics 32 screen.

Here is Screen 12 colors with equivalent RGB32 constants (but I may have changed values to my preferences):

Code: QB64: [Select]

1. DIM SHARED qb(15)   '<<<<<<<<<< to set up array
2. qb(0) = &HFF000000
3. qb(1) = &HFF000088
4. qb(2) = &HFF008800
5. qb(3) = &HFF008888
6. qb(4) = &HFF880000
7. qb(5) = &HFF880088
8. qb(6) = &HFF888800
9. qb(7) = &HFFCCCCCC
10. qb(8) = &HFF888888
11. qb(9) = &HFF0000FF
12. qb(10) = &HFF00FF00
13. qb(11) = &HFF00FFFF
14. qb(12) = &HFFFF0000
15. qb(13) = &HFFFF00FF
16. qb(14) = &HFFFFFF00
17. qb(15) = &HFFFFFFFF
18.  

or learn RGB32: _RGB32(255, 0, 0) is red
_RGB32(0, 0, 255) is blue
_RGB32(255, 255, 0) is yellow
and many many many more combos!

I am sure Johnno or Steve have a more authentic set of color equivalents for 0-15.

Here is some code you can diddle with colors even create constants to paste into code:
https://www.qb64.org/forum/index.php?topic=1363.0


Oh if you'd rather do it by color name here is this:

Code: QB64: [Select]

1.  
2. 'easy to remember color names?
3. CONST blackl = &HFF000000
4. CONST bluel = &HFF000088
5. CONST greenl = &HFF008800
6. CONST cyanl = &HFF008888
7. CONST redl = &HFF880000
8. CONST purplel = &HFF880088
9. CONST yellowl = &HFF888800
10. CONST whitel = &HFFCCCCCC
11. CONST blackh = &HFF888888
12. CONST blueh = &HFF0000FF
13. CONST greenh = &HFF00FF00
14. CONST cyanh = &HFF00FFFF
15. CONST redh = &HFFFF0000
16. CONST purpleh = &HFFFF00FF
17. CONST yellowh = &HFFFFFF00
18. CONST whiteh = &HFFFFFFFF
19.  

l stands for low or dark, h for high or light, change names to what you prefer (and values for that matter!)


Oh wiki has a screen 12 code sample showing the numbers accurately:

Code: QB64: [Select]

1. SCREEN 12
2. alpha$ = "FF" 'solid alpha colors only
3. OUT &H3C8, 0: OUT &H3C9, 0: OUT &H3C9, 0: OUT &H3C9, 20 'set black background to dark blue
4. PRINT "Attribute = Hex value      Red          Green         Blue "
5. PRINT
6. COLOR 7
7. FOR attribute = 0 TO 15
8.   OUT &H3C7, attribute 'set color attribute to read
9.   red$ = HEX$(INP(&H3C9) * 4) 'convert port setting to 32 bit values
10.   grn$ = HEX$(INP(&H3C9) * 4)
11.   blu$ = HEX$(INP(&H3C9) * 4)
12.   IF LEN(red$) = 1 THEN red$ = "0" + red$ '2 hex digits required
13.   IF LEN(grn$) = 1 THEN grn$ = "0" + grn$ 'for low or zero hex values
14.   IF LEN(blu$) = 1 THEN blu$ = "0" + blu$
15.   hex32$ = "&H" + alpha$ + red$ + grn$ + blu$
16.   _PALETTECOLOR attribute, VAL(hex32$) 'VAL converts hex string to a LONG 32 bit value
17.   IF attribute THEN COLOR attribute 'exclude black color print
18.   PRINT "COLOR" + STR$(attribute) + " = " + hex32$, red$, grn$, blu$ 'returns closest attribute
19. NEXT
20.  

[OldMoses]

Doh!! I forgot about the colors. You'd think I would have learned by now, as many times as I've run into that issue.

I did set up a 16 color array in my program, and use it often, but forgot to add one to TempodiBasic's example. I usually use clr&(x) to hold the long values, where the x is the corresponding color in SCREEN 0 thru whatever.

Blundering along...

[TempodiBasic]

to complete the above my code here the sequential difference between the old and the new way to use  a piece of the screen as a different screen with its own cohordinates

Code: QB64: [Select]

1. SCREEN 12
2. ' Graphic viewport with absolute cohordinate
3. VIEW SCREEN(1, 1)-(200, 50), 2, 7 ' viewport1
4. MakeG ' this draws in absolute cohordinates
5. VIEW SCREEN(1, 51)-(200, 100), 12, 14 ' viewport2
6. MakeG ' also this draws at absolute cohordinates  --> graphic is made on previous port
7. VIEW (1, 101)-(200, 150), 1, 4 ' viewport3
8. MakeG ' this draws at relative cohordinate of the viewport
9. VIEW (201, 1)-(400, 50), 3, 5 ' viewport4
10. WINDOW SCREEN(1, 1)-(200, 50) ' this set a different cohordinates that mimic those of viewport1
11. MakeG ' this draws in relative cohordinates
12.  
13. VIEW
14. LOCATE 24, 1
15. PRINT "Press a key to see the emulation of these graphic with _QB64 keywords": SLEEP
16. CLS
17. ' porting to 32bit with canvas surface to draw
18. A& = _NEWIMAGE(640, 480, 32) ' main viewport= the whole screen
19. B& = _NEWIMAGE(200, 50, 32) 'viewport1
20. C& = _NEWIMAGE(200, 50, 32) 'viewport2
21. D& = _NEWIMAGE(200, 50, 32) 'viewport3
22. E& = _NEWIMAGE(200, 50, 32) 'viewport4
23.  
24. ' Bplus colors for 32 bit similar to screen 12
25. DIM SHARED qb(15) '<<<<<<<<<< to set up array
26. qb(0) = &HFF000000
27. qb(1) = &HFF000088
28. qb(2) = &HFF008800
29. qb(3) = &HFF008888
30. qb(4) = &HFF880000
31. qb(5) = &HFF880088
32. qb(6) = &HFF888800
33. qb(7) = &HFFCCCCCC
34. qb(8) = &HFF888888
35. qb(9) = &HFF0000FF
36. qb(10) = &HFF00FF00
37. qb(11) = &HFF00FFFF
38. qb(12) = &HFFFF0000
39. qb(13) = &HFFFF00FF
40. qb(14) = &HFFFFFF00
41. qb(15) = &HFFFFFFFF
42.  
43. IF A& < -1 THEN SCREEN A& ' it creates the screen
44. _DEST B& ' set canvas viewport1
45. PAINT (1, 1), qb(2)
46. LINE (1, 1)-(200, 50), qb(7), B
47. MakeG2 ' this draws on viewport1
48. _PUTIMAGE (1, 1), B&, A& ' this put on screen (whole original viewport) canvas1
49.  
50. _DEST C& ' set canvas viewport2
51. PAINT (1, 1), qb(12)
52. LINE (1, 1)-(200, 50), qb(14), B
53. MakeG2 ' this draws on viewport2 . Note here there is no SCREEN option to use absolute cohordinates of screen
54. _PUTIMAGE (1, 51), C&, A& ' this put on screen (whole original viewport) canvas2
55.  
56. _DEST D& ' set canvas viewport3
57. PAINT (1, 1), qb(1)
58. LINE (1, 1)-(200, 50), qb(4), B
59. MakeG2 ' this draws on viewport3
60. _PUTIMAGE (1, 101), D&, A& ' this put on screen (whole original viewport) canvas3
61.  
62. _DEST E& ' set canvas viewport4
63. PAINT (1, 1), qb(3)
64. LINE (1, 1)-(200, 50), qb(5), B
65. MakeG2 ' this draws on viewport4
66. _PUTIMAGE (201, 1), E&, A& ' this put on screen (whole original viewport) canvas4
67.  
68. _DEST A&
69. LOCATE 24, 1
70. PRINT "Press a key to quit the emulation of these graphic with _QB64 keywords": SLEEP
71. CLS
72.  
73. END
74.  
75. SUB MakeG
76.     LINE (10, 2)-(60, 18), 15, BF
77.     CIRCLE (50, 30), 10, 7
78. END SUB
79.  
80. SUB MakeG2
81.     LINE (10, 2)-(60, 18), qb(15), BF
82.     CIRCLE (50, 30), 10, qb(7)
83. END SUB
84.  

as you have noted by comments and running the code in the old mode (view and window) the SCREEN option of command VIEW let  re-drawing the same picture again on  viewport1 at place of drawing on viewport2... this kind of error is not possible using canvas!
Surely you can resize the scale of cohordinates for each canvas and this affects the graphic instructions made in it

try to add this code  just after a definition of a viewport/canvas  with _DEST

Code: QB64: [Select]

1. WINDOW (1, 1)-(100, 50)

running code you can see how picture drawn is changed in size!

[OldMoses]

That's what I'm looking to do, only in my case I'm doing a 620x620 image with a relative coordinate system from -1000 to 1000 in both axis. Putting that to the right hand side of a 1200 x 700 screen. I've now abandoned the idea of a view window in A& and am opting for a putimage approach. Only now I can't get it to accept the putimage command.

In the main module:
A& = _NEWIMAGE(1200, 700, 32)
SS& = _NEWIMAGE(620, 620, 32)
SCREEN A&

Then it's into the SUBs were:
_DEST SS&
VIEW (1, 1)-(618, 618), clr&(0), clr&(3) 'the border wouldn't show unless I left a pixel for it
WINDOW (-1000, 1000)-(1000, -1000)

Draw all the stuff I need to draw in SS&
Then:

_PUTIMAGE (560, 18), SS&, A&

Whereupon everything is drawn properly, but instead of floating on the right side with the upper left at {560, 18}, it is up in the left corner and the program crashes with a illegal function call error pointing to whatever line the putimage is in.

[bplus]

Hi OldMoses,

Did you set _DEST back to A& before _PUTIMAGE?

Code: QB64: [Select]

1.  
2. A& = _NEWIMAGE(1200, 700, 32)
3. SS& = _NEWIMAGE(620, 620, 32)
4. SCREEN A&
5.  
6.  
7. _DEST SS&
8. VIEW (1, 1)-(618, 618), clr&(0), clr&(3) 'the border wouldn't show unless I left a pixel for it
9. WINDOW (-1000, 1000)-(1000, -1000)
10. FOR r = 1 TO 1100 STEP 10
11.     CIRCLE (0, 0), r
12. NEXT
13.  
14.  
15. '_DEST A& 'commented out it draws nothing but no error, with comment it draws on screen
16. CLS
17. _PUTIMAGE (100, 100), SS&, A&
18.  
19.  

[OldMoses]

Hi OldMoses,

Did you set _DEST back to A& before _PUTIMAGE?

Yes, I thought that might be it, but it doesn't seem to make any difference. I know I must be missing something, because I played with the process in some practice code and had no problems, but something is tripping it up in my main project.

[OldMoses]

Found it!

Another stupid oversight on my part. I didn't DIM SHARED the image handles.

Funny how such simple things will stop you cold for hours or days...

[bplus]

Found it!

Another stupid oversight on my part. I didn't DIM SHARED the image handles.

Funny how such simple things will stop you cold for hours or days...

Ha! makes you so happy you forget all the misery and frustration from the hour before! Guess I've been down that path a few times. :)

[OldMoses]

Ha! makes you so happy you forget all the misery and frustration from the hour before! Guess I've been down that path a few times. :)

I got two happys for the price of one out of this bug.

I found out that when I put images in a _DEST image I also have to SCREEN that image or it dumps the sub images in the outer screen unpredictably. I think this one is ready to push to the program thread finally.