Convert Decimal to Fraction

[Jack002]

After some more experimenting I see it also fails for 1/60. GCD is given two numbers, one is negative. It seems to always happen when one or both numbers given GCD are negative
{1/56 also fails for the same reason, both numbers given to GCD are negative}
 

[bplus]

Ok so vd1 is larger than vd2. You multiply both by adj and take a difference. Won't that number be positive? If so, why is this negative?
 

Yes why are your numerator and denominator negative? The only time I see that is when the number exceeds it's TYPE limit.

And why is your adj 1000000 when mine is 10? That might make VD1 and VD2 too big even for _INTEGER64 limit.

So the crux of our difference might begin here with the calculation of adj&&

Code: QB64: [Select]

1.     adj&& = 1 'convert to whole numbers
2.     WHILE n## <> INT(n##)
3.         adj&& = adj&& * 10
4.         n## = n## * 10
5.     WEND
6.  

adj&& is the multiplier needed to get VD1-VD2 (which becomes the numerator of the fraction) into a whole number.

We are using the same code. Is there a version 1.3 difference in handling the variable types?




Has anyone else tried 1/62? What do you get with what version of QB64?


OK I am still getting good results with Jack002 code on an older version of QB64.
 

 

Jack002 are you using 32 bit of even X86 versions of QB64?

[bplus]

After some more experimenting I see it also fails for 1/60. GCD is given two numbers, one is negative. It seems to always happen when one or both numbers given GCD are negative
{1/56 also fails for the same reason, both numbers given to GCD are negative}
 

The 3rd number from left of the 2nd line from bottom adj&& is supposed to be a simple power of 10, eg 10, 100, 1000, 10000...

Code: QB64: [Select]

1.     adj&& = 1 'convert to whole numbers
2.     WHILE n## <> INT(n##)
3.         adj&& = adj&& * 10
4.         n## = n## * 10
5.     WEND

So there is a type limit problem.

[bplus]

1/56 works perfectly:
 

1/60 has a suspiciously high adj&&
 

[Jack002]

The while loop that makes ADJ has issues. I ran this test script and its not seeing it's done?! Hello? McFly!?
I don't know why this is failing. The number and the INT are the same.

Code: QB64: [Select]

1. vd1## = .166
2. vd2## = .016
3.  
4. n## = vd1## - vd2## 'subtract dec2$ from dec1$
5.  
6. PRINT "vd1"; vd1##
7. PRINT "vd2"; vd2##
8. PRINT "n##"; n##
9. SLEEP
10.  
11. adj&& = 1 'convert to whole numbers
12. WHILE n## <> INT(n##)
13.     adj&& = adj&& * 10
14.     PRINT "adj"; adj&&
15.     n## = n## * 10
16.     PRINT "test, is "; n##; " = "; INT(n##); "?"
17.     SLEEP
18. WEND
19.  

I see it keeps going till ADJ is 1.5D+19!!

[Jack002]

I see some kind of rounding error here. I added a difference between n## and int(n##)  and things get funny

Code: QB64: [Select]

1. vd1## = .166
2. vd2## = .016
3.  
4. n## = vd1## - vd2## 'subtract dec2$ from dec1$
5.  
6. PRINT "vd1"; vd1##
7. PRINT "vd2"; vd2##
8. PRINT "n##"; n##
9. SLEEP
10.  
11. adj&& = 1 'convert to whole numbers
12. WHILE n## <> INT(n##)
13.     adj&& = adj&& * 10
14.     PRINT "adj"; adj&&
15.     n## = n## * 10
16.     PRINT "test, is "; n##; " = "; INT(n##); "?"
17.     PRINT n## - INT(n##)
18.     SLEEP
19. WEND
20.  

EDIT

I made two changes to the while loop. Now it seems to work

Code: QB64: [Select]

1.     WHILE (n## - INT(n##)) > 1.0D-15
2.         adj&& = adj&& * 10
3.         n## = n## * 10 + 1.0D+15
4.         PRINT n##; INT(n##); (n## - INT(n##)); adj&&
5.         SLEEP
6.     WEND
7.  

I have to add 1.0D-15 to n## so it won't keep drifting.

[bplus]

Hi Jack002,

Yep! I was convinced something was screwy when I saw the adj&& for 1/60.

Here is another way around adj&& calc:

Code: QB64: [Select]

1.     'adj&& = 1 'convert to whole numbers
2.     'WHILE n## <> INT(n##)
3.     '    adj&& = adj&& * 10
4.     '    n## = n## * 10
5.     'WEND
6.  
7.     ns$ = STR$(n##)
8.     dot = INSTR(ns$, ".")
9.     p2 = LEN(ns$) - dot
10.     adj&& = 10 ^ p2
11.  

I also had to reduce max length of the repeat section below 13 because 1/79 was getting negative numerator and denominator like you were getting, which means the type limit was exceeded.

Modified code:

Code: QB64: [Select]

1. _TITLE "n slash d to R notation and back again" '2019-04-24
2. ' from:"Decimal Expansion of Division without Dividing  by bplus 2017-12-03"
3. ' dove tailing Adrians and my recent dividing programs
4.  
5. ' 2019-04-24
6. ' I want to isolate the repeated section immediately not write the fraction out and then repeat the repeated section
7. ' not 1/6 = .16R6 >>> but .1R6
8.  
9. 'hmm... look like have to cycle through twice to get the length of the repeat section
10. ' but before returning backup to start of repeat section insert the R where it starts the first time
11. ' and end it where " repeat " starts.
12.  
13. '2019-04-24
14. ' just for kicks, convert the R notation back to fraction if possible.
15. ' Had to revert back to the redundant " repeat " form of R notation.
16.  
17. '2019-04-27 Thanks to Jack002's comments and replies this code to calculate adj&& may have been improved.
18.  
19. RANDOMIZE TIMER
20. DEFLNG A-Z
21. DO
22.     PRINT: PRINT "Enter 2 integers < 3200, numerator / denominator, 0's quit, don't forget / "
23.     INPUT nd$
24.     slash = INSTR(nd$, "/")
25.     IF slash THEN
26.         dvsr = VAL(MID$(nd$, slash + 1))
27.         IF dvsr = 0 THEN PRINT "Divisor is 0, bye.": END
28.         numerator = VAL(MID$(nd$, 1, slash - 1))
29.         IF numerator = 0 THEN PRINT "Numerator is 0, bye.": END
30.     ELSE
31.         PRINT "No slash found, bye.": END
32.     END IF
33.     CLS
34.     d$ = divide$(numerator, dvsr)
35.     PRINT numerator; " / "; dvsr; " = "; d$
36.  
37.     'and now arttemp"t to convert back to fraction
38.     PRINT: PRINT "Check if can convert back to fraction:"
39.     result$ = convertRnotation2Fraction$(d$)
40.     IF result$ <> "" THEN PRINT result$
41. LOOP
42.  
43. FUNCTION convertRnotation2Fraction$ (rNotedDecimal$)
44.     'check if R in the decimal
45.     dotPos = INSTR(rNotedDecimal$, ".")
46.     IF dotPos = 0 THEN convertRnotation2Fraction$ = rNotedDecimal$: EXIT FUNCTION
47.     RPos = INSTR(rNotedDecimal$, " repeat ")
48.     IF RPos = 0 THEN convertRnotation2Fraction$ = convert2Fraction$(rNotedDecimal$): EXIT FUNCTION
49.  
50.     'still here? we have an R and a decimal
51.     whole$ = MID$(rNotedDecimal$, 1, dotPos - 1)
52.     IF VAL(whole$) = 0 THEN whole$ = ""
53.  
54.     p = LEN(rNotedDecimal$) - RPos - LEN(" repeat ") + 1
55.     PRINT "Debug: repeat length ="; p
56.     IF p > 12 THEN
57.         PRINT "The length of the repeat section of: "
58.         PRINT rNotedDecimal$
59.         PRINT " is too long to convert back to fraction."
60.         EXIT FUNCTION
61.     END IF
62.  
63.     dec$ = MID$(rNotedDecimal$, dotPos)
64.     PRINT "Debug: converting dec$ "; dec$
65.  
66.     'remove " repeat "
67.     RPos = INSTR(dec$, " repeat ")
68.     dec1$ = MID$(dec$, 1, RPos - 1) + MID$(dec$, RPos + LEN(" repeat "))
69.     dec2$ = MID$(dec$, 1, RPos - 1)
70.     PRINT "Debug: dec1$ (double repeat), dec2$ (single repeat) = "; dec1$; ", "; dec2$
71.  
72.     'mult by 10^p to get the 2nd repeat part in dec1$ aligned to 1st repeat part  in dec2$
73.     vd1## = VAL(dec1$) * 10 ^ p
74.     vd2## = VAL(dec2$)
75.     n## = vd1## - vd2## 'subtract dec2$ from dec1$
76.  
77.     'adj&& = 1 'convert to whole numbers
78.     'WHILE n## <> INT(n##)
79.     '    adj&& = adj&& * 10
80.     '    n## = n## * 10
81.     'WEND
82.  
83.     'calculate adj&& from length of decimal
84.     ns$ = STR$(n##)
85.     dot = INSTR(ns$, ".")
86.     p2 = LEN(ns$) - dot
87.     adj&& = 10 ^ p2
88.  
89.     'reevaluate to avoid rounding errors from crazy floating point math
90.     n1&& = vd1## * adj&& - vd2## * adj&&
91.     PRINT "Debug values: vd1, vd2, adj&&, n1&& (difference * adj&& for whole number):"
92.     PRINT vd1##; ", "; vd2##; ", "; adj&&; ", "; n1&&
93.  
94.     d&& = (10 ^ p - 1) * adj&&
95.     PRINT "Debug: Giant numerator, denominator "; n1&&; ", "; d&& 'giant numbers
96.  
97.     'reduce giant numbers by Gretaest Common Divisor between them
98.     g&& = gcd&&(n1&&, d&&): sn&& = n1&& / g&&: sd&& = d&& / g&&
99.  
100.     convertRnotation2Fraction$ = whole$ + " " + _TRIM$(STR$(sn&&)) + "/" + _TRIM$(STR$(sd&&))
101. END FUNCTION
102.  
103. FUNCTION convert2Fraction$ (decimal$)
104.     dot%% = INSTR(decimal$, ".")
105.     IF dot%% > 0 THEN
106.         whole$ = MID$(decimal$, 1, dot%% - 1)
107.         IF VAL(whole$) = 0 THEN whole$ = ""
108.         p%% = LEN(decimal$) - dot%%
109.         n&& = VAL(MID$(decimal$, dot%% + 1))
110.         d&& = 10 ^ p%%
111.         g&& = gcd&&(n&&, d&&): sn&& = n&& / g&&: sd&& = d&& / g&&
112.         convert2Fraction$ = whole$ + " " + _TRIM$(STR$(sn&&)) + "/" + _TRIM$(STR$(sd&&))
113.     ELSE
114.         convert2Fraction$ = decimal$
115.     END IF
116. END FUNCTION
117.  
118. FUNCTION gcd&& (a&&, b&&)
119.     'a and b will be changed unless make copies
120.     c&& = a&&: d&& = b&&
121.     WHILE c&& <> 0 AND d&& <> 0
122.         IF c&& > d&& THEN c&& = c&& MOD d&& ELSE d&& = d&& MOD c&&
123.     WEND
124.     gcd&& = c&& + d&&
125. END FUNCTION
126.  
127.  
128. FUNCTION divide$ (n, d)
129.     'n = original product or numerator (preserve value of n)
130.     'd = divisor  (also preserve value)
131.     c = n 'copy of n to be reduced until <= d, c will be the remainder part of division
132.     a = 0 'a is for answer or accumulate, the integer part of the division result
133.  
134.     'find lowest power of 10 such that: d * 10^p > n
135.     p = 0 'power of 10
136.     WHILE d * (10 ^ p) < n
137.         p = p + 1
138.     WEND
139.     WHILE c >= d
140.         IF c = d THEN a = a + 1: c = 0: EXIT WHILE
141.         p = p - 1
142.         IF p >= 0 THEN
143.             m = 0
144.             WHILE d * m * 10 ^ p < c
145.                 m = m + 1
146.             WEND
147.             m = m - 1
148.             c = c - d * m * 10 ^ p
149.             a = a + m * 10 ^ p
150.         END IF
151.     WEND
152.  
153.     'Now for the decimal expansion isolating the repeating part if one
154.     IF c <> 0 THEN
155.         DIM b(d)
156.         b$ = "."
157.         WHILE c <> 0
158.  
159.             'emergency bug out!
160.             loopct = loopct + 1 'loop count should not exceed 1000 for numbers I am testing
161.             IF loopct > 1000 THEN PRINT "Error: loop too long, bugging out! ": GOTO skip
162.  
163.             'track repeats  b() tracks been here once, b2() tracks been here twice
164.             IF b(c) = 1 THEN 'been here!
165.                 IF rFlag = 1 THEN 'been here twice!
166.                     IF b2(c) = 1 THEN EXIT WHILE 'strike 3, we're out of here
167.                     b2(c) = 1
168.                 ELSE
169.                     rFlag = 1
170.                     DIM b2(d)
171.                     b$ = b$ + " repeat "
172.                     b2(c) = 1
173.                 END IF
174.             ELSE
175.                 b(c) = 1
176.             END IF
177.  
178.             'c was last remainder, mult by 10 and see if some m * d > can reduce it
179.             tc = 10 * c
180.             flag = 0
181.             FOR m = 0 TO 9
182.                 IF ((tc - m * d) >= 0) AND ((tc - (m + 1) * d) < 0) THEN
183.                     flag = 1: b$ = b$ + LTRIM$(STR$(m))
184.                     EXIT FOR
185.                 END IF
186.             NEXT
187.             IF flag = 0 THEN b$ = b$ + "0": m = 0
188.             c = tc - d * m
189.         WEND
190.     END IF
191.  
192.     'OK either d divided n eventually or there is a repeated pattern recorded in b$
193.     skip: '< needed for debugging
194.     r$ = STR$(a)
195.     IF b$ <> "" THEN r$ = r$ + b$
196.     divide$ = r$
197. END FUNCTION
198.  

[Jack002]

I was proud to hack some kind of solution. I had my doubts. I have written one like your first part that does the dec equivalent, but never thought to make it go back again. Well done (in spite of any problems)

Why do you suppose there is so much rounding error between the versions? This is like the old 8 bit days when you do 1/3 and then * 3 and get this long line of 9s. I know I saw that on the commodore 64.

[bplus]

I was proud to hack some kind of solution. I had my doubts. I have written one like your first part that does the dec equivalent, but never thought to make it go back again. Well done (in spite of any problems)

Why do you suppose there is so much rounding error between the versions? This is like the old 8 bit days when you do 1/3 and then * 3 and get this long line of 9s. I know I saw that on the commodore 64.

Hi Jack002,

I am sorry I missed the experience with a Commodore 64, you have obviously been deeply affected by it. I did have experience with GW BASIC and DOS and loved the way the two worked together, then later VB for DOS and DOS great stuff!

The great difference between our different results of this code, I am still attributing to the possibility you are using a 32 bit version of QB64 or even x86. You have not said X64, x32 or even x86 that your version of QB64 is. If you are using a X64 bit version of QB64 I am completely baffled! LOL wouldn't be first time!

[SMcNeill]

Hi Jack002,

I am sorry I missed the experience with a Commodore 64, you have obviously been deeply affected by it. I did have experience with GW BASIC and DOS and loved the way the two worked together, then later VB for DOS and DOS great stuff!

The great difference between our different results of this code, I am still attributing to the possibility you are using a 32 bit version of QB64 or even x86. You have not said X64, x32 or even x86 that your version of QB64 is. If you are using a X64 bit version of QB64 I am completely baffled! LOL wouldn't be first time!

We’ve seen some drastic differences in the past with how Windows does math with 32-bit and 64-bit code, so I’m guessing that’s probably the difference as well. 

[Jack002]

I am on QB64 1.2, I have a 64 bit computer. Its a Dell latitude running windows 10

If we can't expect every computer to make the same calculations in things like this how can we ever plan to write a program that works for everyone? I'm stumped.

[bplus]

Hi Jack002,

Until version 1.3 all stable versions of QB64 were 32 bit, didn't matter if your computer was 64 bit.

[Jack002]

For fun I put the program I made in QB64 to find what the issue was with getting ADJ in the vice C64 emulator. Similar problems, offsets were bigger.
 

[Pete]

To answer your question, Jack, you would need your program to identify the system it is running on and have algorithms for all possible situations. It's the same PITA that web designers go though these days.

Pete

[Jack002]

Thanks Pete. Looks like I need to get over to v1.3 right away. These rounding issues are making me thirsty. (Seinfeld)