Collision Detection in OpenGL

[Ashish]

Hi everyone!
I have found an easy way to detect collision detection of cursor with object rendered with OpenGL. (https://www.opengl.org/archives/resources/faq/technical/selection.htm)
Move your cursor over the shapes.

Code: QB64: [Select]

1. _TITLE "Move cursor on shape(s)."
2. randomize timer
3. SCREEN _NEWIMAGE(600, 600, 32)
4.  
5. DECLARE LIBRARY 'external function(s)
6.     SUB drawCube ALIAS glutSolidCube (BYVAL dsize AS DOUBLE)
7.         SUB gluPickMatrix (BYVAL x AS SINGLE, BYVAL y AS SINGLE, BYVAL delX AS SINGLE, BYVAL delY AS SINGLE, viewport AS LONG)
8. END DECLARE
9.  
10. type vec3
11.         x as single
12.         y as single
13.         z as single
14. end type
15.  
16. type cube
17.         pos as vec3 'position
18.         col as vec3 'color
19.         rot as vec3 'rotation
20. end type
21.  
22. DIM SHARED mouseX, mouseY, gl, collision, obj_type
23. Dim shared cubes(10) as cube
24. DIM SHARED selectBuffer(4) AS _UNSIGNED LONG, hits&, viewport&(4)
25.  
26. for i = 0 to ubound(cubes)
27.         cubes(i).pos.x = p5random(-1 ,1)
28.         cubes(i).pos.y = p5random(-1, 1)
29.         cubes(i).pos.z = p5random(-0.8,0)
30.         cubes(i).col.x = rnd : cubes(i).col.y = rnd : cubes(i).col.z = rnd
31.         cubes(i).rot.x = p5random(0,360)
32.         cubes(i).rot.y = p5random(0,360)
33.         cubes(i).rot.z = p5random(0,360)
34. next
35.  
36.  
37. gl = -1
38. _GLRENDER _BEHIND
39. DO
40.     WHILE _MOUSEINPUT: WEND
41.     mouseX = _MOUSEX: mouseY = _MOUSEY
42.     _LIMIT 40
43.     CLS , 1
44.     COLOR _RGB(255, 0, 0), 1
45.     IF hits& >= 1 THEN
46.                 collision = selectBuffer(3)
47.                 ? collision, hits&
48.         ELSE
49.                 collision = 0
50.         end if
51. LOOP
52.  
53. SUB _GL ()
54.         static buffer(4) as _unsigned long, tmp
55.  
56.     IF gl = 0 THEN EXIT SUB
57.  
58.  
59.     _glEnable _GL_LIGHTING
60.     _glEnable _GL_LIGHT0
61.     _glEnable _GL_DEPTH_TEST
62.     _glEnable _GL_COLOR_MATERIAL
63.  
64.     _glLightfv _GL_LIGHT0, _GL_AMBIENT, glVec4(0.1, 0.1, 0.1, 0)
65.     _glLightfv _GL_LIGHT0, _GL_SPECULAR, glVec4(0.8, 0.8, 0.8, 0)
66.     _glLightfv _GL_LIGHT0, _GL_POSITION, glVec4(1, 1, 0, 0)
67.  
68.  
69.     _glGetIntegerv _GL_VIEWPORT, _OFFSET(viewport&())
70.  
71.     _glSelectBuffer 4, _OFFSET(buffer())
72.     dummy = _glRenderMode(_GL_SELECT)
73.     _glInitNames
74.     _glPushName 0
75.  
76.     _glMatrixMode _GL_PROJECTION
77.     _glLoadIdentity
78.  
79.         _glPushMatrix
80.  
81.     gluPickMatrix mouseX, _HEIGHT - mouseY, 1,1, viewport&()
82.  
83.         for i = 0 to ubound(cubes)
84.                 _glLoadName (i+1)
85.                 _glPushMatrix
86.                 _glcolor3f cubes(i).col.x,cubes(i).col.y,cubes(i).col.z
87.                 _glrotatef cubes(i).rot.x+tmp,1,0,0
88.                 _glrotatef cubes(i).rot.y+tmp,0,1,0
89.                 _glrotatef cubes(i).rot.z,0,0,1
90.                 _gltranslatef cubes(i).pos.x,cubes(i).pos.y,cubes(i).pos.z
91.                 drawCube 0.22
92.                 _glPopMatrix
93.         next
94.  
95.         _glPopMatrix
96.  
97.     hits& = _glRenderMode(_GL_RENDER)
98.         selectBuffer(3) = buffer(3)
99.  
100.     _glMatrixMode _GL_MODELVIEW
101.        
102.         for i = 0 to ubound(cubes)
103.                 _glPushMatrix
104.                 if collision = (i+1) then _glColor3f 1,0.5,0 else _glcolor3f cubes(i).col.x,cubes(i).col.y,cubes(i).col.z
105.                 _glrotatef cubes(i).rot.x+tmp,1,0,0
106.                 _glrotatef cubes(i).rot.y+tmp,0,1,0
107.                 _glrotatef cubes(i).rot.z,0,0,1
108.                 _gltranslatef cubes(i).pos.x,cubes(i).pos.y,cubes(i).pos.z
109.                 drawCube 0.22
110.                 _glPopMatrix
111.         next
112.        
113.     _glFlush
114.    
115.         tmp=tmp+1
116. END SUB
117.  
118. FUNCTION p5random! (mn!, mx!)
119.     IF mn! > mx! THEN
120.         SWAP mn!, mx!
121.     END IF
122.     p5random! = RND * (mx! - mn!) + mn!
123. END FUNCTION
124.  
125. FUNCTION glVec4%& (x, y, z, w)
126.     STATIC internal_vec4(3)
127.     internal_vec4(0) = x
128.     internal_vec4(1) = y
129.     internal_vec4(2) = z
130.     internal_vec4(3) = w
131.     glVec4%& = _OFFSET(internal_vec4())
132. END FUNCTION
133.  

[Petr]

This is a very useful matter. Thank you for sharing, Ashish.

[Ashish]

This is a very useful matter. Thank you for sharing, Ashish.

Thanks Petr! But remember, when I include gluPerspective() with rendering, it doesn't work. This subject need to be studied more.

[Petr]

Thanks Petr! But remember, when I include gluPerspective() with rendering, it doesn't work. This subject need to be studied more.

I'm sure I'll get to it soon. So far, I have been solving collision detection in a Maze program using a two-dimensional array (X/Z) and it works perfectly and quickly, but of course it's not an
OpenGL version.