Author Topic: Incorrect Array type passed to function error (Read 3259 times)

Cobalt · « **on:** March 06, 2019, 07:46:12 pm »

Ok I've stared at this code for about the last 15 mins and even tried changing the setting up of the arrays but the error persists. Can anyone else figure out why this is saying I'm trying to pass the wrong type of array to my function?

The Error is on line 71(and probably 73,75,77 as they all use the same array elements)

Code: QB64: [Select]

TYPE Game_Data
 Allow_Reverse AS _BYTE
 Level AS _BYTE
 Button AS INTEGER
 MouseX AS INTEGER
 MouseY AS INTEGER
END TYPE
 
CONST TRUE = -1, FALSE = NOT TRUE, DOWN = 1, UP = 2
CONST Total_Words = 30
CONST Words_to_Find = 5
 
DIM G AS Game_Data
DIM Columns(10) AS _BYTE
DIM Grid(80, 60) AS STRING * 1
DIM GridColor(80, 60) AS _UNSIGNED LONG
DIM WordList(Total_Words) AS STRING
DIM Words(Words_to_Find) AS STRING
DIM WordStart(Words_to_Find) AS _BYTE
DIM WordStop(Words_to_Find) AS _BYTE
DIM WordMethod(Words_to_Find) AS _BYTE
 
Columndata:
DATA 16,18,20,24,26
 
WordsList:
DATA BASIC,APPLE,PEACH,COMPUTER,TRICYCLE
DATA TORNADO,GARBAGE,SUNSHINE,PRETTY,MEDIA
DATA EXPERIMENT,TECHNIQUE,CHALLENGE,ACTIVE,SPEECH
DATA TRADITION,COFFEE,MEMORY,STANDING,ORANGE
DATA DRAMA,FOUNDATION,LISTEN,NATURAL,WATER
DATA SUPPORT,TYRANNY,DINOSAUR,COBRA,PUPPY
 
'Empty the grid field
FOR r%% = 1 TO 60
 FOR c%% = 1 TO 80
  Grid(c%%, r%%) = ""
  GridColor(c%%, r%%) = _RGB32(6, 6, 6)
 NEXT c%%
NEXT r%%
 
'load the word list
FOR i%% = 1 TO Total_Words
 READ WordList(i%%)
NEXT i%%
 
'Pick words for current Game
FOR i%% = 1 TO Words_to_Find
 DO
  w%% = INT(RND * Total_Words) + 1
  IF WordList(w%%) <> "" THEN Is_Good = TRUE ELSE Is_Good = FALSE
 LOOP UNTIL Is_Good
 
 'now Place word in current list
 SWAP Words(i%%), WordList(w%%)
NEXT i%%
 
'---------Lets find a place for each word--------
FOR i%% = 1 TO Words_to_Find
 DO
  '----Find a Place to start word----
  DO
   col%% = INT(RND * Columns(G.Level)) + 1
   row%% = INT(RND * (Columns(G.Level) \ 2)) + 1
   IF Grid(col%%, row%%) = "" THEN Is_Good%% = TRUE ELSE Is_Good%% = FALSE
  LOOP UNTIL Is_Good%%
  '----------------------------------
  '---------Try to Place word--------
  SELECT CASE INT(RND * 4) + 1
   CASE 1
   It_Works%%=Horz_fit(Grid(),Words(),Col%%,Row%%,I%%,Columns(G.level),G.Allow_Reverse)
  case 2
   It_Works%%=Vert_fit(Grid(),Words(),Col%%,Row%%,I%%,Columns(G.level)/2,G.Allow_Reverse)
  case 3
   It_Works%%=Diag_fit(Grid(),Words(),Col%%,Row%%,I%%,Columns(G.level),G.Allow_Reverse,DOWN)
  case 4
   It_Works%%=Diag_fit(Grid(),Words(),Col%%,Row%%,I%%,Columns(G.level),G.Allow_Reverse,UP)
 end select
'----------------------------------
 Loop until It_Works%%
Next i%%
'------------------------------------------------
 
'-Fill in rest of the space with random letters--
FOR row%% = 1 TO Columns(g.level)/2
 FOR col%% = 1 TO columns(g.level)
  IF Grid(col%%, row%%) = "" THEN
   Grid(col%%, row%%) = CHR$(64 + INT(RND * 26) + 1)
  END IF
 NEXT Col%%
NEXT Row%%
'------------------------------------------------
'display the grid!
line(0,0)-step(639,479),_RGB32(255,223,79),bf
PrintGrid Columns(G.level)
 
 
 
 
 
 
 
 
 
Sub PrintGrid(CC%%)
'CC%%-- Column count (Passed as Columns(G.Level))
 Locate 1, 1
 FOR Row%% = 1 TO CC%%/2
  FOR Col%% = 1 TO CC%%
   COLOR _RGB32(GridColor(col%%, row%%))
   PRINT Grid(col%%, row%%);
  NEXT Col%%
  PRINT
 NEXT Row%%
End Sub
 
Function Horz_Fit(WG$(),WA$(),Col%%,Row%%,CW%%,CC%%,AR%%)
'WG$()- Word Grid array
'WA$()- Word array
'Col%%- Column of Word Grid
'Row%%- Row of Word Grid
'CW%%-- Current Word array element
'CC%%-- Column count (Passed as Columns(G.Level))
'AR%%-- Allow Reversed word flag(passed as G.Allow_Reverse)
 
'see if the word will even fit here
 WordLength%%=len(WA$(cw%%))
 LeftLength%%=CC%%-col%%
 
 if WordLenght%%<=LeftLength%% then
 'if the word fits
  if AR%% and Int(Rnd*100)>49 then
  'see if the letters work backwards
   for i%%=0 to WordLength%%-1
    if WG$(col%%+i%%,row%%)<>"" and WG$(col%%+i%%,row%%)<>mid$(WA$(cw%%),WordLength%%-i%%,1) then Failed_Reverse%%=True:I%%=WordLength%%+1:Result%%=FALSE else Failed_Reverse%%=false
   next i%%
 
   if NOT failed_reverse%% then 
   'the word will work, write it to grid
    Result%%=TRUE 'function will return success
    for i%%=0 to WordLength%%-1
     wg$(col%%+i%%,row%%)=mid$(Wa$(CW),wordlength%%-i%%,1)
    next i%%
   end if
  else
   Failed_reverse%%=true 'set due to not using reverse
  end if
 
  if Failed_Reverse%% then 'try going forward
   for i%%=0 to wordlength%%-1
    if wg$(col%%+i%%,row%%)<>"" and wg$(col%%+i%%,row%%)<>mid$(wa$(cw%%),i%%+1,1) then result%%=FALSE:I%%=Wordlength%%+1 else Result%%=true
   next i%%
 
   if result%%=true then
    FOR i%% = 0 TO wLen - 1
    wG$(col%% + i%%, row%%) = MID$(wa$(cw), i%% + 1, 1)
    next i%%
   end if
 end if
 Horz_Fit=result%%
end Function
 
Function Vert_Fit(WG$(),WA$(),Col%%,Row%%,CW%%,RC%%,AR%%)
'WG$()- Word Grid array
'WA$()- Word array
'Col%%- Column of Word Grid
'Row%%- Row of Word Grid
'CW%%-- Current Word array element
'RC%%-- Row count (Passed as Columns(G.Level)/2)
'AR%%-- Allow Reversed word flag(passed as G.Allow_Reverse)
 
'see if the word will even fit here
 WordLength%%=len(WA$(cw%%))
 LeftLength%%=RC%%-Row%%
 
 if WordLenght%%<=LeftLength%% then
 'if the word fits
  if AR%% and Int(Rnd*100)>49 then
  'see if the letters work backwards
   for i%%=0 to WordLength%%-1
    if WG$(col%%,row%%+i%%)<>"" and WG$(col%%,row%%+i%%)<>mid$(WA$(cw%%),WordLength%%-i%%,1) then Failed_Reverse%%=True:I%%=WordLength%%+1:Result%%=FALSE else Failed_Reverse%%=false
   next i%%
 
   if NOT failed_reverse%% then 
   'the word will work, write it to grid
    Result%%=TRUE 'function will return success
    for i%%=0 to WordLength%%-1
     wg$(col%%,row%%+i%%)=mid$(Wa$(CW),wordlength%%-i%%,1)
    next i%%
   end if
  else
   Failed_reverse%%=true 'set due to not using reverse
  end if
 
  if Failed_Reverse%% then 'try going forward
   for i%%=0 to wordlength%%-1
    if wg$(col%%,row%%+i%%)<>"" and wg$(col%%,row%%+i%%)<>mid$(wa$(cw%%),i%%+1,1) then result%%=FALSE:I%%=Wordlength%%+1 else Result%%=true
   next i%%
 
   if result%%=true then
    FOR i%% = 0 TO wLen - 1
    wG$(col%%, row%%+i%%) = MID$(wa$(cw), i%% + 1, 1)
    next i%%
   end if
 end if
 Vert_Fit=result%%
end Function
 
Function Diag_Fit(WG$(),WA$(),Col%%,Row%%,CW%%,CC%%,AR%%,D%%)
'WG$()- Word Grid array
'WA$()- Word array
'Col%%- Column of Word Grid
'Row%%- Row of Word Grid
'CW%%-- Current Word array element
'CC%%-- Column count (Passed as Columns(G.Level))
'AR%%-- Allow Reversed word flag(passed as G.Allow_Reverse)
'D%%--- Direction Flag(1-Down,2-Up)
 
 WordLength%%=len(WA$(cw%%))
 
Select case D%%
 case 1'Diagonal Down
 'see if the word will even fit here
  HorzLeftLen%%=CC%%-col%%
  VertLeftLen%%=CC%%/2-row%%
  If VertLeftLen%%>HorzLeftLen%% then LeftLength%%=HorzLeftLen%% else LeftLength%%=VertLeftLen%%
 
  if WordLenght%%<=LeftLength%% then
  'if the word fits
   if AR%% and Int(Rnd*100)>49 then
   'see if the letters work backwards
    for i%%=0 to WordLength%%-1
     if WG$(col%%+i%%,row%%+i%%)<>"" and WG$(col%%+i%%,row%%+i%%)<>mid$(WA$(cw%%),WordLength%%-i%%,1) then Failed_Reverse%%=True:I%%=WordLength%%+1:Result%%=FALSE else Failed_Reverse%%=false
    next i%%
 
    if NOT failed_reverse%% then 
    'the word will work, write it to grid
     Result%%=TRUE 'function will return success
     for i%%=0 to WordLength%%-1
      wg$(col%%+i%%,row%%+I%%)=mid$(Wa$(CW),wordlength%%-i%%,1)
     next i%%
    end if
   else
    Failed_reverse%%=true 'set due to not using reverse
   end if
 
   if Failed_Reverse%% then 'try going forward
    for i%%=0 to wordlength%%-1
     if wg$(col%%+i%%,row%%+1)<>"" and wg$(col%%+i%%,row%%+1)<>mid$(wa$(cw%%),i%%+1,1) then result%%=FALSE:I%%=Wordlength%%+1 else Result%%=true
    next i%%
 
    if result%%=true then
     FOR i%% = 0 TO wLen - 1
     wG$(col%% + i%%, row%%+1) = MID$(wa$(cw), i%% + 1, 1)
     next i%%
    end if
  end if
 case 2'Diagonal Up
 'see if the word will even fit here
  HorzLeftLen%%=CC%%-col%%
  VertLeftLen%%=row%%
  If VertLeftLen%%>HorzLeftLen%% then LeftLength%%=HorzLeftLen%% else LeftLength%%=VertLeftLen%%
 
  if WordLenght%%<=LeftLength%% then
  'if the word fits
   if AR%% and Int(Rnd*100)>49 then
   'see if the letters work backwards
    for i%%=0 to WordLength%%-1
     if WG$(col%%+i%%,row%%-i%%)<>"" and WG$(col%%+i%%,row%%-i%%)<>mid$(WA$(cw%%),WordLength%%-i%%,1) then Failed_Reverse%%=True:I%%=WordLength%%+1:Result%%=FALSE else Failed_Reverse%%=false
    next i%%
 
    if NOT failed_reverse%% then 
    'the word will work, write it to grid
     Result%%=TRUE 'function will return success
     for i%%=0 to WordLength%%-1
      wg$(col%%+i%%,row%%-I%%)=mid$(Wa$(CW),wordlength%%-i%%,1)
     next i%%
    end if
   else
    Failed_reverse%%=true 'set due to not using reverse
   end if
 
   if Failed_Reverse%% then 'try going forward
    for i%%=0 to wordlength%%-1
     if wg$(col%%+i%%,row%%-1)<>"" and wg$(col%%+i%%,row%%-1)<>mid$(wa$(cw%%),i%%+1,1) then result%%=FALSE:I%%=Wordlength%%+1 else Result%%=true
    next i%%
 
    if result%%=true then
     FOR i%% = 0 TO wLen - 1
     wG$(col%% + i%%, row%%-1) = MID$(wa$(cw), i%% + 1, 1)
     next i%%
    end if
  end if
 
 end select
 Diag_Fit=result%%
end Function
 

The two arrays I am passing are both setup as strings and the Function is expecting 2 string arrays. But I must have something wrong.

bplus · « **Reply #1 on:** March 06, 2019, 08:14:59 pm »

The error line disappears when I do this

Code: QB64: [Select]

'DIM Grid(80, 60) AS STRING * 1 
DIM Grid(80, 60) AS STRING ' * 1 
 

but then another error pops up down the line.

So a fixed string array is different than variable length string array.

bplus · « **Reply #2 on:** March 07, 2019, 09:25:35 am »

Here is stripped down version of problem:

Code: QB64: [Select]

DIM fs(10) AS STRING * 1 'line 13 is fixed by commenting out * 1 on this line
DIM vs(10) AS STRING
FOR i = 0 TO 10
    fs(i) = MID$("cobaltbblue", i + 1, 1)
    vs(i) = MID$("cobaltbblue", i + 1, 1)
NEXT
 
'OK
PRINT sPlus1$(vs(0))
PRINT sPlus1$(fs(0))
 
PRINT sPlus2$(vs(), 0)
PRINT sPlus2$(fs(), 0)
 
 
'this works
FUNCTION sPlus1$ (s$)
    sPlus1$ = CHR$(ASC(s$) + 1)  'EDIT this line
END FUNCTION
 
FUNCTION sPlus2$ (s() AS STRING, index)
    sPlus2$ = CHR$(ASC(s(index)) + 1)
END FUNCTION
 

Except for fixed record lengths and binary access of file info, are fixed strings needed for anything else?

Append: Oh yeah, if you want to use a string in a type definition but that was sort of fixed...

Dimster · « **Reply #3 on:** March 07, 2019, 10:48:15 am »

Hi Cobalt - are you working with the text Screen 0 ?

Cobalt · « **Reply #4 on:** March 07, 2019, 12:50:32 pm »

Quote from: Dimster on March 07, 2019, 10:48:15 am

Hi Cobalt - are you working with the text Screen 0 ?

Haven't decided. It will depend on just which way I find the Puzzle displays best.

Dimster · « **Reply #5 on:** March 07, 2019, 02:08:44 pm »

OK Thanks, reason I asked was the line

Dim Grid (80,60) as string * 1

Screen 0 would have them reversed no?

Cobalt · « **Reply #6 on:** March 07, 2019, 08:05:44 pm »

Quote from: Dimster on March 07, 2019, 02:08:44 pm

OK Thanks, reason I asked was the line

Dim Grid (80,60) as string * 1

Screen 0 would have them reversed no?

No, Screen 0 is 80 wide(COL) and (normally) 25 tall(ROW). Now Locate would be reversed; LOCATE ROW, COL

News:

Author Topic: Incorrect Array type passed to function error (Read 3259 times)

Cobalt

Incorrect Array type passed to function error

bplus

Re: Incorrect Array type passed to function error

bplus

Re: Incorrect Array type passed to function error

Dimster

Re: Incorrect Array type passed to function error

Cobalt

Re: Incorrect Array type passed to function error

Dimster

Re: Incorrect Array type passed to function error

Cobalt

Re: Incorrect Array type passed to function error