Convert Decimal to Fraction

[Pete]

Funny, never thought of myself as a string variable. I'm more of a numeric type, although I do get parsed off at times.

Pete

[Jack002]

That's wonderful. Basically what I wrote in CLISP many years ago.
Well done.

[bplus]

R notation changed back to the redundant " repeat " form. This makes it easier to convert the R notation decimal number back to the fraction form if the repeat section is not too long (= over 14 digits).

The trick to converting a repeating decimal number to fraction is to align a second repeating section over the first by multiplying by some power of 10, p,  = length of repeating section. This way when you subtract  x * 10 ^ p - x = a definite finite decimal, d st.

x * (10 ^ p - 1) = d
then x = d / (10 ^ p - 1) a fraction!

QB64 can only process p up to around 14 digits in the repeating section of the decimal.

Code: QB64: [Select]

1. _TITLE "n slash d to R notation and back again" '2019-04-24
2. ' from:"Decimal Expansion of Division without Dividing  by bplus 2017-12-03"
3. ' dove tailing Adrians and my recent dividing programs
4.  
5. ' 2019-04-24
6. ' I want to isolate the repeated section immediately not write the fraction out and then repeat the repeated section
7. ' not 1/6 = .16R6 >>> but .1R6
8.  
9. 'hmm... look like have to cycle through twice to get the length of the repeat section
10. ' but before returning backup to start of repeat section insert the R where it starts the first time
11. ' and end it where " repeat " starts.
12.  
13. '2019-04-24
14. ' just for kicks, convert the R notation back to fraction if possible.
15. ' Had to revert back to the redundant " repeat " form of R notation.
16.  
17. RANDOMIZE TIMER
18. DEFLNG A-Z
19. DO
20.     PRINT: PRINT "Enter 2 integers < 3200, numerator / denominator, 0's quit, don't forget / "
21.     INPUT nd$
22.     slash = INSTR(nd$, "/")
23.     IF slash THEN
24.         dvsr = VAL(MID$(nd$, slash + 1))
25.         IF dvsr = 0 THEN PRINT "Divisor is 0, bye.": END
26.         numerator = VAL(MID$(nd$, 1, slash - 1))
27.         IF numerator = 0 THEN PRINT "Numerator is 0, bye.": END
28.     ELSE
29.         PRINT "No slash found, bye.": END
30.     END IF
31.     CLS
32.     d$ = divide$(numerator, dvsr)
33.     PRINT numerator; " / "; dvsr; " = "; d$
34.  
35.     'and now arttemp"t to convert back to fraction
36.     PRINT: PRINT "Check if can convert back to fraction:"
37.     result$ = convertRnotation2Fraction$(d$)
38.     IF result$ <> "" THEN PRINT result$
39. LOOP
40.  
41. FUNCTION convertRnotation2Fraction$ (rNotedDecimal$)
42.     'check if R in the decimal
43.     dotPos = INSTR(rNotedDecimal$, ".")
44.     IF dotPos = 0 THEN convertRnotation2Fraction$ = rNotedDecimal$: EXIT FUNCTION
45.     RPos = INSTR(rNotedDecimal$, " repeat ")
46.     IF RPos = 0 THEN convertRnotation2Fraction$ = convert2Fraction$(rNotedDecimal$): EXIT FUNCTION
47.  
48.     'still here? we have an R and a decimal
49.     whole$ = MID$(rNotedDecimal$, 1, dotPos - 1)
50.     IF VAL(whole$) = 0 THEN whole$ = ""
51.  
52.     p = LEN(rNotedDecimal$) - RPos - LEN(" repeat ") + 1
53.     PRINT "Debug: repeat length ="; p
54.     IF p > 15 THEN
55.         PRINT "The length of the repeat section of: "
56.         PRINT rNotedDecimal$
57.         PRINT " is too long to convert back to fraction."
58.         EXIT FUNCTION
59.     END IF
60.  
61.     dec$ = MID$(rNotedDecimal$, dotPos)
62.     PRINT "Debug: converting dec$ "; dec$
63.  
64.     'remove " repeat "
65.     RPos = INSTR(dec$, " repeat ")
66.     dec1$ = MID$(dec$, 1, RPos - 1) + MID$(dec$, RPos + LEN(" repeat "))
67.     dec2$ = MID$(dec$, 1, RPos - 1)
68.     PRINT "Debug: dec1$ (double repeat), dec2$ (single repeat) = "; dec1$; ", "; dec2$
69.  
70.     'mult by 10^p to get the 2nd repeat part in dec1$ aligned to 1st repeat part  in dec2$
71.     vd1## = VAL(dec1$) * 10 ^ p
72.     vd2## = VAL(dec2$)
73.     n## = vd1## - vd2## 'subtract dec2$ from dec1$
74.  
75.     adj&& = 1 'convert to whole numbers
76.     WHILE n## <> INT(n##)
77.         adj&& = adj&& * 10
78.         n## = n## * 10
79.     WEND
80.  
81.     'reevaluate to avoid rounding errors from crazy floating point math
82.     n1&& = vd1## * adj&& - vd2## * adj&&
83.     PRINT "Debug values: vd1, vd2, adj&&, n1&& (difference * adj&& for whole number):"
84.     PRINT vd1##; ", "; vd2##; ", "; adj&&; ", "; n1&&
85.  
86.     d&& = (10 ^ p - 1) * adj&&
87.     PRINT "Debug: Giant numerator, denominator "; n1&&; ", "; d&& 'giant numbers
88.  
89.     'reduce giant numbers by Gretaest Common Divisor between them
90.     g&& = gcd&&(n1&&, d&&): sn&& = n1&& / g&&: sd&& = d&& / g&&
91.  
92.     convertRnotation2Fraction$ = whole$ + " " + _TRIM$(STR$(sn&&)) + "/" + _TRIM$(STR$(sd&&))
93. END FUNCTION
94.  
95. FUNCTION convert2Fraction$ (decimal$)
96.     dot%% = INSTR(decimal$, ".")
97.     IF dot%% > 0 THEN
98.         whole$ = MID$(decimal$, 1, dot%% - 1)
99.         IF VAL(whole$) = 0 THEN whole$ = ""
100.         p%% = LEN(decimal$) - dot%%
101.         n&& = VAL(MID$(decimal$, dot%% + 1))
102.         d&& = 10 ^ p%%
103.         g&& = gcd&&(n&&, d&&): sn&& = n&& / g&&: sd&& = d&& / g&&
104.         convert2Fraction$ = whole$ + " " + _TRIM$(STR$(sn&&)) + "/" + _TRIM$(STR$(sd&&))
105.     ELSE
106.         convert2Fraction$ = decimal$
107.     END IF
108. END FUNCTION
109.  
110. FUNCTION gcd&& (a&&, b&&)
111.     'a and b will be changed unless make copies
112.     c&& = a&&: d&& = b&&
113.     WHILE c&& <> 0 AND d&& <> 0
114.         IF c&& > d&& THEN c&& = c&& MOD d&& ELSE d&& = d&& MOD c&&
115.     WEND
116.     gcd&& = c&& + d&&
117. END FUNCTION
118.  
119.  
120. FUNCTION divide$ (n, d)
121.     'n = original product or numerator (preserve value of n)
122.     'd = divisor  (also preserve value)
123.     c = n 'copy of n to be reduced until <= d, c will be the remainder part of division
124.     a = 0 'a is for answer or accumulate, the integer part of the division result
125.  
126.     'find lowest power of 10 such that: d * 10^p > n
127.     p = 0 'power of 10
128.     WHILE d * (10 ^ p) < n
129.         p = p + 1
130.     WEND
131.     WHILE c >= d
132.         IF c = d THEN a = a + 1: c = 0: EXIT WHILE
133.         p = p - 1
134.         IF p >= 0 THEN
135.             m = 0
136.             WHILE d * m * 10 ^ p < c
137.                 m = m + 1
138.             WEND
139.             m = m - 1
140.             c = c - d * m * 10 ^ p
141.             a = a + m * 10 ^ p
142.         END IF
143.     WEND
144.  
145.     'Now for the decimal expansion isolating the repeating part if one
146.     IF c <> 0 THEN
147.         DIM b(d)
148.         b$ = "."
149.         WHILE c <> 0
150.  
151.             'emergency bug out!
152.             loopct = loopct + 1 'loop count should not exceed 1000 for numbers I am testing
153.             IF loopct > 1000 THEN PRINT "Error: loop too long, bugging out! ": GOTO skip
154.  
155.             'track repeats  b() tracks been here once, b2() tracks been here twice
156.             IF b(c) = 1 THEN 'been here!
157.                 IF rFlag = 1 THEN 'been here twice!
158.                     IF b2(c) = 1 THEN EXIT WHILE 'strike 3, we're out of here
159.                     b2(c) = 1
160.                 ELSE
161.                     rFlag = 1
162.                     DIM b2(d)
163.                     b$ = b$ + " repeat "
164.                     b2(c) = 1
165.                 END IF
166.             ELSE
167.                 b(c) = 1
168.             END IF
169.  
170.             'c was last remainder, mult by 10 and see if some m * d > can reduce it
171.             tc = 10 * c
172.             flag = 0
173.             FOR m = 0 TO 9
174.                 IF ((tc - m * d) >= 0) AND ((tc - (m + 1) * d) < 0) THEN
175.                     flag = 1: b$ = b$ + LTRIM$(STR$(m))
176.                     EXIT FOR
177.                 END IF
178.             NEXT
179.             IF flag = 0 THEN b$ = b$ + "0": m = 0
180.             c = tc - d * m
181.         WEND
182.     END IF
183.  
184.     'OK either d divided n eventually or there is a repeated pattern recorded in b$
185.     skip: '< needed for debugging
186.     r$ = STR$(a)
187.     IF b$ <> "" THEN r$ = r$ + b$
188.     divide$ = r$
189. END FUNCTION
190.  
191.  

[Jack002]

I crashed it with 1/62
[edit]
No, I think its just me. I am not on the new version yet. I replaced _trim$ with ltrim$. Seems that didn't work.

[bplus]

I crashed it with 1/62
[edit]
No, I think its just me. I am not on the new version yet. I replaced _trim$ with ltrim$. Seems that didn't work.

Hi Jack002,

Oh! looks like I was allowing repeat sections up to 15 because 1/62 was 15. OK on my system QB64 v1.3 on Windows 10,   the code works and arrives back at 1/62.

[Jack002]

I'm on V 1.2, I need to get the new 1.3 version installed.
(all the posts here seem to use the new functions of 1.3, so this version is no good for any of those)

[bplus]

I'm on V 1.2, I need to get the new 1.3 version installed.
(all the posts here seem to use the new functions of 1.3, so this version is no good for any of those)

I think _TRIM$ is the only new function I am using from v1.3 and replacing it with LTRIM$ should be fine, the only thing it is doing is formatting the output display, it shouldn't interfere with main code. (Though I don't want to discourage you from updating. :)

Jack002 are you using Windows 10 for OS?

[Jack002]

Yes, windows 10 and I changed _trim$ to ltrim$ and it fails.

[FellippeHeitor]

_TRIM$() stands for RTRIM$(LTRIM$()). Try that.

[bplus]

It's not _trim$ that is causing problem for 1/62 because, I changed them to LTRIM$ and get same results with extra space on right in display.
 

A variable type is different, I can see that in the negative numbers in Jack002's last line of output and also adj&& is different, I have 10, Jack002s' code has way more for adj&&. Perhaps Jack002 changed more than _TRIM$??

I'd like to compare the code Jack002 is running with mine through WinMerge.

[Jack002]

No, all I changed was trim. Here it is just how I ran it
[edit]
I just now changed all my ltrims to rtrim$(ltrim$()), no change. It still does the same thing

Code: QB64: [Select]

1. _TITLE "n slash d to R notation and back again" '2019-04-24
2. ' from:"Decimal Expansion of Division without Dividing  by bplus 2017-12-03"
3. ' dove tailing Adrians and my recent dividing programs
4.  
5. ' 2019-04-24
6. ' I want to isolate the repeated section immediately not write the fraction out and then repeat the repeated section
7. ' not 1/6 = .16R6 >>> but .1R6
8.  
9. 'hmm... look like have to cycle through twice to get the length of the repeat section
10. ' but before returning backup to start of repeat section insert the R where it starts the first time
11. ' and end it where " repeat " starts.
12.  
13. '2019-04-24
14. ' just for kicks, convert the R notation back to fraction if possible.
15. ' Had to revert back to the redundant " repeat " form of R notation.
16.  
17. RANDOMIZE TIMER
18. DEFLNG A-Z
19. DO
20.     PRINT: PRINT "Enter 2 integers < 3200, numerator / denominator, 0's quit, don't forget / "
21.     INPUT nd$
22.     slash = INSTR(nd$, "/")
23.     IF slash THEN
24.         dvsr = VAL(MID$(nd$, slash + 1))
25.         IF dvsr = 0 THEN PRINT "Divisor is 0, bye.": END
26.         numerator = VAL(MID$(nd$, 1, slash - 1))
27.         IF numerator = 0 THEN PRINT "Numerator is 0, bye.": END
28.     ELSE
29.         PRINT "No slash found, bye.": END
30.     END IF
31.     CLS
32.     d$ = divide$(numerator, dvsr)
33.     PRINT numerator; " / "; dvsr; " = "; d$
34.  
35.     'and now arttemp"t to convert back to fraction
36.     PRINT: PRINT "Check if can convert back to fraction:"
37.     result$ = convertRnotation2Fraction$(d$)
38.     IF result$ <> "" THEN PRINT result$
39. LOOP
40.  
41. FUNCTION convertRnotation2Fraction$ (rNotedDecimal$)
42.     'check if R in the decimal
43.     dotPos = INSTR(rNotedDecimal$, ".")
44.     IF dotPos = 0 THEN convertRnotation2Fraction$ = rNotedDecimal$: EXIT FUNCTION
45.     RPos = INSTR(rNotedDecimal$, " repeat ")
46.     IF RPos = 0 THEN convertRnotation2Fraction$ = convert2Fraction$(rNotedDecimal$): EXIT FUNCTION
47.  
48.     'still here? we have an R and a decimal
49.     whole$ = MID$(rNotedDecimal$, 1, dotPos - 1)
50.     IF VAL(whole$) = 0 THEN whole$ = ""
51.  
52.     p = LEN(rNotedDecimal$) - RPos - LEN(" repeat ") + 1
53.     PRINT "Debug: repeat length ="; p
54.     IF p > 15 THEN
55.         PRINT "The length of the repeat section of: "
56.         PRINT rNotedDecimal$
57.         PRINT " is too long to convert back to fraction."
58.         EXIT FUNCTION
59.     END IF
60.  
61.     dec$ = MID$(rNotedDecimal$, dotPos)
62.     PRINT "Debug: converting dec$ "; dec$
63.  
64.     'remove " repeat "
65.     RPos = INSTR(dec$, " repeat ")
66.     dec1$ = MID$(dec$, 1, RPos - 1) + MID$(dec$, RPos + LEN(" repeat "))
67.     dec2$ = MID$(dec$, 1, RPos - 1)
68.     PRINT "Debug: dec1$ (double repeat), dec2$ (single repeat) = "; dec1$; ", "; dec2$
69.  
70.     'mult by 10^p to get the 2nd repeat part in dec1$ aligned to 1st repeat part  in dec2$
71.     vd1## = VAL(dec1$) * 10 ^ p
72.     vd2## = VAL(dec2$)
73.     n## = vd1## - vd2## 'subtract dec2$ from dec1$
74.  
75.     adj&& = 1 'convert to whole numbers
76.     WHILE n## <> INT(n##)
77.         adj&& = adj&& * 10
78.         n## = n## * 10
79.     WEND
80.  
81.     'reevaluate to avoid rounding errors from crazy floating point math
82.     n1&& = vd1## * adj&& - vd2## * adj&&
83.     PRINT "Debug values: vd1, vd2, adj&&, n1&& (difference * adj&& for whole number):"
84.     PRINT vd1##; ", "; vd2##; ", "; adj&&; ", "; n1&&
85.  
86.     d&& = (10 ^ p - 1) * adj&&
87.     PRINT "Debug: Giant numerator, denominator "; n1&&; ", "; d&& 'giant numbers
88.  
89.     'reduce giant numbers by Gretaest Common Divisor between them
90.     g&& = gcd&&(n1&&, d&&): sn&& = n1&& / g&&: sd&& = d&& / g&&
91.  
92.     convertRnotation2Fraction$ = whole$ + " " + LTRIM$(STR$(sn&&)) + "/" + LTRIM$(STR$(sd&&))
93. END FUNCTION
94.  
95. FUNCTION convert2Fraction$ (decimal$)
96.     dot%% = INSTR(decimal$, ".")
97.     IF dot%% > 0 THEN
98.         whole$ = MID$(decimal$, 1, dot%% - 1)
99.         IF VAL(whole$) = 0 THEN whole$ = ""
100.         p%% = LEN(decimal$) - dot%%
101.         n&& = VAL(MID$(decimal$, dot%% + 1))
102.         d&& = 10 ^ p%%
103.         g&& = gcd&&(n&&, d&&): sn&& = n&& / g&&: sd&& = d&& / g&&
104.         convert2Fraction$ = whole$ + " " + LTRIM$(STR$(sn&&)) + "/" + LTRIM$(STR$(sd&&))
105.     ELSE
106.         convert2Fraction$ = decimal$
107.     END IF
108. END FUNCTION
109.  
110. FUNCTION gcd&& (a&&, b&&)
111.     'a and b will be changed unless make copies
112.     c&& = a&&: d&& = b&&
113.     WHILE c&& <> 0 AND d&& <> 0
114.         IF c&& > d&& THEN c&& = c&& MOD d&& ELSE d&& = d&& MOD c&&
115.     WEND
116.     gcd&& = c&& + d&&
117. END FUNCTION
118.  
119.  
120. FUNCTION divide$ (n, d)
121.     'n = original product or numerator (preserve value of n)
122.     'd = divisor  (also preserve value)
123.     c = n 'copy of n to be reduced until <= d, c will be the remainder part of division
124.     a = 0 'a is for answer or accumulate, the integer part of the division result
125.  
126.     'find lowest power of 10 such that: d * 10^p > n
127.     p = 0 'power of 10
128.     WHILE d * (10 ^ p) < n
129.         p = p + 1
130.     WEND
131.     WHILE c >= d
132.         IF c = d THEN a = a + 1: c = 0: EXIT WHILE
133.         p = p - 1
134.         IF p >= 0 THEN
135.             m = 0
136.             WHILE d * m * 10 ^ p < c
137.                 m = m + 1
138.             WEND
139.             m = m - 1
140.             c = c - d * m * 10 ^ p
141.             a = a + m * 10 ^ p
142.         END IF
143.     WEND
144.  
145.     'Now for the decimal expansion isolating the repeating part if one
146.     IF c <> 0 THEN
147.         DIM b(d)
148.         b$ = "."
149.         WHILE c <> 0
150.  
151.             'emergency bug out!
152.             loopct = loopct + 1 'loop count should not exceed 1000 for numbers I am testing
153.             IF loopct > 1000 THEN PRINT "Error: loop too long, bugging out! ": GOTO skip
154.  
155.             'track repeats  b() tracks been here once, b2() tracks been here twice
156.             IF b(c) = 1 THEN 'been here!
157.                 IF rFlag = 1 THEN 'been here twice!
158.                     IF b2(c) = 1 THEN EXIT WHILE 'strike 3, we're out of here
159.                     b2(c) = 1
160.                 ELSE
161.                     rFlag = 1
162.                     DIM b2(d)
163.                     b$ = b$ + " repeat "
164.                     b2(c) = 1
165.                 END IF
166.             ELSE
167.                 b(c) = 1
168.             END IF
169.  
170.             'c was last remainder, mult by 10 and see if some m * d > can reduce it
171.             tc = 10 * c
172.             flag = 0
173.             FOR m = 0 TO 9
174.                 IF ((tc - m * d) >= 0) AND ((tc - (m + 1) * d) < 0) THEN
175.                     flag = 1: b$ = b$ + LTRIM$(STR$(m))
176.                     EXIT FOR
177.                 END IF
178.             NEXT
179.             IF flag = 0 THEN b$ = b$ + "0": m = 0
180.             c = tc - d * m
181.         WEND
182.     END IF
183.  
184.     'OK either d divided n eventually or there is a repeated pattern recorded in b$
185.     skip: '< needed for debugging
186.     r$ = STR$(a)
187.     IF b$ <> "" THEN r$ = r$ + b$
188.     divide$ = r$
189. END FUNCTION
190.  
191.  
192.  

[bplus]

Thanks for your reply Jack002.

Yeah, I run very same and do get back to 1/62 on last line.

Don't know what our difference is????

[Jack002]

I blame Obama

LOL
[edit]

It fails on this line
 g&& = gcd&&(n1&&, d&&)
I don't follow all the logic here, once you make vd1 and vd2 etc you start to lose me.
Does it matter that the value of vd1 is not an integer? Its 16129032258064.52

[bplus]

VD1 is not an integer until we multiply it and VD2 by adj&&

Here is an example of converting 1/6 in English:

Convert a repeating decimal back to fraction:

1/6 = .16R6  = x

10x = 1.666...   VD1
- x =    .166...   VD2
=============
9x   = 1.5      VD1 - VD2

adj = 10  a multiplier to get rid of decimal

90x = 15 or x = 15 /90

GCD(15, 90) = greatest common denominator of 15 and 90 is 15

15/15 = 1   and 90/15 = 6 so 15/90 = 1/6

x = 1/6

[Jack002]

Ok so vd1 is larger than vd2. You multiply both by adj and take a difference. Won't that number be positive? If so, why is this negative?