Visualizing _PI challenge

[FellippeHeitor]

Anyone would be willing to take on the challenge to recreate this or even reinvent it? https://www.reddit.com/r/dataisbeautiful/comments/b13h1d/adding_to_the_pi_visualizations_oc/

[bplus]

Hi Fellippe,

Is there some sort of calculation of Pi going on or is this just bouncing from digit to digit of a Pi expansion?

Repeating digits could use a little loop, internal or external.

[Qwerkey]

... And when you have taken up this challenge, unless you produce pi to more than 31 trillion digits, we shall think that you have hardly tried at all.  (To any mathematicians out there, why do mathematicians do that sort of thing and who knows if they're correct?).

[Petr]

It looks interesting. To calculate pi, we could use the formula π = 2 x (2 x 2 x 4 x 4 x 6 x 6 ...) / (1 x 3 x 3 x 5 x 5 x 7 ...)
but a sample example uses only a few decimal places to visualize ...

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(800, 600, 32)
2.  
3. TYPE nrs
4.     x AS INTEGER
5.     y AS INTEGER
6. END TYPE
7. DIM N(10) AS nrs
8.  
9. CONST CX = 400
10. CONST CY = 300
11. pi$ = "3.141592653589793238462643383279502884197169399375105820974944592307816406286208998628034825342117067982148086513282306647093844609550582231725359408128481117450284102701938521105559644622948954930381964428810975665933446128475648233786783165271201909145648566923460348610454326648213393607260249141273"
12.  
13. FOR p = -60 TO 264 STEP 36
14.     q = _D2R(p)
15.     N(w).x = CX + COS(q) * 150
16.     N(w).y = CY + SIN(q) * 150
17.     w = w + 1
18.     CIRCLE (CX + COS(q) * 150, CY + SIN(q) * 150), 3
19.     _PRINTSTRING (CX + COS(q) * 170, CY + SIN(q) * 170), _TRIM$(STR$(num))
20.     num = num + 1
21. NEXT
22.  
23. CIRCLE (400, 300), 150
24.  
25. FOR sh = 1 TO LEN(pi$)
26.     IF ASC(pi$, sh) >= 48 AND ASC(pi$, sh) <= 57 THEN
27.         v$ = MID$(pi$, sh, 1)
28.         LINE (ox, oy)-(ox2, oy2), _RGB32(127, 127, 127)
29.          i = ASC(pi$, sh) - 48
30.         LOCATE 1, 1: PRINT MID$(pi$, 1, sh)
31.         ox = N(oldN).x: oy = N(oldN).y: ox2 = N(i).x: oy2 = N(i).y
32.         LINE (N(oldN).x, N(oldN).y)-(N(i).x, N(i).y), _RGB32(255, 255, 255): oldN = i
33.         oldN = i
34.         _DELAY .2
35.     END IF
36. NEXT sh
37.  

[Petr]

There is one more way - the infinite division using MOD, but the fraction 22/7 is inaccurate, because there is a wrong result in the third decimal place. Another fraction is 355/113, but there will also be an error in the seventh decimal place.

[FellippeHeitor]

Wow, that was fast, Petr. Good job!

@bplus
I don't know if they're calculating as they go or if it's just fetching from a precalculated list of digits. I just liked the visualization very much when I fist came across it.

@Qwerkey
It's indeed silly to try to break any supercomputer's record in findind the next digits of pi... Maybe mathematicians just wanna have fun in the end too (and measure dick).

I'm looking to take part in the challenge myself. I'll keep this thread as a post-it reminder for me to do it eventually.

[Petr]

Thank you Fellippe, it was a welcome change, such a rebound from the 3D maze editor that I am writing.

[jack]

I think the Spigot algorithm would be perfect for this https://rosettacode.org/wiki/Pi

[Pete]

I haven't figured out how far my string math routines would go, I just know if it was accurate and infinite, it would take about 40 years to surpass the record pi calculation to date, of 31.4 trillion digits. Anyone know where I can find a computer that will last 40 years, without a %^&^$# Windows update?

Pete

[bplus]

Hey Petr, nice and fast.

I had basic scheme worked out when I saw you had already posted. So I better have some better features!

I do. :)

This draws an outer loop around digit when digit repeats sequentially (you have to wait awhile for 7), plus it has the pointer moving between points...

Code: QB64: [Select]

1. _TITLE "Visualizing Pi" 'B+ 2019-03-15
2.  
3. 'Featuring a circle loop around the a repeated digit.
4. ' 3 first, 8, 9, 4, 1, 6, 2, 5, 0 (300+ digits), 7 (560 digits) EDIT
5.  
6. 'ref  http://www.math.com/tables/constants/pi.htm  First 100 digits
7. CONST pi100 = "3141592653589793238462643383279502884197169399375105820974944592307816406286208998628034825342117067"
8. 'ref same as above 1000 digits, see if can circle all digits pi shortened to 560 digits
9. CONST pi = "314159265358979323846264338327950288419716939937510582097494459230781640628620899862803482534211706798214808651328230664709384460955058223172535940812848111745028410270193852110555964462294895493038196442881097566593344612847564823378678316527120190914564856692346034861045432664821339360726024914127372458700660631558817488152092096282925409171536436789259036001133053054882046652138414695194151160943305727036575959195309218611738193261179310511854807446237996274956735188575272489122793818301194912983367336244065664308602139494639522473719070217986094370277"
10. 'PRINT INSTR(pi, "77") ' last number to get circled for repeating at 560
11.  
12. CONST xmax = 800
13. CONST ymax = 720
14. CONST x0 = 400
15. CONST y0 = 420
16. CONST radius = 240
17. CONST r2 = 20
18.  
19. TYPE vectorType
20.     x AS SINGLE
21.     y AS SINGLE
22. END TYPE
23.  
24. SCREEN _NEWIMAGE(xmax, ymax, 32)
25. _SCREENMOVE 300, 20
26. s2& = _NEWIMAGE(xmax, ymax, 32) 'to update drawing lines in isolation
27. t = TIMER(.001)
28. ca = _PI(2 / 10)
29. DIM vdigit(0 TO 9) AS vectorType
30. DIM outer(0 TO 9) AS vectorType
31. CIRCLE (x0, y0), radius
32. FOR i = 0 TO 9
33.     vdigit(i).x = x0 + radius * COS(ca * i - 2 * ca)
34.     vdigit(i).y = y0 + radius * SIN(ca * i - 2 * ca)
35.     CIRCLE (vdigit(i).x, vdigit(i).y), 2
36.     x = x0 + (radius + 18) * COS(ca * i - 2 * ca) - 2
37.     y = y0 + (radius + 18) * SIN(ca * i - 2 * ca) - 6
38.     _PRINTSTRING (x, y), LTRIM$(STR$(i))
39.     outer(i).x = x0 + (radius + r2) * COS(ca * i - 2 * ca)
40.     outer(i).y = y0 + (radius + r2) * SIN(ca * i - 2 * ca)
41. NEXT
42. _PUTIMAGE , 0, s2&
43.  
44. digitPointer = 1
45. cx = x0: cy = y0: speed = 10
46. WHILE digitPointer <= LEN(pi)
47.     d = VAL(MID$(pi, digitPointer, 1))
48.     targetx = vdigit(d).x: targety = vdigit(d).y
49.     targetangle = _ATAN2(targety - cy, targetx - cx)
50.     rc~& = _RGB32(255 * RND, 255 * RND, 255 * RND)
51.     IF lastd = d THEN
52.         _DEST s2&
53.         CIRCLE (outer(d).x, outer(d).y), r2, rc~&
54.         _DEST 0
55.         CLS
56.         _PUTIMAGE , s2&, 0
57.         CIRCLE (cx, cy), 2, &HFFFFFFFF, BF
58.         LOCATE 1, 1: PRINT MID$(pi, 1, digitPointer - 1)
59.         _DISPLAY
60.     ELSE
61.         DO
62.             dist = SQR((targetx - cx) ^ 2 + (targety - cy) ^ 2)
63.             IF dist < speed THEN
64.                 newX = targetx
65.                 newY = targety
66.             ELSE
67.                 newX = cx + speed * COS(targetangle)
68.                 newY = cy + speed * SIN(targetangle)
69.             END IF
70.             _DEST s2&
71.             LINE (cx, cy)-(newX, newY), rc~&
72.             _DEST 0
73.             CLS
74.             _PUTIMAGE , s2&, 0
75.             CIRCLE (newX, newY), 2, &HFFFFFFFF, BF
76.             cx = newX: cy = newY
77.             LOCATE 1, 1: PRINT MID$(pi, 1, digitPointer - 1)
78.             _DISPLAY
79.             _LIMIT 60
80.         LOOP UNTIL cx = targetx AND cy = targety
81.     END IF
82.     digitPointer = digitPointer + 1
83.     lastd = d
84. WEND
85. LOCATE 1, 1: PRINT MID$(pi, 1, digitPointer)
86. PRINT TIMER(.001) - t; " secs"
87. _DISPLAY
88.  

[Petr]

Hi BPlus!  It's very nice. I even discovered the BF parameter for Circle with your program, I haven't seen it yet. Motion in circle is also very interesting.

[bplus]

Hi BPlus!  It's very nice. I even discovered the BF parameter for Circle with your program, I haven't seen it yet. Motion in circle is also very interesting.

HA! Twice!

Code: QB64: [Select]

1. CIRCLE (cx, cy), 2, &HFFFFFFFF, BF  
2.  

I started with a line for a solid pointer, forgot to erase that BF!

[Petr]

I started with a line for a solid pointer, forgot to erase that BF!

Really? I thought I discovered something new! :-D

[jack]

hello bplus
here's spigot sub for you

Code: QB64: [Select]

1. DIM pi(100) AS _BYTE
2. DIM i AS LONG
3. spigot pi()
4.  
5. PRINT LTRIM$(STR$(pi(1))); ".";
6. FOR i = 2 TO UBOUND(pi)
7.     PRINT LTRIM$(STR$(pi(i)));
8. NEXT
9. PRINT
10. END
11.  
12. SUB spigot (pi() AS _BYTE)
13.     DIM N AS LONG
14.     N = UBOUND(pi)
15.     DIM ln AS LONG
16.     ln = INT((10 * N) / 3) + 1
17.     DIM A(0 TO ln - 1) AS LONG
18.     DIM npi AS LONG
19.     DIM i AS LONG, j AS LONG, k AS LONG
20.     npi = 0
21.     FOR i = 0 TO ln - 1
22.         A(i) = 2
23.     NEXT
24.  
25.     DIM nines AS LONG
26.     DIM predigit AS LONG
27.     nines = 0
28.     predigit = 0
29.     FOR j = 1 TO N
30.         DIM q AS LONG
31.         q = 0
32.         FOR i = ln TO 1 STEP -1
33.             DIM x AS LONG
34.             x = (10 * A((i - 1))) + (q * i)
35.             A((i - 1)) = x MOD ((2 * i) - 1)
36.             q = x \ ((2 * i) - 1)
37.         NEXT
38.         A(0) = q MOD 10
39.         q = q \ 10
40.  
41.         IF 9 = q THEN
42.             nines = nines + 1
43.         ELSEIF 10 = q THEN
44.             pi(npi) = predigit + 1: npi = npi + 1
45.             FOR k = 0 TO nines - 1
46.                 pi(npi) = 0: npi = npi + 1
47.             NEXT
48.             predigit = 0
49.             nines = 0
50.         ELSE
51.             pi(npi) = predigit: npi = npi + 1
52.             predigit = q
53.  
54.             IF 0 <> nines THEN
55.                 FOR k = 0 TO nines - 1
56.                     pi(npi) = 9: npi = npi + 1
57.                 NEXT
58.                 nines = 0
59.             END IF
60.         END IF
61.     NEXT
62.     pi(npi) = predigit
63. END SUB
64.  

[bplus]

Thanks Jack I will check it out.

Update: That compares very well with the reference Pi I was using. I used the following code as a check:

Code: QB64: [Select]

1. 'from Jack 2019-03-15 QB64 forum "Visualizing Pi" B+ mod to check Pi with reference Pi.
2. _TITLE "Compare Spigot to Pi Ref digit by digit"
3. SCREEN _NEWIMAGE(600, 720, 32)
4. _SCREENMOVE 300, 20
5. CONST piRef = "314159265358979323846264338327950288419716939937510582097494459230781640628620899862803482534211706798214808651328230664709384460955058223172535940812848111745028410270193852110555964462294895493038196442881097566593344612847564823378678316527120190914564856692346034861045432664821339360726024914127372458700660631558817488152092096282925409171536436789259036001133053054882046652138414695194151160943305727036575959195309218611738193261179310511854807446237996274956735188575272489122793818301194912983367336244065664308602139494639522473719070217986094370277"
6. DIM pi%(561)
7. spigot pi%()
8.  
9. FOR i = 1 TO UBOUND(pi%)
10.     PRINT i; " digit spigot vrs ref "; pi%(i); " vrs "; MID$(piRef, i, 1)
11.     IF i MOD 30 = 29 THEN
12.         INPUT "OK, press enter "; wate$
13.         CLS
14.     END IF
15. NEXT
16. END
17.  
18. SUB spigot (pi%())
19.     DIM N%
20.     N% = UBOUND(pi%)
21.     DIM ln AS LONG
22.     ln = INT((10 * N%) / 3) + 1
23.     DIM A(0 TO ln - 1) AS LONG
24.     DIM npi AS LONG
25.     DIM i AS INTEGER, j AS INTEGER, k AS INTEGER
26.     npi = 0
27.     FOR i = 0 TO ln - 1
28.         A(i) = 2
29.     NEXT
30.  
31.     DIM nines AS LONG
32.     DIM predigit AS LONG
33.     nines = 0
34.     predigit = 0
35.     FOR j = 1 TO N%
36.         DIM q AS LONG
37.         q = 0
38.         FOR i = ln TO 1 STEP -1
39.             DIM x AS LONG
40.             x = (10 * A((i - 1))) + (q * i)
41.             A((i - 1)) = x MOD ((2 * i) - 1)
42.             q = x \ ((2 * i) - 1)
43.         NEXT
44.         A(0) = q MOD 10
45.         q = q \ 10
46.  
47.         IF 9 = q THEN
48.             nines = nines + 1
49.         ELSEIF 10 = q THEN
50.             pi%(npi) = predigit + 1: npi = npi + 1
51.             FOR k = 0 TO nines - 1
52.                 pi%(npi) = 0: npi = npi + 1
53.             NEXT
54.             predigit = 0
55.             nines = 0
56.         ELSE
57.             pi%(npi) = predigit: npi = npi + 1
58.             predigit = q
59.  
60.             IF 0 <> nines THEN
61.                 FOR k = 0 TO nines - 1
62.                     pi%(npi) = 9: npi = npi + 1
63.                 NEXT
64.                 nines = 0
65.             END IF
66.         END IF
67.     NEXT
68.     pi%(npi) = predigit
69. END SUB
70.  
71.